#!/usr/bin/perl
#
# This is to test C4/Koha
# It requires a working Koha database with the sample data

use strict;
use warnings;
use C4::Context;
use Koha::DateUtils qw(dt_from_string);

use Test::More tests => 8;
use DateTime::Format::MySQL;

BEGIN {
    use_ok('C4::Koha', qw( :DEFAULT GetDailyQuote ));
    use_ok('C4::Members');
}

my $dbh = C4::Context->dbh;
$dbh->{AutoCommit} = 0;
$dbh->{RaiseError} = 1;

subtest 'Authorized Values Tests' => sub {
    plan tests => 8;

    my $data = {
        category            => 'CATEGORY',
        authorised_value    => 'AUTHORISED_VALUE',
        lib                 => 'LIB',
        lib_opac            => 'LIBOPAC',
        imageurl            => 'IMAGEURL'
    };


# Insert an entry into authorised_value table
    my $insert_success = AddAuthorisedValue($data->{category}, $data->{authorised_value}, $data->{lib}, $data->{lib_opac}, $data->{imageurl});
    ok($insert_success, "Insert data in database");


# Tests
    SKIP: {
        skip "INSERT failed", 5 unless $insert_success;

        is ( GetAuthorisedValueByCode($data->{category}, $data->{authorised_value}), $data->{lib}, "GetAuthorisedValueByCode" );
        is ( GetKohaImageurlFromAuthorisedValues($data->{category}, $data->{lib}), $data->{imageurl}, "GetKohaImageurlFromAuthorisedValues" );

        my $sortdet=C4::Members::GetSortDetails("lost", "3");
        is ($sortdet, "Lost and Paid For", "lost and paid works");

        my $sortdet2=C4::Members::GetSortDetails("loc", "child");
        is ($sortdet2, "Children's Area", "Child area works");

        my $sortdet3=C4::Members::GetSortDetails("withdrawn", "1");
        is ($sortdet3, "Withdrawn", "Withdrawn works");
    }

# Clean up
    if($insert_success){
        my $query = "DELETE FROM authorised_values WHERE category=? AND authorised_value=? AND lib=? AND lib_opac=? AND imageurl=?;";
        my $sth = $dbh->prepare($query);
        $sth->execute($data->{category}, $data->{authorised_value}, $data->{lib}, $data->{lib_opac}, $data->{imageurl});
    }

    SKIP: {
        eval { require Test::Deep; import Test::Deep; };
        skip "Test::Deep required to run the GetAuthorisedValues() tests.", 2 if $@;
        AddAuthorisedValue('BUG10656', 'ZZZ', 'Z_STAFF', 'A_PUBLIC', '');
        AddAuthorisedValue('BUG10656', 'AAA', 'A_STAFF', 'Z_PUBLIC', '');
        # the next one sets lib_opac to NULL; in that case, the staff
        # display value is meant to be used.
        AddAuthorisedValue('BUG10656', 'DDD', 'D_STAFF', undef, '');
        my $authvals = GetAuthorisedValues('BUG10656');
        cmp_deeply(
            $authvals,
            [
                {
                    id => ignore(),
                    category => 'BUG10656',
                    authorised_value => 'AAA',
                    selected => 0,
                    lib => 'A_STAFF',
                    lib_opac => 'Z_PUBLIC',
                    imageurl => '',
                },
                {
                    id => ignore(),
                    category => 'BUG10656',
                    authorised_value => 'DDD',
                    selected => 0,
                    lib => 'D_STAFF',
                    lib_opac => undef,
                    imageurl => '',
                },
                {
                    id => ignore(),
                    category => 'BUG10656',
                    authorised_value => 'ZZZ',
                    selected => 0,
                    lib => 'Z_STAFF',
                    lib_opac => 'A_PUBLIC',
                    imageurl => '',
                },
            ],
            'list of authorised values in staff mode sorted by staff label (bug 10656)'
        );
        $authvals = GetAuthorisedValues('BUG10656', '', 1);
        cmp_deeply(
            $authvals,
            [
                {
                    id => ignore(),
                    category => 'BUG10656',
                    authorised_value => 'ZZZ',
                    selected => 0,
                    lib => 'A_PUBLIC',
                    lib_opac => 'A_PUBLIC',
                    imageurl => '',
                },
                {
                    id => ignore(),
                    category => 'BUG10656',
                    authorised_value => 'DDD',
                    selected => 0,
                    lib => 'D_STAFF',
                    lib_opac => undef,
                    imageurl => '',
                },
                {
                    id => ignore(),
                    category => 'BUG10656',
                    authorised_value => 'AAA',
                    selected => 0,
                    lib => 'Z_PUBLIC',
                    lib_opac => 'Z_PUBLIC',
                    imageurl => '',
                },
            ],
            'list of authorised values in OPAC mode sorted by OPAC label (bug 10656)'
        );
    }

};

subtest 'Itemtype info Tests' => sub {
    like ( getitemtypeinfo('BK')->{'imageurl'}, qr/intranet-tmpl/, 'getitemtypeinfo on unspecified interface returns intranet imageurl (legacy behavior)' );
    like ( getitemtypeinfo('BK', 'intranet')->{'imageurl'}, qr/intranet-tmpl/, 'getitemtypeinfo on "intranet" interface returns intranet imageurl' );
    like ( getitemtypeinfo('BK', 'opac')->{'imageurl'}, qr/opac-tmpl/, 'getitemtypeinfo on "opac" interface returns opac imageurl' );
};















