Bug 23151: Modifiy database structure
[koha.git] / about.pl
1 #!/usr/bin/perl
2
3 # Copyright Pat Eyler 2003
4 # Copyright Biblibre 2006
5 # Parts Copyright Liblime 2008
6 # Parts Copyright Chris Nighswonger 2010
7 #
8 # This file is part of Koha.
9 #
10 # Koha is free software; you can redistribute it and/or modify it
11 # under the terms of the GNU General Public License as published by
12 # the Free Software Foundation; either version 3 of the License, or
13 # (at your option) any later version.
14 #
15 # Koha is distributed in the hope that it will be useful, but
16 # WITHOUT ANY WARRANTY; without even the implied warranty of
17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 # GNU General Public License for more details.
19 #
20 # You should have received a copy of the GNU General Public License
21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
22
23 use Modern::Perl;
24
25 use CGI qw ( -utf8 );
26 use DateTime::TimeZone;
27 use File::Spec;
28 use List::MoreUtils qw/ any /;
29 use LWP::Simple;
30 use Module::Load::Conditional qw(can_load);
31 use XML::Simple;
32 use Config;
33 use Search::Elasticsearch;
34 use Try::Tiny;
35 use YAML qw/LoadFile/;
36
37 use C4::Output;
38 use C4::Auth;
39 use C4::Context;
40 use C4::Installer;
41
42 use Koha;
43 use Koha::DateUtils qw(dt_from_string output_pref);
44 use Koha::Acquisition::Currencies;
45 use Koha::Patron::Categories;
46 use Koha::Patrons;
47 use Koha::Caches;
48 use Koha::Config::SysPrefs;
49 use Koha::Illrequest::Config;
50 use Koha::SearchEngine::Elasticsearch;
51
52 use C4::Members::Statistics;
53
54
55 #use Smart::Comments '####';
56
57 my $query = new CGI;
58 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
59     {
60         template_name   => "about.tt",
61         query           => $query,
62         type            => "intranet",
63         authnotrequired => 0,
64         flagsrequired   => { catalogue => 1 },
65         debug           => 1,
66     }
67 );
68
69 my $config_timezone = C4::Context->config('timezone') // '';
70 my $config_invalid  = !DateTime::TimeZone->is_valid_name( $config_timezone );
71 my $env_timezone    = $ENV{TZ} // '';
72 my $env_invalid     = !DateTime::TimeZone->is_valid_name( $env_timezone );
73 my $actual_bad_tz_fallback = 0;
74
75 if ( $config_timezone ne '' &&
76      $config_invalid ) {
77     # Bad config
78     $actual_bad_tz_fallback = 1;
79 }
80 elsif ( $config_timezone eq '' &&
81         $env_timezone    ne '' &&
82         $env_invalid ) {
83     # No config, but bad ENV{TZ}
84     $actual_bad_tz_fallback = 1;
85 }
86
87 my $time_zone = {
88     actual                 => C4::Context->tz->name,
89     actual_bad_tz_fallback => $actual_bad_tz_fallback,
90     config                 => $config_timezone,
91     config_invalid         => $config_invalid,
92     environment            => $env_timezone,
93     environment_invalid    => $env_invalid
94 };
95
96 $template->param(
97     time_zone              => $time_zone,
98     current_date_and_time  => output_pref({ dt => dt_from_string(), dateformat => 'iso' })
99 );
100
101 my $perl_path = $^X;
102 if ($^O ne 'VMS') {
103     $perl_path .= $Config{_exe} unless $perl_path =~ m/$Config{_exe}$/i;
104 }
105
106 my $zebraVersion = `zebraidx -V`;
107
108 # Check running PSGI env
109 if ( any { /(^psgi\.|^plack\.)/i } keys %ENV ) {
110     $template->param(
111         is_psgi => 1,
112         psgi_server => ($ENV{ PLACK_ENV }) ? "Plack ($ENV{PLACK_ENV})" :
113                        ($ENV{ MOD_PERL })  ? "mod_perl ($ENV{MOD_PERL})" :
114                                              'Unknown'
115     );
116 }
117
118 # Memcached configuration
119 my $memcached_servers   = $ENV{MEMCACHED_SERVERS} || C4::Context->config('memcached_servers');
120 my $memcached_namespace = $ENV{MEMCACHED_NAMESPACE} || C4::Context->config('memcached_namespace') // 'koha';
121
122 my $cache = Koha::Caches->get_instance;
123 my $effective_caching_method = ref($cache->cache);
124 # Memcached may have been running when plack has been initialized but could have been stopped since
125 # FIXME What are the consequences of that??
126 my $is_memcached_still_active = $cache->set_in_cache('test_for_about_page', "just a simple value");
127
128 my $where_is_memcached_config = 'nowhere';
129 if ( $ENV{MEMCACHED_SERVERS} and C4::Context->config('memcached_servers') ) {
130     $where_is_memcached_config = 'both';
131 } elsif ( $ENV{MEMCACHED_SERVERS} and not C4::Context->config('memcached_servers') ) {
132     $where_is_memcached_config = 'ENV_only';
133 } elsif ( C4::Context->config('memcached_servers') ) {
134     $where_is_memcached_config = 'config_only';
135 }
136
137 $template->param(
138     effective_caching_method => $effective_caching_method,
139     memcached_servers   => $memcached_servers,
140     memcached_namespace => $memcached_namespace,
141     is_memcached_still_active => $is_memcached_still_active,
142     where_is_memcached_config => $where_is_memcached_config,
143     memcached_running   => Koha::Caches->get_instance->memcached_cache,
144 );
145
146 # Additional system information for warnings
147
148 my $warnStatisticsFieldsError;
149 my $prefStatisticsFields = C4::Context->preference('StatisticsFields');
150 if ($prefStatisticsFields) {
151     $warnStatisticsFieldsError = $prefStatisticsFields
152         unless ( $prefStatisticsFields eq C4::Members::Statistics->get_fields() );
153 }
154
155 my $prefAutoCreateAuthorities = C4::Context->preference('AutoCreateAuthorities');
156 my $prefBiblioAddsAuthorities = C4::Context->preference('BiblioAddsAuthorities');
157 my $warnPrefBiblioAddsAuthorities = ( $prefAutoCreateAuthorities && ( !$prefBiblioAddsAuthorities) );
158
159 my $prefEasyAnalyticalRecords  = C4::Context->preference('EasyAnalyticalRecords');
160 my $prefUseControlNumber  = C4::Context->preference('UseControlNumber');
161 my $warnPrefEasyAnalyticalRecords  = ( $prefEasyAnalyticalRecords  && $prefUseControlNumber );
162 my $warnPrefAnonymousPatron = (
163     C4::Context->preference('OPACPrivacy')
164         and not C4::Context->preference('AnonymousPatron')
165 );
166
167 my $anonymous_patron = Koha::Patrons->find( C4::Context->preference('AnonymousPatron') );
168 my $warnPrefAnonymousPatron_PatronDoesNotExist = ( not $anonymous_patron and Koha::Patrons->search({ privacy => 2 })->count );
169
170 my $errZebraConnection = C4::Context->Zconn("biblioserver",0)->errcode();
171
172 my $warnIsRootUser   = (! $loggedinuser);
173
174 my $warnNoActiveCurrency = (! defined Koha::Acquisition::Currencies->get_active);
175
176 my @xml_config_warnings;
177
178 my $context = new C4::Context;
179
180 if (    C4::Context->config('zebra_bib_index_mode')
181     and C4::Context->config('zebra_bib_index_mode') eq 'grs1' )
182 {
183     push @xml_config_warnings, { error => 'zebra_bib_index_mode_is_grs1' };
184 }
185
186 if (    C4::Context->config('zebra_auth_index_mode')
187     and C4::Context->config('zebra_auth_index_mode') eq 'grs1' )
188 {
189     push @xml_config_warnings, { error => 'zebra_auth_index_mode_is_grs1' };
190 }
191
192 if ( (C4::Context->config('zebra_auth_index_mode') eq 'dom') && ($context->{'server'}->{'authorityserver'}->{'config'} !~ /zebra-authorities-dom.cfg/) ) {
193     push @xml_config_warnings, {
194         error => 'zebra_auth_index_mode_mismatch_warn'
195     };
196 }
197
198 if ( ! defined C4::Context->config('log4perl_conf') ) {
199     push @xml_config_warnings, {
200         error => 'log4perl_entry_missing'
201     }
202 }
203
204 if ( ! defined C4::Context->config('upload_path') ) {
205     if ( Koha::Config::SysPrefs->find('OPACBaseURL')->value ) {
206         # OPACBaseURL seems to be set
207         push @xml_config_warnings, {
208             error => 'uploadpath_entry_missing'
209         }
210     } else {
211         push @xml_config_warnings, {
212             error => 'uploadpath_and_opacbaseurl_entry_missing'
213         }
214     }
215 }
216
217 if ( ! C4::Context->config('tmp_path') ) {
218     my $temporary_directory = C4::Context::temporary_directory;
219     push @xml_config_warnings, {
220         error             => 'tmp_path_missing',
221         effective_tmp_dir => $temporary_directory,
222     }
223 }
224
225 # Test QueryParser configuration sanity
226 if ( C4::Context->preference( 'UseQueryParser' ) ) {
227     # Get the QueryParser configuration file name
228     my $queryparser_file          = C4::Context->config( 'queryparser_config' );
229     my $queryparser_fallback_file = '/etc/koha/searchengine/queryparser.yaml';
230     # Check QueryParser is functional
231     my $QParser = C4::Context->queryparser();
232     my $queryparser_error = {};
233     if ( ! defined $QParser || ref($QParser) ne 'Koha::QueryParser::Driver::PQF' ) {
234         # Error initializing the QueryParser object
235         # Get the used queryparser.yaml file path to report the user
236         $queryparser_error->{ fallback } = ( defined $queryparser_file ) ? 0 : 1;
237         $queryparser_error->{ file }     = ( defined $queryparser_file )
238                                                 ? $queryparser_file
239                                                 : $queryparser_fallback_file;
240         # Report error data to the template
241         $template->param( QueryParserError => $queryparser_error );
242     } else {
243         # Check for an absent queryparser_config entry in koha-conf.xml
244         if ( ! defined $queryparser_file ) {
245             # Not an error but a warning for the missing entry in koha-conf-xml
246             push @xml_config_warnings, {
247                     error => 'queryparser_entry_missing',
248                     file  => $queryparser_fallback_file
249             };
250         }
251     }
252 }
253
254 # Test Zebra facets configuration
255 if ( !defined C4::Context->config('use_zebra_facets') ) {
256     push @xml_config_warnings, { error => 'use_zebra_facets_entry_missing' };
257 }
258
259 # ILL module checks
260 if ( C4::Context->preference('ILLModule') ) {
261     my $warnILLConfiguration = 0;
262     my $ill_config_from_file = C4::Context->config("interlibrary_loans");
263     my $ill_config = Koha::Illrequest::Config->new;
264
265     my $available_ill_backends =
266       ( scalar @{ $ill_config->available_backends } > 0 );
267
268     # Check backends
269     if ( !$available_ill_backends ) {
270         $template->param( no_ill_backends => 1 );
271         $warnILLConfiguration = 1;
272     }
273
274     # Check partner_code
275     if ( !Koha::Patron::Categories->find($ill_config->partner_code) ) {
276         $template->param( ill_partner_code_doesnt_exist => $ill_config->partner_code );
277         $warnILLConfiguration = 1;
278     }
279
280     if ( !$ill_config_from_file->{partner_code} ) {
281         # partner code not defined
282         $template->param( ill_partner_code_not_defined => 1 );
283         $warnILLConfiguration = 1;
284     }
285
286
287     if ( !$ill_config_from_file->{branch} ) {
288         # branch not defined
289         $template->param( ill_branch_not_defined => 1 );
290         $warnILLConfiguration = 1;
291     }
292
293     $template->param( warnILLConfiguration => $warnILLConfiguration );
294 }
295
296 if ( C4::Context->preference('SearchEngine') eq 'Elasticsearch' ) {
297     # Check ES configuration health and runtime status
298
299     my $es_status;
300     my $es_config_error;
301     my $es_running = 1;
302
303     my $es_conf;
304     try {
305         $es_conf = Koha::SearchEngine::Elasticsearch::_read_configuration();
306     }
307     catch {
308         if ( ref($_) eq 'Koha::Exceptions::Config::MissingEntry' ) {
309             $template->param( elasticsearch_fatal_config_error => $_->message );
310             $es_config_error = 1;
311         }
312     };
313     if ( !$es_config_error ) {
314
315         my $biblios_index_name     = $es_conf->{index_name} . "_" . $Koha::SearchEngine::BIBLIOS_INDEX;
316         my $authorities_index_name = $es_conf->{index_name} . "_" . $Koha::SearchEngine::AUTHORITIES_INDEX;
317
318         my @indexes = ($biblios_index_name, $authorities_index_name);
319         # TODO: When new indexes get added, we could have other ways to
320         #       fetch the list of available indexes (e.g. plugins, etc)
321         $es_status->{nodes} = $es_conf->{nodes};
322         my $es = Search::Elasticsearch->new({ nodes => $es_conf->{nodes} });
323
324         foreach my $index ( @indexes ) {
325             my $count;
326             try {
327                 $count = $es->indices->stats( index => $index )
328                       ->{_all}{primaries}{docs}{count};
329             }
330             catch {
331                 if ( ref($_) eq 'Search::Elasticsearch::Error::Missing' ) {
332                     push @{ $es_status->{errors} }, "Index not found ($index)";
333                     $count = -1;
334                 }
335                 elsif ( ref($_) eq 'Search::Elasticsearch::Error::NoNodes' ) {
336                     $es_running = 0;
337                 }
338                 else {
339                     # TODO: when time comes, we will cover more use cases
340                     die $_;
341                 }
342             };
343
344             push @{ $es_status->{indexes} },
345               {
346                 index_name => $index,
347                 count      => $count
348               };
349         }
350         $es_status->{running} = $es_running;
351
352         $template->param( elasticsearch_status => $es_status );
353     }
354 }
355
356 if ( C4::Context->preference('RESTOAuth2ClientCredentials') ) {
357     # Do we have the required deps?
358     unless ( can_load( modules => { 'Net::OAuth2::AuthorizationServer' => undef }) ) {
359         $template->param( oauth2_missing_deps => 1 );
360     }
361 }
362
363 # Sco Patron should not contain any other perms than circulate => self_checkout
364 if (  C4::Context->preference('WebBasedSelfCheck')
365       and C4::Context->preference('AutoSelfCheckAllowed')
366 ) {
367     my $userid = C4::Context->preference('AutoSelfCheckID');
368     my $all_permissions = C4::Auth::get_user_subpermissions( $userid );
369     my ( $has_self_checkout_perm, $has_other_permissions );
370     while ( my ( $module, $permissions ) = each %$all_permissions ) {
371         if ( $module eq 'self_check' ) {
372             while ( my ( $permission, $flag ) = each %$permissions ) {
373                 if ( $permission eq 'self_checkout_module' ) {
374                     $has_self_checkout_perm = 1;
375                 } else {
376                     $has_other_permissions = 1;
377                 }
378             }
379         } else {
380             $has_other_permissions = 1;
381         }
382     }
383     $template->param(
384         AutoSelfCheckPatronDoesNotHaveSelfCheckPerm => not ( $has_self_checkout_perm ),
385         AutoSelfCheckPatronHasTooManyPerm => $has_other_permissions,
386     );
387 }
388
389 # Test YAML system preferences
390 # FIXME: This is list of current YAML formatted prefs, should by type of preference
391 my @yaml_prefs = (
392     "UpdateNotForLoanStatusOnCheckin",
393     "OpacHiddenItems",
394     "BibtexExportAdditionalFields",
395     "RisExportAdditionalFields",
396     "UpdateItemWhenLostFromHoldList",
397     "MarcFieldsToOrder",
398     "MarcItemFieldsToOrder",
399     "UpdateitemLocationOnCheckin",
400     "ItemsDeniedRenewal"
401 );
402 my @bad_yaml_prefs;
403 foreach my $syspref (@yaml_prefs) {
404     my $yaml = C4::Context->preference( $syspref );
405     if ( $yaml ) {
406         eval { YAML::Load( "$yaml\n\n" ); };
407         if ($@) {
408             push @bad_yaml_prefs, $syspref;
409         }
410     }
411 }
412 $template->param( 'bad_yaml_prefs' => \@bad_yaml_prefs ) if @bad_yaml_prefs;
413
414 {
415     my $dbh       = C4::Context->dbh;
416     my $patrons = $dbh->selectall_arrayref(
417         q|select b.borrowernumber from borrowers b join deletedborrowers db on b.borrowernumber=db.borrowernumber|,
418         { Slice => {} }
419     );
420     my $biblios = $dbh->selectall_arrayref(
421         q|select b.biblionumber from biblio b join deletedbiblio db on b.biblionumber=db.biblionumber|,
422         { Slice => {} }
423     );
424     my $items = $dbh->selectall_arrayref(
425         q|select i.itemnumber from items i join deleteditems di on i.itemnumber=di.itemnumber|,
426         { Slice => {} }
427     );
428     my $checkouts = $dbh->selectall_arrayref(
429         q|select i.issue_id from issues i join old_issues oi on i.issue_id=oi.issue_id|,
430         { Slice => {} }
431     );
432     my $holds = $dbh->selectall_arrayref(
433         q|select r.reserve_id from reserves r join old_reserves o on r.reserve_id=o.reserve_id|,
434         { Slice => {} }
435     );
436     if ( @$patrons or @$biblios or @$items or @$checkouts or @$holds ) {
437         $template->param(
438             has_ai_issues => 1,
439             ai_patrons    => $patrons,
440             ai_biblios    => $biblios,
441             ai_items      => $items,
442             ai_checkouts  => $checkouts,
443             ai_holds      => $holds,
444         );
445     }
446 }
447 my %versions = C4::Context::get_versions();
448
449 $template->param(
450     kohaVersion   => $versions{'kohaVersion'},
451     osVersion     => $versions{'osVersion'},
452     perlPath      => $perl_path,
453     perlVersion   => $versions{'perlVersion'},
454     perlIncPath   => [ map { perlinc => $_ }, @INC ],
455     mysqlVersion  => $versions{'mysqlVersion'},
456     apacheVersion => $versions{'apacheVersion'},
457     zebraVersion  => $zebraVersion,
458     prefBiblioAddsAuthorities => $prefBiblioAddsAuthorities,
459     prefAutoCreateAuthorities => $prefAutoCreateAuthorities,
460     warnPrefBiblioAddsAuthorities => $warnPrefBiblioAddsAuthorities,
461     warnPrefEasyAnalyticalRecords  => $warnPrefEasyAnalyticalRecords,
462     warnPrefAnonymousPatron => $warnPrefAnonymousPatron,
463     warnPrefAnonymousPatron_PatronDoesNotExist => $warnPrefAnonymousPatron_PatronDoesNotExist,
464     errZebraConnection => $errZebraConnection,
465     warnIsRootUser => $warnIsRootUser,
466     warnNoActiveCurrency => $warnNoActiveCurrency,
467     warnNoTemplateCaching => ( C4::Context->config('template_cache_dir') ? 0 : 1 ),
468     xml_config_warnings => \@xml_config_warnings,
469     warnStatisticsFieldsError => $warnStatisticsFieldsError,
470 );
471
472 my @components = ();
473
474 my $perl_modules = C4::Installer::PerlModules->new;
475 $perl_modules->versions_info;
476
477 my @pm_types = qw(missing_pm upgrade_pm current_pm);
478
479 foreach my $pm_type(@pm_types) {
480     my $modules = $perl_modules->get_attr($pm_type);
481     foreach (@$modules) {
482         my ($module, $stats) = each %$_;
483         push(
484             @components,
485             {
486                 name    => $module,
487                 version => $stats->{'cur_ver'},
488                 missing => ($pm_type eq 'missing_pm' ? 1 : 0),
489                 upgrade => ($pm_type eq 'upgrade_pm' ? 1 : 0),
490                 current => ($pm_type eq 'current_pm' ? 1 : 0),
491                 require => $stats->{'required'},
492                 reqversion => $stats->{'min_ver'},
493             }
494         );
495     }
496 }
497
498 @components = sort {$a->{'name'} cmp $b->{'name'}} @components;
499
500 my $counter=0;
501 my $row = [];
502 my $table = [];
503 foreach (@components) {
504     push (@$row, $_);
505     unless (++$counter % 4) {
506         push (@$table, {row => $row});
507         $row = [];
508     }
509 }
510 # Processing the last line (if there are any modules left)
511 if (scalar(@$row) > 0) {
512     # Extending $row to the table size
513     $$row[3] = '';
514     # Pushing the last line
515     push (@$table, {row => $row});
516 }
517 ## ## $table
518
519 $template->param( table => $table );
520
521
522 ## ------------------------------------------
523 ## Koha contributions
524 my $docdir;
525 if ( defined C4::Context->config('docdir') ) {
526     $docdir = C4::Context->config('docdir');
527 } else {
528     # if no <docdir> is defined in koha-conf.xml, use the default location
529     # this is a work-around to stop breakage on upgraded Kohas, bug 8911
530     $docdir = C4::Context->config('intranetdir') . '/docs';
531 }
532
533 ## Release teams
534 my $teams =
535   -e "$docdir" . "/teams.yaml"
536   ? LoadFile( "$docdir" . "/teams.yaml" )
537   : {};
538 my $dev_team = (sort {$b <=> $a} (keys %{$teams->{team}}))[0];
539 my $short_version = substr($versions{'kohaVersion'},0,5);
540 my $minor = substr($versions{'kohaVersion'},3,2);
541 my $development_version = ( $minor eq '05' || $minor eq '11' ) ? 0 : 1;
542 $template->param( short_version => $short_version );
543 $template->param( development_version => $development_version );
544
545 ## Contributors
546 my $contributors =
547   -e "$docdir" . "/contributors.yaml"
548   ? LoadFile( "$docdir" . "/contributors.yaml" )
549   : {};
550 for my $version ( sort { $a <=> $b } keys %{$teams->{team}} ) {
551     for my $role ( keys %{ $teams->{team}->{$version} } ) {
552         my $normalized_role = "$role";
553         $normalized_role =~ s/s$//;
554         if ( ref( $teams->{team}->{$version}->{$role} ) eq 'ARRAY' ) {
555             for my $contributor ( @{ $teams->{team}->{$version}->{$role} } ) {
556                 my $name = $contributor->{name};
557                 # Add role to contributors
558                 push @{ $contributors->{$name}->{roles}->{$normalized_role} },
559                   $version;
560                 # Add openhub to teams
561                 if ( exists( $contributors->{$name}->{openhub} ) ) {
562                     $contributor->{openhub} = $contributors->{$name}->{openhub};
563                 }
564             }
565         }
566         elsif ( $role ne 'release_date' ) {
567             my $name = $teams->{team}->{$version}->{$role}->{name};
568             # Add role to contributors
569             push @{ $contributors->{$name}->{roles}->{$normalized_role} },
570               $version;
571             # Add openhub to teams
572             if ( exists( $contributors->{$name}->{openhub} ) ) {
573                 $teams->{team}->{$version}->{$role}->{openhub} =
574                   $contributors->{$name}->{openhub};
575             }
576         }
577         else {
578             $teams->{team}->{$version}->{$role} = DateTime->from_epoch( epoch => $teams->{team}->{$version}->{$role});
579         }
580     }
581 }
582
583 ## Create last name ordered array of people from contributors
584 my @people = map {
585     { name => $_, ( $contributors->{$_} ? %{ $contributors->{$_} } : () ) }
586 } sort {
587     my ($alast) = ( split( /\s/, $a ) )[-1];
588     my ($blast) = ( split( /\s/, $b ) )[-1];
589     lc($alast) cmp lc($blast)
590 } keys %{$contributors};
591
592 $template->param( contributors => \@people );
593 $template->param( maintenance_team => $teams->{team}->{$dev_team} );
594 $template->param( release_team => $teams->{team}->{$short_version} );
595
596 ## Timeline
597 if ( open( my $file, "<:encoding(UTF-8)", "$docdir" . "/history.txt" ) ) {
598
599     my $i = 0;
600
601     my @rows2 = ();
602     my $row2  = [];
603
604     my @lines = <$file>;
605     close($file);
606
607     shift @lines; #remove header row
608
609     foreach (@lines) {
610         my ( $epoch, $date, $desc, $tag ) = split(/\t/);
611         if(!$desc && $date=~ /(?<=\d{4})\s+/) {
612             ($date, $desc)= ($`, $');
613         }
614         push(
615             @rows2,
616             {
617                 date => $date,
618                 desc => $desc,
619             }
620         );
621     }
622
623     my $table2 = [];
624     #foreach my $row2 (@rows2) {
625     foreach  (@rows2) {
626         push (@$row2, $_);
627         push( @$table2, { row2 => $row2 } );
628         $row2 = [];
629     }
630
631     $template->param( table2 => $table2 );
632 } else {
633     $template->param( timeline_read_error => 1 );
634 }
635
636 output_html_with_http_headers $query, $cookie, $template->output;