C4/Auth.pm

   1 package C4::Auth;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22 use Carp qw( croak );
  23
  24 use Digest::MD5 qw( md5_base64 );
  25 use CGI::Session;
  26 use CGI::Session::ErrorHandler;
  27 use URI;
  28 use URI::QueryParam;
  29
  30 use C4::Context;
  31 use C4::Templates;    # to get the template
  32 use C4::Languages;
  33 use C4::Search::History;
  34 use Koha;
  35 use Koha::Logger;
  36 use Koha::Caches;
  37 use Koha::AuthUtils qw( get_script_name hash_password );
  38 use Koha::Auth::TwoFactorAuth;
  39 use Koha::Checkouts;
  40 use Koha::DateUtils qw( dt_from_string );
  41 use Koha::Library::Groups;
  42 use Koha::Libraries;
  43 use Koha::Cash::Registers;
  44 use Koha::Desks;
  45 use Koha::Patrons;
  46 use Koha::Patron::Consents;
  47 use List::MoreUtils qw( any );
  48 use Encode;
  49 use C4::Auth_with_shibboleth qw( shib_ok get_login_shib login_shib_url logout_shib checkpw_shib );
  50 use Net::CIDR;
  51 use C4::Log qw( logaction );
  52 use Koha::CookieManager;
  53
  54 # use utf8;
  55
  56 use vars qw($ldap $cas $caslogout);
  57 our (@ISA, @EXPORT_OK);
  58 BEGIN {
  59     sub psgi_env { any { /^psgi\./ } keys %ENV }
  60
  61     sub safe_exit {
  62         if   (psgi_env) { die 'psgi:exit' }
  63         else            { exit }
  64     }
  65
  66     C4::Context->set_remote_address;
  67
  68     require Exporter;
  69     @ISA = qw(Exporter);
  70
  71     @EXPORT_OK = qw(
  72       checkauth check_api_auth get_session check_cookie_auth checkpw checkpw_internal checkpw_hash
  73       get_all_subpermissions get_user_subpermissions track_login_daily in_iprange
  74       get_template_and_user haspermission
  75     );
  76
  77     $ldap      = C4::Context->config('useldapserver') || 0;
  78     $cas       = C4::Context->preference('casAuthentication');
  79     $caslogout = C4::Context->preference('casLogout');
  80
  81     if ($ldap) {
  82         require C4::Auth_with_ldap;
  83         import C4::Auth_with_ldap qw(checkpw_ldap);
  84     }
  85     if ($cas) {
  86         require C4::Auth_with_cas;    # no import
  87         import C4::Auth_with_cas qw(check_api_auth_cas checkpw_cas login_cas logout_cas login_cas_url logout_if_required multipleAuth getMultipleAuth);
  88     }
  89
  90 }
  91
  92 =head1 NAME
  93
  94 C4::Auth - Authenticates Koha users
  95
  96 =head1 SYNOPSIS
  97
  98   use CGI qw ( -utf8 );
  99   use C4::Auth;
 100   use C4::Output;
 101
 102   my $query = CGI->new;
 103
 104   my ($template, $borrowernumber, $cookie)
 105     = get_template_and_user(
 106         {
 107             template_name   => "opac-main.tt",
 108             query           => $query,
 109       type            => "opac",
 110       authnotrequired => 0,
 111       flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 112   }
 113     );
 114
 115   output_html_with_http_headers $query, $cookie, $template->output;
 116
 117 =head1 DESCRIPTION
 118
 119 The main function of this module is to provide
 120 authentification. However the get_template_and_user function has
 121 been provided so that a users login information is passed along
 122 automatically. This gets loaded into the template.
 123
 124 =head1 FUNCTIONS
 125
 126 =head2 get_template_and_user
 127
 128  my ($template, $borrowernumber, $cookie)
 129      = get_template_and_user(
 130        {
 131          template_name   => "opac-main.tt",
 132          query           => $query,
 133          type            => "opac",
 134          authnotrequired => 0,
 135          flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 136        }
 137      );
 138
 139 This call passes the C<query>, C<flagsrequired> and C<authnotrequired>
 140 to C<&checkauth> (in this module) to perform authentification.
 141 See C<&checkauth> for an explanation of these parameters.
 142
 143 The C<template_name> is then used to find the correct template for
 144 the page. The authenticated users details are loaded onto the
 145 template in the logged_in_user variable (which is a Koha::Patron object). Also the
 146 C<sessionID> is passed to the template. This can be used in templates
 147 if cookies are disabled. It needs to be put as and input to every
 148 authenticated page.
 149
 150 More information on the C<gettemplate> sub can be found in the
 151 Output.pm module.
 152
 153 =cut
 154
 155 sub get_template_and_user {
 156
 157     my $in = shift;
 158     my ( $user, $cookie, $sessionID, $flags );
 159     $cookie = [];
 160
 161     my $cookie_mgr = Koha::CookieManager->new;
 162
 163     # Get shibboleth login attribute
 164     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 165     my $shib_login = $shib ? get_login_shib() : undef;
 166
 167     C4::Context->interface( $in->{type} );
 168
 169     $in->{'authnotrequired'} ||= 0;
 170
 171     # the following call includes a bad template check; might croak
 172     my $template = C4::Templates::gettemplate(
 173         $in->{'template_name'},
 174         $in->{'type'},
 175         $in->{'query'},
 176     );
 177
 178     if ( $in->{'template_name'} !~ m/maintenance/ ) {
 179         ( $user, $cookie, $sessionID, $flags ) = checkauth(
 180             $in->{'query'},
 181             $in->{'authnotrequired'},
 182             $in->{'flagsrequired'},
 183             $in->{'type'},
 184             undef,
 185             $in->{template_name},
 186         );
 187     }
 188
 189     # If we enforce GDPR and the user did not consent, redirect
 190     # Exceptions for consent page itself and SCI/SCO system
 191     if( $in->{type} eq 'opac' && $user &&
 192         $in->{'template_name'} !~ /^(opac-patron-consent|sc[io]\/)/ &&
 193         C4::Context->preference('GDPR_Policy') eq 'Enforced' )
 194     {
 195         my $consent = Koha::Patron::Consents->search({
 196             borrowernumber => getborrowernumber($user),
 197             type => 'GDPR_PROCESSING',
 198             given_on => { '!=', undef },
 199         })->next;
 200         if( !$consent ) {
 201             print $in->{query}->redirect(-uri => '/cgi-bin/koha/opac-patron-consent.pl', -cookie => $cookie);
 202             safe_exit;
 203         }
 204     }
 205
 206     if ( $in->{type} eq 'opac' && $user ) {
 207         my $is_sco_user;
 208         if ($sessionID){
 209             my $session = get_session($sessionID);
 210             if ($session){
 211                 $is_sco_user = $session->param('sco_user');
 212             }
 213         }
 214         my $kick_out;
 215
 216         if (
 217 # If the user logged in is the SCO user and they try to go out of the SCO module,
 218 # log the user out removing the CGISESSID cookie
 219             $in->{template_name} !~ m|sco/| && $in->{template_name} !~ m|errors/errorpage.tt|
 220             && (
 221                 $is_sco_user ||
 222                 (
 223                     C4::Context->preference('AutoSelfCheckID')
 224                     && $user eq C4::Context->preference('AutoSelfCheckID')
 225                 )
 226             )
 227           )
 228         {
 229             $kick_out = 1;
 230         }
 231         elsif (
 232 # If the user logged in is the SCI user and they try to go out of the SCI module,
 233 # kick them out unless it is SCO with a valid permission
 234 # or they are a superlibrarian
 235                $in->{template_name} !~ m|sci/|
 236             && haspermission( $user, { self_check => 'self_checkin_module' } )
 237             && !(
 238                 $in->{template_name} =~ m|sco/| && haspermission(
 239                     $user, { self_check => 'self_checkout_module' }
 240                 )
 241             )
 242             && $flags && $flags->{superlibrarian} != 1
 243           )
 244         {
 245             $kick_out = 1;
 246         }
 247
 248         if ($kick_out) {
 249             $template = C4::Templates::gettemplate( 'opac-auth.tt', 'opac',
 250                 $in->{query} );
 251             $cookie = $cookie_mgr->replace_in_list( $cookie, $in->{query}->cookie(
 252                 -name     => 'CGISESSID',
 253                 -value    => '',
 254                 -HttpOnly => 1,
 255                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 256                 -sameSite => 'Lax',
 257             ));
 258
 259             $template->param(
 260                 loginprompt => 1,
 261                 script_name => get_script_name(),
 262             );
 263
 264             print $in->{query}->header(
 265                 {
 266                     type              => 'text/html',
 267                     charset           => 'utf-8',
 268                     cookie            => $cookie,
 269                     'X-Frame-Options' => 'SAMEORIGIN'
 270                 }
 271               ),
 272               $template->output;
 273             safe_exit;
 274         }
 275     }
 276
 277     my $borrowernumber;
 278     if ($user) {
 279
 280         # It's possible for $user to be the borrowernumber if they don't have a
 281         # userid defined (and are logging in through some other method, such
 282         # as SSL certs against an email address)
 283         my $patron;
 284         $borrowernumber = getborrowernumber($user) if defined($user);
 285         if ( !defined($borrowernumber) && defined($user) ) {
 286             $patron = Koha::Patrons->find( $user );
 287             if ($patron) {
 288                 $borrowernumber = $user;
 289
 290                 # A bit of a hack, but I don't know there's a nicer way
 291                 # to do it.
 292                 $user = $patron->firstname . ' ' . $patron->surname;
 293             }
 294         } else {
 295             $patron = Koha::Patrons->find( $borrowernumber );
 296             # FIXME What to do if $patron does not exist?
 297         }
 298
 299         # user info
 300         $template->param( loggedinusername   => $user ); # OBSOLETE - Do not reuse this in template, use logged_in_user.userid instead
 301         $template->param( loggedinusernumber => $borrowernumber ); # FIXME Should be replaced with logged_in_user.borrowernumber
 302         $template->param( logged_in_user     => $patron );
 303         $template->param( sessionID          => $sessionID );
 304
 305         if ( $in->{'type'} eq 'opac' ) {
 306             require Koha::Virtualshelves;
 307             my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 308                 {
 309                     borrowernumber => $borrowernumber,
 310                     public         => 0,
 311                 }
 312             );
 313             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 314                 {
 315                     public => 1,
 316                 }
 317             );
 318             $template->param(
 319                 some_private_shelves => $some_private_shelves,
 320                 some_public_shelves  => $some_public_shelves,
 321             );
 322         }
 323
 324         my $all_perms = get_all_subpermissions();
 325
 326         my @flagroots = qw(circulate catalogue parameters borrowers permissions reserveforothers borrow
 327           editcatalogue updatecharges tools editauthorities serials reports acquisition clubs problem_reports);
 328
 329         # We are going to use the $flags returned by checkauth
 330         # to create the template's parameters that will indicate
 331         # which menus the user can access.
 332         if ( $flags && $flags->{superlibrarian} == 1 ) {
 333             $template->param( CAN_user_circulate        => 1 );
 334             $template->param( CAN_user_catalogue        => 1 );
 335             $template->param( CAN_user_parameters       => 1 );
 336             $template->param( CAN_user_borrowers        => 1 );
 337             $template->param( CAN_user_permissions      => 1 );
 338             $template->param( CAN_user_reserveforothers => 1 );
 339             $template->param( CAN_user_editcatalogue    => 1 );
 340             $template->param( CAN_user_updatecharges    => 1 );
 341             $template->param( CAN_user_acquisition      => 1 );
 342             $template->param( CAN_user_suggestions      => 1 );
 343             $template->param( CAN_user_tools            => 1 );
 344             $template->param( CAN_user_editauthorities  => 1 );
 345             $template->param( CAN_user_serials          => 1 );
 346             $template->param( CAN_user_reports          => 1 );
 347             $template->param( CAN_user_staffaccess      => 1 );
 348             $template->param( CAN_user_coursereserves   => 1 );
 349             $template->param( CAN_user_plugins          => 1 );
 350             $template->param( CAN_user_lists            => 1 );
 351             $template->param( CAN_user_clubs            => 1 );
 352             $template->param( CAN_user_ill              => 1 );
 353             $template->param( CAN_user_stockrotation    => 1 );
 354             $template->param( CAN_user_cash_management  => 1 );
 355             $template->param( CAN_user_problem_reports  => 1 );
 356             $template->param( CAN_user_recalls          => 1 );
 357
 358             foreach my $module ( keys %$all_perms ) {
 359                 foreach my $subperm ( keys %{ $all_perms->{$module} } ) {
 360                     $template->param( "CAN_user_${module}_${subperm}" => 1 );
 361                 }
 362             }
 363         }
 364
 365         if ($flags) {
 366             foreach my $module ( keys %$all_perms ) {
 367                 if ( defined($flags->{$module}) && $flags->{$module} == 1 ) {
 368                     foreach my $subperm ( keys %{ $all_perms->{$module} } ) {
 369                         $template->param( "CAN_user_${module}_${subperm}" => 1 );
 370                     }
 371                 } elsif ( ref( $flags->{$module} ) ) {
 372                     foreach my $subperm ( keys %{ $flags->{$module} } ) {
 373                         $template->param( "CAN_user_${module}_${subperm}" => 1 );
 374                     }
 375                 }
 376             }
 377         }
 378
 379         if ($flags) {
 380             foreach my $module ( keys %$flags ) {
 381                 if ( $flags->{$module} == 1 or ref( $flags->{$module} ) ) {
 382                     $template->param( "CAN_user_$module" => 1 );
 383                 }
 384             }
 385         }
 386
 387         # Logged-in opac search history
 388         # If the requested template is an opac one and opac search history is enabled
 389         if ( $in->{type} eq 'opac' && C4::Context->preference('EnableOpacSearchHistory') ) {
 390             my $dbh   = C4::Context->dbh;
 391             my $query = "SELECT COUNT(*) FROM search_history WHERE userid=?";
 392             my $sth   = $dbh->prepare($query);
 393             $sth->execute($borrowernumber);
 394
 395             # If at least one search has already been performed
 396             if ( $sth->fetchrow_array > 0 ) {
 397
 398                 # We show the link in opac
 399                 $template->param( EnableOpacSearchHistory => 1 );
 400             }
 401             if (C4::Context->preference('LoadSearchHistoryToTheFirstLoggedUser'))
 402             {
 403                 # And if there are searches performed when the user was not logged in,
 404                 # we add them to the logged-in search history
 405                 my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 406                 if (@recentSearches) {
 407                     my $dbh   = C4::Context->dbh;
 408                     my $query = q{
 409                         INSERT INTO search_history(userid, sessionid, query_desc, query_cgi, type,  total, time )
 410                         VALUES (?, ?, ?, ?, ?, ?, ?)
 411                     };
 412                     my $sth = $dbh->prepare($query);
 413                     $sth->execute( $borrowernumber,
 414                         $in->{query}->cookie("CGISESSID"),
 415                         $_->{query_desc},
 416                         $_->{query_cgi},
 417                         $_->{type} || 'biblio',
 418                         $_->{total},
 419                         $_->{time},
 420                     ) foreach @recentSearches;
 421
 422                     # clear out the search history from the session now that
 423                     # we've saved it to the database
 424                  }
 425               }
 426               C4::Search::History::set_to_session( { cgi => $in->{'query'}, search_history => [] } );
 427
 428         } elsif ( $in->{type} eq 'intranet' and C4::Context->preference('EnableSearchHistory') ) {
 429             $template->param( EnableSearchHistory => 1 );
 430         }
 431     }
 432     else {    # if this is an anonymous session, setup to display public lists...
 433
 434         # If shibboleth is enabled, and we're in an anonymous session, we should allow
 435         # the user to attempt login via shibboleth.
 436         if ($shib) {
 437             $template->param( shibbolethAuthentication => $shib,
 438                 shibbolethLoginUrl => login_shib_url( $in->{'query'} ),
 439             );
 440
 441             # If shibboleth is enabled and we have a shibboleth login attribute,
 442             # but we are in an anonymous session, then we clearly have an invalid
 443             # shibboleth koha account.
 444             if ($shib_login) {
 445                 $template->param( invalidShibLogin => '1' );
 446             }
 447         }
 448
 449         $template->param( sessionID => $sessionID );
 450
 451         if ( $in->{'type'} eq 'opac' ){
 452             require Koha::Virtualshelves;
 453             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 454                 {
 455                     public => 1,
 456                 }
 457             );
 458             $template->param(
 459                 some_public_shelves  => $some_public_shelves,
 460             );
 461
 462             # Set default branch if one has been passed by the environment.
 463             $template->param( default_branch => $ENV{OPAC_BRANCH_DEFAULT} ) if $ENV{OPAC_BRANCH_DEFAULT};
 464         }
 465     }
 466
 467     # Sysprefs disabled via URL param
 468     # Note that value must be defined in order to override via ENV
 469     foreach my $syspref (
 470         qw(
 471             OPACUserCSS
 472             OPACUserJS
 473             IntranetUserCSS
 474             IntranetUserJS
 475             OpacAdditionalStylesheet
 476             opaclayoutstylesheet
 477             intranetcolorstylesheet
 478             intranetstylesheet
 479         )
 480       )
 481     {
 482         $ENV{"OVERRIDE_SYSPREF_$syspref"} = q{}
 483           if $in->{'query'}->param("DISABLE_SYSPREF_$syspref");
 484     }
 485
 486     # Anonymous opac search history
 487     # If opac search history is enabled and at least one search has already been performed
 488     if ( C4::Context->preference('EnableOpacSearchHistory') ) {
 489         my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 490         if (@recentSearches) {
 491             $template->param( EnableOpacSearchHistory => 1 );
 492         }
 493     }
 494
 495     if ( C4::Context->preference('dateformat') ) {
 496         $template->param( dateformat => C4::Context->preference('dateformat') );
 497     }
 498
 499     $template->param(auth_forwarded_hash => scalar $in->{'query'}->param('auth_forwarded_hash'));
 500
 501     # these template parameters are set the same regardless of $in->{'type'}
 502
 503     my $minPasswordLength = C4::Context->preference('minPasswordLength');
 504     $minPasswordLength = 3 if not $minPasswordLength or $minPasswordLength < 3;
 505     $template->param(
 506         EnhancedMessagingPreferences                                       => C4::Context->preference('EnhancedMessagingPreferences'),
 507         GoogleJackets                                                      => C4::Context->preference("GoogleJackets"),
 508         OpenLibraryCovers                                                  => C4::Context->preference("OpenLibraryCovers"),
 509         KohaAdminEmailAddress                                              => "" . C4::Context->preference("KohaAdminEmailAddress"),
 510         LoginFirstname  => ( C4::Context->userenv ? C4::Context->userenv->{"firstname"} : "Bel" ),
 511         LoginSurname    => C4::Context->userenv ? C4::Context->userenv->{"surname"}      : "Inconnu",
 512         emailaddress    => C4::Context->userenv ? C4::Context->userenv->{"emailaddress"} : undef,
 513         TagsEnabled     => C4::Context->preference("TagsEnabled"),
 514         hide_marc       => C4::Context->preference("hide_marc"),
 515         item_level_itypes  => C4::Context->preference('item-level_itypes'),
 516         patronimages       => C4::Context->preference("patronimages"),
 517         singleBranchMode   => ( Koha::Libraries->search->count == 1 ),
 518         noItemTypeImages   => C4::Context->preference("noItemTypeImages"),
 519         marcflavour        => C4::Context->preference("marcflavour"),
 520         OPACBaseURL        => C4::Context->preference('OPACBaseURL'),
 521         minPasswordLength  => $minPasswordLength,
 522     );
 523     if ( $in->{'type'} eq "intranet" ) {
 524         $template->param(
 525             AmazonCoverImages                                                          => C4::Context->preference("AmazonCoverImages"),
 526             AutoLocation                                                               => C4::Context->preference("AutoLocation"),
 527             PatronAutoComplete                                                         => C4::Context->preference("PatronAutoComplete"),
 528             FRBRizeEditions                                                            => C4::Context->preference("FRBRizeEditions"),
 529             IndependentBranches                                                        => C4::Context->preference("IndependentBranches"),
 530             IntranetNav                                                                => C4::Context->preference("IntranetNav"),
 531             IntranetmainUserblock                                                      => C4::Context->preference("IntranetmainUserblock"),
 532             LibraryName                                                                => C4::Context->preference("LibraryName"),
 533             advancedMARCEditor                                                         => C4::Context->preference("advancedMARCEditor"),
 534             canreservefromotherbranches                                                => C4::Context->preference('canreservefromotherbranches'),
 535             intranetcolorstylesheet                                                    => C4::Context->preference("intranetcolorstylesheet"),
 536             IntranetFavicon                                                            => C4::Context->preference("IntranetFavicon"),
 537             intranetreadinghistory                                                     => C4::Context->preference("intranetreadinghistory"),
 538             intranetstylesheet                                                         => C4::Context->preference("intranetstylesheet"),
 539             IntranetUserCSS                                                            => C4::Context->preference("IntranetUserCSS"),
 540             IntranetUserJS                                                             => C4::Context->preference("IntranetUserJS"),
 541             suggestion                                                                 => C4::Context->preference("suggestion"),
 542             virtualshelves                                                             => C4::Context->preference("virtualshelves"),
 543             StaffSerialIssueDisplayCount                                               => C4::Context->preference("StaffSerialIssueDisplayCount"),
 544             EasyAnalyticalRecords                                                      => C4::Context->preference('EasyAnalyticalRecords'),
 545             LocalCoverImages                                                           => C4::Context->preference('LocalCoverImages'),
 546             OPACLocalCoverImages                                                       => C4::Context->preference('OPACLocalCoverImages'),
 547             AllowMultipleCovers                                                        => C4::Context->preference('AllowMultipleCovers'),
 548             EnableBorrowerFiles                                                        => C4::Context->preference('EnableBorrowerFiles'),
 549             UseCourseReserves                                                          => C4::Context->preference("UseCourseReserves"),
 550             useDischarge                                                               => C4::Context->preference('useDischarge'),
 551             pending_checkout_notes                                                     => Koha::Checkouts->search({ noteseen => 0 }),
 552             plugins_enabled                                                            => C4::Context->config("enable_plugins"),
 553         );
 554     }
 555     else {
 556         warn "template type should be OPAC, here it is=[" . $in->{'type'} . "]" unless ( $in->{'type'} eq 'opac' );
 557
 558         #TODO : replace LibraryName syspref with 'system name', and remove this html processing
 559         my $LibraryNameTitle = C4::Context->preference("LibraryName");
 560         $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
 561         $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
 562
 563         # clean up the busc param in the session
 564         # if the page is not opac-detail and not the "add to list" page
 565         # and not the "edit comments" page
 566         if ( C4::Context->preference("OpacBrowseResults")
 567             && $in->{'template_name'} =~ /opac-(.+)\.(?:tt|tmpl)$/ ) {
 568             my $pagename = $1;
 569             unless ( $pagename =~ /^(?:MARC|ISBD)?detail$/
 570                 or $pagename =~ /^showmarc$/
 571                 or $pagename =~ /^addbybiblionumber$/
 572                 or $pagename =~ /^review$/ )
 573             {
 574                 my $sessionSearch = get_session( $sessionID );
 575                 $sessionSearch->clear( ["busc"] ) if $sessionSearch;
 576             }
 577         }
 578
 579         # variables passed from CGI: opac_css_override and opac_search_limits.
 580         my $opac_search_limit   = $ENV{'OPAC_SEARCH_LIMIT'};
 581         my $opac_limit_override = $ENV{'OPAC_LIMIT_OVERRIDE'};
 582         my $opac_name           = '';
 583         if (
 584             ( $opac_limit_override && $opac_search_limit && $opac_search_limit =~ /branch:([\w-]+)/ ) ||
 585             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /branch:([\w-]+)/ ) ||
 586             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /multibranchlimit:(\w+)/ )
 587           ) {
 588             $opac_name = $1;    # opac_search_limit is a branch, so we use it.
 589         } elsif ( $in->{'query'}->param('multibranchlimit') ) {
 590             $opac_name = $in->{'query'}->param('multibranchlimit');
 591         } elsif ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv && C4::Context->userenv->{'branch'} ) {
 592             $opac_name = C4::Context->userenv->{'branch'};
 593         }
 594
 595         my @search_groups = Koha::Library::Groups->get_search_groups({ interface => 'opac' })->as_list;
 596         $template->param(
 597             AnonSuggestions                       => "" . C4::Context->preference("AnonSuggestions"),
 598             LibrarySearchGroups                   => \@search_groups,
 599             opac_name                             => $opac_name,
 600             LibraryName                           => "" . C4::Context->preference("LibraryName"),
 601             LibraryNameTitle                      => "" . $LibraryNameTitle,
 602             OPACAmazonCoverImages                 => C4::Context->preference("OPACAmazonCoverImages"),
 603             OPACFRBRizeEditions                   => C4::Context->preference("OPACFRBRizeEditions"),
 604             OpacHighlightedWords                  => C4::Context->preference("OpacHighlightedWords"),
 605             OPACShelfBrowser                      => "" . C4::Context->preference("OPACShelfBrowser"),
 606             OPACURLOpenInNewWindow                => "" . C4::Context->preference("OPACURLOpenInNewWindow"),
 607             OPACUserCSS                           => "" . C4::Context->preference("OPACUserCSS"),
 608             OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
 609             opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
 610             opac_search_limit                     => $opac_search_limit,
 611             opac_limit_override                   => $opac_limit_override,
 612             OpacBrowser                           => C4::Context->preference("OpacBrowser"),
 613             OpacCloud                             => C4::Context->preference("OpacCloud"),
 614             OpacKohaUrl                           => C4::Context->preference("OpacKohaUrl"),
 615             OpacPasswordChange                    => C4::Context->preference("OpacPasswordChange"),
 616             OPACPatronDetails                     => C4::Context->preference("OPACPatronDetails"),
 617             OPACPrivacy                           => C4::Context->preference("OPACPrivacy"),
 618             OPACFinesTab                          => C4::Context->preference("OPACFinesTab"),
 619             OpacTopissue                          => C4::Context->preference("OpacTopissue"),
 620             'Version'                             => C4::Context->preference('Version'),
 621             hidelostitems                         => C4::Context->preference("hidelostitems"),
 622             mylibraryfirst                        => ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv ) ? C4::Context->userenv->{'branch'} : '',
 623             opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
 624             OpacFavicon                           => C4::Context->preference("OpacFavicon"),
 625             opaclanguagesdisplay                  => "" . C4::Context->preference("opaclanguagesdisplay"),
 626             opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
 627             OPACUserJS                            => C4::Context->preference("OPACUserJS"),
 628             opacuserlogin                         => "" . C4::Context->preference("opacuserlogin"),
 629             OpenLibrarySearch                     => C4::Context->preference("OpenLibrarySearch"),
 630             ShowReviewer                          => C4::Context->preference("ShowReviewer"),
 631             ShowReviewerPhoto                     => C4::Context->preference("ShowReviewerPhoto"),
 632             suggestion                            => "" . C4::Context->preference("suggestion"),
 633             virtualshelves                        => "" . C4::Context->preference("virtualshelves"),
 634             OPACSerialIssueDisplayCount           => C4::Context->preference("OPACSerialIssueDisplayCount"),
 635             SyndeticsClientCode                   => C4::Context->preference("SyndeticsClientCode"),
 636             SyndeticsEnabled                      => C4::Context->preference("SyndeticsEnabled"),
 637             SyndeticsCoverImages                  => C4::Context->preference("SyndeticsCoverImages"),
 638             SyndeticsTOC                          => C4::Context->preference("SyndeticsTOC"),
 639             SyndeticsSummary                      => C4::Context->preference("SyndeticsSummary"),
 640             SyndeticsEditions                     => C4::Context->preference("SyndeticsEditions"),
 641             SyndeticsExcerpt                      => C4::Context->preference("SyndeticsExcerpt"),
 642             SyndeticsReviews                      => C4::Context->preference("SyndeticsReviews"),
 643             SyndeticsAuthorNotes                  => C4::Context->preference("SyndeticsAuthorNotes"),
 644             SyndeticsAwards                       => C4::Context->preference("SyndeticsAwards"),
 645             SyndeticsSeries                       => C4::Context->preference("SyndeticsSeries"),
 646             SyndeticsCoverImageSize               => C4::Context->preference("SyndeticsCoverImageSize"),
 647             OPACLocalCoverImages                  => C4::Context->preference("OPACLocalCoverImages"),
 648             PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
 649             PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
 650             useDischarge                 => C4::Context->preference('useDischarge'),
 651         );
 652
 653         $template->param( OpacPublic => '1' ) if ( $user || C4::Context->preference("OpacPublic") );
 654     }
 655
 656     # Check if we were asked using parameters to force a specific language
 657     if ( defined $in->{'query'}->param('language') ) {
 658
 659         # Extract the language, let C4::Languages::getlanguage choose
 660         # what to do
 661         my $language = C4::Languages::getlanguage( $in->{'query'} );
 662         my $languagecookie = C4::Templates::getlanguagecookie( $in->{'query'}, $language );
 663         $cookie = $cookie_mgr->replace_in_list( $cookie, $languagecookie );
 664     }
 665
 666     return ( $template, $borrowernumber, $cookie, $flags );
 667 }
 668
 669 =head2 checkauth
 670
 671   ($userid, $cookie, $sessionID) = &checkauth($query, $noauth, $flagsrequired, $type);
 672
 673 Verifies that the user is authorized to run this script.  If
 674 the user is authorized, a (userid, cookie, session-id, flags)
 675 quadruple is returned.  If the user is not authorized but does
 676 not have the required privilege (see $flagsrequired below), it
 677 displays an error page and exits.  Otherwise, it displays the
 678 login page and exits.
 679
 680 Note that C<&checkauth> will return if and only if the user
 681 is authorized, so it should be called early on, before any
 682 unfinished operations (e.g., if you've opened a file, then
 683 C<&checkauth> won't close it for you).
 684
 685 C<$query> is the CGI object for the script calling C<&checkauth>.
 686
 687 The C<$noauth> argument is optional. If it is set, then no
 688 authorization is required for the script.
 689
 690 C<&checkauth> fetches user and session information from C<$query> and
 691 ensures that the user is authorized to run scripts that require
 692 authorization.
 693
 694 The C<$flagsrequired> argument specifies the required privileges
 695 the user must have if the username and password are correct.
 696 It should be specified as a reference-to-hash; keys in the hash
 697 should be the "flags" for the user, as specified in the Members
 698 intranet module. Any key specified must correspond to a "flag"
 699 in the userflags table. E.g., { circulate => 1 } would specify
 700 that the user must have the "circulate" privilege in order to
 701 proceed. To make sure that access control is correct, the
 702 C<$flagsrequired> parameter must be specified correctly.
 703
 704 Koha also has a concept of sub-permissions, also known as
 705 granular permissions.  This makes the value of each key
 706 in the C<flagsrequired> hash take on an additional
 707 meaning, i.e.,
 708
 709  1
 710
 711 The user must have access to all subfunctions of the module
 712 specified by the hash key.
 713
 714  *
 715
 716 The user must have access to at least one subfunction of the module
 717 specified by the hash key.
 718
 719  specific permission, e.g., 'export_catalog'
 720
 721 The user must have access to the specific subfunction list, which
 722 must correspond to a row in the permissions table.
 723
 724 The C<$type> argument specifies whether the template should be
 725 retrieved from the opac or intranet directory tree.  "opac" is
 726 assumed if it is not specified; however, if C<$type> is specified,
 727 "intranet" is assumed if it is not "opac".
 728
 729 If C<$query> does not have a valid session ID associated with it
 730 (i.e., the user has not logged in) or if the session has expired,
 731 C<&checkauth> presents the user with a login page (from the point of
 732 view of the original script, C<&checkauth> does not return). Once the
 733 user has authenticated, C<&checkauth> restarts the original script
 734 (this time, C<&checkauth> returns).
 735
 736 The login page is provided using a HTML::Template, which is set in the
 737 systempreferences table or at the top of this file. The variable C<$type>
 738 selects which template to use, either the opac or the intranet
 739 authentification template.
 740
 741 C<&checkauth> returns a user ID, a cookie, and a session ID. The
 742 cookie should be sent back to the browser; it verifies that the user
 743 has authenticated.
 744
 745 =cut
 746
 747 sub _version_check {
 748     my $type  = shift;
 749     my $query = shift;
 750     my $version;
 751
 752     # If version syspref is unavailable, it means Koha is being installed,
 753     # and so we must redirect to OPAC maintenance page or to the WebInstaller
 754     # also, if OpacMaintenance is ON, OPAC should redirect to maintenance
 755     if ( C4::Context->preference('OpacMaintenance') && $type eq 'opac' ) {
 756         warn "OPAC Install required, redirecting to maintenance";
 757         print $query->redirect("/cgi-bin/koha/maintenance.pl");
 758         safe_exit;
 759     }
 760     unless ( $version = C4::Context->preference('Version') ) {    # assignment, not comparison
 761         if ( $type ne 'opac' ) {
 762             warn "Install required, redirecting to Installer";
 763             print $query->redirect("/cgi-bin/koha/installer/install.pl");
 764         } else {
 765             warn "OPAC Install required, redirecting to maintenance";
 766             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 767         }
 768         safe_exit;
 769     }
 770
 771     # check that database and koha version are the same
 772     # there is no DB version, it's a fresh install,
 773     # go to web installer
 774     # there is a DB version, compare it to the code version
 775     my $kohaversion = Koha::version();
 776
 777     # remove the 3 last . to have a Perl number
 778     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
 779     Koha::Logger->get->debug("kohaversion : $kohaversion");
 780     if ( $version < $kohaversion ) {
 781         my $warning = "Database update needed, redirecting to %s. Database is $version and Koha is $kohaversion";
 782         if ( $type ne 'opac' ) {
 783             warn sprintf( $warning, 'Installer' );
 784             print $query->redirect("/cgi-bin/koha/installer/install.pl?step=1&op=updatestructure");
 785         } else {
 786             warn sprintf( "OPAC: " . $warning, 'maintenance' );
 787             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 788         }
 789         safe_exit;
 790     }
 791 }
 792
 793 sub _timeout_syspref {
 794     my $default_timeout = 600;
 795     my $timeout = C4::Context->preference('timeout') || $default_timeout;
 796
 797     # value in days, convert in seconds
 798     if ( $timeout =~ /^(\d+)[dD]$/ ) {
 799         $timeout = $1 * 86400;
 800     }
 801     # value in hours, convert in seconds
 802     elsif ( $timeout =~ /^(\d+)[hH]$/ ) {
 803         $timeout = $1 * 3600;
 804     }
 805     elsif ( $timeout !~ m/^\d+$/ ) {
 806         warn "The value of the system preference 'timeout' is not correct, defaulting to $default_timeout";
 807         $timeout = $default_timeout;
 808     }
 809
 810     return $timeout;
 811 }
 812
 813 sub checkauth {
 814     my $query = shift;
 815
 816     # Get shibboleth login attribute
 817     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 818     my $shib_login = $shib ? get_login_shib() : undef;
 819
 820     # $authnotrequired will be set for scripts which will run without authentication
 821     my $authnotrequired = shift;
 822     my $flagsrequired   = shift;
 823     my $type            = shift;
 824     my $emailaddress    = shift;
 825     my $template_name   = shift;
 826     $type = 'opac' unless $type;
 827
 828     unless ( C4::Context->preference("OpacPublic") ) {
 829         my @allowed_scripts_for_private_opac = qw(
 830           opac-memberentry.tt
 831           opac-registration-email-sent.tt
 832           opac-registration-confirmation.tt
 833           opac-memberentry-update-submitted.tt
 834           opac-password-recovery.tt
 835           opac-reset-password.tt
 836         );
 837         $authnotrequired = 0 unless grep { $_ eq $template_name }
 838           @allowed_scripts_for_private_opac;
 839     }
 840
 841     my $dbh     = C4::Context->dbh;
 842     my $timeout = _timeout_syspref();
 843
 844     my $cookie_mgr = Koha::CookieManager->new;
 845
 846     _version_check( $type, $query );
 847
 848     # state variables
 849     my $loggedin = 0;
 850     my $auth_state = 'failed';
 851     my %info;
 852     my ( $userid, $cookie, $sessionID, $flags );
 853     $cookie = [];
 854     my $logout = $query->param('logout.x');
 855
 856     my $anon_search_history;
 857     my $cas_ticket = '';
 858     # This parameter is the name of the CAS server we want to authenticate against,
 859     # when using authentication against multiple CAS servers, as configured in Auth_cas_servers.yaml
 860     my $casparam = $query->param('cas');
 861     my $q_userid = $query->param('userid') // '';
 862
 863     my $session;
 864     my $invalid_otp_token;
 865     my $require_2FA = ( C4::Context->preference('TwoFactorAuthentication') && $type ne "opac" ) ? 1 : 0;
 866
 867     # Basic authentication is incompatible with the use of Shibboleth,
 868     # as Shibboleth may return REMOTE_USER as a Shibboleth attribute,
 869     # and it may not be the attribute we want to use to match the koha login.
 870     #
 871     # Also, do not consider an empty REMOTE_USER.
 872     #
 873     # Finally, after those tests, we can assume (although if it would be better with
 874     # a syspref) that if we get a REMOTE_USER, that's from basic authentication,
 875     # and we can affect it to $userid.
 876     if ( !$shib and defined( $ENV{'REMOTE_USER'} ) and $ENV{'REMOTE_USER'} ne '' and $userid = $ENV{'REMOTE_USER'} ) {
 877
 878         # Using Basic Authentication, no cookies required
 879         $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 880             -name     => 'CGISESSID',
 881             -value    => '',
 882             -HttpOnly => 1,
 883             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 884             -sameSite => 'Lax',
 885         ));
 886         $loggedin = 1;
 887     }
 888     elsif ( $emailaddress) {
 889         # the Google OpenID Connect passes an email address
 890     }
 891     elsif ( $sessionID = $query->cookie("CGISESSID") ) {    # assignment, not comparison
 892         my ( $return, $more_info );
 893         # NOTE: $flags in the following call is still undefined !
 894         ( $return, $session, $more_info ) = check_cookie_auth( $sessionID, $flags,
 895             { remote_addr => $ENV{REMOTE_ADDR}, skip_version_check => 1 }
 896         );
 897
 898         if ( $return eq 'ok' || $return eq 'additional-auth-needed' ) {
 899             $userid = $session->param('id');
 900         }
 901
 902         $auth_state =
 903             $return eq 'ok'                     ? 'completed'
 904           : $return eq 'additional-auth-needed' ? 'additional-auth-needed'
 905           :                                       'failed';
 906
 907         # We are at the second screen if the waiting-for-2FA is set in session
 908         # and otp_token param has been passed
 909         if (   $require_2FA
 910             && $auth_state eq 'additional-auth-needed'
 911             && ( my $otp_token = $query->param('otp_token') ) )
 912         {
 913             my $patron    = Koha::Patrons->find( { userid => $userid } );
 914             my $auth      = Koha::Auth::TwoFactorAuth->new( { patron => $patron } );
 915             my $verified = $auth->verify($otp_token, 1);
 916             $auth->clear;
 917             if ( $verified ) {
 918                 # The token is correct, the user is fully logged in!
 919                 $auth_state = 'completed';
 920                 $session->param( 'waiting-for-2FA', 0 );
 921
 922                # This is an ugly trick to pass the test
 923                # $query->param('koha_login_context') && ( $q_userid ne $userid )
 924                # few lines later
 925                 $q_userid = $userid;
 926             }
 927             else {
 928                 $invalid_otp_token = 1;
 929             }
 930         }
 931
 932         if ( $auth_state eq 'completed' ) {
 933             Koha::Logger->get->debug(sprintf "AUTH_SESSION: (%s)\t%s %s - %s", map { $session->param($_) || q{} } qw(cardnumber firstname surname branch));
 934
 935             if ( ( $query->param('koha_login_context') && ( $q_userid ne $userid ) )
 936                 || ( $cas && $query->param('ticket') && !C4::Context->userenv->{'id'} )
 937                 || ( $shib && $shib_login && !$logout && !C4::Context->userenv->{'id'} )
 938             ) {
 939
 940                 #if a user enters an id ne to the id in the current session, we need to log them in...
 941                 #first we need to clear the anonymous session...
 942                 $anon_search_history = $session->param('search_history');
 943                 $session->delete();
 944                 $session->flush;
 945                 $cookie = $cookie_mgr->clear_unless( $query->cookie, @$cookie );
 946                 C4::Context::_unset_userenv($sessionID);
 947                 $sessionID = undef;
 948                 undef $userid; # IMPORTANT: this assures us a new session in code below
 949             } elsif (!$logout) {
 950
 951                 $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 952                     -name     => 'CGISESSID',
 953                     -value    => $session->id,
 954                     -HttpOnly => 1,
 955                     -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 956                     -sameSite => 'Lax',
 957                 ));
 958
 959                 $flags = haspermission( $userid, $flagsrequired );
 960                 unless ( $flags ) {
 961                     $auth_state = 'failed';
 962                     $info{'nopermission'} = 1;
 963                 }
 964             }
 965         } elsif ( !$logout ) {
 966             if ( $return eq 'expired' ) {
 967                 $info{timed_out} = 1;
 968             } elsif ( $return eq 'restricted' ) {
 969                 $info{oldip}        = $more_info->{old_ip};
 970                 $info{newip}        = $more_info->{new_ip};
 971                 $info{different_ip} = 1;
 972             } elsif ( $return eq 'password_expired' ) {
 973                 $info{password_has_expired} = 1;
 974             }
 975         }
 976     }
 977
 978     if ( $auth_state eq 'failed' || $logout ) {
 979         $sessionID = undef;
 980         $userid    = undef;
 981     }
 982
 983     if ($logout) {
 984
 985         # voluntary logout the user
 986         # check wether the user was using their shibboleth session or a local one
 987         my $shibSuccess = C4::Context->userenv ? C4::Context->userenv->{'shibboleth'} : undef;
 988         if ( $session ) {
 989             $session->delete();
 990             $session->flush;
 991         }
 992         C4::Context::_unset_userenv($sessionID);
 993         $cookie = $cookie_mgr->clear_unless( $query->cookie, @$cookie );
 994
 995         if ($cas and $caslogout) {
 996             logout_cas($query, $type);
 997         }
 998
 999         # If we are in a shibboleth session (shibboleth is enabled, a shibboleth match attribute is set and matches koha matchpoint)
1000         if ( $shib and $shib_login and $shibSuccess) {
1001             logout_shib($query);
1002         }
1003
1004         $session   = undef;
1005         $auth_state = 'logout';
1006     }
1007
1008     unless ( $userid ) {
1009         #we initiate a session prior to checking for a username to allow for anonymous sessions...
1010         if( !$session or !$sessionID ) { # if we cleared sessionID, we need a new session
1011             $session = get_session() or die "Auth ERROR: Cannot get_session()";
1012         }
1013
1014         # Save anonymous search history in new session so it can be retrieved
1015         # by get_template_and_user to store it in user's search history after
1016         # a successful login.
1017         if ($anon_search_history) {
1018             $session->param( 'search_history', $anon_search_history );
1019         }
1020
1021         $sessionID = $session->id;
1022         C4::Context->_new_userenv($sessionID);
1023         $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1024             -name     => 'CGISESSID',
1025             -value    => $sessionID,
1026             -HttpOnly => 1,
1027             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1028             -sameSite => 'Lax',
1029         ));
1030         my $pki_field = C4::Context->preference('AllowPKIAuth');
1031         if ( !defined($pki_field) ) {
1032             print STDERR "ERROR: Missing system preference AllowPKIAuth.\n";
1033             $pki_field = 'None';
1034         }
1035         if ( ( $cas && $query->param('ticket') )
1036             || $q_userid
1037             || ( $shib && $shib_login )
1038             || $pki_field ne 'None'
1039             || $emailaddress )
1040         {
1041             my $password    = $query->param('password');
1042             my $shibSuccess = 0;
1043             my ( $return, $cardnumber );
1044
1045             # If shib is enabled and we have a shib login, does the login match a valid koha user
1046             if ( $shib && $shib_login ) {
1047                 my $retuserid;
1048
1049                 # Do not pass password here, else shib will not be checked in checkpw.
1050                 ( $return, $cardnumber, $retuserid ) = checkpw( $dbh, $q_userid, undef, $query );
1051                 $userid      = $retuserid;
1052                 $shibSuccess = $return;
1053                 $info{'invalidShibLogin'} = 1 unless ($return);
1054             }
1055
1056             # If shib login and match were successful, skip further login methods
1057             unless ($shibSuccess) {
1058                 if ( $cas && $query->param('ticket') ) {
1059                     my $retuserid;
1060                     ( $return, $cardnumber, $retuserid, $cas_ticket ) =
1061                       checkpw( $dbh, $userid, $password, $query, $type );
1062                     $userid = $retuserid;
1063                     $info{'invalidCasLogin'} = 1 unless ($return);
1064                 }
1065
1066                 elsif ( $emailaddress ) {
1067                     my $value = $emailaddress;
1068
1069                     # If we're looking up the email, there's a chance that the person
1070                     # doesn't have a userid. So if there is none, we pass along the
1071                     # borrower number, and the bits of code that need to know the user
1072                     # ID will have to be smart enough to handle that.
1073                     my $patrons = Koha::Patrons->search({ email => $value });
1074                     if ($patrons->count) {
1075
1076                         # First the userid, then the borrowernum
1077                         my $patron = $patrons->next;
1078                         $value = $patron->userid || $patron->borrowernumber;
1079                     } else {
1080                         undef $value;
1081                     }
1082                     $return = $value ? 1 : 0;
1083                     $userid = $value;
1084                 }
1085
1086                 elsif (
1087                     ( $pki_field eq 'Common Name' && $ENV{'SSL_CLIENT_S_DN_CN'} )
1088                     || ( $pki_field eq 'emailAddress'
1089                         && $ENV{'SSL_CLIENT_S_DN_Email'} )
1090                   )
1091                 {
1092                     my $value;
1093                     if ( $pki_field eq 'Common Name' ) {
1094                         $value = $ENV{'SSL_CLIENT_S_DN_CN'};
1095                     }
1096                     elsif ( $pki_field eq 'emailAddress' ) {
1097                         $value = $ENV{'SSL_CLIENT_S_DN_Email'};
1098
1099                         # If we're looking up the email, there's a chance that the person
1100                         # doesn't have a userid. So if there is none, we pass along the
1101                         # borrower number, and the bits of code that need to know the user
1102                         # ID will have to be smart enough to handle that.
1103                         my $patrons = Koha::Patrons->search({ email => $value });
1104                         if ($patrons->count) {
1105
1106                             # First the userid, then the borrowernum
1107                             my $patron = $patrons->next;
1108                             $value = $patron->userid || $patron->borrowernumber;
1109                         } else {
1110                             undef $value;
1111                         }
1112                     }
1113
1114                     $return = $value ? 1 : 0;
1115                     $userid = $value;
1116
1117                 }
1118                 else {
1119                     my $retuserid;
1120                     my $request_method = $query->request_method();
1121
1122                     if (
1123                         $request_method eq 'POST'
1124                         || ( C4::Context->preference('AutoSelfCheckID')
1125                             && $q_userid eq C4::Context->preference('AutoSelfCheckID') )
1126                       )
1127                     {
1128
1129                         ( $return, $cardnumber, $retuserid, $cas_ticket ) =
1130                           checkpw( $dbh, $q_userid, $password, $query, $type );
1131                         $userid = $retuserid if ($retuserid);
1132                         $info{'invalid_username_or_password'} = 1 unless ($return);
1133                     }
1134                 }
1135             }
1136
1137             # If shib configured and shibOnly enabled, we should ignore anything other than a shibboleth type login.
1138             if (
1139                    $shib
1140                 && !$shibSuccess
1141                 && (
1142                     (
1143                         ( $type eq 'opac' )
1144                         && C4::Context->preference('OPACShibOnly')
1145                     )
1146                     || ( ( $type ne 'opac' )
1147                         && C4::Context->preference('staffShibOnly') )
1148                 )
1149               )
1150             {
1151                 $return = 0;
1152             }
1153
1154             # $return: 1 = valid user
1155             if ($return > 0) {
1156
1157                 if ( $flags = haspermission( $userid, $flagsrequired ) ) {
1158                     $auth_state = "logged_in";
1159                 }
1160                 else {
1161                     $auth_state = 'failed';
1162                     # FIXME We could add $return = 0; or even delete the session?
1163                     # Currently return == 1 and we will fill session info later on,
1164                     # although we do present an authorization failure. (Yes, the
1165                     # authentication was actually correct.)
1166                     $info{'nopermission'} = 1;
1167                     C4::Context::_unset_userenv($sessionID);
1168                 }
1169                 my ( $borrowernumber, $firstname, $surname, $userflags,
1170                     $branchcode, $branchname, $emailaddress, $desk_id,
1171                     $desk_name, $register_id, $register_name );
1172
1173                 if ( $return == 1 ) {
1174                     my $select = "
1175                     SELECT borrowernumber, firstname, surname, flags, borrowers.branchcode,
1176                     branches.branchname    as branchname, email
1177                     FROM borrowers
1178                     LEFT JOIN branches on borrowers.branchcode=branches.branchcode
1179                     ";
1180                     my $sth = $dbh->prepare("$select where userid=?");
1181                     $sth->execute($userid);
1182                     unless ( $sth->rows ) {
1183                         $sth = $dbh->prepare("$select where cardnumber=?");
1184                         $sth->execute($cardnumber);
1185
1186                         unless ( $sth->rows ) {
1187                             $sth->execute($userid);
1188                         }
1189                     }
1190                     if ( $sth->rows ) {
1191                         ( $borrowernumber, $firstname, $surname, $userflags,
1192                             $branchcode, $branchname, $emailaddress ) = $sth->fetchrow;
1193                     }
1194
1195                     # launch a sequence to check if we have a ip for the branch, i
1196                     # if we have one we replace the branchcode of the userenv by the branch bound in the ip.
1197
1198                     my $ip = $ENV{'REMOTE_ADDR'};
1199
1200                     # if they specify at login, use that
1201                     if ( $query->param('branch') ) {
1202                         $branchcode = $query->param('branch');
1203                         my $library = Koha::Libraries->find($branchcode);
1204                         $branchname = $library? $library->branchname: '';
1205                     }
1206                     if ( $query->param('desk_id') ) {
1207                         $desk_id = $query->param('desk_id');
1208                         my $desk = Koha::Desks->find($desk_id);
1209                         $desk_name = $desk ? $desk->desk_name : '';
1210                     }
1211                     if ( C4::Context->preference('UseCashRegisters') ) {
1212                         my $register =
1213                           $query->param('register_id')
1214                           ? Koha::Cash::Registers->find($query->param('register_id'))
1215                           : Koha::Cash::Registers->search(
1216                             { branch => $branchcode, branch_default => 1 },
1217                             { rows   => 1 } )->single;
1218                         $register_id   = $register->id   if ($register);
1219                         $register_name = $register->name if ($register);
1220                     }
1221                     my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search->as_list };
1222                     if ( $type ne 'opac' and C4::Context->preference('AutoLocation') ) {
1223
1224                         # we have to check they are coming from the right ip range
1225                         my $domain = $branches->{$branchcode}->{'branchip'};
1226                         $domain =~ s|\.\*||g;
1227                         if ( $ip !~ /^$domain/ ) {
1228                             $loggedin = 0;
1229                             $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1230                                 -name     => 'CGISESSID',
1231                                 -value    => '',
1232                                 -HttpOnly => 1,
1233                                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1234                                 -sameSite => 'Lax',
1235                             ));
1236                             $info{'wrongip'} = 1;
1237                         }
1238                     }
1239
1240                     foreach my $br ( keys %$branches ) {
1241
1242                         #     now we work with the treatment of ip
1243                         my $domain = $branches->{$br}->{'branchip'};
1244                         if ( $domain && $ip =~ /^$domain/ ) {
1245                             $branchcode = $branches->{$br}->{'branchcode'};
1246
1247                             # new op dev : add the branchname to the cookie
1248                             $branchname    = $branches->{$br}->{'branchname'};
1249                         }
1250                     }
1251
1252                     my $is_sco_user = 0;
1253                     if ( $query->param('sco_user_login') && ( $query->param('sco_user_login') eq '1' ) ){
1254                         $is_sco_user = 1;
1255                     }
1256
1257                     $session->param( 'number',       $borrowernumber );
1258                     $session->param( 'id',           $userid );
1259                     $session->param( 'cardnumber',   $cardnumber );
1260                     $session->param( 'firstname',    $firstname );
1261                     $session->param( 'surname',      $surname );
1262                     $session->param( 'branch',       $branchcode );
1263                     $session->param( 'branchname',   $branchname );
1264                     $session->param( 'desk_id',      $desk_id);
1265                     $session->param( 'desk_name',     $desk_name);
1266                     $session->param( 'flags',        $userflags );
1267                     $session->param( 'emailaddress', $emailaddress );
1268                     $session->param( 'ip',           $session->remote_addr() );
1269                     $session->param( 'lasttime',     time() );
1270                     $session->param( 'interface',    $type);
1271                     $session->param( 'shibboleth',   $shibSuccess );
1272                     $session->param( 'register_id',  $register_id );
1273                     $session->param( 'register_name',  $register_name );
1274                     $session->param( 'sco_user', $is_sco_user );
1275                 }
1276                 $session->param('cas_ticket', $cas_ticket) if $cas_ticket;
1277                 C4::Context->set_userenv(
1278                     $session->param('number'),       $session->param('id'),
1279                     $session->param('cardnumber'),   $session->param('firstname'),
1280                     $session->param('surname'),      $session->param('branch'),
1281                     $session->param('branchname'),   $session->param('flags'),
1282                     $session->param('emailaddress'), $session->param('shibboleth'),
1283                     $session->param('desk_id'),      $session->param('desk_name'),
1284                     $session->param('register_id'),  $session->param('register_name')
1285                 );
1286
1287             }
1288             # $return: 0 = invalid user
1289             # reset to anonymous session
1290             else {
1291                 if ($userid) {
1292                     $info{'invalid_username_or_password'} = 1;
1293                     C4::Context::_unset_userenv($sessionID);
1294                 }
1295                 $session->param( 'lasttime', time() );
1296                 $session->param( 'ip',       $session->remote_addr() );
1297                 $session->param( 'sessiontype', 'anon' );
1298                 $session->param( 'interface', $type);
1299             }
1300         }    # END if ( $q_userid
1301         elsif ( $type eq "opac" ) {
1302
1303             # anonymous sessions are created only for the OPAC
1304
1305             # setting a couple of other session vars...
1306             $session->param( 'ip',          $session->remote_addr() );
1307             $session->param( 'lasttime',    time() );
1308             $session->param( 'sessiontype', 'anon' );
1309             $session->param( 'interface', $type);
1310         }
1311         $session->flush;
1312     }    # END unless ($userid)
1313
1314
1315     if ( $auth_state eq 'logged_in' ) {
1316         $auth_state = 'completed';
1317
1318         # Auth is completed unless an additional auth is needed
1319         if ( $require_2FA ) {
1320             my $patron = Koha::Patrons->find({userid => $userid});
1321             if ( $patron->auth_method eq 'two-factor' ) {
1322                 # Ask for the OTP token
1323                 $auth_state = 'additional-auth-needed';
1324                 $session->param('waiting-for-2FA', 1);
1325                 %info = ();# We remove the warnings/errors we may have set incorrectly before
1326             }
1327         }
1328     }
1329
1330     # finished authentification, now respond
1331     if ( $auth_state eq 'completed' || $authnotrequired ) {
1332         # successful login
1333         unless (@$cookie) {
1334             $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1335                 -name     => 'CGISESSID',
1336                 -value    => '',
1337                 -HttpOnly => 1,
1338                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1339                 -sameSite => 'Lax',
1340             ));
1341         }
1342
1343         track_login_daily( $userid );
1344
1345         # In case, that this request was a login attempt, we want to prevent that users can repost the opac login
1346         # request. We therefore redirect the user to the requested page again without the login parameters.
1347         # See Post/Redirect/Get (PRG) design pattern: https://en.wikipedia.org/wiki/Post/Redirect/Get
1348         if ( $type eq "opac" && $query->param('koha_login_context') && $query->param('koha_login_context') ne 'sco' && $query->param('password') && $query->param('userid') ) {
1349             my $uri = URI->new($query->url(-relative=>1, -query_string=>1));
1350             $uri->query_param_delete('userid');
1351             $uri->query_param_delete('password');
1352             $uri->query_param_delete('koha_login_context');
1353             print $query->redirect(-uri => $uri->as_string, -cookie => $cookie, -status=>'303 See other');
1354             safe_exit;
1355         }
1356
1357         return ( $userid, $cookie, $sessionID, $flags );
1358     }
1359
1360     #
1361     #
1362     # AUTH rejected, show the login/password template, after checking the DB.
1363     #
1364     #
1365
1366     my $patron = Koha::Patrons->find({ userid => $q_userid }); # Not necessary logged in!
1367
1368     # get the inputs from the incoming query
1369     my @inputs = ();
1370     my @inputs_to_clean = qw( userid password ticket logout.x otp_token );
1371     foreach my $name ( param $query) {
1372         next if grep { $name eq $_ } @inputs_to_clean;
1373         my @value = $query->multi_param($name);
1374         push @inputs, { name => $name, value => $_ } for @value;
1375     }
1376
1377     my $LibraryNameTitle = C4::Context->preference("LibraryName");
1378     $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
1379     $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
1380
1381     my $auth_template_name = ( $type eq 'opac' ) ? 'opac-auth.tt' : 'auth.tt';
1382     my $template = C4::Templates::gettemplate( $auth_template_name, $type, $query );
1383     $template->param(
1384         login                                 => 1,
1385         INPUTS                                => \@inputs,
1386         script_name                           => get_script_name(),
1387         casAuthentication                     => C4::Context->preference("casAuthentication"),
1388         shibbolethAuthentication              => $shib,
1389         suggestion                            => C4::Context->preference("suggestion"),
1390         virtualshelves                        => C4::Context->preference("virtualshelves"),
1391         LibraryName                           => "" . C4::Context->preference("LibraryName"),
1392         LibraryNameTitle                      => "" . $LibraryNameTitle,
1393         opacuserlogin                         => C4::Context->preference("opacuserlogin"),
1394         OpacFavicon                           => C4::Context->preference("OpacFavicon"),
1395         opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
1396         opaclanguagesdisplay                  => C4::Context->preference("opaclanguagesdisplay"),
1397         OPACUserJS                            => C4::Context->preference("OPACUserJS"),
1398         opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
1399         OpacCloud                             => C4::Context->preference("OpacCloud"),
1400         OpacTopissue                          => C4::Context->preference("OpacTopissue"),
1401         OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
1402         OpacBrowser                           => C4::Context->preference("OpacBrowser"),
1403         TagsEnabled                           => C4::Context->preference("TagsEnabled"),
1404         OPACUserCSS                           => C4::Context->preference("OPACUserCSS"),
1405         intranetcolorstylesheet               => C4::Context->preference("intranetcolorstylesheet"),
1406         intranetstylesheet                    => C4::Context->preference("intranetstylesheet"),
1407         IntranetNav                           => C4::Context->preference("IntranetNav"),
1408         IntranetFavicon                       => C4::Context->preference("IntranetFavicon"),
1409         IntranetUserCSS                       => C4::Context->preference("IntranetUserCSS"),
1410         IntranetUserJS                        => C4::Context->preference("IntranetUserJS"),
1411         IndependentBranches                   => C4::Context->preference("IndependentBranches"),
1412         AutoLocation                          => C4::Context->preference("AutoLocation"),
1413         wrongip                               => $info{'wrongip'},
1414         PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
1415         PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
1416         opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
1417         too_many_login_attempts               => ( $patron and $patron->account_locked ),
1418         password_has_expired                  => ( $patron and $patron->password_expired ),
1419     );
1420
1421     $template->param( SCO_login => 1 ) if ( $query->param('sco_user_login') );
1422     $template->param( SCI_login => 1 ) if ( $query->param('sci_user_login') );
1423     $template->param( OpacPublic => C4::Context->preference("OpacPublic") );
1424     $template->param( loginprompt => 1 ) unless $info{'nopermission'};
1425     if ( $auth_state eq 'additional-auth-needed' ) {
1426         $template->param(
1427             TwoFA_prompt => 1,
1428             invalid_otp_token => $invalid_otp_token,
1429         );
1430     }
1431
1432     if ( $type eq 'opac' ) {
1433         require Koha::Virtualshelves;
1434         my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
1435             {
1436                 public => 1,
1437             }
1438         );
1439         $template->param(
1440             some_public_shelves  => $some_public_shelves,
1441         );
1442     }
1443
1444     if ($cas) {
1445
1446         # Is authentication against multiple CAS servers enabled?
1447         require C4::Auth_with_cas;
1448         if ( multipleAuth() && !$casparam ) {
1449             my $casservers = getMultipleAuth();
1450             my @tmplservers;
1451             foreach my $key ( keys %$casservers ) {
1452                 push @tmplservers, { name => $key, value => login_cas_url( $query, $key, $type ) . "?cas=$key" };
1453             }
1454             $template->param(
1455                 casServersLoop => \@tmplservers
1456             );
1457         } else {
1458             $template->param(
1459                 casServerUrl => login_cas_url($query, undef, $type),
1460             );
1461         }
1462
1463         $template->param(
1464             invalidCasLogin => $info{'invalidCasLogin'}
1465         );
1466     }
1467
1468     if ($shib) {
1469         #If shibOnly is enabled just go ahead and redirect directly
1470         if ( (($type eq 'opac') && C4::Context->preference('OPACShibOnly')) || (($type ne 'opac') && C4::Context->preference('staffShibOnly')) ) {
1471             my $redirect_url = login_shib_url( $query );
1472             print $query->redirect( -uri => "$redirect_url", -status => 303 );
1473             safe_exit;
1474         }
1475
1476         $template->param(
1477             shibbolethAuthentication => $shib,
1478             shibbolethLoginUrl       => login_shib_url($query),
1479         );
1480     }
1481
1482     if (C4::Context->preference('GoogleOpenIDConnect')) {
1483         if ($query->param("OpenIDConnectFailed")) {
1484             my $reason = $query->param('OpenIDConnectFailed');
1485             $template->param(invalidGoogleOpenIDConnectLogin => $reason);
1486         }
1487     }
1488
1489     $template->param(
1490         LibraryName => C4::Context->preference("LibraryName"),
1491     );
1492     $template->param(%info);
1493
1494     #    $cookie = $query->cookie(CGISESSID => $session->id
1495     #   );
1496     print $query->header(
1497         {   type              => 'text/html',
1498             charset           => 'utf-8',
1499             cookie            => $cookie,
1500             'X-Frame-Options' => 'SAMEORIGIN',
1501             -sameSite => 'Lax'
1502         }
1503       ),
1504       $template->output;
1505     safe_exit;
1506 }
1507
1508 =head2 check_api_auth
1509
1510   ($status, $cookie, $sessionId) = check_api_auth($query, $userflags);
1511
1512 Given a CGI query containing the parameters 'userid' and 'password' and/or a session
1513 cookie, determine if the user has the privileges specified by C<$userflags>.
1514
1515 C<check_api_auth> is is meant for authenticating users of web services, and
1516 consequently will always return and will not attempt to redirect the user
1517 agent.
1518
1519 If a valid session cookie is already present, check_api_auth will return a status
1520 of "ok", the cookie, and the Koha session ID.
1521
1522 If no session cookie is present, check_api_auth will check the 'userid' and 'password
1523 parameters and create a session cookie and Koha session if the supplied credentials
1524 are OK.
1525
1526 Possible return values in C<$status> are:
1527
1528 =over
1529
1530 =item "ok" -- user authenticated; C<$cookie> and C<$sessionid> have valid values.
1531
1532 =item "failed" -- credentials are not correct; C<$cookie> and C<$sessionid> are undef
1533
1534 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1535
1536 =item "expired -- session cookie has expired; API user should resubmit userid and password
1537
1538 =item "restricted" -- The IP has changed (if SessionRestrictionByIP)
1539
1540 =item "additional-auth-needed -- User is in an authentication process that is not finished
1541
1542 =back
1543
1544 =cut
1545
1546 sub check_api_auth {
1547
1548     my $query         = shift;
1549     my $flagsrequired = shift;
1550     my $dbh     = C4::Context->dbh;
1551     my $timeout = _timeout_syspref();
1552
1553     unless ( C4::Context->preference('Version') ) {
1554
1555         # database has not been installed yet
1556         return ( "maintenance", undef, undef );
1557     }
1558     my $kohaversion = Koha::version();
1559     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1560     if ( C4::Context->preference('Version') < $kohaversion ) {
1561
1562         # database in need of version update; assume that
1563         # no API should be called while databsae is in
1564         # this condition.
1565         return ( "maintenance", undef, undef );
1566     }
1567
1568     my ( $sessionID, $session );
1569     unless ( $query->param('userid') ) {
1570         $sessionID = $query->cookie("CGISESSID");
1571     }
1572     if ( $sessionID && not( $cas && $query->param('PT') ) ) {
1573
1574         my $return;
1575         ( $return, $session, undef ) = check_cookie_auth(
1576             $sessionID, $flagsrequired, { remote_addr => $ENV{REMOTE_ADDR} } );
1577
1578         return ( $return, undef, undef ) # Cookie auth failed
1579             if $return ne "ok";
1580
1581         my $cookie = $query->cookie(
1582             -name     => 'CGISESSID',
1583             -value    => $session->id,
1584             -HttpOnly => 1,
1585             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1586             -sameSite => 'Lax'
1587         );
1588         return ( $return, $cookie, $session ); # return == 'ok' here
1589
1590     } else {
1591
1592         # new login
1593         my $userid   = $query->param('userid');
1594         my $password = $query->param('password');
1595         my ( $return, $cardnumber, $cas_ticket );
1596
1597         # Proxy CAS auth
1598         if ( $cas && $query->param('PT') ) {
1599             my $retuserid;
1600
1601             # In case of a CAS authentication, we use the ticket instead of the password
1602             my $PT = $query->param('PT');
1603             ( $return, $cardnumber, $userid, $cas_ticket ) = check_api_auth_cas( $dbh, $PT, $query );    # EXTERNAL AUTH
1604         } else {
1605
1606             # User / password auth
1607             unless ( $userid and $password ) {
1608
1609                 # caller did something wrong, fail the authenticateion
1610                 return ( "failed", undef, undef );
1611             }
1612             my $newuserid;
1613             ( $return, $cardnumber, $newuserid, $cas_ticket ) = checkpw( $dbh, $userid, $password, $query );
1614         }
1615
1616         if ( $return and haspermission( $userid, $flagsrequired ) ) {
1617             my $session = get_session("");
1618             return ( "failed", undef, undef ) unless $session;
1619
1620             my $sessionID = $session->id;
1621             C4::Context->_new_userenv($sessionID);
1622             my $cookie = $query->cookie(
1623                 -name     => 'CGISESSID',
1624                 -value    => $sessionID,
1625                 -HttpOnly => 1,
1626                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1627                 -sameSite => 'Lax'
1628             );
1629             if ( $return == 1 ) {
1630                 my (
1631                     $borrowernumber, $firstname,  $surname,
1632                     $userflags,      $branchcode, $branchname,
1633                     $emailaddress
1634                 );
1635                 my $sth =
1636                   $dbh->prepare(
1637 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where userid=?"
1638                   );
1639                 $sth->execute($userid);
1640                 (
1641                     $borrowernumber, $firstname,  $surname,
1642                     $userflags,      $branchcode, $branchname,
1643                     $emailaddress
1644                 ) = $sth->fetchrow if ( $sth->rows );
1645
1646                 unless ( $sth->rows ) {
1647                     my $sth = $dbh->prepare(
1648 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
1649                     );
1650                     $sth->execute($cardnumber);
1651                     (
1652                         $borrowernumber, $firstname,  $surname,
1653                         $userflags,      $branchcode, $branchname,
1654                         $emailaddress
1655                     ) = $sth->fetchrow if ( $sth->rows );
1656
1657                     unless ( $sth->rows ) {
1658                         $sth->execute($userid);
1659                         (
1660                             $borrowernumber, $firstname,  $surname,       $userflags,
1661                             $branchcode,     $branchname, $emailaddress
1662                         ) = $sth->fetchrow if ( $sth->rows );
1663                     }
1664                 }
1665
1666                 my $ip = $ENV{'REMOTE_ADDR'};
1667
1668                 # if they specify at login, use that
1669                 if ( $query->param('branch') ) {
1670                     $branchcode = $query->param('branch');
1671                     my $library = Koha::Libraries->find($branchcode);
1672                     $branchname = $library? $library->branchname: '';
1673                 }
1674                 my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search->as_list };
1675                 foreach my $br ( keys %$branches ) {
1676
1677                     #     now we work with the treatment of ip
1678                     my $domain = $branches->{$br}->{'branchip'};
1679                     if ( $domain && $ip =~ /^$domain/ ) {
1680                         $branchcode = $branches->{$br}->{'branchcode'};
1681
1682                         # new op dev : add the branchname to the cookie
1683                         $branchname    = $branches->{$br}->{'branchname'};
1684                     }
1685                 }
1686                 $session->param( 'number',       $borrowernumber );
1687                 $session->param( 'id',           $userid );
1688                 $session->param( 'cardnumber',   $cardnumber );
1689                 $session->param( 'firstname',    $firstname );
1690                 $session->param( 'surname',      $surname );
1691                 $session->param( 'branch',       $branchcode );
1692                 $session->param( 'branchname',   $branchname );
1693                 $session->param( 'flags',        $userflags );
1694                 $session->param( 'emailaddress', $emailaddress );
1695                 $session->param( 'ip',           $session->remote_addr() );
1696                 $session->param( 'lasttime',     time() );
1697                 $session->param( 'interface',    'api'  );
1698             }
1699             $session->param( 'cas_ticket', $cas_ticket);
1700             C4::Context->set_userenv(
1701                 $session->param('number'),       $session->param('id'),
1702                 $session->param('cardnumber'),   $session->param('firstname'),
1703                 $session->param('surname'),      $session->param('branch'),
1704                 $session->param('branchname'),   $session->param('flags'),
1705                 $session->param('emailaddress'), $session->param('shibboleth'),
1706                 $session->param('desk_id'),      $session->param('desk_name'),
1707                 $session->param('register_id'),  $session->param('register_name')
1708             );
1709             return ( "ok", $cookie, $sessionID );
1710         } else {
1711             return ( "failed", undef, undef );
1712         }
1713     }
1714 }
1715
1716 =head2 check_cookie_auth
1717
1718   ($status, $sessionId) = check_cookie_auth($cookie, $userflags);
1719
1720 Given a CGISESSID cookie set during a previous login to Koha, determine
1721 if the user has the privileges specified by C<$userflags>. C<$userflags>
1722 is passed unaltered into C<haspermission> and as such accepts all options
1723 avaiable to that routine with the one caveat that C<check_api_auth> will
1724 also allow 'undef' to be passed and in such a case the permissions check
1725 will be skipped altogether.
1726
1727 C<check_cookie_auth> is meant for authenticating special services
1728 such as tools/upload-file.pl that are invoked by other pages that
1729 have been authenticated in the usual way.
1730
1731 Possible return values in C<$status> are:
1732
1733 =over
1734
1735 =item "ok" -- user authenticated; C<$sessionID> have valid values.
1736
1737 =item "anon" -- user not authenticated but valid for anonymous session.
1738
1739 =item "failed" -- credentials are not correct; C<$sessionid> are undef
1740
1741 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1742
1743 =item "expired -- session cookie has expired; API user should resubmit userid and password
1744
1745 =item "restricted" -- The IP has changed (if SessionRestrictionByIP)
1746
1747 =back
1748
1749 =cut
1750
1751 sub check_cookie_auth {
1752     my $sessionID     = shift;
1753     my $flagsrequired = shift;
1754     my $params        = shift;
1755
1756     my $remote_addr = $params->{remote_addr} || $ENV{REMOTE_ADDR};
1757
1758     my $skip_version_check = $params->{skip_version_check}; # Only for checkauth
1759
1760     unless ( $skip_version_check ) {
1761         unless ( C4::Context->preference('Version') ) {
1762
1763             # database has not been installed yet
1764             return ( "maintenance", undef );
1765         }
1766         my $kohaversion = Koha::version();
1767         $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1768         if ( C4::Context->preference('Version') < $kohaversion ) {
1769
1770             # database in need of version update; assume that
1771             # no API should be called while databsae is in
1772             # this condition.
1773             return ( "maintenance", undef );
1774         }
1775     }
1776
1777     # see if we have a valid session cookie already
1778     # however, if a userid parameter is present (i.e., from
1779     # a form submission, assume that any current cookie
1780     # is to be ignored
1781     unless ( $sessionID ) {
1782         return ( "failed", undef );
1783     }
1784     C4::Context::_unset_userenv($sessionID); # remove old userenv first
1785     my $session   = get_session($sessionID);
1786     if ($session) {
1787         my $userid   = $session->param('id');
1788         my $ip       = $session->param('ip');
1789         my $lasttime = $session->param('lasttime');
1790         my $timeout = _timeout_syspref();
1791
1792         if ( !$lasttime || ( $lasttime < time() - $timeout ) ) {
1793             # time out
1794             $session->delete();
1795             $session->flush;
1796             return ("expired", undef);
1797
1798         } elsif ( C4::Context->preference('SessionRestrictionByIP') && $ip ne $remote_addr ) {
1799             # IP address changed
1800             $session->delete();
1801             $session->flush;
1802             return ( "restricted", undef, { old_ip => $ip, new_ip => $remote_addr});
1803
1804         } elsif ( $userid ) {
1805             $session->param( 'lasttime', time() );
1806             my $patron = Koha::Patrons->find({ userid => $userid });
1807             $patron = Koha::Patron->find({ cardnumber => $userid }) unless $patron;
1808             return ("password_expired", undef ) if $patron->password_expired;
1809             my $flags = defined($flagsrequired) ? haspermission( $userid, $flagsrequired ) : 1;
1810             if ($flags) {
1811                 C4::Context->_new_userenv($sessionID);
1812                 C4::Context->interface($session->param('interface'));
1813                 C4::Context->set_userenv(
1814                     $session->param('number'),       $session->param('id') // '',
1815                     $session->param('cardnumber'),   $session->param('firstname'),
1816                     $session->param('surname'),      $session->param('branch'),
1817                     $session->param('branchname'),   $session->param('flags'),
1818                     $session->param('emailaddress'), $session->param('shibboleth'),
1819                     $session->param('desk_id'),      $session->param('desk_name'),
1820                     $session->param('register_id'),  $session->param('register_name')
1821                 );
1822                 return ( "additional-auth-needed", $session )
1823                     if $session->param('waiting-for-2FA');
1824
1825                 return ( "ok", $session );
1826             } else {
1827                 $session->delete();
1828                 $session->flush;
1829                 return ( "failed", undef );
1830             }
1831
1832         } else {
1833             C4::Context->_new_userenv($sessionID);
1834             C4::Context->interface($session->param('interface'));
1835             C4::Context->set_userenv( undef, q{} );
1836             return ( "anon", $session );
1837         }
1838     } else {
1839         return ( "expired", undef );
1840     }
1841 }
1842
1843 =head2 get_session
1844
1845   use CGI::Session;
1846   my $session = get_session($sessionID);
1847
1848 Given a session ID, retrieve the CGI::Session object used to store
1849 the session's state.  The session object can be used to store
1850 data that needs to be accessed by different scripts during a
1851 user's session.
1852
1853 If the C<$sessionID> parameter is an empty string, a new session
1854 will be created.
1855
1856 =cut
1857
1858 sub _get_session_params {
1859     my $storage_method = C4::Context->preference('SessionStorage');
1860     if ( $storage_method eq 'mysql' ) {
1861         my $dbh = C4::Context->dbh;
1862         return { dsn => "serializer:yamlxs;driver:MySQL;id:md5", dsn_args => { Handle => $dbh } };
1863     }
1864     elsif ( $storage_method eq 'Pg' ) {
1865         my $dbh = C4::Context->dbh;
1866         return { dsn => "serializer:yamlxs;driver:PostgreSQL;id:md5", dsn_args => { Handle => $dbh } };
1867     }
1868     elsif ( $storage_method eq 'memcached' && Koha::Caches->get_instance->memcached_cache ) {
1869         my $memcached = Koha::Caches->get_instance()->memcached_cache;
1870         return { dsn => "serializer:yamlxs;driver:memcached;id:md5", dsn_args => { Memcached => $memcached } };
1871     }
1872     else {
1873         # catch all defaults to tmp should work on all systems
1874         my $dir = C4::Context::temporary_directory;
1875         my $instance = C4::Context->config( 'database' ); #actually for packages not exactly the instance name, but generally safer to leave it as it is
1876         return { dsn => "serializer:yamlxs;driver:File;id:md5", dsn_args => { Directory => "$dir/cgisess_$instance" } };
1877     }
1878 }
1879
1880 sub get_session {
1881     my $sessionID      = shift;
1882     my $params = _get_session_params();
1883     my $session;
1884     if( $sessionID ) { # find existing
1885         CGI::Session::ErrorHandler->set_error( q{} ); # clear error, cpan issue #111463
1886         $session = CGI::Session->load( $params->{dsn}, $sessionID, $params->{dsn_args} );
1887     } else {
1888         $session = CGI::Session->new( $params->{dsn}, $sessionID, $params->{dsn_args} );
1889         # no need to flush here
1890     }
1891     return $session;
1892 }
1893
1894
1895 # FIXME no_set_userenv may be replaced with force_branchcode_for_userenv
1896 # (or something similar)
1897 # Currently it's only passed from C4::SIP::ILS::Patron::check_password, but
1898 # not having a userenv defined could cause a crash.
1899 sub checkpw {
1900     my ( $dbh, $userid, $password, $query, $type, $no_set_userenv ) = @_;
1901     $type = 'opac' unless $type;
1902
1903     # Get shibboleth login attribute
1904     my $shib = C4::Context->config('useshibboleth') && shib_ok();
1905     my $shib_login = $shib ? get_login_shib() : undef;
1906
1907     my @return;
1908     my $patron;
1909     if ( defined $userid ){
1910         $patron = Koha::Patrons->find({ userid => $userid });
1911         $patron = Koha::Patrons->find({ cardnumber => $userid }) unless $patron;
1912     }
1913     my $check_internal_as_fallback = 0;
1914     my $passwd_ok = 0;
1915     # Note: checkpw_* routines returns:
1916     # 1 if auth is ok
1917     # 0 if auth is nok
1918     # -1 if user bind failed (LDAP only)
1919
1920     if ( $patron and ( $patron->account_locked )  ) {
1921         # Nothing to check, account is locked
1922     } elsif ($ldap && defined($password)) {
1923         my ( $retval, $retcard, $retuserid ) = checkpw_ldap(@_);    # EXTERNAL AUTH
1924         if ( $retval == 1 ) {
1925             @return = ( $retval, $retcard, $retuserid );
1926             $passwd_ok = 1;
1927         }
1928         $check_internal_as_fallback = 1 if $retval == 0;
1929
1930     } elsif ( $cas && $query && $query->param('ticket') ) {
1931
1932         # In case of a CAS authentication, we use the ticket instead of the password
1933         my $ticket = $query->param('ticket');
1934         $query->delete('ticket');                                   # remove ticket to come back to original URL
1935         my ( $retval, $retcard, $retuserid, $cas_ticket ) = checkpw_cas( $dbh, $ticket, $query, $type );    # EXTERNAL AUTH
1936         if ( $retval ) {
1937             @return = ( $retval, $retcard, $retuserid, $cas_ticket );
1938         } else {
1939             @return = (0);
1940         }
1941         $passwd_ok = $retval;
1942     }
1943
1944     # If we are in a shibboleth session (shibboleth is enabled, and a shibboleth match attribute is present)
1945     # Check for password to asertain whether we want to be testing against shibboleth or another method this
1946     # time around.
1947     elsif ( $shib && $shib_login && !$password ) {
1948
1949         # In case of a Shibboleth authentication, we expect a shibboleth user attribute
1950         # (defined under shibboleth mapping in koha-conf.xml) to contain the login of the
1951         # shibboleth-authenticated user
1952
1953         # Then, we check if it matches a valid koha user
1954         if ($shib_login) {
1955             my ( $retval, $retcard, $retuserid ) = C4::Auth_with_shibboleth::checkpw_shib($shib_login);    # EXTERNAL AUTH
1956             if ( $retval ) {
1957                 @return = ( $retval, $retcard, $retuserid );
1958             }
1959             $passwd_ok = $retval;
1960         }
1961     } else {
1962         $check_internal_as_fallback = 1;
1963     }
1964
1965     # INTERNAL AUTH
1966     if ( $check_internal_as_fallback ) {
1967         @return = checkpw_internal( $dbh, $userid, $password, $no_set_userenv);
1968         $passwd_ok = 1 if $return[0] > 0; # 1 or 2
1969     }
1970
1971     if( $patron ) {
1972         if ( $passwd_ok ) {
1973             $patron->update({ login_attempts => 0 });
1974             if( $patron->password_expired ){
1975                 @return = (-2);
1976             }
1977         } elsif( !$patron->account_locked ) {
1978             $patron->update({ login_attempts => $patron->login_attempts + 1 });
1979         }
1980     }
1981
1982     # Optionally log success or failure
1983     if( $patron && $passwd_ok && C4::Context->preference('AuthSuccessLog') ) {
1984         logaction( 'AUTH', 'SUCCESS', $patron->id, "Valid password for $userid", $type );
1985     } elsif( !$passwd_ok && C4::Context->preference('AuthFailureLog') ) {
1986         logaction( 'AUTH', 'FAILURE', $patron ? $patron->id : 0, "Wrong password for $userid", $type );
1987     }
1988
1989     return @return;
1990 }
1991
1992 sub checkpw_internal {
1993     my ( $dbh, $userid, $password, $no_set_userenv ) = @_;
1994
1995     $password = Encode::encode( 'UTF-8', $password )
1996       if Encode::is_utf8($password);
1997
1998     my $sth =
1999       $dbh->prepare(
2000         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where userid=?"
2001       );
2002     $sth->execute($userid);
2003     if ( $sth->rows ) {
2004         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
2005             $surname, $branchcode, $branchname, $flags )
2006           = $sth->fetchrow;
2007
2008         if ( checkpw_hash( $password, $stored_hash ) ) {
2009
2010             C4::Context->set_userenv( "$borrowernumber", $userid, $cardnumber,
2011                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
2012             return 1, $cardnumber, $userid;
2013         }
2014     }
2015     $sth =
2016       $dbh->prepare(
2017         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
2018       );
2019     $sth->execute($userid);
2020     if ( $sth->rows ) {
2021         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
2022             $surname, $branchcode, $branchname, $flags )
2023           = $sth->fetchrow;
2024
2025         if ( checkpw_hash( $password, $stored_hash ) ) {
2026
2027             C4::Context->set_userenv( $borrowernumber, $userid, $cardnumber,
2028                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
2029             return 1, $cardnumber, $userid;
2030         }
2031     }
2032     return 0;
2033 }
2034
2035 sub checkpw_hash {
2036     my ( $password, $stored_hash ) = @_;
2037
2038     return if $stored_hash eq '!';
2039
2040     # check what encryption algorithm was implemented: Bcrypt - if the hash starts with '$2' it is Bcrypt else md5
2041     my $hash;
2042     if ( substr( $stored_hash, 0, 2 ) eq '$2' ) {
2043         $hash = hash_password( $password, $stored_hash );
2044     } else {
2045         $hash = md5_base64($password);
2046     }
2047     return $hash eq $stored_hash;
2048 }
2049
2050 =head2 getuserflags
2051
2052     my $authflags = getuserflags($flags, $userid, [$dbh]);
2053
2054 Translates integer flags into permissions strings hash.
2055
2056 C<$flags> is the integer userflags value ( borrowers.userflags )
2057 C<$userid> is the members.userid, used for building subpermissions
2058 C<$authflags> is a hashref of permissions
2059
2060 =cut
2061
2062 sub getuserflags {
2063     my $flags  = shift;
2064     my $userid = shift;
2065     my $dbh    = @_ ? shift : C4::Context->dbh;
2066     my $userflags;
2067     {
2068         # I don't want to do this, but if someone logs in as the database
2069         # user, it would be preferable not to spam them to death with
2070         # numeric warnings. So, we make $flags numeric.
2071         no warnings 'numeric';
2072         $flags += 0;
2073     }
2074     my $sth = $dbh->prepare("SELECT bit, flag, defaulton FROM userflags");
2075     $sth->execute;
2076
2077     while ( my ( $bit, $flag, $defaulton ) = $sth->fetchrow ) {
2078         if ( ( $flags & ( 2**$bit ) ) || $defaulton ) {
2079             $userflags->{$flag} = 1;
2080         }
2081         else {
2082             $userflags->{$flag} = 0;
2083         }
2084     }
2085
2086     # get subpermissions and merge with top-level permissions
2087     my $user_subperms = get_user_subpermissions($userid);
2088     foreach my $module ( keys %$user_subperms ) {
2089         next if $userflags->{$module} == 1;    # user already has permission for everything in this module
2090         $userflags->{$module} = $user_subperms->{$module};
2091     }
2092
2093     return $userflags;
2094 }
2095
2096 =head2 get_user_subpermissions
2097
2098   $user_perm_hashref = get_user_subpermissions($userid);
2099
2100 Given the userid (note, not the borrowernumber) of a staff user,
2101 return a hashref of hashrefs of the specific subpermissions
2102 accorded to the user.  An example return is
2103
2104  {
2105     tools => {
2106         export_catalog => 1,
2107         import_patrons => 1,
2108     }
2109  }
2110
2111 The top-level hash-key is a module or function code from
2112 userflags.flag, while the second-level key is a code
2113 from permissions.
2114
2115 The results of this function do not give a complete picture
2116 of the functions that a staff user can access; it is also
2117 necessary to check borrowers.flags.
2118
2119 =cut
2120
2121 sub get_user_subpermissions {
2122     my $userid = shift;
2123
2124     my $dbh = C4::Context->dbh;
2125     my $sth = $dbh->prepare( "SELECT flag, user_permissions.code
2126                              FROM user_permissions
2127                              JOIN permissions USING (module_bit, code)
2128                              JOIN userflags ON (module_bit = bit)
2129                              JOIN borrowers USING (borrowernumber)
2130                              WHERE userid = ?" );
2131     $sth->execute($userid);
2132
2133     my $user_perms = {};
2134     while ( my $perm = $sth->fetchrow_hashref ) {
2135         $user_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2136     }
2137     return $user_perms;
2138 }
2139
2140 =head2 get_all_subpermissions
2141
2142   my $perm_hashref = get_all_subpermissions();
2143
2144 Returns a hashref of hashrefs defining all specific
2145 permissions currently defined.  The return value
2146 has the same structure as that of C<get_user_subpermissions>,
2147 except that the innermost hash value is the description
2148 of the subpermission.
2149
2150 =cut
2151
2152 sub get_all_subpermissions {
2153     my $dbh = C4::Context->dbh;
2154     my $sth = $dbh->prepare( "SELECT flag, code
2155                              FROM permissions
2156                              JOIN userflags ON (module_bit = bit)" );
2157     $sth->execute();
2158
2159     my $all_perms = {};
2160     while ( my $perm = $sth->fetchrow_hashref ) {
2161         $all_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2162     }
2163     return $all_perms;
2164 }
2165
2166 =head2 haspermission
2167
2168   $flagsrequired = '*';                                 # Any permission at all
2169   $flagsrequired = 'a_flag';                            # a_flag must be satisfied (all subpermissions)
2170   $flagsrequired = [ 'a_flag', 'b_flag' ];              # a_flag OR b_flag must be satisfied
2171   $flagsrequired = { 'a_flag => 1, 'b_flag' => 1 };     # a_flag AND b_flag must be satisfied
2172   $flagsrequired = { 'a_flag' => 'sub_a' };             # sub_a of a_flag must be satisfied
2173   $flagsrequired = { 'a_flag' => [ 'sub_a, 'sub_b' ] }; # sub_a OR sub_b of a_flag must be satisfied
2174
2175   $flags = ($userid, $flagsrequired);
2176
2177 C<$userid> the userid of the member
2178 C<$flags> is a query structure similar to that used by SQL::Abstract that
2179 denotes the combination of flags required. It is a required parameter.
2180
2181 The main logic of this method is that things in arrays are OR'ed, and things
2182 in hashes are AND'ed. The `*` character can be used, at any depth, to denote `ANY`
2183
2184 Returns member's flags or 0 if a permission is not met.
2185
2186 =cut
2187
2188 sub _dispatch {
2189     my ($required, $flags) = @_;
2190
2191     my $ref = ref($required);
2192     if ($ref eq '') {
2193         if ($required eq '*') {
2194             return 0 unless ( $flags or ref( $flags ) );
2195         } else {
2196             return 0 unless ( $flags and (!ref( $flags ) || $flags->{$required} ));
2197         }
2198     } elsif ($ref eq 'HASH') {
2199         foreach my $key (keys %{$required}) {
2200             next if $flags == 1;
2201             my $require = $required->{$key};
2202             my $rflags  = $flags->{$key};
2203             return 0 unless _dispatch($require, $rflags);
2204         }
2205     } elsif ($ref eq 'ARRAY') {
2206         my $satisfied = 0;
2207         foreach my $require ( @{$required} ) {
2208             my $rflags =
2209               ( ref($flags) && !ref($require) && ( $require ne '*' ) )
2210               ? $flags->{$require}
2211               : $flags;
2212             $satisfied++ if _dispatch( $require, $rflags );
2213         }
2214         return 0 unless $satisfied;
2215     } else {
2216         croak "Unexpected structure found: $ref";
2217     }
2218
2219     return $flags;
2220 };
2221
2222 sub haspermission {
2223     my ( $userid, $flagsrequired ) = @_;
2224
2225     #Koha::Exceptions::WrongParameter->throw('$flagsrequired should not be undef')
2226     #  unless defined($flagsrequired);
2227
2228     my $sth = C4::Context->dbh->prepare("SELECT flags FROM borrowers WHERE userid=?");
2229     $sth->execute($userid);
2230     my $row = $sth->fetchrow();
2231     my $flags = getuserflags( $row, $userid );
2232
2233     return $flags unless defined($flagsrequired);
2234     return $flags if $flags->{superlibrarian};
2235     return _dispatch($flagsrequired, $flags);
2236
2237     #FIXME - This fcn should return the failed permission so a suitable error msg can be delivered.
2238 }
2239
2240 =head2 in_iprange
2241
2242   $flags = ($iprange);
2243
2244 C<$iprange> A space separated string describing an IP range. Can include single IPs or ranges
2245
2246 Returns 1 if the remote address is in the provided iprange, or 0 otherwise.
2247
2248 =cut
2249
2250 sub in_iprange {
2251     my ($iprange) = @_;
2252     my $result = 1;
2253     my @allowedipranges = $iprange ? split(' ', $iprange) : ();
2254     if (scalar @allowedipranges > 0) {
2255         my @rangelist;
2256         eval { @rangelist = Net::CIDR::range2cidr(@allowedipranges); }; return 0 if $@;
2257         eval { $result = Net::CIDR::cidrlookup($ENV{'REMOTE_ADDR'}, @rangelist) } || Koha::Logger->get->warn('cidrlookup failed for ' . join(' ',@rangelist) );
2258      }
2259      return $result ? 1 : 0;
2260 }
2261
2262 sub getborrowernumber {
2263     my ($userid) = @_;
2264     my $userenv = C4::Context->userenv;
2265     if ( defined($userenv) && ref($userenv) eq 'HASH' && $userenv->{number} ) {
2266         return $userenv->{number};
2267     }
2268     my $dbh = C4::Context->dbh;
2269     for my $field ( 'userid', 'cardnumber' ) {
2270         my $sth =
2271           $dbh->prepare("select borrowernumber from borrowers where $field=?");
2272         $sth->execute($userid);
2273         if ( $sth->rows ) {
2274             my ($bnumber) = $sth->fetchrow;
2275             return $bnumber;
2276         }
2277     }
2278     return 0;
2279 }
2280
2281 =head2 track_login_daily
2282
2283     track_login_daily( $userid );
2284
2285 Wraps the call to $patron->track_login, the method used to update borrowers.lastseen. We only call track_login once a day.
2286
2287 =cut
2288
2289 sub track_login_daily {
2290     my $userid = shift;
2291     return if !$userid || !C4::Context->preference('TrackLastPatronActivity');
2292
2293     my $cache     = Koha::Caches->get_instance();
2294     my $cache_key = "track_login_" . $userid;
2295     my $cached    = $cache->get_from_cache($cache_key);
2296     my $today = dt_from_string()->ymd;
2297     return if $cached && $cached eq $today;
2298
2299     my $patron = Koha::Patrons->find({ userid => $userid });
2300     return unless $patron;
2301     $patron->track_login;
2302     $cache->set_in_cache( $cache_key, $today );
2303 }
2304
2305 END { }    # module clean-up code here (global destructor)
2306 1;
2307 __END__
2308
2309 =head1 SEE ALSO
2310
2311 CGI(3)
2312
2313 C4::Output(3)
2314
2315 Crypt::Eksblowfish::Bcrypt(3)
2316
2317 Digest::MD5(3)
2318
2319 =cut