opac/opac-export.pl

   1 #!/usr/bin/perl
   2
   3 # Parts Copyright Catalyst IT 2011
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use C4::Record;
  23 use C4::Auth;
  24 use C4::Output;
  25 use C4::Biblio;
  26 use CGI qw ( -utf8 );
  27 use C4::Auth;
  28 use C4::Ris;
  29 use Koha::RecordProcessor;
  30
  31 my $query = CGI->new;
  32 my $op=$query->param("op")||''; #op=export is currently the only use
  33 my $format=$query->param("format")||'utf8';
  34 my $biblionumber = $query->param("bib")||0;
  35 $biblionumber = int($biblionumber);
  36 my $error = q{};
  37
  38 my $include_items = ($format =~ /bibtex/) ? 0 : 1;
  39 my $marc = GetMarcBiblio($biblionumber, $include_items)
  40     if $biblionumber;
  41
  42 if(!$marc) {
  43     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  44     exit;
  45 }
  46
  47 # ASSERT: There is a biblionumber, because GetMarcBiblio returned something.
  48 my $framework = GetFrameworkCode( $biblionumber );
  49 my $record_processor = Koha::RecordProcessor->new({
  50     filters => 'ViewPolicy',
  51     options => {
  52         interface => 'opac',
  53         frameworkcode => $framework
  54     }
  55 });
  56 $record_processor->process($marc);
  57
  58 if ($format =~ /endnote/) {
  59     $marc = marc2endnote($marc);
  60     $format = 'endnote';
  61 }
  62 elsif ($format =~ /marcxml/) {
  63     $marc = marc2marcxml($marc);
  64     $format = 'marcxml';
  65 }
  66 elsif ($format=~ /mods/) {
  67     $marc = marc2modsxml($marc);
  68     $format = 'mods';
  69 }
  70 elsif ($format =~ /ris/) {
  71     $marc = marc2ris($marc);
  72     $format = 'ris';
  73 }
  74 elsif ($format =~ /bibtex/) {
  75     $marc = marc2bibtex($marc,$biblionumber);
  76     $format = 'bibtex';
  77 }
  78 elsif ($format =~ /dc$/) {
  79     # TODO: Dublin Core leaks fields marked hidden by framework.
  80     $marc = marc2dcxml($marc, undef, $biblionumber, $format);
  81     $format = "dublin-core.xml";
  82 }
  83 elsif ($format =~ /marc8/) {
  84     ($error,$marc) = changeEncoding($marc,"MARC","MARC21","MARC-8");
  85     $marc = $marc->as_usmarc() unless $error;
  86     $format = 'marc8';
  87 }
  88 elsif ($format =~ /utf8/) {
  89     C4::Charset::SetUTF8Flag($marc,1);
  90     $marc = $marc->as_usmarc();
  91     $format = 'utf8';
  92 }
  93 elsif ($format =~ /marcstd/) {
  94     C4::Charset::SetUTF8Flag($marc,1);
  95     ($error,$marc) = marc2marc($marc, 'marcstd', C4::Context->preference('marcflavour'));
  96     $format = 'marcstd';
  97 }
  98 elsif ( $format =~ /isbd/ ) {
  99     $marc   = GetISBDView({
 100         'record'    => $marc,
 101         'template'  => 'opac',
 102         'framework' => $framework,
 103     });
 104     $format = 'isbd';
 105 }
 106 else {
 107     $error= "Format $format is not supported.";
 108 }
 109
 110 if ($error){
 111     print $query->header();
 112     print $query->start_html();
 113     print "<h1>An error occurred </h1>";
 114     print $query->escapeHTML("$error");
 115     print $query->end_html();
 116 }
 117 else {
 118     if ($format eq 'marc8'){
 119         print $query->header(
 120             -type => 'application/marc',
 121             -charset=>'ISO-2022',
 122             -attachment=>"bib-$biblionumber.$format");
 123     }
 124     elsif ( $format eq 'isbd' ) {
 125         print $query->header(
 126             -type       => 'text/plain',
 127             -charset    => 'utf-8',
 128             -attachment =>  "bib-$biblionumber.txt"
 129         );
 130     } else {
 131         binmode STDOUT, ':encoding(UTF-8)';
 132         print $query->header(
 133             -type => 'application/octet-stream',
 134             -charset => 'utf-8',
 135             -attachment => "bib-$biblionumber.$format"
 136         );
 137     }
 138     print $marc;
 139 }
 140
 141 1;