Koha/C4/XISBN.pm

package C4::XISBN;
# Copyright (C) 2007 LibLime
# Joshua Ferraro <jmf@liblime.com>
#
# This file is part of Koha.
#
# Koha is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3 of the License, or
# (at your option) any later version.
#
# Koha is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with Koha; if not, see <http://www.gnu.org/licenses>.

use XML::Simple;
#use LWP::Simple;
use C4::Biblio;
use C4::Koha;
use C4::Search;
use C4::External::Syndetics qw(get_syndetics_editions);
use LWP::UserAgent;
use HTTP::Request::Common;

use Koha::Biblios;
use Koha::SearchEngine;
use Koha::SearchEngine::Search;

use strict;
#use warnings; FIXME - Bug 2505
use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);

BEGIN {
	require Exporter;
	@ISA = qw(Exporter);
	@EXPORT_OK = qw(
		&get_xisbns
	);
}

=head1 NAME

C4::XISBN - Functions for retrieving XISBN content in Koha

=head1 FUNCTIONS

This module provides facilities for retrieving ThingISBN and XISBN content in Koha

=cut

sub _get_biblio_from_xisbn {
    my $xisbn = shift;
    my $dbh = C4::Context->dbh;

    my $searcher = Koha::SearchEngine::Search->new({index => $Koha::SearchEngine::BIBLIOS_INDEX});
    my ( $errors, $results, $total_hits ) = $searcher->simple_search_compat( "nb=$xisbn", 0, 1 );
    return unless ( !$errors && scalar @$results );

    my $record = C4::Search::new_record_from_zebra( 'biblioserver', $results->[0] );
    my $biblionumber = C4::Biblio::TransformMarcToKohaOneField( 'biblio.biblionumber', $record );
    return unless $biblionumber;

    my $biblio = Koha::Biblios->find( $biblionumber );
    return unless $biblio;
    my $isbn = $biblio->biblioitem->isbn;
    $biblio = $biblio->unblessed;
    $biblio->{normalized_isbn} = GetNormalizedISBN($isbn);
    return $biblio;
}

=head1 get_xisbns($isbn);

=head2 $isbn is an ISBN string

=cut

sub get_xisbns {
    my ( $isbn ) = @_;
    my ($response,$thing_response,$syndetics_response,$errors);
    # THINGISBN
    if ( C4::Context->preference('ThingISBN') ) {
        my $url = "http://www.librarything.com/api/thingISBN/".$isbn;
        $thing_response = _get_url($url,'thingisbn');
    }

	if ( C4::Context->preference("SyndeticsEnabled") && C4::Context->preference("SyndeticsEditions") ) {
    	my $syndetics_preresponse = &get_syndetics_editions($isbn);
		my @syndetics_response;
		for my $response (@$syndetics_preresponse) {
			push @syndetics_response, {content => $response->{a}};
		}
		$syndetics_response = {isbn => \@syndetics_response};
	}

    $response->{isbn} = [ @{ $syndetics_response->{isbn} or [] }, @{ $thing_response->{isbn} or [] } ];
    my @xisbns;
    my $unique_xisbns; # a hashref

    # loop through each ISBN and scope to the local collection
    for my $response_data( @{ $response->{ isbn } } ) {
        next if $response_data->{'content'} eq $isbn;
        next if $isbn eq $response_data;
        next if $unique_xisbns->{ $response_data->{content} };
        $unique_xisbns->{ $response_data->{content} }++;
        my $xbiblio= _get_biblio_from_xisbn($response_data->{content});
        push @xisbns, $xbiblio if $xbiblio;
    }
    if ( wantarray ) {
        return (\@xisbns, $errors);
    }
    else {
        return \@xisbns;
    }
}

sub _get_url {
    my ($url,$service_type) = @_;
    my $ua = LWP::UserAgent->new(
        timeout => 2
        );

    my $response = $ua->get($url);
    if ($response->is_success) {
        warn "WARNING could not retrieve $service_type $url" unless $response;
        if ($response) {
            my $xmlsimple = XML::Simple->new();
            my $content = $xmlsimple->XMLin(
            $response->content,
            ForceArray => [ qw(isbn) ],
            ForceContent => 1,
            );
            return $content;
        }
    } else {
        warn "WARNING: URL Request Failed " . $response->status_line . "\n";
    }

}

1;
__END__

=head1 NOTES

=cut

=head1 AUTHOR

Joshua Ferraro <jmf@liblime.com>

=cut