members/statistics.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2012 BibLibre
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 =head1 members/statistics.pl
  20
  21   Generate statistic issues for a member
  22
  23 =cut
  24
  25 use Modern::Perl;
  26
  27 use CGI qw ( -utf8 );
  28 use C4::Auth;
  29 use C4::Context;
  30 use C4::Members;
  31 use C4::Members::Statistics;
  32 use C4::Members::Attributes qw(GetBorrowerAttributes);
  33 use C4::Output;
  34 use Koha::Patrons;
  35
  36 my $input = new CGI;
  37
  38 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  39     {   template_name   => "members/statistics.tt",
  40         query           => $input,
  41         type            => "intranet",
  42         authnotrequired => 0,
  43         flagsrequired   => { borrowers => 'edit_borrowers' },
  44         debug           => 1,
  45     }
  46 );
  47
  48 my $borrowernumber = $input->param('borrowernumber');
  49
  50 my $logged_in_user = Koha::Patrons->find( $loggedinuser ) or die "Not logged in";
  51 my $patron         = Koha::Patrons->find( $borrowernumber );
  52 output_and_exit_if_error( $input, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
  53
  54 my $category = $patron->category;
  55
  56 # Construct column names
  57 my $fields = C4::Members::Statistics::get_fields();
  58 our @statistic_column_names = split '\|', $fields;
  59 our @value_column_names = ( 'count_precedent_state', 'count_total_issues_today', 'count_total_issues_returned_today' );
  60 our @column_names = ( @statistic_column_names, @value_column_names );
  61
  62 # Get statistics
  63 my $precedent_state = GetPrecedentStateByBorrower( $borrowernumber );
  64 my $total_issues_today = GetTotalIssuesTodayByBorrower( $borrowernumber );
  65 my $total_issues_returned_today = GetTotalIssuesReturnedTodayByBorrower( $borrowernumber );
  66 my $r = merge (
  67     @$precedent_state, @$total_issues_today, @$total_issues_returned_today
  68 );
  69
  70 add_actual_state( $r );
  71 my ( $total, $datas ) = build_array( $r );
  72
  73 # Gettings sums
  74 my $count_total_precedent_state = $total->{count_precedent_state} || 0;
  75 my $count_total_issues = $total->{count_total_issues_today} || 0;
  76 my $count_total_issues_returned = $total->{count_total_issues_returned_today} || 0;
  77 my $count_total_actual_state = ($count_total_precedent_state - $count_total_issues_returned + $count_total_issues);
  78
  79 if (C4::Context->preference('ExtendedPatronAttributes')) {
  80     my $attributes = GetBorrowerAttributes($borrowernumber);
  81     $template->param(
  82         ExtendedPatronAttributes => 1,
  83         extendedattributes => $attributes
  84     );
  85 }
  86
  87 $template->param(
  88     patron             => $patron,
  89     statisticsview     => 1,
  90     datas              => $datas,
  91     column_names       => \@statistic_column_names,
  92     count_total_issues => $count_total_issues,
  93     count_total_issues_returned => $count_total_issues_returned,
  94     count_total_precedent_state => $count_total_precedent_state,
  95     count_total_actual_state => $count_total_actual_state,
  96 );
  97
  98 output_html_with_http_headers $input, $cookie, $template->output;
  99
 100
 101 =head1 FUNCTIONS
 102
 103 =head2 add_actual_state
 104
 105   Add a 'count_actual_state' key in all hashes
 106   count_actual_state = count_precedent_state - count_total_issues_returned_today + count_total_issues_today
 107
 108 =cut
 109
 110 sub add_actual_state {
 111     my ( $array ) = @_;
 112     for my $hash ( @$array ) {
 113         $hash->{count_actual_state} = ( $hash->{count_precedent_state} // 0 ) - ( $hash->{count_total_issues_returned_today} // 0 ) + ( $hash->{count_total_issues_today} // 0 );
 114     }
 115 }
 116
 117 =head2 build_array
 118
 119   Build a new array containing values of hashes.
 120   It used by template whitch display silly values.
 121   ex:
 122     $array = [
 123       {
 124         'count_total_issues_returned_today' => 1,
 125         'ccode' => 'ccode',
 126         'count_actual_state' => 1,
 127         'count_precedent_state' => 1,
 128         'homebranch' => 'homebranch',
 129         'count_total_issues_today' => 1,
 130         'itype' => 'itype'
 131       }
 132     ];
 133   and returns:
 134     [
 135       [
 136         'homebranch',
 137         'itype',
 138         'ccode',
 139         1,
 140         1,
 141         1,
 142         1
 143       ]
 144     ];
 145
 146 =cut
 147
 148 sub build_array {
 149     my ( $array ) = @_;
 150     my ( @r, $total );
 151     for my $hash ( @$array) {
 152         my @line;
 153         for my $cn ( ( @column_names, 'count_actual_state') ) {
 154             if ( grep /$cn/, ( @value_column_names, 'count_actual_state') ) {
 155                 $hash->{$cn} //= 0;
 156                 if ( exists $total->{$cn} ) {
 157                     $total->{$cn} += $hash->{$cn} if $hash->{$cn};
 158                 } else {
 159                     $total->{$cn} = $hash->{$cn};
 160                 }
 161             }
 162             push @line, $hash->{$cn};
 163         }
 164         push @r, \@line;
 165     }
 166     return ( $total, \@r );
 167 }
 168
 169 =head2 merge
 170
 171   Merge hashes with the same statistic column names into one
 172   param: array, a arrayref of arrayrefs
 173   ex:
 174   @array = (
 175      {
 176        'ccode' => 'ccode',
 177        'count_precedent_state' => '1',
 178        'homebranch' => 'homebranch',
 179        'itype' => 'itype'
 180      },
 181      {
 182        'count_total_issues_returned_today' => '1',
 183        'ccode' => 'ccode',
 184        'homebranch' => 'homebranch',
 185        'itype' => 'itype'
 186      }
 187    );
 188    and returns:
 189    [
 190      {
 191        'count_total_issues_returned_today' => '1',
 192        'ccode' => 'ccode',
 193        'count_precedent_state' => '1',
 194        'homebranch' => 'homebranch',
 195        'itype' => 'itype'
 196      }
 197    ];
 198
 199 =cut
 200
 201 sub merge {
 202     my @array = @_;
 203     my @r;
 204     for my $h ( @array ) {
 205         my $exists = 0;
 206         for my $ch ( @r ) {
 207             $exists = 1;
 208             for my $cn ( @statistic_column_names ) {
 209                 if ( $ch->{$cn} and not $ch->{$cn} eq $h->{$cn} ) {
 210                     $exists = 0;
 211                     last;
 212                 }
 213             }
 214             if ($exists){
 215                 for my $cn ( @value_column_names ) {
 216                     next if not exists $h->{$cn};
 217                     $ch->{$cn} = $h->{$cn} ? $h->{$cn} : 0;
 218                 }
 219                 last;
 220             }
 221         }
 222
 223         if ( not $exists ) {push @r, $h;}
 224     }
 225     return \@r;
 226 }