Makefile.PL

   1 # Copyright 2007 MJ Ray
   2 #
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along with
  15 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  16 # Suite 330, Boston, MA  02111-1307 USA
  17 #
  18 # Current maintainer MJR http://mjr.towers.org.uk/
  19 # See http://www.koha.org/wiki/?page=KohaInstaller
  20 #
  21
  22 use strict;
  23 use warnings;
  24 use ExtUtils::MakeMaker;
  25 use POSIX;
  26 use File::Spec;
  27
  28 my $DEBUG = 0;
  29 die "perl 5.6.1 or later required" unless ($] >= 5.006001);
  30
  31 # Hash up directory structure & files beginning with the directory we were called from (should be the base of koha)...
  32
  33 my $dirtree = hashdir('.');
  34 my %result = ();
  35
  36 =head1 NAME
  37
  38 Makefile.PL - Koha packager and installer
  39
  40 =head1 SYNOPSIS
  41
  42 =head2 BASIC INSTALLATION
  43
  44         perl Makefile.PL
  45         make
  46         sudo make install
  47
  48 =head2 PACKAGING RELEASE TARBALLS
  49
  50         make manifest tardist
  51         make manifest zipdist
  52
  53 =head2 CLEANING UP
  54
  55         make clean
  56
  57 =head1 DESCRIPTION
  58
  59 This is a packager and installer that uses
  60 ExtUtils::MakeMaker, which is fairly common
  61 on perl systems.
  62 As well as building tar or zip files
  63 and installing with the above commands,
  64 it allows us to check pre-requisites
  65 and generate configuration files.
  66
  67 =head1 VARIABLES
  68
  69 =head2 NAME, VERSION_FROM, ABSTRACT, AUTHOR
  70
  71 Basic metadata about this software.
  72
  73 =head2 NO_META
  74
  75 Suppress generation of META.yml file.
  76
  77 =head2 PREREQ_PM
  78
  79 Hash of perl modules and versions required.
  80
  81 =head2 PM
  82
  83 Hash of file mappings
  84
  85 =head2 PL_FILES
  86
  87 This is a hash of PL scripts to run after installation and
  88 the files to ask them to generate.
  89 Maybe use the values from CONFIGURE
  90 to generate initial configuration files in future.
  91
  92 =cut
  93
  94 =head2 target_map
  95
  96 This is a hash mapping directories and files in the
  97 source tree to installation target directories.  The rules
  98 for this mapping are:
  99
 100 =over 4
 101
 102 =item If a directory or file is specified, it and its
 103 contents will be copied to the installation target directory.
 104
 105 =item If a subdirectory of a mapped directory is specified,
 106 its target overrides the parent's target for that subdirectory.
 107
 108 =item The value of each map entry may either be a scalar containing
 109 one target or a reference to a hash containing 'target' and 'trimdir'
 110 keys.
 111
 112 =item Any files at the top level of the source tree that are
 113 not included in the map will not be installed.
 114
 115 =item Any directories at the top level of the source tree
 116 that are not included in the map will be installed in
 117 INTRANET_CGI_DIR.  This is a sensible default given the
 118 current organization of the source tree, but (FIXME) it
 119 would be better to reorganize the source tree to better
 120 match the installation system, to allow adding new directories
 121 without having to adjust Makefile.PL each time.  The idea
 122 is to make the C<$target_map> hash as minimal as possible.
 123
 124 =back
 125
 126 The permitted installation targets are:
 127
 128 =over 4
 129
 130 =item INTRANET_CGI_DIR
 131
 132 CGI scripts for intranet (staff) interface.
 133
 134 =item INTRANET_TMPL_DIR
 135
 136 HTML templates for the intranet interface.
 137
 138 =item INTRANET_WWW_DIR
 139
 140 HTML files, images, etc. for DocumentRoot for the intranet interface.
 141
 142 =item OPAC_CGI_DIR
 143
 144 CGI scripts for OPAC (public) interface.
 145
 146 =item OPAC_TMPL_DIR
 147
 148 HTML templates for the OPAC interface.
 149
 150 =item OPAC_WWW_DIR
 151
 152 HTML files, images, etc. for DocumentRoot for the OPAC interface.
 153
 154 =item PERL_MODULE_DIR
 155
 156 Perl modules (at present just the C4 modules) that are intimately
 157 tied to Koha.  Depending on the installation options, these
 158 may or may not be installed one of the standard directories
 159 in Perl's default @LIB.
 160
 161 =item KOHA_CONF_DIR
 162
 163 Directory for Koha configuration files.
 164
 165 =item ZEBRA_CONF_DIR
 166
 167 Directory for Zebra configuration files.
 168
 169 =item ZEBRA_LOCK_DIR
 170
 171 Directory for Zebra's lock files.
 172
 173 =item ZEBRA_DATA_DIR
 174
 175 Directory for Zebra's data files.
 176
 177 =item ZEBRA_RUN_DIR
 178
 179 Directory for Zebra's UNIX-domain sockets.
 180
 181 =item EXAMPLE_DIR
 182
 183 Directory for example configuration files.  This directory
 184 exists primarily to make it easier to change the
 185 MARC format or language of the active Zebra
 186 indexes.
 187
 188 =item SCRIPT_DIR
 189
 190 Directory for command-line scripts and daemons.
 191
 192 =item MAN_DIR
 193
 194 Directory for man pages created from POD -- will mostly
 195 contain information of interest to Koha developers.
 196
 197 =item DOC_DIR
 198
 199 Directory for Koha documentation accessed from the
 200 command-line, e.g., READMEs.
 201
 202 =item LOG_DIR
 203
 204 Directory for Apache and Zebra logs produced by Koha.
 205
 206 =item NONE
 207
 208 This is a dummy target used to explicitly state
 209 that a given file or directory is not to be installed.
 210 This is used either for parts of the installer itself
 211 or for development tools that are not applicable to a
 212 production installation.
 213
 214 =back
 215
 216 =cut
 217
 218 my $target_map = {
 219   './about.pl'                  => 'INTRANET_CGI_DIR',
 220   './acqui'                     => 'INTRANET_CGI_DIR',
 221   './admin'                     => 'INTRANET_CGI_DIR',
 222   './authorities'               => 'INTRANET_CGI_DIR',
 223   './C4'                        => 'PERL_MODULE_DIR',
 224   './C4/SIP/t'                  => 'NONE',
 225   './C4/SIP/koha_test'          => 'NONE',
 226   './C4/tests'                  => 'NONE',
 227   './catalogue'                 => 'INTRANET_CGI_DIR',
 228   './cataloguing'               => 'INTRANET_CGI_DIR',
 229   './changelanguage.pl'         => 'INTRANET_CGI_DIR',
 230   './check_sysprefs.pl'         => 'NONE',
 231   './circ'                      => 'INTRANET_CGI_DIR',
 232   './edithelp.pl'               => 'INTRANET_CGI_DIR',
 233   './etc'                       => { target => 'KOHA_CONF_DIR', trimdir => -1 },
 234   './etc/zebradb'               => { target => 'ZEBRA_CONF_DIR', trimdir => -1 },
 235   './help.pl'                   => 'NONE', # FIXME
 236   './installer-CPAN.pl'         => 'NONE',
 237   './installer'                 => 'INTRANET_CGI_DIR',
 238   './koha-tmpl/errors'          => {target => 'INTRANET_CGI_DIR', trimdir => 2},
 239   './koha-tmpl/intranet-tmpl'   => {target => 'INTRANET_TMPL_DIR', trimdir => -1},
 240   './koha-tmpl/opac-tmpl'       => {target => 'OPAC_TMPL_DIR', trimdir => -1},
 241   './kohaversion.pl'            => 'INTRANET_CGI_DIR', # FIXME this may need to be in OPAC_CGI_DIR as well, with an update to C4::Context
 242   './labels'                    => 'INTRANET_CGI_DIR',
 243   './mainpage.pl'               => 'INTRANET_CGI_DIR',
 244   './Makefile.PL'               => 'NONE',
 245   './MANIFEST.SKIP'             => 'NONE',
 246   './members'                   => 'INTRANET_CGI_DIR',
 247   './misc'                      => { target => 'SCRIPT_DIR', trimdir => -1 },
 248   './misc/info'                 => { target => 'DOC_DIR', trimdir => 2 },
 249   './misc/release notes'        => { target => 'DOC_DIR', trimdir => 2 },
 250   './misc/translator'           => { target => 'EXAMPLE_DIR', trimdir => 2 },
 251   './misc/installer_devel_notes' => 'NONE',
 252   './opac'                      => 'OPAC_CGI_DIR',
 253   './README.txt'                => 'NONE',
 254   './reports'                   => 'INTRANET_CGI_DIR',
 255   './reserve'                   => 'INTRANET_CGI_DIR',
 256   './reviews'                   => 'INTRANET_CGI_DIR',
 257   './rewrite-config.PL'         => 'NONE',
 258   './reviews'                   => 'INTRANET_CGI_DIR',
 259   './rss'                       => 'NONE', # FIXME deal with a little later
 260   './serials'                   => 'INTRANET_CGI_DIR',
 261   './sms'                       => 'INTRANET_CGI_DIR',
 262   './suggestion'                => 'INTRANET_CGI_DIR',
 263   './svc'                       => 'INTRANET_CGI_DIR',
 264   './t'                         => 'NONE',
 265   './tmp'                       => 'NONE', # FIXME deal with later
 266   './tools'                     => 'INTRANET_CGI_DIR',
 267   './virtualshelves'            => 'INTRANET_CGI_DIR',
 268   # ignore files and directories created by the install itself
 269   './pm_to_blib'                => 'NONE',
 270   './blib'                      => 'NONE',
 271 };
 272
 273 =head1 CONFIGURATION OPTIONS
 274
 275 The following configuration options are used by the installer.
 276
 277 =over 4
 278
 279 =item INSTALL_MODE
 280
 281 Specifies whether installation will be FHS-compliant (default,
 282 assumes user has root), put everything under
 283 a single directory (for users installing on a web host
 284 that allows CGI scripts and a MySQL database but not root
 285 access), or development (for a developer who wants to run
 286 Koha from a git clone with no fuss).
 287
 288 =item INSTALL_BASE
 289
 290 Directory under which most components will go.  Default
 291 value will vary depending on INSTALL_MODE.
 292
 293 =item INSTALL_ZEBRA
 294
 295 Whether to install Zebra configuration files and data
 296 directories.
 297
 298 =item ZEBRA_MARC_FORMAT
 299
 300 Specifies format of MARC records to be indexed by Zebra.
 301
 302 =item ZEBRA_LANGUAGE
 303
 304 Specifies primary language of records that will be
 305 indexed by Zebra.
 306
 307 =back
 308
 309 =cut
 310
 311 # default configuration options
 312 my %config_defaults = (
 313   'INSTALL_MODE'      => 'standard',
 314   'INSTALL_BASE'      => '/usr/share/koha',
 315   'DB_TYPE'           => 'mysql',
 316   'DB_HOST'           => 'localhost',
 317   'DB_NAME'           => 'koha',
 318   'DB_USER'           => 'kohaadmin',
 319   'DB_PASS'           => 'katikoan',
 320   'INSTALL_ZEBRA'     => 'yes',
 321   'ZEBRA_MARC_FORMAT' => 'marc21',
 322   'ZEBRA_LANGUAGE'    => 'en',
 323   'ZEBRA_USER'        => 'kohauser',
 324   'ZEBRA_PASS'        => 'zebrastripes',
 325 );
 326
 327 # valid values for certain configuration options
 328 my %valid_config_values = (
 329   'INSTALL_MODE'  => { 'standard' => 1, 'single' => 1, 'dev' => 1 },
 330   'DB_TYPE' => { 'mysql' => 1, 'Pg' => 1 },
 331   'INSTALL_ZEBRA' => { 'yes' => 1, 'no' => 1 },
 332   'ZEBRA_MARC_FORMAT' => { 'marc21' => 1, 'unimarc' => 1 }, # FIXME should generate from contents of distributation
 333   'ZEBRA_LANGUAGE'    => { 'en' => 1, 'fr' => 1 }, # FIXME should generate from contents of distribution
 334 );
 335
 336 my %config = get_configuration(\%config_defaults, \%valid_config_values);
 337 my %target_directories = get_target_directories(\%config);
 338 display_configuration(\%config, \%target_directories);
 339 my $file_map = {};
 340 get_file_map($target_map, $dirtree, $file_map);
 341
 342 WriteMakefile(
 343     NAME => 'koha',
 344     #VERSION => strftime('2.9.%Y%m%d%H',gmtime),
 345     VERSION_FROM => 'C4/Context.pm',
 346     ABSTRACT => 'Award-winning integrated library system (ILS) and Web OPAC',
 347     AUTHOR => 'Koha Developers <koha-devel@nongnu.org>',
 348     NO_META => 1,
 349     PREREQ_PM => {
 350 'CGI' => 3.15,
 351 'CGI::Carp' => 1.29,
 352 'CGI::Session' => '4.10',
 353 'Class::Factory::Util' => 1.7,
 354 'Class::Accessor' => 0.30,
 355 'DBD::mysql' => 3.0008,
 356 'DBI' => 1.53,
 357 'Data::Dumper' => 2.121_08,
 358 'Date::Calc' => 5.4,
 359 'Date::Manip' => 5.44,
 360 'Digest::MD5' => 2.36,
 361 'File::Temp' => 0.16,
 362 'GD::Barcode::UPCE' => 1.1,
 363 'Getopt::Long' => 2.35,
 364 'Getopt::Std' => 1.05,
 365 'HTML::Template::Pro' => 0.65,
 366 'HTTP::Cookies' => 1.39,
 367 'HTTP::Request::Common' => 1.26,
 368 'LWP::Simple' => 1.41,
 369 'LWP::UserAgent' => 2.033,
 370 'Lingua::Stem' => 0.82,
 371 'List::Util' => 1.18,
 372 'Locale::Language' => 2.07,
 373 'MARC::Charset' => 0.98,
 374 'MARC::Crosswalk::DublinCore' => 0.03,
 375 'MARC::File::XML' => 0.88,
 376 'MARC::Record' => 2.00,
 377 'MIME::Base64' => 3.07,
 378 'MIME::QuotedPrint' => 3.07,
 379 'Mail::Sendmail' => 0.79,
 380 'PDF::API2' => 2.000,
 381 'PDF::API2::Page' => 2.000,
 382 'PDF::API2::Util' => 2.000,
 383 'PDF::Reuse' => 0.33,
 384 'PDF::Reuse::Barcode' => 0.05,
 385 'POSIX' => 1.09,
 386 'Schedule::At' => 1.06,
 387 'Term::ANSIColor' => 1.10,
 388 'Test' => 1.25,
 389 'Test::Harness' => 2.56,
 390 'Test::More' => 0.62,
 391 'Text::CSV' => 0.01,
 392 'Text::CSV_XS' => 0.32,
 393 'Text::Wrap' => 2005.082401,
 394 'Time::HiRes' => 1.86,
 395 'Time::localtime' => 1.02,
 396 'Unicode::Normalize' => 0.32,
 397 'XML::Dumper' => 0.81,
 398 'XML::LibXML' => 1.59,
 399 'XML::SAX::ParserFactory' => 1.01,
 400 'XML::Simple' => 2.14,
 401 'XML::RSS' => 1.31,
 402 'ZOOM' => 1.16,
 403         },
 404
 405         # File tree mapping
 406         PM => $file_map,
 407
 408     # Man pages generated from POD
 409     INSTALLMAN1DIR => File::Spec->catdir($target_directories{'MAN_DIR'}, 'man1'),
 410     INSTALLMAN3DIR => File::Spec->catdir($target_directories{'MAN_DIR'}, 'man3'),
 411
 412 #   CONFIGURE => sub {
 413 #     # Ask for options with prompt($question,$default) calls here?
 414 #     return { macro => { 'export TEST' => '755' } }
 415 #     },
 416
 417    PL_FILES => { # generator => target(s)
 418       'rewrite-config.PL' => [
 419          'blib/KOHA_CONF_DIR/koha-conf.xml',
 420          'blib/KOHA_CONF_DIR/koha-httpd.conf',
 421          'blib/ZEBRA_CONF_DIR/etc/passwd',
 422          'blib/ZEBRA_CONF_DIR/zebra-biblios.cfg',
 423          'blib/ZEBRA_CONF_DIR/zebra-authorities.cfg'
 424          ]
 425    }
 426 #     'opac/getfromintranet.PL' => ['$(INST_LIBDIR)/opac/cgi-bin/detail.pl','$(INST_LIBDIR)/opac/cgi-bin/moredetail.pl','$(INST_LIBDIR)/opac/cgi-bin/search.pl','$(INST_LIBDIR)/opac/cgi-bin/subjectsearch.pl','$(INST_LIBDIR)/opac/cgi-bin/logout.pl'],
 427 #     'misc/koha.conf.PL' => '$(INST_LIBDIR)/../etc/koha.conf',
 428 #     'misc/apache-koha.conf.PL' => '$(INST_LIBDIR)/../etc/apache-koha.conf',
 429 #     'misc/koha.sql.PL' => '$(INST_LIBDIR)/intranet/scripts/koha.sql',
 430 #     'z3950/z3950-daemon-options.PL' => '$(INST_LIBDIR)/intranet/scripts/z3950daemon/z3950-daemon-options',
 431 #     # fake target to check permissions
 432 #     'misc/chmod.PL' => '$(INST_LIBDIR)/fake-target'
 433 #     }
 434    # need to set ownerships
 435    # need to load koha.sql
 436    # need to link koha-httpd.conf
 437    # need to start z3950-daemon
 438 );
 439
 440 =head1 FUNCTIONS
 441
 442 =head2 hashdir
 443
 444 This function recurses through the directory structure and builds
 445 a hash of hashes containing the structure with arrays holding filenames.
 446 This directory hashing routine was taken from BrowserUK @ http://www.perlmonks.org/?node_id=219919
 447
 448 =cut
 449
 450 sub hashdir{
 451     my $dir = shift;
 452     opendir my $dh, $dir or die $!;
 453     my $tree = {}->{$dir} = {};
 454     while( my $file = readdir($dh) ) {
 455         next if $file =~ m/^\.{1,2}/ and $file !~ /^\.htaccess/; # .htaccess is a special case
 456         my $path = $dir .'/' . $file;
 457         $tree->{$file} = hashdir($path), next if -d $path;
 458         push @{$tree->{'.'}}, $file;
 459     }
 460     return $tree;
 461 }
 462
 463 =head2 get_file_map
 464
 465 This function combines the target_map and file hash to
 466 map each source file to its destination relative to
 467 the set of installation targets.
 468
 469 Output will be a hash mapping from each source file
 470 to its destination value, like this:
 471
 472 'mainpage.pl' => '$(INTRANET_CGI_DIR)/mainpage.pl'
 473
 474 =cut
 475
 476 sub get_file_map {
 477     my $target_map = shift;
 478     my $dirtree = shift;
 479     my $file_map = shift;
 480     my $curr_path = @_ ? shift : ['.'];
 481
 482     # Traverse the directory tree.
 483     # For each file or directory, identify the
 484     # most specific match in the target_map
 485     foreach my $dir (sort keys %{ $dirtree }) {
 486         if ($dir eq '.') {
 487             # deal with files in directory
 488             foreach my $file (sort @{ $dirtree->{$dir} }) {
 489                 my $targetdir = undef;
 490                 my $matchlevel = undef;
 491                 # first, see if there is a match on this specific
 492                 # file in the target map
 493                 my $filepath = join("/", @$curr_path, $file);
 494                 if (exists $target_map->{$filepath}) {
 495                     $targetdir = $target_map->{$filepath};
 496                     $matchlevel = scalar(@$curr_path) + 1;
 497                 } else {
 498                     # no match on the specific file; look for
 499                     # a directory match
 500                     for (my $i = scalar(@$curr_path) - 1; $i >= 0; $i--)  {
 501                         my $dirpath = join("/", @$curr_path[0..$i]);
 502                         if (exists $target_map->{$dirpath}) {
 503                             $targetdir = $target_map->{$dirpath};
 504                             $matchlevel = $i + 1;
 505                             last;
 506                         }
 507                     }
 508                 }
 509                 if (defined $targetdir) {
 510                      _add_to_file_map($file_map, $targetdir, $curr_path, $file, $matchlevel);
 511                 } else {
 512                     my $path = join("/", @$curr_path);
 513                     print "failed to map: $path/$file\n" if $DEBUG;
 514                 }
 515             }
 516         } else {
 517             # dealing with subdirectory
 518             push @$curr_path, $dir;
 519             get_file_map($target_map, $dirtree->{$dir}, $file_map, $curr_path);
 520             pop @$curr_path;
 521         }
 522     }
 523 }
 524
 525 sub _add_to_file_map {
 526     my $file_map = shift;
 527     my $targetdir = shift;
 528     my $curr_path = shift;
 529     my $file = shift;
 530     my $matchlevel = shift;
 531     my $dest_path = @_ ? shift : $curr_path;
 532
 533     # The target can be one of the following:
 534     # 1. scalar representing target symbol
 535     # 2. hash ref containing target and trimdir keys
 536     #
 537     # Consequently, this routine traverses this structure,
 538     # calling itself recursively, until it deals with
 539     # all of the scalar target symbols.
 540     if (ref $targetdir eq 'HASH') {
 541         my $subtarget = $targetdir->{target};
 542         if (exists $targetdir->{trimdir}) {
 543             # if we get here, we've specified that
 544             # rather than installing the file to
 545             # $(TARGET)/matching/dirs/subdirs/file,
 546             # we want to install it to
 547             # $(TARGET)/subdirs/file
 548             #
 549             # Note that this the only place where
 550             # $matchlevel is used.
 551             my @new_dest_path = @$dest_path;
 552             if ($targetdir->{trimdir} == -1)  {
 553                 splice @new_dest_path, 0, $matchlevel;
 554             } else {
 555                 splice @new_dest_path, 0, $targetdir->{trimdir};
 556             }
 557             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, \@new_dest_path);
 558         } else {
 559             # actually getting here means that the
 560             # target was unnecessarily listed
 561             # as a hash, but we'll forgive that
 562             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel);
 563         }
 564     } elsif ($targetdir ne 'NONE' and $targetdir ne '') {
 565         my $source = File::Spec->catfile(@$curr_path, $file);
 566         my $destination = File::Spec->catfile('blib', $targetdir, @$dest_path, $file);
 567         #print "$source => $destination\n"; # DEBUG
 568         # quote spaces in file names
 569         # FIXME: this is of questionable portability and
 570         # probably depends on user's make recognizing this
 571         # quoting syntax -- probably better to remove
 572         # spaces and shell metacharacters from all file names
 573         $source =~ s/ /\\ /g;
 574         $destination =~ s/ /\\ /g;
 575
 576         $file_map->{$source} = $destination;
 577     }
 578 }
 579
 580 =head2 get_configuration_options
 581
 582 This prompts the user for various configuration options.
 583
 584 =cut
 585
 586 sub get_configuration {
 587   my $defaults = shift;
 588   my $valid_values = shift;
 589   my %config = ();
 590
 591   my $msg = q(
 592 By default, Koha can be installed in one of three ways:
 593
 594 standard: Install files in conformance with the Filesystem
 595           Hierarchy Standard (FHS).  This is the default mode
 596           and should be used when installing a production
 597           Koha system.  On Unix systems, root access is
 598           needed to complete a standard installation.
 599
 600 single:   Install files under a single directory.  This option
 601           is useful for installing Koha without root access, e.g.,
 602           on a web host that allows CGI scripts and MySQL databases
 603           but requires the user to keep all files under the user's
 604           HOME directory.
 605
 606 dev:      Create a set of symbolic links and configuration files to
 607           allow Koha to run directly from the source distribution.
 608           This mode is useful for developers who want to run
 609           Koha from a git clone.
 610
 611 Please choose the installation mode);
 612     $msg .= _add_valid_values_disp('INSTALL_MODE', $valid_values);
 613     $config{'INSTALL_MODE'} = _get_value('INSTALL_MODE', $msg, $defaults->{'INSTALL_MODE'}, $valid_values);
 614
 615     # set message and default value for INSTALL_BASE
 616     # depending on value of INSTALL_MODE
 617     my $install_base_default = $defaults->{'INSTALL_BASE'};
 618     if ($config{'INSTALL_MODE'} eq 'dev') {
 619         $msg = q(
 620 Please specify the directory in which to install Koha's
 621 active configuration files and (if applicable) the
 622 Zebra database.  Koha's CGI scripts and templates will
 623 be run from the current directory.);
 624         # FIXME - home directory portability consideration apply
 625         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha-dev" : "/usr/share/koha-dev";
 626     } elsif ($config{'INSTALL_MODE'} eq 'single') {
 627         $msg = "\nPlease specify the directory in which to install Koha";
 628         # FIXME -- we're assuming under a 'single' mode install
 629         # that user will likely want to install under the home
 630         # directory.  This is OK in and of itself, but we should
 631         # use File::HomeDir to locate the home directory portably.
 632         # This is deferred for now because File::HomeDir is not yet
 633         # core.
 634         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha" : "/usr/share/koha";
 635     } else {
 636         # must be standard
 637         $msg = q(
 638 Please specify the directory under which most Koha files
 639 will be installed.
 640
 641 Note that if you are planning in installing more than
 642 one instance of Koha, you may want to modify the last
 643 component of the directory path, which will be used
 644 as the package name in the FHS layout.);
 645     }
 646     $config{'INSTALL_BASE'} = _get_value('INSTALL_BASE', $msg, $install_base_default, $valid_values);
 647     $config{'INSTALL_BASE'} = File::Spec->rel2abs($config{'INSTALL_BASE'});
 648
 649     $msg = q(
 650 Please specify which database engine you will use
 651 to store data in Koha.  The choices are MySQL and
 652 PostgreSQL; please note that at the moment
 653 PostgreSQL support is highly experimental.
 654
 655 DBMS to use);
 656     $msg .= _add_valid_values_disp('DB_TYPE', $valid_values);
 657     $config{'DB_TYPE'} = _get_value('DB_TYPE', $msg, $defaults->{'DB_TYPE'}, $valid_values);
 658
 659     $msg = q(
 660 Please specify the name or address of your
 661 database server.  Note that the database
 662 does not have to exist at this point, it
 663 can be created after running 'make install'
 664 and before you try using Koha for the first time.
 665
 666 Database server);
 667     $config{'DB_HOST'} = _get_value('DB_HOST', $msg, $defaults->{'DB_HOST'}, $valid_values);
 668
 669     $msg = q(
 670 Please specify the port used to connect to the
 671 DMBS);
 672     my $db_port_default = $config{'DB_TYPE'} eq 'mysql' ? '3306' : '5432';
 673     $config{'DB_PORT'} = _get_value('DB_PORT', $msg, $db_port_default, $valid_values);
 674
 675     $msg = q(
 676 Please specify the name of the database to be
 677 used by Koha);
 678     $config{'DB_NAME'} = _get_value('DB_NAME', $msg, $defaults->{'DB_NAME'}, $valid_values);
 679
 680     $msg = q(
 681 Please specify the user that owns the database to be
 682 used by Koha);
 683     $config{'DB_USER'} = _get_value('DB_USER', $msg, $defaults->{'DB_USER'}, $valid_values);
 684
 685     $msg = q(
 686 Please specify the password of the user that owns the
 687 database to be used by Koha);
 688     $config{'DB_PASS'} = _get_value('DB_PASS', $msg, $defaults->{'DB_PASS'}, $valid_values);
 689
 690     $msg = q(
 691 Koha can use the Zebra search engine for high-performance
 692 searching of bibliographic and authority records.  If you
 693 have installed the Zebra software and would like to use it,
 694 please answer 'yes' to the following question.  Otherwise,
 695 Koha will default to using its internal search engine.
 696
 697 Please specify whether to install the Zebra configuration files);
 698     $msg .= _add_valid_values_disp('INSTALL_ZEBRA', $valid_values);
 699     $config{'INSTALL_ZEBRA'} = _get_value('INSTALL_ZEBRA', $msg, $defaults->{'INSTALL_ZEBRA'}, $valid_values);
 700
 701     if ($config{'INSTALL_ZEBRA'} eq 'yes') {
 702         $msg = q(
 703 Since you've chosen to use Zebra with Koha,
 704 you must specify the primary MARC format of the
 705 records to be indexed by Zebra.
 706
 707 Koha provides Zebra configuration files for MARC 21
 708 and UNIMARC.
 709
 710 Please specify the MARC format);
 711         $msg .= _add_valid_values_disp('ZEBRA_MARC_FORMAT', $valid_values);
 712         $config{'ZEBRA_MARC_FORMAT'} = _get_value('ZEBRA_MARC_FORMAT', $msg, $defaults->{'ZEBRA_MARC_FORMAT'}, $valid_values);
 713         $msg = q(
 714 Koha supplies Zebra configuration files tuned for
 715 searching either English (en) or French (fr) MARC
 716 records.
 717
 718 Please specify the primary language of the MARC records);
 719         $msg .= _add_valid_values_disp('ZEBRA_LANGUAGE', $valid_values);
 720         $config{'ZEBRA_LANGUAGE'} = _get_value('ZEBRA_LANGUAGE', $msg, $defaults->{'ZEBRA_LANGUAGE'}, $valid_values);
 721
 722         $msg = q(
 723 Please specify Zebra database user);
 724         $config{'ZEBRA_USER'} = _get_value('ZEBRA_USER', $msg, $defaults->{'ZEBRA_USER'}, $valid_values);
 725
 726         $msg = q(
 727 Please specify the Zebra database password);
 728         $config{'ZEBRA_PASS'} = _get_value('ZEBRA_PASS', $msg, $defaults->{'ZEBRA_PASS'}, $valid_values);
 729
 730     }
 731     return %config;
 732 }
 733
 734 sub _add_valid_values_disp {
 735     my $key = shift;
 736     my $valid_values = shift;
 737
 738     my $disp = "";
 739     if (exists $valid_values->{$key}) {
 740         $disp = " (" . join(", ", sort keys %{ $valid_values->{$key} }) . ")";
 741     }
 742     return $disp;
 743 }
 744
 745 sub _get_value {
 746     my $key = shift;
 747     my $msg = shift;
 748     my $default = shift;
 749     my $valid_values = shift;
 750
 751     my $val = prompt($msg, $default);
 752     while (exists $valid_values->{$key} and not exists $valid_values->{$key}->{$val}) {
 753         my $retry_msg = "Value '$val' is not a valid option.\n";
 754         $retry_msg .= "Please enter a value";
 755         $retry_msg .= _add_valid_values_disp($key, $valid_values);
 756         $val = prompt($retry_msg, $default);
 757     }
 758     return $val;
 759 }
 760
 761 =head2 get_target_directories
 762
 763 Creates a hash mapping from symbols for installation target
 764 directories to actual directory paths.
 765
 766 =cut
 767
 768 sub get_target_directories {
 769     my $config = shift;
 770
 771     my $base = $config->{'INSTALL_BASE'};
 772     my $mode = $config->{'INSTALL_MODE'};
 773
 774     # get last component of install base directory
 775     # to treat as package name
 776     my ($volume, $directories, $file) = File::Spec->splitpath($base, 1);
 777     my @basedir = File::Spec->splitdir($directories);
 778     my $package = pop @basedir;
 779
 780     my %dirmap = ();
 781     if ($mode eq 'single') {
 782         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
 783         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
 784         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
 785         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
 786         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
 787         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
 788         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
 789         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
 790         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
 791         $dirmap{'EXAMPLE_DIR'} = File::Spec->catdir(@basedir, $package, 'example');
 792         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 793         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 794         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 795         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
 796         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
 797         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
 798         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
 799     } elsif ($mode eq 'dev') {
 800         my $curdir = File::Spec->rel2abs(File::Spec->curdir());
 801         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir($curdir);
 802         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'intranet-tmpl');
 803         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'intranet-tmpl');
 804         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir($curdir, 'opac');
 805         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'opac-tmpl');
 806         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'opac-tmpl');
 807         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir($curdir);
 808         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
 809         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
 810         $dirmap{'EXAMPLE_DIR'} = File::Spec->catdir(@basedir, $package, 'example');
 811         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 812         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 813         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 814         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
 815         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
 816         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
 817         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
 818     } else {
 819         # mode is standard, i.e., 'fhs'
 820         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
 821         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
 822         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
 823         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
 824         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
 825         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
 826         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
 827         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package);
 828         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'zebradb');
 829         $dirmap{'EXAMPLE_DIR'} = File::Spec->catdir(@basedir, $package, 'example');
 830         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 831         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 832         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 833         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'var', 'lock', $package, 'zebradb');
 834         $dirmap{'LOG_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'log', $package);
 835         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'zebradb');
 836         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'run', $package, 'zebradb');
 837     }
 838
 839     _get_argv_overrides(\%dirmap);
 840
 841     return %dirmap;
 842 }
 843
 844 sub _get_argv_overrides {
 845     my $dirmap = shift;
 846
 847     my @new_argv = ();
 848     for (my $i = 0; $i <= $#ARGV; $i++) {
 849         if ($ARGV[$i] =~ /^([^=]+)=([^=]+)$/ and exists $dirmap->{$1}) {
 850             $dirmap->{$1} = $2;
 851         } else {
 852             push @new_argv, $ARGV[$i];
 853         }
 854     }
 855     @ARGV = @new_argv;
 856 }
 857
 858 sub display_configuration {
 859     my $config = shift;
 860     my $dirmap = shift;
 861     print "\n\nKoha will be installed with the following configuration parameters:\n\n";
 862     foreach my $key (sort keys %$config) {
 863         print sprintf("%-25.25s%s\n", $key, $config->{$key});
 864     }
 865
 866     print "\nand in the following directories:\n\n";
 867     foreach my $key (sort keys %$dirmap) {
 868         print sprintf("%-25.25s%s\n", $key, $dirmap->{$key});
 869     }
 870     print "\n\nTo change any configuration setting, please run\n";
 871     print "perl Makefile.PL again.  To override one of the target\n";
 872     print "directories, you can do so on the command line like this:\n";
 873     print "\nperl Makefile.PL PERL_MODULE_DIR=/usr/share/perl/5.8\n\n";
 874 }
 875
 876 package MY;
 877
 878 sub test {
 879     my $self = shift;
 880     my $test = $self->SUPER::test(@_);
 881     $test =~ s!\$\(INST_LIB\)!blib/PERL_MODULE_DIR!g;
 882     return $test;
 883 }
 884
 885 sub install {
 886     my $self = shift;
 887     my $install = "";
 888     # NOTE: we're *not* doing this: my $install = $self->SUPER::install(@_);
 889     # This means that we're completely overriding EU::MM's default
 890     # installation and uninstallation targets.
 891     foreach my $key (sort keys %target_directories) {
 892         $install .= qq(
 893 KOHA_INST_$key = blib/$key
 894 KOHA_DEST_$key = $target_directories{$key}
 895 );
 896     }
 897
 898     $install .= qq(
 899 install :: all install_koha
 900 \t\$(NOECHO) \$(NOOP)
 901 );
 902     $install .= "install_koha ::\n";
 903     $install .= "\t\$(NOECHO) umask 022; \$(MOD_INSTALL) \\\n";
 904     foreach my $key (sort keys %target_directories) {
 905         $install .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n";
 906     }
 907     $install .= "\t\t\$(INST_MAN1DIR) \$(DESTINSTALLMAN1DIR) \\\n";
 908     $install .= "\t\t\$(INST_MAN3DIR) \$(DESTINSTALLMAN3DIR)\n";
 909     return $install;
 910 }
 911
 912 sub postamble {
 913     # put directory mappings into Makefile
 914     # so that Make will export as environment
 915     # variables -- this is for the use of
 916     # rewrite-confg.PL
 917     my $env = join("\n", map { "export __${_}__ = $target_directories{$_}" } keys %target_directories);
 918     $env .= join("\n", map { "export __${_}__ = $config{$_}" } keys %config);
 919     return "$env\n";
 920 }
 921
 922 __END__
 923
 924
 925 =head1 SEE ALSO
 926
 927 ExtUtils::MakeMaker(3)
 928
 929 =head1 AUTHORS
 930
 931 MJ Ray mjr at phonecoop.coop
 932
 933 =cut
 934 FIXME: Zebra lang/MARC mapping
 935 FIXME: deal with .htaccess