admin/koha2marclinks.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2017 Rijksmuseum
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use CGI qw ( -utf8 );
  23
  24 use Koha::Database;
  25 use C4::Auth;
  26 use C4::Biblio;
  27 use C4::Output;
  28 use Koha::BiblioFrameworks;
  29 use Koha::Caches;
  30 use Koha::MarcSubfieldStructures;
  31
  32 my $input       = new CGI;
  33
  34 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  35     {
  36         template_name   => "admin/koha2marclinks.tt",
  37         query           => $input,
  38         type            => "intranet",
  39         authnotrequired => 0,
  40         flagsrequired   => { parameters => 'manage_marc_frameworks' },
  41         debug           => 1,
  42     }
  43 );
  44
  45 my $schema = Koha::Database->new->schema;
  46 my $cache = Koha::Caches->get_instance();
  47
  48 # Update data before showing the form
  49 my $no_upd;
  50
  51 if( $input->param('add_field') && $input->request_method eq 'POST' ) {
  52     # add a mapping to all frameworks
  53     my ($kohafield, $tag, $sub) = split /,/, $input->param('add_field'), 3;
  54     my $rs = Koha::MarcSubfieldStructures->search({ tagfield => $tag, tagsubfield => $sub });
  55     if( $rs->count ) {
  56         $rs->update({ kohafield => $kohafield });
  57     } else {
  58         $template->param( error_add => 1, error_info => "$tag, $sub" );
  59     }
  60
  61 } elsif( $input->param('remove_field') && $input->request_method eq 'POST' ) {
  62     # remove a mapping from all frameworks
  63     my ($tag, $sub) = split /,/, $input->param('remove_field'), 2;
  64     Koha::MarcSubfieldStructures->search({ tagfield => $tag, tagsubfield => $sub })->update({ kohafield => undef });
  65
  66 } else {
  67     $no_upd = 1;
  68 }
  69
  70 # Clear the cache when needed
  71 unless( $no_upd ) {
  72     for( qw| default_value_for_mod_marc- MarcSubfieldStructure- | ) {
  73         $cache->clear_from_cache($_);
  74     }
  75 }
  76
  77 # Build/Show the form
  78 my $dbix_map = {
  79     # Koha to MARC mappings are found in only three tables
  80     biblio => 'Biblio',
  81     biblioitems => 'Biblioitem',
  82     items => 'Item',
  83 };
  84 my @cols;
  85 foreach my $tbl ( sort keys %{$dbix_map} ) {
  86     push @cols,
  87         map { "$tbl.$_" } $schema->source( $dbix_map->{$tbl} )->columns;
  88 }
  89 my $kohafields = Koha::MarcSubfieldStructures->search({
  90     frameworkcode => q{},
  91     kohafield => { '>', '' },
  92 });
  93 my @loop_data;
  94 foreach my $col ( @cols ) {
  95     my $found;
  96     my $readonly = $col =~ /\.(biblio|biblioitem|item)number$/;
  97     foreach my $row ( $kohafields->search({ kohafield => $col }) ) {
  98         $found = 1;
  99         push @loop_data, {
 100             kohafield    => $col,
 101             tagfield     => $row->tagfield,
 102             tagsubfield  => $row->tagsubfield,
 103             liblibrarian => $row->liblibrarian,
 104             readonly     => $readonly,
 105         };
 106     }
 107     push @loop_data, {
 108             kohafield    => $col,
 109             readonly     => $readonly,
 110     } if !$found;
 111 }
 112
 113 $template->param(
 114     loop       => \@loop_data,
 115 );
 116
 117 output_html_with_http_headers $input, $cookie, $template->output;