tools/automatic_item_modification_by_age.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright 2013 BibLibre
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 automatic_item_modification_by_age.pl: Update new status for items.
  23
  24 =cut
  25
  26 =head1 DESCRIPTION
  27
  28 This script allows a user to update the new status for items.
  29
  30 =cut
  31
  32 use Modern::Perl;
  33
  34 use CGI;
  35 use JSON qw( to_json from_json );
  36
  37 use C4::Auth;
  38 use C4::Context;
  39 use C4::Items;
  40 use C4::Output;
  41 use C4::Koha;
  42
  43 use Koha::Items;
  44 use Koha::Biblioitems;
  45
  46 my $cgi = new CGI;
  47
  48 # open template
  49 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  50     {
  51         template_name   => "tools/automatic_item_modification_by_age.tt",
  52         query           => $cgi,
  53         type            => "intranet",
  54         authnotrequired => 0,
  55         flagsrequired   => { tools => 'items_batchmod' },
  56     }
  57 );
  58
  59 my $op = $cgi->param('op') // 'show';
  60
  61 my $syspref_name = q|automatic_item_modification_by_age_configuration|;
  62 if ( $op eq 'update' ) {
  63     my @rules;
  64     my @unique_ids = $cgi->multi_param('unique_id');
  65     for my $unique_id ( @unique_ids ) {
  66         my @substitution_fields = $cgi->multi_param("substitution_field_$unique_id");
  67         my @substitution_values = $cgi->multi_param("substitution_value_$unique_id");
  68         my @condition_fields = $cgi->multi_param("condition_field_$unique_id");
  69         my @condition_values = $cgi->multi_param("condition_value_$unique_id");
  70         my $rule = {
  71             substitutions => [],
  72             conditions => [],
  73         };
  74         for my $value ( @substitution_values ) {
  75             my $field = shift @substitution_fields;
  76             last unless $field;
  77             push @{ $rule->{substitutions} }, { field => $field, value => $value };
  78         }
  79         push @{ $rule->{substitutions} }, {}
  80             unless @{ $rule->{substitutions} };
  81         for my $value ( @condition_values ) {
  82             my $field = shift @condition_fields;
  83             last unless $field;
  84             push @{ $rule->{conditions} }, { field => $field, value => $value };
  85         }
  86         push @{ $rule->{conditions} }, {}
  87             unless @{ $rule->{conditions} };
  88         $rule->{age} = $cgi->param("age_$unique_id");
  89         push @rules, $rule;
  90     }
  91     my $syspref_content = to_json( \@rules );
  92     C4::Context->set_preference($syspref_name, $syspref_content);
  93
  94     $op = 'show';
  95 }
  96
  97 my @messages;
  98 my $syspref_content = C4::Context->preference($syspref_name);
  99 my $rules;
 100 $rules = eval { JSON::from_json( $syspref_content ) }
 101     if $syspref_content;
 102 if ( $@ ) {
 103     push @messages, {
 104         type => 'error',
 105         code => 'unable_to_load_configuration'
 106     };
 107     $template->param( messages => \@messages );
 108     output_html_with_http_headers $cgi, $cookie, $template->output;
 109     exit;
 110 }
 111
 112 my @item_fields = map { "items.$_" } Koha::Items->columns;
 113 my @biblioitem_fields = map { "biblioitems.$_" } Koha::Biblioitems->columns;
 114 $template->param(
 115     op => $op,
 116     messages => \@messages,
 117     condition_fields => [ @item_fields, @biblioitem_fields ],
 118     substitution_fields => \@item_fields,
 119     rules => $rules,
 120 );
 121
 122 output_html_with_http_headers $cgi, $cookie, $template->output;