fixing bug 1754: Hide language chooser if only one translation is available
[wip/koha-chris_n.git] / C4 / Languages.pm
1 package C4::Languages;
2
3 # Copyright 2006 (C) LibLime
4 # Joshua Ferraro <jmf@liblime.com>
5 #
6 # This file is part of Koha.
7 #
8 # Koha is free software; you can redistribute it and/or modify it under the
9 # terms of the GNU General Public License as published by the Free Software
10 # Foundation; either version 2 of the License, or (at your option) any later
11 # version.
12 #
13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License along with
18 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
19 # Suite 330, Boston, MA  02111-1307 USA
20
21
22 use strict; 
23 use warnings;   #FIXME: turn off warnings before release
24 use Carp;
25 use C4::Context;
26 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $DEBUG);
27
28 BEGIN {
29     $VERSION = 3.00;
30     require Exporter;
31     @ISA    = qw(Exporter);
32     @EXPORT = qw(
33         &getFrameworkLanguages
34         &getTranslatedLanguages
35         &getAllLanguages
36     );
37     @EXPORT_OK = qw(getFrameworkLanguages getTranslatedLanguages getAllLanguages get_bidi regex_lang_subtags language_get_description accept_language);
38     $DEBUG = 0;
39 }
40
41 =head1 NAME
42
43 C4::Languages - Perl Module containing language list functions for Koha 
44
45 =head1 SYNOPSIS
46
47 use C4::Languages;
48
49 =head1 DESCRIPTION
50
51 =head1 FUNCTIONS
52
53 =head2 getFrameworkLanguages
54
55 Returns a reference to an array of hashes:
56
57  my $languages = getFrameworkLanguages();
58  for my $language(@$languages) {
59     print "$language->{language_code}\n"; # language code in iso 639-2
60     print "$language->{language_name}\n"; # language name in native script
61     print "$language->{language_locale_name}\n"; # language name in current locale
62  }
63
64 =cut
65
66 sub getFrameworkLanguages {
67     # get a hash with all language codes, names, and locale names
68     my $all_languages = getAllLanguages();
69     my @languages;
70     
71     # find the available directory names
72     my $dir=C4::Context->config('intranetdir')."/installer/data/";
73     opendir (MYDIR,$dir);
74     my @listdir= grep { !/^\.|CVS/ && -d "$dir/$_"} readdir(MYDIR);    
75     closedir MYDIR;
76
77     # pull out all data for the dir names that exist
78     for my $dirname (@listdir) {
79         for my $language_set (@$all_languages) {
80
81             if ($dirname eq $language_set->{language_code}) {
82                 push @languages, {
83                     'language_code'=>$dirname, 
84                     'language_description'=>$language_set->{language_description}, 
85                     'native_descrition'=>$language_set->{language_native_description} }
86             }
87         }
88     }
89     return \@languages;
90 }
91
92 =head2 getTranslatedLanguages
93
94 Returns a reference to an array of hashes:
95
96  my $languages = getTranslatedLanguages();
97  print "Available translated langauges:\n";
98  for my $language(@$trlanguages) {
99     print "$language->{language_code}\n"; # language code in iso 639-2
100     print "$language->{language_name}\n"; # language name in native script
101     print "$language->{language_locale_name}\n"; # language name in current locale
102  }
103
104 =cut
105
106 sub getTranslatedLanguages {
107     my ($interface, $theme, $current_language, $which) = @_;
108     my $htdocs;
109     my $all_languages = getAllLanguages();
110     my @languages;
111     my $lang;
112     my @enabled_languages;
113  
114     if ($interface && $interface eq 'opac' ) {
115         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
116         $htdocs = C4::Context->config('opachtdocs');
117         if ( $theme and -d "$htdocs/$theme" ) {
118             (@languages) = _get_language_dirs($htdocs,$theme);
119             return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
120         }
121         else {
122             for my $theme ( _get_themes('opac') ) {
123                 push @languages, _get_language_dirs($htdocs,$theme);
124             }
125             return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
126         }
127     }
128     elsif ($interface && $interface eq 'intranet' ) {
129         @enabled_languages = split ",", C4::Context->preference('language');
130         $htdocs = C4::Context->config('intrahtdocs');
131         if ( $theme and -d "$htdocs/$theme" ) {
132             @languages = _get_language_dirs($htdocs,$theme);
133             return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
134         }
135         else {
136             foreach my $theme ( _get_themes('intranet') ) {
137                 push @languages, _get_language_dirs($htdocs,$theme);
138             }
139             return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
140         }
141     }
142     else {
143         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
144         my $htdocs = C4::Context->config('intrahtdocs');
145         foreach my $theme ( _get_themes('intranet') ) {
146             push @languages, _get_language_dirs($htdocs,$theme);
147         }
148         $htdocs = C4::Context->config('opachtdocs');
149         foreach my $theme ( _get_themes('opac') ) {
150             push @languages, _get_language_dirs($htdocs,$theme);
151         }
152         return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
153     }
154 }
155
156 =head2 getAllLanguages
157
158 Returns a reference to an array of hashes:
159
160  my $alllanguages = getAllLanguages();
161  print "Available translated langauges:\n";
162  for my $language(@$alllanguages) {
163     print "$language->{language_code}\n";
164     print "$language->{language_name}\n";
165     print "$language->{language_locale_name}\n";
166  }
167
168 =cut
169
170 sub getAllLanguages {
171     my @languages_loop;
172     my $dbh=C4::Context->dbh;
173     my $current_language = 'en';
174     my $sth = $dbh->prepare('SELECT * FROM language_subtag_registry WHERE type=\'language\'');
175     $sth->execute();
176     while (my $language_subtag_registry = $sth->fetchrow_hashref) {
177
178         # pull out all the script descriptions for each language
179         my $sth2= $dbh->prepare("SELECT * FROM language_descriptions LEFT JOIN language_rfc4646_to_iso639 on language_rfc4646_to_iso639.rfc4646_subtag = language_descriptions.subtag WHERE type='language' AND subtag =?");
180         $sth2->execute($language_subtag_registry->{subtag});
181
182         # add the correct description info
183         while (my $language_descriptions = $sth2->fetchrow_hashref) {
184         # fill in the ISO6329 code
185         $language_subtag_registry->{iso639_2_code} = $language_descriptions->{iso639_2_code};
186             $language_subtag_registry->{language_description} = $language_descriptions->{description};
187         }
188         push @languages_loop, $language_subtag_registry;
189     }
190     return \@languages_loop;
191 }
192
193 =head2 _get_themes
194
195 Internal function, returns an array of all available themes.
196
197   (@themes) = &_get_themes('opac');
198   (@themes) = &_get_themes('intranet');
199
200 =cut
201
202 sub _get_themes {
203     my $interface = shift;
204     my $htdocs;
205     my @themes;
206     if ( $interface eq 'intranet' ) {
207         $htdocs = C4::Context->config('intrahtdocs');
208     }
209     else {
210         $htdocs = C4::Context->config('opachtdocs');
211     }
212     opendir D, "$htdocs";
213     my @dirlist = readdir D;
214     foreach my $directory (@dirlist) {
215         # if there's an en dir, it's a valid theme
216         -d "$htdocs/$directory/en" and push @themes, $directory;
217     }
218     return @themes;
219 }
220
221 =head2 _get_language_dirs
222
223 Internal function, returns an array of directory names, excluding non-language directories
224
225 =cut
226
227 sub _get_language_dirs {
228     my ($htdocs,$theme) = @_;
229     my @lang_strings;
230     opendir D, "$htdocs/$theme";
231     for my $lang_string ( readdir D ) {
232         next if $lang_string =~/^\./;
233         next if $lang_string eq 'all';
234         next if $lang_string =~/png$/;
235         next if $lang_string =~/css$/;
236         next if $lang_string =~/CVS$/;
237         next if $lang_string =~/\.txt$/i;     #Don't read the readme.txt !
238         next if $lang_string =~/img|images/;
239         push @lang_strings, $lang_string;
240     }
241         return (@lang_strings);
242 }
243
244 =head2 _build_languages_arrayref 
245
246 Internal function for building the ref to array of hashes
247
248 FIXME: this could be rewritten and simplified using map
249
250 =cut
251
252 sub _build_languages_arrayref {
253         my ($all_languages,$translated_languages,$current_language,$enabled_languages) = @_;
254         my @translated_languages = @$translated_languages;
255         my @languages_loop; # the final reference to an array of hashrefs
256         my @enabled_languages = @$enabled_languages;
257         # how many languages are enabled, if one, take note, some contexts won't need to display it
258         my $one_language_enabled = 1 unless @enabled_languages > 1;
259         my %seen_languages; # the language tags we've seen
260         my %found_languages;
261         my $language_groups;
262         my $track_language_groups;
263         my $current_language_regex = regex_lang_subtags($current_language);
264         # Loop through the translated languages
265         for my $translated_language (@translated_languages) {
266             # separate the language string into its subtag types
267             my $language_subtags_hashref = regex_lang_subtags($translated_language);
268
269             # is this language string 'enabled'?
270             for my $enabled_language (@enabled_languages) {
271                 #warn "Checking out if $translated_language eq $enabled_language";
272                 $language_subtags_hashref->{'enabled'} = 1 if $translated_language eq $enabled_language;
273             }
274             
275             # group this language, key by langtag
276             $language_subtags_hashref->{'sublanguage_current'} = 1 if $translated_language eq $current_language;
277             $language_subtags_hashref->{'rfc4646_subtag'} = $translated_language;
278             $language_subtags_hashref->{'native_description'} = language_get_description($language_subtags_hashref->{language},$language_subtags_hashref->{language},'language');
279             $language_subtags_hashref->{'script_description'} = language_get_description($language_subtags_hashref->{script},$language_subtags_hashref->{'language'},'script');
280             $language_subtags_hashref->{'region_description'} = language_get_description($language_subtags_hashref->{region},$language_subtags_hashref->{'language'},'region');
281             $language_subtags_hashref->{'variant_description'} = language_get_description($language_subtags_hashref->{variant},$language_subtags_hashref->{'language'},'variant');
282             $track_language_groups->{$language_subtags_hashref->{'language'}}++;
283             push ( @{ $language_groups->{$language_subtags_hashref->{language}} }, $language_subtags_hashref );
284         }
285         # $key is a language subtag like 'en'
286         while( my ($key, $value) = each %$language_groups) {
287
288             # is this language group enabled? are any of the languages within it enabled?
289             my $enabled;
290             for my $enabled_language (@enabled_languages) {
291                 my $regex_enabled_language = regex_lang_subtags($enabled_language);
292                 $enabled = 1 if $key eq $regex_enabled_language->{language};
293             }
294             push @languages_loop,  {
295                             # this is only use if there is one
296                             rfc4646_subtag => @$value[0]->{rfc4646_subtag},
297                             native_description => language_get_description($key,$key,'language'),
298                             language => $key,
299                             sublanguages_loop => $value,
300                             plural => $track_language_groups->{$key} >1 ? 1 : 0,
301                             current => $current_language_regex->{language} eq $key ? 1 : 0,
302                             group_enabled => $enabled,
303                             one_language_enabled => $one_language_enabled,
304                            };
305         }
306         return \@languages_loop;
307 }
308
309 sub language_get_description {
310     my ($script,$lang,$type) = @_;
311     my $dbh = C4::Context->dbh;
312     my $desc;
313     my $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
314     #warn "QUERY: SELECT description FROM language_descriptions WHERE subtag=$script AND lang=$lang AND type=$type";
315     $sth->execute($script,$lang,$type);
316     while (my $descriptions = $sth->fetchrow_hashref) {
317         $desc = $descriptions->{'description'};
318     }
319     unless ($desc) {
320         $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
321         $sth->execute($script,'en',$type);
322         while (my $descriptions = $sth->fetchrow_hashref) {
323             $desc = $descriptions->{'description'};
324         }
325     }
326     return $desc;
327 }
328 =head2 regex_lang_subtags
329
330 This internal sub takes a string composed according to RFC 4646 as
331 an input and returns a reference to a hash containing keys and values
332 for ( language, script, region, variant, extension, privateuse )
333
334 =cut
335
336 sub regex_lang_subtags {
337     my $string = shift;
338
339     # Regex for recognizing RFC 4646 well-formed tags
340     # http://www.rfc-editor.org/rfc/rfc4646.txt
341
342     # regexes based on : http://unicode.org/cldr/data/tools/java/org/unicode/cldr/util/data/langtagRegex.txt
343     # The structure requires no forward references, so it reverses the order.
344     # The uppercase comments are fragments copied from RFC 4646
345     #
346     # Note: the tool requires that any real "=" or "#" or ";" in the regex be escaped.
347
348     my $alpha   = qr/[a-zA-Z]/ ;    # ALPHA
349     my $digit   = qr/[0-9]/ ;   # DIGIT
350     my $alphanum    = qr/[a-zA-Z0-9]/ ; # ALPHA / DIGIT
351     my $x   = qr/[xX]/ ;    # private use singleton
352     my $singleton = qr/[a-w y-z A-W Y-Z]/ ; # other singleton
353     my $s   = qr/[-]/ ; # separator -- lenient parsers will use [-_]
354
355     # Now do the components. The structure is slightly different to allow for capturing the right components.
356     # The notation (?:....) is a non-capturing version of (...): so the "?:" can be deleted if someone doesn't care about capturing.
357
358     my $extlang = qr{(?: $s $alpha{3} )}x ; # *3("-" 3ALPHA)
359     my $language    = qr{(?: $alpha{2,3} | $alpha{4,8} )}x ;
360     #my $language   = qr{(?: $alpha{2,3}$extlang{0,3} | $alpha{4,8} )}x ;   # (2*3ALPHA [ extlang ]) / 4ALPHA / 5*8ALPHA
361
362     my $script  = qr{(?: $alpha{4} )}x ;    # 4ALPHA 
363
364     my $region  = qr{(?: $alpha{2} | $digit{3} )}x ;     # 2ALPHA / 3DIGIT
365
366     my $variantSub  = qr{(?: $digit$alphanum{3} | $alphanum{5,8} )}x ;  # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
367     my $variant = qr{(?: $variantSub (?: $s$variantSub )* )}x ; # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
368
369     my $extensionSub    = qr{(?: $singleton (?: $s$alphanum{2,8} )+ )}x ;   # singleton 1*("-" (2*8alphanum))
370     my $extension   = qr{(?: $extensionSub (?: $s$extensionSub )* )}x ; # singleton 1*("-" (2*8alphanum))
371
372     my $privateuse  = qr{(?: $x (?: $s$alphanum{1,8} )+ )}x ;   # ("x"/"X") 1*("-" (1*8alphanum))
373
374     # Define certain grandfathered codes, since otherwise the regex is pretty useless.
375     # Since these are limited, this is safe even later changes to the registry --
376     # the only oddity is that it might change the type of the tag, and thus
377     # the results from the capturing groups.
378     # http://www.iana.org/assignments/language-subtag-registry
379     # Note that these have to be compared case insensitively, requiring (?i) below.
380
381     my $grandfathered   = qr{(?: (?i)
382         en $s GB $s oed
383     |   i $s (?: ami | bnn | default | enochian | hak | klingon | lux | mingo | navajo | pwn | tao | tay | tsu )
384     |   sgn $s (?: BE $s fr | BE $s nl | CH $s de)
385 )}x;
386
387     # For well-formedness, we don't need the ones that would otherwise pass, so they are commented out here
388
389     #   |   art $s lojban
390     #   |   cel $s gaulish
391     #   |   en $s (?: boont | GB $s oed | scouse )
392     #   |   no $s (?: bok | nyn)
393     #   |   zh $s (?: cmn | cmn $s Hans | cmn $s Hant | gan | guoyu | hakka | min | min $s nan | wuu | xiang | yue)
394
395     # Here is the final breakdown, with capturing groups for each of these components
396     # The language, variants, extensions, grandfathered, and private-use may have interior '-'
397
398     #my $root = qr{(?: ($language) (?: $s ($script) )? 40% (?: $s ($region) )? 40% (?: $s ($variant) )? 10% (?: $s ($extension) )? 5% (?: $s ($privateuse) )? 5% ) 90% | ($grandfathered) 5% | ($privateuse) 5% };
399
400     $string =~  qr{^ (?:($language)) (?:$s($script))? (?:$s($region))?  (?:$s($variant))?  (?:$s($extension))?  (?:$s($privateuse))? $}xi;  # |($grandfathered) | ($privateuse) $}xi;
401     my %subtag = (
402         'rfc4646_subtag' => $string,
403         'language' => $1,
404         'script' => $2,
405         'region' => $3,
406         'variant' => $4,
407         'extension' => $5,
408         'privateuse' => $6,
409     );
410     return \%subtag;
411 }
412
413 # Script Direction Resources:
414 # http://www.w3.org/International/questions/qa-scripts
415 sub get_bidi {
416     my ($language_script)= @_;
417     my $dbh = C4::Context->dbh;
418     my $bidi;
419     my $sth = $dbh->prepare('SELECT bidi FROM language_script_bidi WHERE rfc4646_subtag=?');
420     $sth->execute($language_script);
421     while (my $result = $sth->fetchrow_hashref) {
422         $bidi = $result->{'bidi'};
423     }
424     return $bidi;
425 };
426
427 sub accept_language {
428     # referenced http://search.cpan.org/src/CGILMORE/I18N-AcceptLanguage-1.04/lib/I18N/AcceptLanguage.pm
429     # FIXME: since this is only used in Output.pm as of Jan 8 2008, maybe it should be IN Output.pm
430     my ($clientPreferences,$supportedLanguages) = @_;
431     my @languages = ();
432     if ($clientPreferences) {
433         # There should be no whitespace anways, but a cleanliness/sanity check
434         $clientPreferences =~ s/\s//g;
435
436         # Prepare the list of client-acceptable languages
437         foreach my $tag (split(/,/, $clientPreferences)) {
438             my ($language, $quality) = split(/\;/, $tag);
439             $quality =~ s/^q=//i if $quality;
440             $quality = 1 unless $quality;
441             next if $quality <= 0;
442             # We want to force the wildcard to be last
443             $quality = 0 if ($language eq '*');
444             # Pushing lowercase language here saves processing later
445             push(@languages, { quality => $quality,
446                language => $language,
447                lclanguage => lc($language) });
448         }
449     } else {
450         carp "accept_language(x,y) called with no clientPreferences (x).";
451     }
452     # Prepare the list of server-supported languages
453     my %supportedLanguages = ();
454     my %secondaryLanguages = ();
455     foreach my $language (@$supportedLanguages) {
456         # warn "Language supported: " . $language->{language_code};
457         $supportedLanguages{lc($language->{language_code})} = $language->{language_code};
458         if ($language->{language_code} =~ /^([^-]+)-?/) {
459             $secondaryLanguages{lc($1)} = $language->{language_code};
460         }
461     }
462
463     # Reverse sort the list, making best quality at the front of the array
464     @languages = sort { $b->{quality} <=> $a->{quality} } @languages;
465     my $secondaryMatch = '';
466     foreach my $tag (@languages) {
467         if (exists($supportedLanguages{$tag->{lclanguage}})) {
468             # Client en-us eq server en-us
469             return $supportedLanguages{$tag->{language}} if exists($supportedLanguages{$tag->{language}});
470             return $supportedLanguages{$tag->{lclanguage}};
471         } elsif (exists($secondaryLanguages{$tag->{lclanguage}})) {
472             # Client en eq server en-us
473             return $secondaryLanguages{$tag->{language}} if exists($secondaryLanguages{$tag->{language}});
474             return $supportedLanguages{$tag->{lclanguage}};
475         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
476             # Client en-gb eq server en-us
477             $secondaryMatch = $secondaryLanguages{$1};
478         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
479             # FIXME: We just checked the exact same conditional!
480             # Client en-us eq server en
481             $secondaryMatch = $supportedLanguages{$1};
482         } elsif ($tag->{lclanguage} eq '*') {
483         # * matches every language not already specified.
484         # It doesn't care which we pick, so let's pick the default,
485         # if available, then the first in the array.
486         #return $acceptor->defaultLanguage() if $acceptor->defaultLanguage();
487         return $supportedLanguages->[0];
488         }
489     }
490     # No primary matches. Secondary? (ie, en-us requested and en supported)
491     return $secondaryMatch if $secondaryMatch;
492     return undef;   # else, we got nothing.
493 }
494 1;
495
496 __END__
497
498 =head1 AUTHOR
499
500 Joshua Ferraro
501
502 =cut