opac/opac-shelves.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2015 Koha Team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use C4::Auth;
  24 use C4::Biblio;
  25 use C4::Koha;
  26 use C4::Items;
  27 use C4::Members;
  28 use C4::Output;
  29 use C4::Tags qw( get_tags );
  30 use C4::XSLT;
  31
  32 use Koha::Biblios;
  33 use Koha::Biblioitems;
  34 use Koha::IssuingRules;
  35 use Koha::Items;
  36 use Koha::ItemTypes;
  37 use Koha::Patrons;
  38 use Koha::Virtualshelves;
  39 use Koha::RecordProcessor;
  40
  41 use constant ANYONE => 2;
  42
  43 my $query = new CGI;
  44
  45 my $template_name = $query->param('rss') ? "opac-shelves-rss.tt" : "opac-shelves.tt";
  46
  47 # if virtualshelves is disabled, leave immediately
  48 if ( ! C4::Context->preference('virtualshelves') ) {
  49     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  50     exit;
  51 }
  52
  53 my ( $template, $loggedinuser, $cookie ) = get_template_and_user({
  54         template_name   => $template_name,
  55         query           => $query,
  56         type            => "opac",
  57         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  58     });
  59
  60 my $op       = $query->param('op')       || 'list';
  61 my $referer  = $query->param('referer')  || $op;
  62 my $category = $query->param('category') || 1;
  63 my ( $shelf, $shelfnumber, @messages );
  64
  65 if ( $op eq 'add_form' ) {
  66     # Only pass default
  67     $shelf = { allow_change_from_owner => 1 };
  68 } elsif ( $op eq 'edit_form' ) {
  69     $shelfnumber = $query->param('shelfnumber');
  70     $shelf       = Koha::Virtualshelves->find($shelfnumber);
  71
  72     if ( $shelf ) {
  73         $category = $shelf->category;
  74         my $patron = Koha::Patrons->find( $shelf->owner );
  75         $template->param( owner => $patron, );
  76         unless ( $shelf->can_be_managed( $loggedinuser ) ) {
  77             push @messages, { type => 'error', code => 'unauthorized_on_update' };
  78             $op = 'list';
  79         }
  80     } else {
  81         push @messages, { type => 'error', code => 'does_not_exist' };
  82     }
  83 } elsif ( $op eq 'add' ) {
  84     if ( $loggedinuser ) {
  85         my $allow_changes_from = $query->param('allow_changes_from');
  86         eval {
  87             $shelf = Koha::Virtualshelf->new(
  88                 {   shelfname          => scalar $query->param('shelfname'),
  89                     sortfield          => scalar $query->param('sortfield'),
  90                     category           => scalar $query->param('category') || 1,
  91                     allow_change_from_owner => $allow_changes_from > 0,
  92                     allow_change_from_others => $allow_changes_from == ANYONE,
  93                     owner              => scalar $loggedinuser,
  94                 }
  95             );
  96             $shelf->store;
  97             $shelfnumber = $shelf->shelfnumber;
  98         };
  99         if ($@) {
 100             push @messages, { type => 'error', code => ref($@), msg => $@ };
 101         } elsif ( not $shelf ) {
 102             push @messages, { type => 'error', code => 'error_on_insert' };
 103         } else {
 104             push @messages, { type => 'message', code => 'success_on_insert' };
 105             $op = 'view';
 106         }
 107     } else {
 108         push @messages, { type => 'error', code => 'unauthorized_on_insert' };
 109         $op = 'list';
 110     }
 111 } elsif ( $op eq 'edit' ) {
 112     $shelfnumber = $query->param('shelfnumber');
 113     $shelf       = Koha::Virtualshelves->find($shelfnumber);
 114     if ( $shelf ) {
 115         $op = $referer;
 116         my $sortfield = $query->param('sortfield');
 117         $sortfield = 'title' unless grep {/^$sortfield$/}qw( title author copyrightdate itemcallnumber dateadded );
 118         if ( $shelf->can_be_managed( $loggedinuser ) ) {
 119             $shelf->shelfname( scalar $query->param('shelfname') );
 120             $shelf->sortfield( $sortfield );
 121             my $allow_changes_from = $query->param('allow_changes_from');
 122             $shelf->allow_change_from_owner( $allow_changes_from > 0 );
 123             $shelf->allow_change_from_others( $allow_changes_from == ANYONE );
 124             $shelf->category( scalar $query->param('category') );
 125             eval { $shelf->store };
 126
 127             if ($@) {
 128                 push @messages, { type => 'error', code => 'error_on_update' };
 129                 $op = 'edit_form';
 130             } else {
 131                 push @messages, { type => 'message', code => 'success_on_update' };
 132             }
 133         } else {
 134             push @messages, { type => 'error', code => 'unauthorized_on_update' };
 135         }
 136     } else {
 137         push @messages, { type => 'error', code => 'does_not_exist' };
 138     }
 139 } elsif ( $op eq 'delete' ) {
 140     $shelfnumber = $query->param('shelfnumber');
 141     $shelf       = Koha::Virtualshelves->find($shelfnumber);
 142     if ($shelf) {
 143         if ( $shelf->can_be_deleted( $loggedinuser ) ) {
 144             eval { $shelf->delete; };
 145             if ($@) {
 146                 push @messages, { type => 'error', code => ref($@), msg => $@ };
 147             } else {
 148                 push @messages, { type => 'message', code => 'success_on_delete' };
 149             }
 150         } else {
 151             push @messages, { type => 'error', code => 'unauthorized_on_delete' };
 152         }
 153     } else {
 154         push @messages, { type => 'error', code => 'does_not_exist' };
 155     }
 156     $op = $referer;
 157 } elsif ( $op eq 'remove_share' ) {
 158     $shelfnumber = $query->param('shelfnumber');
 159     $shelf = Koha::Virtualshelves->find($shelfnumber);
 160     if ($shelf) {
 161         my $removed = eval { $shelf->remove_share( $loggedinuser ); };
 162         if ($@) {
 163             push @messages, { type => 'error', code => ref($@), msg => $@ };
 164         } elsif ( $removed ) {
 165             push @messages, { type => 'message', code => 'success_on_remove_share' };
 166         } else {
 167             push @messages, { type => 'error', code => 'error_on_remove_share' };
 168         }
 169     } else {
 170         push @messages, { type => 'error', code => 'does_not_exist' };
 171     }
 172     $op = $referer;
 173
 174 } elsif ( $op eq 'add_biblio' ) {
 175     $shelfnumber = $query->param('shelfnumber');
 176     $shelf = Koha::Virtualshelves->find($shelfnumber);
 177     if ($shelf) {
 178         if( my $barcode = $query->param('barcode') ) {
 179             my $item = Koha::Items->find({ barcode => $barcode });
 180             if ( $item ) {
 181                 if ( $shelf->can_biblios_be_added( $loggedinuser ) ) {
 182                     my $added = eval { $shelf->add_biblio( $item->biblionumber, $loggedinuser ); };
 183                     if ($@) {
 184                         push @messages, { type => 'error', code => ref($@), msg => $@ };
 185                     } elsif ( $added ) {
 186                         push @messages, { type => 'message', code => 'success_on_add_biblio' };
 187                     } else {
 188                         push @messages, { type => 'message', code => 'error_on_add_biblio' };
 189                     }
 190                 } else {
 191                     push @messages, { type => 'error', code => 'unauthorized_on_add_biblio' };
 192                 }
 193             } else {
 194                 push @messages, { type => 'error', code => 'item_does_not_exist' };
 195             }
 196         }
 197     } else {
 198         push @messages, { type => 'error', code => 'does_not_exist' };
 199     }
 200     $op = $referer;
 201 } elsif ( $op eq 'remove_biblios' ) {
 202     $shelfnumber = $query->param('shelfnumber');
 203     $shelf = Koha::Virtualshelves->find($shelfnumber);
 204     my @biblionumber = $query->multi_param('biblionumber');
 205     if ($shelf) {
 206         if ( $shelf->can_biblios_be_removed( $loggedinuser ) ) {
 207             my $number_of_biblios_removed = eval {
 208                 $shelf->remove_biblios(
 209                     {
 210                         biblionumbers => \@biblionumber,
 211                         borrowernumber => $loggedinuser,
 212                     }
 213                 );
 214             };
 215             if ($@) {
 216                 push @messages, { type => 'error', code => ref($@), msg => $@ };
 217             } elsif ( $number_of_biblios_removed ) {
 218                 push @messages, { type => 'message', code => 'success_on_remove_biblios' };
 219             } else {
 220                 push @messages, { type => 'error', code => 'no_biblio_removed' };
 221             }
 222         } else {
 223             push @messages, { type => 'error', code => 'unauthorized_on_remove_biblios' };
 224         }
 225     } else {
 226         push @messages, { type => 'error', code => 'does_not_exist' };
 227     }
 228     $op = 'view';
 229 }
 230
 231 if ( $op eq 'view' ) {
 232     $shelfnumber ||= $query->param('shelfnumber');
 233     $shelf = Koha::Virtualshelves->find($shelfnumber);
 234     if ( $shelf ) {
 235         if ( $shelf->can_be_viewed( $loggedinuser ) ) {
 236             $category = $shelf->category;
 237             my $sortfield = $query->param('sortfield') || $shelf->sortfield;    # Passed in sorting overrides default sorting
 238             $sortfield = 'title' unless grep {/^$sortfield$/}qw( title author copyrightdate itemcallnumber dateadded );
 239             my $direction = $query->param('direction') || 'asc';
 240             $direction = 'asc' if $direction ne 'asc' and $direction ne 'desc';
 241             my ( $page, $rows );
 242             unless ( $query->param('print') or $query->param('rss') ) {
 243                 $rows = C4::Context->preference('OPACnumSearchResults') || 20;
 244                 $page = ( $query->param('page') ? $query->param('page') : 1 );
 245             }
 246             my $order_by = $sortfield eq 'itemcallnumber' ? 'items.cn_sort' : $sortfield;
 247             my $contents = $shelf->get_contents->search(
 248                 {},
 249                 {
 250                     prefetch => [ { 'biblionumber' => { 'biblioitems' => 'items' } } ],
 251                     page     => $page,
 252                     rows     => $rows,
 253                     order_by => { "-$direction" => $order_by },
 254                 }
 255             );
 256
 257             # get biblionumbers stored in the cart
 258             my @cart_list;
 259             if(my $cart_list = $query->cookie('bib_list')){
 260                 @cart_list = split(/\//, $cart_list);
 261             }
 262
 263             my $patron = Koha::Patrons->find( $loggedinuser );
 264
 265             # Lists display falls back to search results configuration
 266             my $xslfile = C4::Context->preference('OPACXSLTListsDisplay');
 267             my $lang   = $xslfile ? C4::Languages::getlanguage()  : undef;
 268             my $sysxml = $xslfile ? C4::XSLT::get_xslt_sysprefs() : undef;
 269
 270             my $record_processor = Koha::RecordProcessor->new({ filters => 'ViewPolicy' });
 271             my @items;
 272             while ( my $content = $contents->next ) {
 273                 my $biblionumber = $content->biblionumber;
 274                 my $this_item    = GetBiblioData($biblionumber);
 275                 my $record = GetMarcBiblio({ biblionumber => $biblionumber });
 276                 my $framework = GetFrameworkCode( $biblionumber );
 277                 my $biblio = Koha::Biblios->find( $biblionumber );
 278                 $record_processor->options({
 279                     interface => 'opac',
 280                     frameworkcode => $framework
 281                 });
 282                 $record_processor->process($record);
 283
 284                 if ( $xslfile ) {
 285                     $this_item->{XSLTBloc} = XSLTParse4Display( $biblionumber, $record, "OPACXSLTListsDisplay",
 286                                                                 1, undef, $sysxml, $xslfile, $lang);
 287                 }
 288
 289                 my $marcflavour = C4::Context->preference("marcflavour");
 290                 my $itemtype = Koha::Biblioitems->search({ biblionumber => $content->biblionumber })->next->itemtype;
 291                 $itemtype = Koha::ItemTypes->find( $itemtype );
 292                 if( $itemtype ) {
 293                     $this_item->{imageurl}          = C4::Koha::getitemtypeimagelocation( 'opac', $itemtype->imageurl );
 294                     $this_item->{description}       = $itemtype->description; #FIXME Should not it be translated_description?
 295                     $this_item->{notforloan}        = $itemtype->notforloan;
 296                 }
 297                 $this_item->{'coins'}           = GetCOinSBiblio($record);
 298                 $this_item->{'subtitle'}        = GetRecordValue( 'subtitle', $record, GetFrameworkCode( $biblionumber ) );
 299                 $this_item->{'normalized_upc'}  = GetNormalizedUPC( $record, $marcflavour );
 300                 $this_item->{'normalized_ean'}  = GetNormalizedEAN( $record, $marcflavour );
 301                 $this_item->{'normalized_oclc'} = GetNormalizedOCLCNumber( $record, $marcflavour );
 302                 $this_item->{'normalized_isbn'} = GetNormalizedISBN( undef, $record, $marcflavour );
 303
 304                 unless ( defined $this_item->{size} ) {
 305
 306                     #TT has problems with size
 307                     $this_item->{size} = q||;
 308                 }
 309
 310                 # Getting items infos for location display
 311                 my @items_infos = &GetItemsLocationInfo( $biblionumber );
 312                 $this_item->{'ITEM_RESULTS'} = \@items_infos;
 313
 314                 if (C4::Context->preference('TagsEnabled') and C4::Context->preference('TagsShowOnList')) {
 315                     $this_item->{TagLoop} = get_tags({
 316                         biblionumber => $biblionumber, approved=>1, 'sort'=>'-weight',
 317                         limit => C4::Context->preference('TagsShowOnList'),
 318                     });
 319                 }
 320
 321                 my $items = $biblio->items;
 322                 while ( my $item = $items->next ) {
 323                     $this_item->{allow_onshelf_holds} = Koha::IssuingRules->get_onshelfholds_policy( { item => $item, patron => $patron } );
 324                     last if $this_item->{allow_onshelf_holds};
 325                 }
 326
 327                 if ( grep {$_ eq $biblionumber} @cart_list) {
 328                     $this_item->{incart} = 1;
 329                 }
 330
 331                 $this_item->{biblionumber} = $biblionumber;
 332                 push @items, $this_item;
 333             }
 334
 335             $template->param(
 336                 can_manage_shelf   => $shelf->can_be_managed($loggedinuser),
 337                 can_delete_shelf   => $shelf->can_be_deleted($loggedinuser),
 338                 can_remove_biblios => $shelf->can_biblios_be_removed($loggedinuser),
 339                 can_add_biblios    => $shelf->can_biblios_be_added($loggedinuser),
 340                 itemsloop          => \@items,
 341                 sortfield          => $sortfield,
 342                 direction          => $direction,
 343             );
 344             if ( $page ) {
 345                 my $pager = $contents->pager;
 346                 $template->param(
 347                     pagination_bar => pagination_bar(
 348                         q||, $pager->last_page - $pager->first_page + 1,
 349                         $page, "page", { op => 'view', shelfnumber => $shelf->shelfnumber, sortfield => $sortfield, direction => $direction, }
 350                     ),
 351                 );
 352             }
 353         } else {
 354             push @messages, { type => 'error', code => 'unauthorized_on_view' };
 355             undef $shelf;
 356         }
 357     } else {
 358         push @messages, { type => 'error', code => 'does_not_exist' };
 359     }
 360 }
 361
 362 if ( $op eq 'list' ) {
 363     my $shelves;
 364     my ( $page, $rows ) = ( $query->param('page') || 1, 20 );
 365     if ( $category == 1 ) {
 366         $shelves = Koha::Virtualshelves->get_private_shelves({ page => $page, rows => $rows, borrowernumber => $loggedinuser, });
 367     } else {
 368         $shelves = Koha::Virtualshelves->get_public_shelves({ page => $page, rows => $rows, });
 369     }
 370
 371     my $pager = $shelves->pager;
 372     $template->param(
 373         shelves => $shelves,
 374         pagination_bar => pagination_bar(
 375             q||, $pager->last_page - $pager->first_page + 1,
 376             $page, "page", { op => 'list', category => $category, }
 377         ),
 378     );
 379 }
 380
 381 $template->param(
 382     op       => $op,
 383     referer  => $referer,
 384     shelf    => $shelf,
 385     messages => \@messages,
 386     category => $category,
 387     print    => scalar $query->param('print') || 0,
 388     listsview => 1,
 389 );
 390
 391 output_html_with_http_headers $query, $cookie, $template->output;