Jonathan Druart
9d6d641d1f
On bug 17591 we discovered that there was something weird going on with the way we export and use subroutines/modules. This patch tries to standardize our EXPORT to use EXPORT_OK only. That way we will need to explicitely define the subroutine we want to use from a module. This patch is a squashed version of: Bug 17600: After export.pl Bug 17600: After perlimport Bug 17600: Manual changes Bug 17600: Other manual changes after second perlimports run Bug 17600: Fix tests And a lot of other manual changes. export.pl is a dirty script that can be found on bug 17600. "perlimport" is: git clone https://github.com/oalders/App-perlimports.git cd App-perlimports/ cpanm --installdeps . export PERL5LIB="$PERL5LIB:/kohadevbox/koha/App-perlimports/lib" find . \( -name "*.pl" -o -name "*.pm" \) -exec perl App-perlimports/script/perlimports --inplace-edit --no-preserve-unused --filename {} \; The ideas of this patch are to: * use EXPORT_OK instead of EXPORT * perltidy the EXPORT_OK list * remove '&' before the subroutine names * remove some uneeded use statements * explicitely import the subroutines we need within the controllers or modules Note that the private subroutines (starting with _) should not be exported (and not used from outside of the module except from tests). EXPORT vs EXPORT_OK (from https://www.thegeekstuff.com/2010/06/perl-exporter-examples/) """ Export allows to export the functions and variables of modules to user’s namespace using the standard import method. This way, we don’t need to create the objects for the modules to access it’s members. @EXPORT and @EXPORT_OK are the two main variables used during export operation. @EXPORT contains list of symbols (subroutines and variables) of the module to be exported into the caller namespace. @EXPORT_OK does export of symbols on demand basis. """ If this patch caused a conflict with a patch you wrote prior to its push: * Make sure you are not reintroducing a "use" statement that has been removed * "$subroutine" is not exported by the C4::$MODULE module means that you need to add the subroutine to the @EXPORT_OK list * Bareword "$subroutine" not allowed while "strict subs" means that you didn't imported the subroutine from the module: - use $MODULE qw( $subroutine list ); You can also use the fully qualified namespace: C4::$MODULE::$subroutine Signed-off-by: Jonathan Druart <jonathan.druart@bugs.koha-community.org>
311 lines
7.5 KiB
Perl
311 lines
7.5 KiB
Perl
package Koha::Library;
|
|
|
|
# Copyright 2015 Koha Development team
|
|
#
|
|
# This file is part of Koha.
|
|
#
|
|
# Koha is free software; you can redistribute it and/or modify it
|
|
# under the terms of the GNU General Public License as published by
|
|
# the Free Software Foundation; either version 3 of the License, or
|
|
# (at your option) any later version.
|
|
#
|
|
# Koha is distributed in the hope that it will be useful, but
|
|
# WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
# GNU General Public License for more details.
|
|
#
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with Koha; if not, see <http://www.gnu.org/licenses>.
|
|
|
|
use Modern::Perl;
|
|
|
|
|
|
use C4::Context;
|
|
|
|
use Koha::Database;
|
|
use Koha::StockRotationStages;
|
|
use Koha::SMTP::Servers;
|
|
|
|
use base qw(Koha::Object);
|
|
|
|
=head1 NAME
|
|
|
|
Koha::Library - Koha Library Object class
|
|
|
|
=head1 API
|
|
|
|
=head2 Class methods
|
|
|
|
=head3 stockrotationstages
|
|
|
|
my $stages = Koha::Library->stockrotationstages;
|
|
|
|
Returns the stockrotation stages associated with this Library.
|
|
|
|
=cut
|
|
|
|
sub stockrotationstages {
|
|
my ( $self ) = @_;
|
|
my $rs = $self->_result->stockrotationstages;
|
|
return Koha::StockRotationStages->_new_from_dbic( $rs );
|
|
}
|
|
|
|
=head3 outgoing_transfers
|
|
|
|
my $outgoing_transfers = Koha::Library->outgoing_transfers;
|
|
|
|
Returns the outgoing item transfers associated with this Library.
|
|
|
|
=cut
|
|
|
|
sub outgoing_transfers {
|
|
my ( $self ) = @_;
|
|
my $rs = $self->_result->branchtransfers_frombranches;
|
|
return Koha::Item::Transfers->_new_from_dbic( $rs );
|
|
}
|
|
|
|
=head3 inbound_transfers
|
|
|
|
my $inbound_transfers = Koha::Library->inbound_transfers;
|
|
|
|
Returns the inbound item transfers associated with this Library.
|
|
|
|
=cut
|
|
|
|
sub inbound_transfers {
|
|
my ( $self ) = @_;
|
|
my $rs = $self->_result->branchtransfers_tobranches;
|
|
return Koha::Item::Transfers->_new_from_dbic( $rs );
|
|
}
|
|
|
|
=head3 get_effective_marcorgcode
|
|
|
|
my $marcorgcode = Koha::Libraries->find( $library_id )->get_effective_marcorgcode();
|
|
|
|
Returns the effective MARC organization code of the library. It falls back to the value
|
|
from the I<MARCOrgCode> syspref if undefined for the library.
|
|
|
|
=cut
|
|
|
|
sub get_effective_marcorgcode {
|
|
my ( $self ) = @_;
|
|
|
|
return $self->marcorgcode || C4::Context->preference("MARCOrgCode");
|
|
}
|
|
|
|
=head3 smtp_server
|
|
|
|
my $smtp_server = $library->smtp_server;
|
|
$library->smtp_server({ smtp_server => $smtp_server });
|
|
$library->smtp_server({ smtp_server => undef });
|
|
|
|
Accessor for getting and setting the library's SMTP server.
|
|
|
|
Returns the effective SMTP server configuration to be used on the library. The returned
|
|
value is always a I<Koha::SMTP::Server> object.
|
|
|
|
Setting it to undef will remove the link to a specific SMTP server and effectively
|
|
make the library use the default setting
|
|
|
|
=cut
|
|
|
|
sub smtp_server {
|
|
my ( $self, $params ) = @_;
|
|
|
|
my $library_smtp_server_rs = $self->_result->library_smtp_server;
|
|
|
|
if ( exists $params->{smtp_server} ) {
|
|
|
|
$self->_result->result_source->schema->txn_do( sub {
|
|
$library_smtp_server_rs->delete
|
|
if $library_smtp_server_rs;
|
|
|
|
if ( defined $params->{smtp_server} ) {
|
|
# Set the new server
|
|
# Remove any already set SMTP server
|
|
|
|
my $smtp_server = $params->{smtp_server};
|
|
$smtp_server->_result->add_to_library_smtp_servers({ library_id => $self->id });
|
|
}
|
|
});
|
|
} # else => reset to default
|
|
else {
|
|
# Getter
|
|
if ( $library_smtp_server_rs ) {
|
|
return Koha::SMTP::Servers->find(
|
|
$library_smtp_server_rs->smtp_server_id );
|
|
}
|
|
|
|
return Koha::SMTP::Servers->get_default;
|
|
}
|
|
|
|
return $self;
|
|
}
|
|
|
|
=head3 from_email_address
|
|
|
|
my $from_email = Koha::Library->from_email_address;
|
|
|
|
Returns the official 'from' email address for the branch.
|
|
|
|
It may well be a 'noreply' or other inaccessible local domain
|
|
address that is being used to satisfy spam protection filters.
|
|
|
|
=cut
|
|
|
|
sub from_email_address {
|
|
my ($self) = @_;
|
|
|
|
return
|
|
$self->branchemail
|
|
|| C4::Context->preference('KohaAdminEmailAddress')
|
|
|| undef;
|
|
}
|
|
|
|
=head3 inbound_email_address
|
|
|
|
my $to_email = Koha::Library->inbound_email_address;
|
|
|
|
Returns an effective email address which should be accessible to librarians at the branch.
|
|
|
|
NOTE: This is the address to use for 'reply_to' or 'to' fields; It should not usually be
|
|
used as the 'from' address for emails as it may lead to mail being caught by spam filters.
|
|
|
|
=cut
|
|
|
|
sub inbound_email_address {
|
|
my ($self) = @_;
|
|
|
|
return
|
|
$self->branchreplyto
|
|
|| $self->branchemail
|
|
|| C4::Context->preference('ReplytoDefault')
|
|
|| C4::Context->preference('KohaAdminEmailAddress')
|
|
|| undef;
|
|
}
|
|
|
|
=head3 inbound_ill_address
|
|
|
|
my $to_email = Koha::Library->inbound_ill_address;
|
|
|
|
Returns an effective email address which should be accessible to librarians at the branch
|
|
for inter library loans communication.
|
|
|
|
=cut
|
|
|
|
sub inbound_ill_address {
|
|
my ($self) = @_;
|
|
|
|
return
|
|
$self->branchillemail
|
|
|| C4::Context->preference('ILLDefaultStaffEmail')
|
|
|| $self->inbound_email_address;
|
|
}
|
|
|
|
=head3 library_groups
|
|
|
|
Return the Library groups of this library
|
|
|
|
=cut
|
|
|
|
sub library_groups {
|
|
my ( $self ) = @_;
|
|
my $rs = $self->_result->library_groups;
|
|
return Koha::Library::Groups->_new_from_dbic( $rs );
|
|
}
|
|
|
|
=head3 cash_registers
|
|
|
|
Return Cash::Registers associated with this Library
|
|
|
|
=cut
|
|
|
|
sub cash_registers {
|
|
my ( $self ) = @_;
|
|
my $rs = $self->_result->cash_registers;
|
|
return Koha::Cash::Registers->_new_from_dbic( $rs );
|
|
}
|
|
|
|
=head3 to_api_mapping
|
|
|
|
This method returns the mapping for representing a Koha::Library object
|
|
on the API.
|
|
|
|
=cut
|
|
|
|
sub to_api_mapping {
|
|
return {
|
|
branchcode => 'library_id',
|
|
branchname => 'name',
|
|
branchaddress1 => 'address1',
|
|
branchaddress2 => 'address2',
|
|
branchaddress3 => 'address3',
|
|
branchzip => 'postal_code',
|
|
branchcity => 'city',
|
|
branchstate => 'state',
|
|
branchcountry => 'country',
|
|
branchphone => 'phone',
|
|
branchfax => 'fax',
|
|
branchemail => 'email',
|
|
branchillemail => 'illemail',
|
|
branchreplyto => 'reply_to_email',
|
|
branchreturnpath => 'return_path_email',
|
|
branchurl => 'url',
|
|
issuing => undef,
|
|
branchip => 'ip',
|
|
branchnotes => 'notes',
|
|
marcorgcode => 'marc_org_code',
|
|
};
|
|
}
|
|
|
|
=head3 get_hold_libraries
|
|
|
|
Return all libraries (including self) that belong to the same hold groups
|
|
|
|
=cut
|
|
|
|
sub get_hold_libraries {
|
|
my ( $self ) = @_;
|
|
my $library_groups = $self->library_groups;
|
|
my @hold_libraries;
|
|
while ( my $library_group = $library_groups->next ) {
|
|
my $root = Koha::Library::Groups->get_root_ancestor({id => $library_group->id});
|
|
if($root->ft_local_hold_group) {
|
|
push @hold_libraries, $root->all_libraries;
|
|
}
|
|
}
|
|
|
|
my %seen;
|
|
@hold_libraries =
|
|
grep { !$seen{ $_->id }++ } @hold_libraries;
|
|
|
|
return Koha::Libraries->search({ branchcode => { '-in' => [ keys %seen ] } });
|
|
}
|
|
|
|
=head3 validate_hold_sibling
|
|
|
|
Return if given library is a valid hold group member
|
|
|
|
=cut
|
|
|
|
sub validate_hold_sibling {
|
|
my ( $self, $params ) = @_;
|
|
|
|
return 1 if $params->{branchcode} eq $self->id;
|
|
|
|
my $branchcode = $params->{branchcode};
|
|
return $self->get_hold_libraries->search( { branchcode => $branchcode } )
|
|
->count > 0;
|
|
}
|
|
|
|
=head2 Internal methods
|
|
|
|
=head3 _type
|
|
|
|
=cut
|
|
|
|
sub _type {
|
|
return 'Branch';
|
|
}
|
|
|
|
1;
|