tools/cleanborrowers.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17 #
  18 #   Written by Antoine Farnault antoine@koha-fr.org on Nov. 2006.
  19
  20 =head1 cleanborrowers.pl
  21
  22 This script allows to do 2 things.
  23
  24 =over 2
  25
  26 =item * Anonymise the borrowers' issues if issue is older than a given date. see C<datefilter1>.
  27
  28 =item * Delete the borrowers who has not borrowed since a given date. see C<datefilter2>.
  29
  30 =back
  31
  32 =cut
  33
  34 use Modern::Perl;
  35
  36 use CGI qw ( -utf8 );
  37 use C4::Auth;
  38 use C4::Output;
  39 use C4::Members;
  40 use C4::Circulation;    # AnonymiseIssueHistory.
  41 use Koha::DateUtils qw( dt_from_string output_pref );
  42 use Koha::Patron::Categories;
  43 use Koha::Patrons;
  44 use Date::Calc qw/Today Add_Delta_YM/;
  45 use Koha::Patrons;
  46 use Koha::List::Patron;
  47
  48 my $cgi = new CGI;
  49
  50 # Fetch the paramater list as a hash in scalar context:
  51 #  * returns paramater list as tied hash ref
  52 #  * we can edit the values by changing the key
  53 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
  54 my $params = $cgi->Vars;
  55
  56 my $step = $params->{step} || 1;
  57 my $not_borrowed_since =    # the date which filter on issue history.
  58   $params->{not_borrowed_since}
  59   ? dt_from_string $params->{not_borrowed_since}
  60   : undef;
  61 my $last_issue_date =         # the date which filter on borrowers last issue.
  62   $params->{last_issue_date}
  63   ? dt_from_string $params->{last_issue_date}
  64   : undef;
  65 my $borrower_dateexpiry =
  66   $params->{borrower_dateexpiry}
  67   ? dt_from_string $params->{borrower_dateexpiry}
  68   : undef;
  69 my $borrower_lastseen =
  70   $params->{borrower_lastseen}
  71   ? dt_from_string $params->{borrower_lastseen}
  72   : undef;
  73 my $patron_list_id = $params->{patron_list_id};
  74
  75 my $borrower_categorycode = $params->{'borrower_categorycode'} || q{};
  76
  77 # getting the template
  78 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  79     {   template_name   => "tools/cleanborrowers.tt",
  80         query           => $cgi,
  81         type            => "intranet",
  82         authnotrequired => 0,
  83         flagsrequired   => { tools => 'delete_anonymize_patrons', catalogue => 1 },
  84     }
  85 );
  86
  87 my $branch = $params->{ branch } || '*';
  88 $template->param( current_branch => $branch );
  89 $template->param( OnlyMine => C4::Context->only_my_library );
  90
  91 if ( $step == 2 ) {
  92
  93     my %checkboxes = map { $_ => 1 } split /\0/, $params->{'checkbox'};
  94
  95     my $patrons_to_delete;
  96     if ( $checkboxes{borrower} ) {
  97         $patrons_to_delete = GetBorrowersToExpunge(
  98              _get_selection_params(
  99                   $not_borrowed_since,
 100                   $borrower_dateexpiry,
 101                   $borrower_lastseen,
 102                   $borrower_categorycode,
 103                   $patron_list_id,
 104                   $branch
 105              )
 106         );
 107     }
 108     _skip_borrowers_with_nonzero_balance($patrons_to_delete);
 109
 110     my $patrons_to_anonymize =
 111         $checkboxes{issue}
 112       ? $branch eq '*'
 113           ? Koha::Patrons->search_patrons_to_anonymise( { before => $last_issue_date } )
 114           : Koha::Patrons->search_patrons_to_anonymise( { before => $last_issue_date, library => $branch } )
 115       : undef;
 116
 117     $template->param(
 118         patrons_to_delete    => $patrons_to_delete,
 119         patrons_to_anonymize => $patrons_to_anonymize,
 120         patron_list_id       => $patron_list_id,
 121     );
 122 }
 123
 124 elsif ( $step == 3 ) {
 125     my $do_delete = $params->{'do_delete'};
 126     my $do_anonym = $params->{'do_anonym'};
 127
 128     my ( $totalDel, $totalAno, $radio ) = ( 0, 0, 0 );
 129
 130     # delete members
 131     if ($do_delete) {
 132         my $patrons_to_delete = GetBorrowersToExpunge(
 133                 _get_selection_params(
 134                     $not_borrowed_since,
 135                     $borrower_dateexpiry,
 136                     $borrower_lastseen,
 137                     $borrower_categorycode,
 138                     $patron_list_id,
 139                     $branch
 140                 )
 141             );
 142         _skip_borrowers_with_nonzero_balance($patrons_to_delete);
 143
 144         $totalDel = scalar(@$patrons_to_delete);
 145         $radio    = $params->{'radio'};
 146         for ( my $i = 0 ; $i < $totalDel ; $i++ ) {
 147             $radio eq 'testrun' && last;
 148             my $borrowernumber = $patrons_to_delete->[$i]->{'borrowernumber'};
 149             my $patron = Koha::Patrons->find($borrowernumber);
 150             $radio eq 'trash' && $patron->move_to_deleted;
 151             $patron->delete;
 152         }
 153         $template->param(
 154             do_delete => '1',
 155             TotalDel  => $totalDel
 156         );
 157     }
 158
 159     # Anonymising all members
 160     if ($do_anonym) {
 161         #FIXME: anonymisation errors are not handled
 162         my $rows = Koha::Patrons->search_patrons_to_anonymise( { before => $last_issue_date } )->anonymise_issue_history( { before => $last_issue_date } );
 163         $template->param(
 164             do_anonym   => $rows,
 165         );
 166     }
 167
 168     $template->param(
 169         trash => ( $radio eq "trash" ) ? (1) : (0),
 170         testrun => ( $radio eq "testrun" ) ? 1: 0,
 171     );
 172 } else { # $step == 1
 173     my @all_lists = GetPatronLists();
 174     my @non_empty_lists;
 175     foreach my $list (@all_lists){
 176     my @patrons = $list->patron_list_patrons();
 177         if( scalar @patrons ) { push(@non_empty_lists,$list) }
 178     }
 179     $template->param( patron_lists => [ @non_empty_lists ] );
 180 }
 181
 182 my $patron_categories = Koha::Patron::Categories->search_limited({}, {order_by => ['description']});
 183
 184 $template->param(
 185     step                   => $step,
 186     not_borrowed_since   => $not_borrowed_since,
 187     borrower_dateexpiry    => $borrower_dateexpiry,
 188     borrower_lastseen      => $borrower_lastseen,
 189     last_issue_date        => $last_issue_date,
 190     borrower_categorycodes => $patron_categories,
 191     borrower_categorycode  => $borrower_categorycode,
 192 );
 193
 194 #writing the template
 195 output_html_with_http_headers $cgi, $cookie, $template->output;
 196
 197 sub _skip_borrowers_with_nonzero_balance {
 198     my $borrowers = shift;
 199     my $balance;
 200     @$borrowers = map {
 201         my $patron = Koha::Patrons->find( $_->{borrowernumber} );
 202         my $balance = $patron->account->balance;
 203         (defined $balance && $balance != 0) ? (): ($_);
 204     } @$borrowers;
 205 }
 206
 207 sub _get_selection_params {
 208     my ($not_borrowed_since, $borrower_dateexpiry, $borrower_lastseen,
 209         $borrower_categorycode, $patron_list_id, $branch) = @_;
 210
 211     my $params = {};
 212     $params->{not_borrowed_since} = output_pref({
 213         dt         => $not_borrowed_since,
 214         dateformat => 'iso',
 215         dateonly   => 1
 216     }) if $not_borrowed_since;
 217     $params->{expired_before} = output_pref({
 218         dt         => $borrower_dateexpiry,
 219         dateformat => 'iso',
 220         dateonly   => 1
 221     }) if $borrower_dateexpiry;
 222     $params->{last_seen} = output_pref({
 223         dt         => $borrower_lastseen,
 224         dateformat => 'iso',
 225         dateonly   => 1
 226     }) if $borrower_lastseen;
 227     $params->{category_code} = $borrower_categorycode if $borrower_categorycode;
 228     $params->{patron_list_id} = $patron_list_id if $patron_list_id;
 229
 230     if ( defined $branch and $branch ne '*' ) {
 231         $params->{ branchcode } = $branch;
 232     }
 233
 234     return $params;
 235 };