### test for C4::Koha->GetDailyQuote()
SKIP:
    {
        eval { require Test::Deep; import Test::Deep; };
        skip "Test::Deep required to run the GetDailyQuote tests.", 1 if $@;

        subtest 'Daily Quotes Test' => sub {
            plan tests => 4;

            SKIP: {

                skip "C4::Koha can't \'GetDailyQuote\'!", 3 unless can_ok('C4::Koha','GetDailyQuote');

                my $expected_quote = {
                    id          => 3,
                    source      => 'Abraham Lincoln',
                    text        => 'Four score and seven years ago our fathers brought forth on this continent, a new nation, conceived in Liberty, and dedicated to the proposition that all men are created equal.',
                    timestamp   => re('\d{4}-\d{2}-\d{2}\s\d{2}:\d{2}:\d{2}'),   #'0000-00-00 00:00:00',
                };

# test quote retrieval based on id

                my $quote = GetDailyQuote('id'=>3);
                cmp_deeply ($quote, $expected_quote, "Got a quote based on id.") or
                    diag('Be sure to run this test on a clean install of sample data.');

# test quote retrieval based on today's date

                my $query = 'UPDATE quotes SET timestamp = ? WHERE id = ?';
                my $sth = C4::Context->dbh->prepare($query);
                $sth->execute(DateTime::Format::MySQL->format_datetime( dt_from_string() ), $expected_quote->{'id'});

                DateTime::Format::MySQL->format_datetime( dt_from_string() ) =~ m/(\d{4}-\d{2}-\d{2})/;
                $expected_quote->{'timestamp'} = re("^$1");

#        $expected_quote->{'timestamp'} = DateTime::Format::MySQL->format_datetime( dt_from_string() );   # update the timestamp of expected quote data

                $quote = GetDailyQuote(); # this is the "default" mode of selection
                cmp_deeply ($quote, $expected_quote, "Got a quote based on today's date.") or
                    diag('Be sure to run this test on a clean install of sample data.');

# test random quote retrieval

                $quote = GetDailyQuote('random'=>1);
                ok ($quote, "Got a random quote.");
            }
        };
}


#
# test that &slashifyDate returns correct (non-US) date
#
subtest 'Date and ISBN tests' => sub {
    plan tests => 7;

    my $date    = "01/01/2002";
    my $newdate = &slashifyDate("2002-01-01");
    my $isbn13  = "9780330356473";
    my $isbn13D = "978-0-330-35647-3";
    my $isbn10  = "033035647X";
    my $isbn10D = "0-330-35647-X";
    ok( $date eq $newdate, 'slashifyDate' );
    my $undef = undef;
    is( xml_escape($undef), '',
        'xml_escape() returns empty string on undef input' );
    my $str = q{'"&<>'};
    is(
        xml_escape($str),
        '&apos;&quot;&amp;&lt;&gt;&apos;',
        'xml_escape() works as expected'
    );
    is( $str, q{'"&<>'}, '... and does not change input in place' );
    is( C4::Koha::_isbn_cleanup('0-590-35340-3'),
        '0590353403', '_isbn_cleanup removes hyphens' );
    is( C4::Koha::_isbn_cleanup('0590353403 (pbk.)'),
        '0590353403', '_isbn_cleanup removes parenthetical' );
    is( C4::Koha::_isbn_cleanup('978-0-321-49694-2'),
        '0321496949', '_isbn_cleanup converts ISBN-13 to ISBN-10' );

};

subtest 'getFacets() tests' => sub {
    plan tests => 2;

    C4::Context->set_preference('singleBranchMode', 0);
    my $facets = C4::Koha::getFacets();
    is(
        scalar( grep { defined $_->{idx} && $_->{idx} eq 'location' } @$facets ),
        1,
        'location facet present with singleBranchMode off (bug 10078)'
    );
    C4::Context->set_preference('singleBranchMode', 1);
    $facets = C4::Koha::getFacets();
    is(
        scalar( grep { defined $_->{idx} && $_->{idx} eq 'location' } @$facets ),
        1,
        'location facet present with singleBranchMode on (bug 10078)'
    );
};

subtest 'GetFrameworksLoop() tests' => sub {
    plan tests => 6;

    $dbh->do("DELETE FROM biblio_framework");

    my $frameworksloop = GetFrameworksLoop();
    is ( scalar(@$frameworksloop), 0, 'No frameworks' );

    $dbh->do("INSERT INTO biblio_framework ( frameworkcode, frameworktext ) VALUES ( 'A', 'Third framework'  )");
    $dbh->do("INSERT INTO biblio_framework ( frameworkcode, frameworktext ) VALUES ( 'B', 'Second framework' )");
    $dbh->do("INSERT INTO biblio_framework ( frameworkcode, frameworktext ) VALUES ( 'C', 'First framework'  )");

    $frameworksloop = GetFrameworksLoop();
    is ( scalar(@$frameworksloop), 3, 'All frameworks' );
    is ( scalar ( grep { defined $_->{'selected'} } @$frameworksloop ), 0, 'None selected' );

    $frameworksloop = GetFrameworksLoop( 'B' );
    is ( scalar ( grep { defined $_->{'selected'} } @$frameworksloop ), 1, 'One selected' );
    my @descriptions = map { $_->{'description'} } @$frameworksloop;
    is ( $descriptions[0], 'First framework', 'Ordered result' );
    cmp_deeply(
        $frameworksloop,
        [
            {
                'value' => 'C',
                'description' => 'First framework',
                'selected' => undef,
            },
            {
                'value' => 'B',
                'description' => 'Second framework',
                'selected' => 1,                # selected
            },
            {
                'value' => 'A',
                'description' => 'Third framework',
                'selected' => undef,
            }
        ],
        'Full check, sorted by description with selected val (Bug 12675)'
    );
};

$dbh->rollback();