basket/downloadcart.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode qw(encode);
  24
  25 use C4::Auth;
  26 use C4::Biblio;
  27 use C4::Items;
  28 use C4::Output;
  29 use C4::Record;
  30 use C4::Ris;
  31
  32 use Koha::CsvProfiles;
  33
  34 use utf8;
  35 my $query = new CGI;
  36
  37 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  38     {
  39         template_name   => "basket/downloadcart.tt",
  40         query           => $query,
  41         type            => "intranet",
  42         authnotrequired => 0,
  43         flagsrequired   => { catalogue => 1 },
  44     }
  45 );
  46
  47 my $bib_list = $query->param('bib_list');
  48 my $format  = $query->param('format');
  49 my $dbh     = C4::Context->dbh;
  50
  51 if ($bib_list && $format) {
  52
  53     my @bibs = split( /\//, $bib_list );
  54
  55     my $marcflavour         = C4::Context->preference('marcflavour');
  56     my $output;
  57
  58     # CSV
  59     if ($format =~ /^\d+$/) {
  60
  61         $output = marc2csv(\@bibs, $format);
  62
  63     # Other formats
  64     } else {
  65
  66         foreach my $biblio (@bibs) {
  67
  68             my $record = GetMarcBiblio({
  69                 biblionumber => $biblio,
  70                 embed_items  => 1 });
  71             next unless $record;
  72
  73             if ($format eq 'iso2709') {
  74                 $output .= $record->as_usmarc();
  75             }
  76             elsif ($format eq 'ris') {
  77                 $output .= marc2ris($record);
  78             }
  79             elsif ($format eq 'bibtex') {
  80                 $output .= marc2bibtex($record, $biblio);
  81             }
  82         }
  83     }
  84
  85     # If it was a CSV export we change the format after the export so the file extension is fine
  86     $format = "csv" if ($format =~ m/^\d+$/);
  87
  88     print $query->header(
  89         -type => 'application/octet-stream',
  90         -'Content-Transfer-Encoding' => 'binary',
  91         -attachment=>"cart.$format");
  92     print $output;
  93
  94 } else {
  95     $template->param(csv_profiles => [ Koha::CsvProfiles->search({ type => 'marc', used_for => 'export_records' }) ]);
  96     $template->param(bib_list => $bib_list);
  97     output_html_with_http_headers $query, $cookie, $template->output;
  98 }