C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use Koha::DateUtils qw( dt_from_string output_pref );
  28 use C4::Context;
  29 use C4::Stats qw( UpdateStats );
  30 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest ItemsAnyAvailableAndNotRestricted );
  31 use C4::Biblio qw( UpdateTotalIssues );
  32 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  33 use C4::Accounts;
  34 use C4::ItemCirculationAlertPreference;
  35 use C4::Message;
  36 use C4::Log qw( logaction ); # logaction
  37 use C4::Overdues;
  38 use C4::RotatingCollections qw(GetCollectionItemBranches);
  39 use Algorithm::CheckDigits qw( CheckDigits );
  40
  41 use Data::Dumper qw( Dumper );
  42 use Koha::Account;
  43 use Koha::AuthorisedValues;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string output_pref );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment GetDebarments AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Carp qw( carp );
  66 use List::MoreUtils qw( any );
  67 use Scalar::Util qw( looks_like_number );
  68 use Date::Calc qw( Date_to_Days );
  69 our (@ISA, @EXPORT_OK);
  70 BEGIN {
  71
  72     require Exporter;
  73     @ISA = qw(Exporter);
  74
  75     # FIXME subs that should probably be elsewhere
  76     push @EXPORT_OK, qw(
  77       barcodedecode
  78       LostItem
  79       ReturnLostItem
  80       GetPendingOnSiteCheckouts
  81
  82       CanBookBeIssued
  83       checkHighHolds
  84       CanBookBeRenewed
  85       AddIssue
  86       GetLoanLength
  87       GetHardDueDate
  88       AddRenewal
  89       GetRenewCount
  90       GetSoonestRenewDate
  91       GetLatestAutoRenewDate
  92       GetIssuingCharges
  93       AddIssuingCharge
  94       GetBranchBorrowerCircRule
  95       GetBranchItemRule
  96       GetBiblioIssues
  97       GetOpenIssue
  98       GetUpcomingDueIssues
  99       CheckIfIssuedToPatron
 100       IsItemIssued
 101       GetAgeRestriction
 102       GetTopIssues
 103
 104       AddReturn
 105       MarkIssueReturned
 106
 107       transferbook
 108       TooMany
 109       GetTransfers
 110       GetTransfersFromTo
 111       updateWrongTransfer
 112       CalcDateDue
 113       CheckValidBarcode
 114       IsBranchTransferAllowed
 115       CreateBranchTransferLimit
 116       DeleteBranchTransferLimits
 117       TransferSlip
 118
 119       GetOfflineOperations
 120       GetOfflineOperation
 121       AddOfflineOperation
 122       DeleteOfflineOperation
 123       ProcessOfflineOperation
 124       ProcessOfflinePayment
 125     );
 126     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 127 }
 128
 129 =head1 NAME
 130
 131 C4::Circulation - Koha circulation module
 132
 133 =head1 SYNOPSIS
 134
 135 use C4::Circulation;
 136
 137 =head1 DESCRIPTION
 138
 139 The functions in this module deal with circulation, issues, and
 140 returns, as well as general information about the library.
 141 Also deals with inventory.
 142
 143 =head1 FUNCTIONS
 144
 145 =head2 barcodedecode
 146
 147   $str = &barcodedecode($barcode, [$filter]);
 148
 149 Generic filter function for barcode string.
 150 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 151 Will do some manipulation of the barcode for systems that deliver a barcode
 152 to circulation.pl that differs from the barcode stored for the item.
 153 For proper functioning of this filter, calling the function on the
 154 correct barcode string (items.barcode) should return an unaltered barcode.
 155
 156 The optional $filter argument is to allow for testing or explicit
 157 behavior that ignores the System Pref.  Valid values are the same as the
 158 System Pref options.
 159
 160 =cut
 161
 162 # FIXME -- the &decode fcn below should be wrapped into this one.
 163 # FIXME -- these plugins should be moved out of Circulation.pm
 164 #
 165 sub barcodedecode {
 166     my ($barcode, $filter) = @_;
 167     my $branch = C4::Context::mybranch();
 168     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 169     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 170     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 171         if ($filter eq 'whitespace') {
 172                 $barcode =~ s/\s//g;
 173         } elsif ($filter eq 'cuecat') {
 174                 chomp($barcode);
 175             my @fields = split( /\./, $barcode );
 176             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 177             ($#results == 2) and return $results[2];
 178         } elsif ($filter eq 'T-prefix') {
 179                 if ($barcode =~ /^[Tt](\d)/) {
 180                         (defined($1) and $1 eq '0') and return $barcode;
 181             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 182                 }
 183         return sprintf("T%07d", $barcode);
 184         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 185         # Why drop the nonzero digit after the T?
 186         # Why pass non-digits (or empty string) to "T%07d"?
 187         } elsif ($filter eq 'libsuite8') {
 188                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 189                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 190                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 191                         }else{
 192                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 193                         }
 194                 }
 195     } elsif ($filter eq 'EAN13') {
 196         my $ean = CheckDigits('ean');
 197         if ( $ean->is_valid($barcode) ) {
 198             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 199             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 200         } else {
 201             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 202         }
 203         }
 204     return $barcode;    # return barcode, modified or not
 205 }
 206
 207 =head2 _decode
 208
 209   $str = &_decode($chunk);
 210
 211 Decodes a segment of a string emitted by a CueCat barcode scanner and
 212 returns it.
 213
 214 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 215 or Javascript based decoding on the client side.
 216
 217 =cut
 218
 219 sub _decode {
 220     my ($encoded) = @_;
 221     my $seq =
 222       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 223     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 224     my $l = ( $#s + 1 ) % 4;
 225     if ($l) {
 226         if ( $l == 1 ) {
 227             # warn "Error: Cuecat decode parsing failed!";
 228             return;
 229         }
 230         $l = 4 - $l;
 231         $#s += $l;
 232     }
 233     my $r = '';
 234     while ( $#s >= 0 ) {
 235         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 236         $r .=
 237             chr( ( $n >> 16 ) ^ 67 )
 238          .chr( ( $n >> 8 & 255 ) ^ 67 )
 239          .chr( ( $n & 255 ) ^ 67 );
 240         @s = @s[ 4 .. $#s ];
 241     }
 242     $r = substr( $r, 0, length($r) - $l );
 243     return $r;
 244 }
 245
 246 =head2 transferbook
 247
 248   ($dotransfer, $messages, $iteminformation) = &transferbook({
 249                                                    from_branch => $frombranch
 250                                                    to_branch => $tobranch,
 251                                                    barcode => $barcode,
 252                                                    ignore_reserves => $ignore_reserves,
 253                                                    trigger => $trigger
 254                                                 });
 255
 256 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 257
 258 C<$fbr> is the code for the branch initiating the transfer.
 259 C<$tbr> is the code for the branch to which the item should be transferred.
 260
 261 C<$barcode> is the barcode of the item to be transferred.
 262
 263 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 264 Otherwise, if an item is reserved, the transfer fails.
 265
 266 C<$trigger> is the enum value for what triggered the transfer.
 267
 268 Returns three values:
 269
 270 =over
 271
 272 =item $dotransfer
 273
 274 is true if the transfer was successful.
 275
 276 =item $messages
 277
 278 is a reference-to-hash which may have any of the following keys:
 279
 280 =over
 281
 282 =item C<BadBarcode>
 283
 284 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 285
 286 =item C<DestinationEqualsHolding>
 287
 288 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 289
 290 =item C<WasReturned>
 291
 292 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 293
 294 =item C<ResFound>
 295
 296 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 297
 298 =item C<WasTransferred>
 299
 300 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 301
 302 =back
 303
 304 =back
 305
 306 =cut
 307
 308 sub transferbook {
 309     my $params = shift;
 310     my $tbr      = $params->{to_branch};
 311     my $fbr      = $params->{from_branch};
 312     my $ignoreRs = $params->{ignore_reserves};
 313     my $barcode  = $params->{barcode};
 314     my $trigger  = $params->{trigger};
 315     my $messages;
 316     my $dotransfer      = 1;
 317     my $item = Koha::Items->find( { barcode => $barcode } );
 318
 319     Koha::Exceptions::MissingParameter->throw(
 320         "Missing mandatory parameter: from_branch")
 321       unless $fbr;
 322
 323     Koha::Exceptions::MissingParameter->throw(
 324         "Missing mandatory parameter: to_branch")
 325       unless $tbr;
 326
 327     # bad barcode..
 328     unless ( $item ) {
 329         $messages->{'BadBarcode'} = $barcode;
 330         $dotransfer = 0;
 331         return ( $dotransfer, $messages );
 332     }
 333
 334     my $itemnumber = $item->itemnumber;
 335     # get branches of book...
 336     my $hbr = $item->homebranch;
 337
 338     # if using Branch Transfer Limits
 339     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 340         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 341         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 342             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 343                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 344                 $dotransfer = 0;
 345             }
 346         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 347             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 348             $dotransfer = 0;
 349         }
 350     }
 351
 352     # can't transfer book if is already there....
 353     if ( $fbr eq $tbr ) {
 354         $messages->{'DestinationEqualsHolding'} = 1;
 355         $dotransfer = 0;
 356     }
 357
 358     # check if it is still issued to someone, return it...
 359     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 360     if ( $issue ) {
 361         AddReturn( $barcode, $fbr );
 362         $messages->{'WasReturned'} = $issue->borrowernumber;
 363     }
 364
 365     # find reserves.....
 366     # That'll save a database query.
 367     my ( $resfound, $resrec, undef ) =
 368       CheckReserves( $itemnumber );
 369     if ( $resfound ) {
 370         $resrec->{'ResFound'} = $resfound;
 371         $messages->{'ResFound'} = $resrec;
 372         $dotransfer = 0 unless $ignoreRs;
 373     }
 374
 375     #actually do the transfer....
 376     if ($dotransfer) {
 377         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 378
 379         # don't need to update MARC anymore, we do it in batch now
 380         $messages->{'WasTransfered'} = $tbr;
 381
 382     }
 383     ModDateLastSeen( $itemnumber );
 384     return ( $dotransfer, $messages );
 385 }
 386
 387
 388 sub TooMany {
 389     my $borrower        = shift;
 390     my $item_object = shift;
 391     my $params = shift;
 392     my $onsite_checkout = $params->{onsite_checkout} || 0;
 393     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 394     my $cat_borrower    = $borrower->{'categorycode'};
 395     my $dbh             = C4::Context->dbh;
 396     # Get which branchcode we need
 397     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 398     my $type = $item_object->effective_itemtype;
 399
 400     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 401     $type_object = Koha::ItemTypes->find( $type );
 402     $parent_type = $type_object->parent_type if $type_object;
 403     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 404     # Find any children if we are a parent_type;
 405
 406     # given branch, patron category, and item type, determine
 407     # applicable issuing rule
 408
 409     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 410         {
 411             categorycode => $cat_borrower,
 412             itemtype     => $parent_type,
 413             branchcode   => $branch,
 414             rule_name    => 'maxissueqty',
 415         }
 416     ) if $parent_type;
 417     # If the parent rule is for default type we discount it
 418     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 419
 420     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 421         {
 422             categorycode => $cat_borrower,
 423             itemtype     => $type,
 424             branchcode   => $branch,
 425             rule_name    => 'maxissueqty',
 426         }
 427     );
 428
 429     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 430         {
 431             categorycode => $cat_borrower,
 432             itemtype     => $type,
 433             branchcode   => $branch,
 434             rule_name    => 'maxonsiteissueqty',
 435         }
 436     );
 437
 438
 439     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 440     # if a rule is found and has a loan limit set, count
 441     # how many loans the patron already has that meet that
 442     # rule
 443     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 444
 445         my $checkouts;
 446         if ( $maxissueqty_rule->branchcode ) {
 447             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 448                 $checkouts = $patron->checkouts->search(
 449                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 450             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 451                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 452             } else {
 453                 $checkouts = $patron->checkouts->search(
 454                     { 'item.homebranch' => $maxissueqty_rule->branchcode } );
 455             }
 456         } else {
 457             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 458         }
 459         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 460
 461         my $sum_checkouts;
 462         my $rule_itemtype = $maxissueqty_rule->itemtype;
 463
 464         my @types;
 465         unless ( $rule_itemtype ) {
 466             # matching rule has the default item type, so count only
 467             # those existing loans that don't fall under a more
 468             # specific rule
 469             @types = Koha::CirculationRules->search(
 470                 {
 471                     branchcode => $maxissueqty_rule->branchcode,
 472                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 473                     itemtype  => { '!=' => undef },
 474                     rule_name => 'maxissueqty'
 475                 }
 476             )->get_column('itemtype');
 477         } else {
 478             if ( $parent_maxissueqty_rule ) {
 479                 # if we have a parent item type then we count loans of the
 480                 # specific item type or its siblings or parent
 481                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 482                 @types = $children->get_column('itemtype');
 483                 push @types, $parent_type;
 484             } elsif ( $child_types ) {
 485                 # If we are a parent type, we need to count all child types and our own type
 486                 @types = $child_types->get_column('itemtype');
 487                 push @types, $type; # And don't forget to count our own types
 488             } else {
 489                 # Otherwise only count the specific itemtype
 490                 push @types, $type;
 491             }
 492         }
 493
 494         while ( my $c = $checkouts->next ) {
 495             my $itemtype = $c->item->effective_itemtype;
 496
 497             unless ( $rule_itemtype ) {
 498                 next if grep {$_ eq $itemtype} @types;
 499             } else {
 500                 next unless grep {$_ eq $itemtype} @types;
 501             }
 502
 503             $sum_checkouts->{total}++;
 504             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 505             $sum_checkouts->{itemtype}->{$itemtype}++;
 506         }
 507
 508         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 509         my $checkout_count = $sum_checkouts->{total} || 0;
 510         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 511
 512         my $checkout_rules = {
 513             checkout_count               => $checkout_count,
 514             onsite_checkout_count        => $onsite_checkout_count,
 515             onsite_checkout              => $onsite_checkout,
 516             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 517             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 518             switch_onsite_checkout       => $switch_onsite_checkout,
 519         };
 520         # If parent rules exists
 521         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 522             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 523             my $qty_over = _check_max_qty($checkout_rules);
 524             return $qty_over if defined $qty_over;
 525
 526             # If the parent rule is less than or equal to the child, we only need check the parent
 527             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 528                 $checkout_rules->{checkout_count} = $checkout_count_type;
 529                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 530                 my $qty_over = _check_max_qty($checkout_rules);
 531                 return $qty_over if defined $qty_over;
 532             }
 533         } else {
 534             my $qty_over = _check_max_qty($checkout_rules);
 535             return $qty_over if defined $qty_over;
 536         }
 537     }
 538
 539     # Now count total loans against the limit for the branch
 540     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 541     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 542         my $checkouts;
 543         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 544             $checkouts = $patron->checkouts->search(
 545                 { 'me.branchcode' => $branch} );
 546         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 547             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 548         } else {
 549             $checkouts = $patron->checkouts->search(
 550                 { 'item.homebranch' => $branch},
 551                 { prefetch          => 'item' } );
 552         }
 553
 554         my $checkout_count = $checkouts->count;
 555         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 556         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 557         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 558
 559         my $qty_over = _check_max_qty(
 560             {
 561                 checkout_count               => $checkout_count,
 562                 onsite_checkout_count        => $onsite_checkout_count,
 563                 onsite_checkout              => $onsite_checkout,
 564                 max_checkouts_allowed        => $max_checkouts_allowed,
 565                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 566                 switch_onsite_checkout       => $switch_onsite_checkout
 567             }
 568         );
 569         return $qty_over if defined $qty_over;
 570     }
 571
 572     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 573         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 574     }
 575
 576     # OK, the patron can issue !!!
 577     return;
 578 }
 579
 580 sub _check_max_qty {
 581     my $params                       = shift;
 582     my $checkout_count               = $params->{checkout_count};
 583     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 584     my $onsite_checkout              = $params->{onsite_checkout};
 585     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 586     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 587     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 588
 589     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 590         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 591         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 592             return {
 593                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 594                 count       => $onsite_checkout_count,
 595                 max_allowed => $max_onsite_checkouts_allowed,
 596             };
 597         }
 598     }
 599     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 600         if ( $max_checkouts_allowed eq '' ) { return; }
 601         my $delta = $switch_onsite_checkout ? 1 : 0;
 602         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 603             return {
 604                 reason      => 'TOO_MANY_CHECKOUTS',
 605                 count       => $checkout_count,
 606                 max_allowed => $max_checkouts_allowed,
 607             };
 608         }
 609     }
 610     elsif ( not $onsite_checkout ) {
 611         if ( $max_checkouts_allowed eq '' ) { return; }
 612         if (
 613             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 614         {
 615             return {
 616                 reason      => 'TOO_MANY_CHECKOUTS',
 617                 count       => $checkout_count - $onsite_checkout_count,
 618                 max_allowed => $max_checkouts_allowed,
 619             };
 620         }
 621     }
 622
 623     return;
 624 }
 625
 626 =head2 CanBookBeIssued
 627
 628   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 629                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 630
 631 Check if a book can be issued.
 632
 633 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 634
 635 IMPORTANT: The assumption by users of this routine is that causes blocking
 636 the issue are keyed by uppercase labels and other returned
 637 data is keyed in lower case!
 638
 639 =over 4
 640
 641 =item C<$patron> is a Koha::Patron
 642
 643 =item C<$barcode> is the bar code of the book being issued.
 644
 645 =item C<$duedates> is a DateTime object.
 646
 647 =item C<$inprocess> boolean switch
 648
 649 =item C<$ignore_reserves> boolean switch
 650
 651 =item C<$params> Hashref of additional parameters
 652
 653 Available keys:
 654     override_high_holds - Ignore high holds
 655     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 656
 657 =back
 658
 659 Returns :
 660
 661 =over 4
 662
 663 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 664 Possible values are :
 665
 666 =back
 667
 668 =head3 INVALID_DATE
 669
 670 sticky due date is invalid
 671
 672 =head3 GNA
 673
 674 borrower gone with no address
 675
 676 =head3 CARD_LOST
 677
 678 borrower declared it's card lost
 679
 680 =head3 DEBARRED
 681
 682 borrower debarred
 683
 684 =head3 UNKNOWN_BARCODE
 685
 686 barcode unknown
 687
 688 =head3 NOT_FOR_LOAN
 689
 690 item is not for loan
 691
 692 =head3 WTHDRAWN
 693
 694 item withdrawn.
 695
 696 =head3 RESTRICTED
 697
 698 item is restricted (set by ??)
 699
 700 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 701 could be prevented, but ones that can be overriden by the operator.
 702
 703 Possible values are :
 704
 705 =head3 DEBT
 706
 707 borrower has debts.
 708
 709 =head3 RENEW_ISSUE
 710
 711 renewing, not issuing
 712
 713 =head3 ISSUED_TO_ANOTHER
 714
 715 issued to someone else.
 716
 717 =head3 RESERVED
 718
 719 reserved for someone else.
 720
 721 =head3 TRANSFERRED
 722
 723 reserved and being transferred for someone else.
 724
 725 =head3 INVALID_DATE
 726
 727 sticky due date is invalid or due date in the past
 728
 729 =head3 TOO_MANY
 730
 731 if the borrower borrows to much things
 732
 733 =cut
 734
 735 sub CanBookBeIssued {
 736     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 737     my %needsconfirmation;    # filled with problems that needs confirmations
 738     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 739     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 740     my %messages;             # filled with information messages that should be displayed.
 741
 742     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 743     my $override_high_holds = $params->{override_high_holds} || 0;
 744
 745     my $item_object = Koha::Items->find({barcode => $barcode });
 746
 747     # MANDATORY CHECKS - unless item exists, nothing else matters
 748     unless ( $item_object ) {
 749         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 750     }
 751     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 752
 753     my $item_unblessed = $item_object->unblessed; # Transition...
 754     my $issue = $item_object->checkout;
 755     my $biblio = $item_object->biblio;
 756
 757     my $biblioitem = $biblio->biblioitem;
 758     my $effective_itemtype = $item_object->effective_itemtype;
 759     my $dbh             = C4::Context->dbh;
 760     my $patron_unblessed = $patron->unblessed;
 761
 762     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 763     #
 764     # DUE DATE is OK ? -- should already have checked.
 765     #
 766     if ($duedate && ref $duedate ne 'DateTime') {
 767         $duedate = dt_from_string($duedate);
 768     }
 769     my $now = dt_from_string();
 770     unless ( $duedate ) {
 771         my $issuedate = $now->clone();
 772
 773         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 774
 775         # Offline circ calls AddIssue directly, doesn't run through here
 776         #  So issuingimpossible should be ok.
 777     }
 778
 779     my $fees = Koha::Charges::Fees->new(
 780         {
 781             patron    => $patron,
 782             library   => $circ_library,
 783             item      => $item_object,
 784             to_date   => $duedate,
 785         }
 786     );
 787
 788     if ($duedate) {
 789         my $today = $now->clone();
 790         $today->truncate( to => 'minute');
 791         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 792             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 793         }
 794     } else {
 795             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 796     }
 797
 798     #
 799     # BORROWER STATUS
 800     #
 801     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 802         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 803         C4::Stats::UpdateStats({
 804                      branch => C4::Context->userenv->{'branch'},
 805                      type => 'localuse',
 806                      itemnumber => $item_object->itemnumber,
 807                      itemtype => $effective_itemtype,
 808                      borrowernumber => $patron->borrowernumber,
 809                      ccode => $item_object->ccode}
 810                     );
 811         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 812         return( { STATS => 1 }, {});
 813     }
 814
 815     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 816         $issuingimpossible{GNA} = 1;
 817     }
 818
 819     if ( $patron->lost && $patron->lost == 1 ) {
 820         $issuingimpossible{CARD_LOST} = 1;
 821     }
 822     if ( $patron->is_debarred ) {
 823         $issuingimpossible{DEBARRED} = 1;
 824     }
 825
 826     if ( $patron->is_expired ) {
 827         $issuingimpossible{EXPIRED} = 1;
 828     }
 829
 830     #
 831     # BORROWER STATUS
 832     #
 833
 834     # DEBTS
 835     my $account = $patron->account;
 836     my $balance = $account->balance;
 837     my $non_issues_charges = $account->non_issues_charges;
 838     my $other_charges = $balance - $non_issues_charges;
 839
 840     my $amountlimit = C4::Context->preference("noissuescharge");
 841     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 842     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 843
 844     # Check the debt of this patrons guarantees
 845     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 846     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 847     if ( defined $no_issues_charge_guarantees ) {
 848         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships();
 849         my $guarantees_non_issues_charges = 0;
 850         foreach my $g ( @guarantees ) {
 851             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 852         }
 853
 854         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 855             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 856         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 857             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 858         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 859             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 860         }
 861     }
 862
 863     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 864     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 865     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 866     if ( defined $no_issues_charge_guarantors ) {
 867         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 868
 869         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 870             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 871         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 872             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 873         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 874             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 875         }
 876     }
 877
 878     if ( C4::Context->preference("IssuingInProcess") ) {
 879         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 880             $issuingimpossible{DEBT} = $non_issues_charges;
 881         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 882             $needsconfirmation{DEBT} = $non_issues_charges;
 883         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 884             $needsconfirmation{DEBT} = $non_issues_charges;
 885         }
 886     }
 887     else {
 888         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 889             $needsconfirmation{DEBT} = $non_issues_charges;
 890         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 891             $issuingimpossible{DEBT} = $non_issues_charges;
 892         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 893             $needsconfirmation{DEBT} = $non_issues_charges;
 894         }
 895     }
 896
 897     if ($balance > 0 && $other_charges > 0) {
 898         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 899     }
 900
 901     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 902     $patron_unblessed = $patron->unblessed;
 903
 904     if ( my $debarred_date = $patron->is_debarred ) {
 905          # patron has accrued fine days or has a restriction. $count is a date
 906         if ($debarred_date eq '9999-12-31') {
 907             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 908         }
 909         else {
 910             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 911         }
 912     } elsif ( my $num_overdues = $patron->has_overdues ) {
 913         ## patron has outstanding overdue loans
 914         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 915             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 916         }
 917         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 918             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 919         }
 920     }
 921
 922     # Additional Materials Check
 923     if ( C4::Context->preference("CircConfirmItemParts")
 924         && $item_object->materials )
 925     {
 926         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 927     }
 928
 929     #
 930     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 931     #
 932     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 933
 934         # Already issued to current borrower.
 935         # If it is an on-site checkout if it can be switched to a normal checkout
 936         # or ask whether the loan should be renewed
 937
 938         if ( $issue->onsite_checkout
 939                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 940             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 941         } else {
 942             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 943                 $patron->borrowernumber,
 944                 $item_object->itemnumber,
 945             );
 946             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 947                 if ( $renewerror eq 'onsite_checkout' ) {
 948                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 949                 }
 950                 else {
 951                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 952                 }
 953             }
 954             else {
 955                 $needsconfirmation{RENEW_ISSUE} = 1;
 956             }
 957         }
 958     }
 959     elsif ( $issue ) {
 960
 961         # issued to someone else
 962
 963         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 964
 965         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 966
 967         unless ( $can_be_returned ) {
 968             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 969             $issuingimpossible{branch_to_return} = $message;
 970         } else {
 971             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 972                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 973             } else {
 974             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 975             $needsconfirmation{issued_firstname} = $patron->firstname;
 976             $needsconfirmation{issued_surname} = $patron->surname;
 977             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 978             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 979             }
 980         }
 981     }
 982
 983     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 984     #
 985     my $switch_onsite_checkout = (
 986           C4::Context->preference('SwitchOnSiteCheckouts')
 987       and $issue
 988       and $issue->onsite_checkout
 989       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 990     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 991     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 992     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 993         if ( $toomany->{max_allowed} == 0 ) {
 994             $needsconfirmation{PATRON_CANT} = 1;
 995         }
 996         if ( C4::Context->preference("AllowTooManyOverride") ) {
 997             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 998             $needsconfirmation{current_loan_count} = $toomany->{count};
 999             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1000         } else {
1001             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1002             $issuingimpossible{current_loan_count} = $toomany->{count};
1003             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1004         }
1005     }
1006
1007     #
1008     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1009     #
1010     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1011     my $wants_check = $patron->wants_check_for_previous_checkout;
1012     $needsconfirmation{PREVISSUE} = 1
1013         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1014
1015     #
1016     # ITEM CHECKING
1017     #
1018     if ( $item_object->notforloan )
1019     {
1020         if(!C4::Context->preference("AllowNotForLoanOverride")){
1021             $issuingimpossible{NOT_FOR_LOAN} = 1;
1022             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1023         }else{
1024             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1025             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1026         }
1027     }
1028     else {
1029         # we have to check itemtypes.notforloan also
1030         if (C4::Context->preference('item-level_itypes')){
1031             # this should probably be a subroutine
1032             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1033             $sth->execute($effective_itemtype);
1034             my $notforloan=$sth->fetchrow_hashref();
1035             if ($notforloan->{'notforloan'}) {
1036                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1037                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1038                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1039                 } else {
1040                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1041                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1042                 }
1043             }
1044         }
1045         else {
1046             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1047             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1048                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1049                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1050                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1051                 } else {
1052                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1053                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1054                 }
1055             }
1056         }
1057     }
1058     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1059     {
1060         $issuingimpossible{WTHDRAWN} = 1;
1061     }
1062     if (   $item_object->restricted
1063         && $item_object->restricted == 1 )
1064     {
1065         $issuingimpossible{RESTRICTED} = 1;
1066     }
1067     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1068         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1069         my $code = $av->count ? $av->next->lib : '';
1070         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1071         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1072     }
1073     if ( C4::Context->preference("IndependentBranches") ) {
1074         my $userenv = C4::Context->userenv;
1075         unless ( C4::Context->IsSuperLibrarian() ) {
1076             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1077             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1078                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1079                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1080             }
1081             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1082               if ( $patron->branchcode ne $userenv->{branch} );
1083         }
1084     }
1085
1086     #
1087     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1088     #
1089     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1090     if ($rentalConfirmation) {
1091         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1092
1093         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1094         if ($itemtype_object) {
1095             my $accumulate_charge = $fees->accumulate_rentalcharge();
1096             if ( $accumulate_charge > 0 ) {
1097                 $rentalCharge += $accumulate_charge;
1098             }
1099         }
1100
1101         if ( $rentalCharge > 0 ) {
1102             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1103         }
1104     }
1105
1106     unless ( $ignore_reserves ) {
1107         # See if the item is on reserve.
1108         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1109         if ($restype) {
1110             my $resbor = $res->{'borrowernumber'};
1111             if ( $resbor ne $patron->borrowernumber ) {
1112                 my $patron = Koha::Patrons->find( $resbor );
1113                 if ( $restype eq "Waiting" )
1114                 {
1115                     # The item is on reserve and waiting, but has been
1116                     # reserved by some other patron.
1117                     $needsconfirmation{RESERVE_WAITING} = 1;
1118                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1119                     $needsconfirmation{'ressurname'} = $patron->surname;
1120                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1121                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1122                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1123                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1124                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1125                 }
1126                 elsif ( $restype eq "Reserved" ) {
1127                     # The item is on reserve for someone else.
1128                     $needsconfirmation{RESERVED} = 1;
1129                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1130                     $needsconfirmation{'ressurname'} = $patron->surname;
1131                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1132                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1133                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1134                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1135                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1136                 }
1137                 elsif ( $restype eq "Transferred" ) {
1138                     # The item is determined hold being transferred for someone else.
1139                     $needsconfirmation{TRANSFERRED} = 1;
1140                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1141                     $needsconfirmation{'ressurname'} = $patron->surname;
1142                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1143                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1144                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1145                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1146                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1147                 }
1148                 elsif ( $restype eq "Processing" ) {
1149                     # The item is determined hold being processed for someone else.
1150                     $needsconfirmation{PROCESSING} = 1;
1151                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1152                     $needsconfirmation{'ressurname'} = $patron->surname;
1153                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1154                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1155                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1156                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1157                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1158                 }
1159             }
1160         }
1161     }
1162
1163     ## CHECK AGE RESTRICTION
1164     my $agerestriction  = $biblioitem->agerestriction;
1165     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1166     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1167         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1168             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1169         }
1170         else {
1171             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1172         }
1173     }
1174
1175     ## check for high holds decreasing loan period
1176     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1177         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1178
1179         if ( $check->{exceeded} ) {
1180             if ($override_high_holds) {
1181                 $alerts{HIGHHOLDS} = {
1182                     num_holds  => $check->{outstanding},
1183                     duration   => $check->{duration},
1184                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1185                 };
1186             }
1187             else {
1188                 $needsconfirmation{HIGHHOLDS} = {
1189                     num_holds  => $check->{outstanding},
1190                     duration   => $check->{duration},
1191                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1192                 };
1193             }
1194         }
1195     }
1196
1197     if (
1198         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1199         # don't do the multiple loans per bib check if we've
1200         # already determined that we've got a loan on the same item
1201         !$issuingimpossible{NO_MORE_RENEWALS} &&
1202         !$needsconfirmation{RENEW_ISSUE}
1203     ) {
1204         # Check if borrower has already issued an item from the same biblio
1205         # Only if it's not a subscription
1206         my $biblionumber = $item_object->biblionumber;
1207         require C4::Serials;
1208         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1209         unless ($is_a_subscription) {
1210             # FIXME Should be $patron->checkouts($args);
1211             my $checkouts = Koha::Checkouts->search(
1212                 {
1213                     borrowernumber => $patron->borrowernumber,
1214                     biblionumber   => $biblionumber,
1215                 },
1216                 {
1217                     join => 'item',
1218                 }
1219             );
1220             # if we get here, we don't already have a loan on this item,
1221             # so if there are any loans on this bib, ask for confirmation
1222             if ( $checkouts->count ) {
1223                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1224             }
1225         }
1226     }
1227
1228     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1229 }
1230
1231 =head2 CanBookBeReturned
1232
1233   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1234
1235 Check whether the item can be returned to the provided branch
1236
1237 =over 4
1238
1239 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1240
1241 =item C<$branch> is the branchcode where the return is taking place
1242
1243 =back
1244
1245 Returns:
1246
1247 =over 4
1248
1249 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1250
1251 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1252
1253 =back
1254
1255 =cut
1256
1257 sub CanBookBeReturned {
1258   my ($item, $branch) = @_;
1259   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1260
1261   # assume return is allowed to start
1262   my $allowed = 1;
1263   my $message;
1264
1265   # identify all cases where return is forbidden
1266   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1267      $allowed = 0;
1268      $message = $item->{'homebranch'};
1269   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1270      $allowed = 0;
1271      $message = $item->{'holdingbranch'};
1272   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1273      $allowed = 0;
1274      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1275   }
1276
1277   return ($allowed, $message);
1278 }
1279
1280 =head2 CheckHighHolds
1281
1282     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1283     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1284     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1285
1286 =cut
1287
1288 sub checkHighHolds {
1289     my ( $item, $borrower ) = @_;
1290     my $branchcode = _GetCircControlBranch( $item, $borrower );
1291     my $item_object = Koha::Items->find( $item->{itemnumber} );
1292
1293     my $return_data = {
1294         exceeded    => 0,
1295         outstanding => 0,
1296         duration    => 0,
1297         due_date    => undef,
1298     };
1299
1300     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1301
1302     if ( $holds->count() ) {
1303         $return_data->{outstanding} = $holds->count();
1304
1305         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1306         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1307         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1308
1309         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1310
1311         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1312
1313             # static means just more than a given number of holds on the record
1314
1315             # If the number of holds is less than the threshold, we can stop here
1316             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1317                 return $return_data;
1318             }
1319         }
1320         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1321
1322             # dynamic means X more than the number of holdable items on the record
1323
1324             # let's get the items
1325             my @items = $holds->next()->biblio()->items()->as_list;
1326
1327             # Remove any items with status defined to be ignored even if the would not make item unholdable
1328             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1329                 @items = grep { !$_->$status } @items;
1330             }
1331
1332             # Remove any items that are not holdable for this patron
1333             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1334
1335             my $items_count = scalar @items;
1336
1337             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1338
1339             # If the number of holds is less than the count of items we have
1340             # plus the number of holds allowed above that count, we can stop here
1341             if ( $holds->count() <= $threshold ) {
1342                 return $return_data;
1343             }
1344         }
1345
1346         my $issuedate = dt_from_string();
1347
1348         my $itype = $item_object->effective_itemtype;
1349         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1350             {
1351                 categorycode => $borrower->{categorycode},
1352                 itemtype     => $itype,
1353                 branchcode   => $branchcode,
1354             }
1355         );
1356         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1357
1358         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1359
1360         my $rule = Koha::CirculationRules->get_effective_rule(
1361             {
1362                 categorycode => $borrower->{categorycode},
1363                 itemtype     => $item_object->effective_itemtype,
1364                 branchcode   => $branchcode,
1365                 rule_name    => 'decreaseloanholds',
1366             }
1367         );
1368
1369         my $duration;
1370         if ( defined($rule) && $rule->rule_value ne '' ){
1371             # overrides decreaseLoanHighHoldsDuration syspref
1372             $duration = $rule->rule_value;
1373         } else {
1374             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1375         }
1376         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1377         $reduced_datedue->set_hour($orig_due->hour);
1378         $reduced_datedue->set_minute($orig_due->minute);
1379         $reduced_datedue->truncate( to => 'minute' );
1380
1381         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1382             $return_data->{exceeded} = 1;
1383             $return_data->{duration} = $duration;
1384             $return_data->{due_date} = $reduced_datedue;
1385         }
1386     }
1387
1388     return $return_data;
1389 }
1390
1391 =head2 AddIssue
1392
1393   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1394
1395 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1396
1397 =over 4
1398
1399 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1400
1401 =item C<$barcode> is the barcode of the item being issued.
1402
1403 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1404 Calculated if empty.
1405
1406 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1407
1408 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1409 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1410
1411 AddIssue does the following things :
1412
1413   - step 01: check that there is a borrowernumber & a barcode provided
1414   - check for RENEWAL (book issued & being issued to the same patron)
1415       - renewal YES = Calculate Charge & renew
1416       - renewal NO  =
1417           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1418           * RESERVE PLACED ?
1419               - fill reserve if reserve to this patron
1420               - cancel reserve or not, otherwise
1421           * TRANSFERT PENDING ?
1422               - complete the transfert
1423           * ISSUE THE BOOK
1424
1425 =back
1426
1427 =cut
1428
1429 sub AddIssue {
1430     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1431
1432     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1433     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1434     my $auto_renew = $params && $params->{auto_renew};
1435     my $dbh          = C4::Context->dbh;
1436     my $barcodecheck = CheckValidBarcode($barcode);
1437
1438     my $issue;
1439
1440     if ( $datedue && ref $datedue ne 'DateTime' ) {
1441         $datedue = dt_from_string($datedue);
1442     }
1443
1444     # $issuedate defaults to today.
1445     if ( !defined $issuedate ) {
1446         $issuedate = dt_from_string();
1447     }
1448     else {
1449         if ( ref $issuedate ne 'DateTime' ) {
1450             $issuedate = dt_from_string($issuedate);
1451
1452         }
1453     }
1454
1455     # Stop here if the patron or barcode doesn't exist
1456     if ( $borrower && $barcode && $barcodecheck ) {
1457         # find which item we issue
1458         my $item_object = Koha::Items->find({ barcode => $barcode })
1459           or return;    # if we don't get an Item, abort.
1460         my $item_unblessed = $item_object->unblessed;
1461
1462         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1463
1464         # get actual issuing if there is one
1465         my $actualissue = $item_object->checkout;
1466
1467         # check if we just renew the issue.
1468         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1469                 and not $switch_onsite_checkout ) {
1470             $datedue = AddRenewal(
1471                 $borrower->{'borrowernumber'},
1472                 $item_object->itemnumber,
1473                 $branchcode,
1474                 $datedue,
1475                 $issuedate,    # here interpreted as the renewal date
1476             );
1477         }
1478         else {
1479             unless ($datedue) {
1480                 my $itype = $item_object->effective_itemtype;
1481                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1482
1483             }
1484             $datedue->truncate( to => 'minute' );
1485
1486             my $patron = Koha::Patrons->find( $borrower );
1487             my $library = Koha::Libraries->find( $branchcode );
1488             my $fees = Koha::Charges::Fees->new(
1489                 {
1490                     patron    => $patron,
1491                     library   => $library,
1492                     item      => $item_object,
1493                     to_date   => $datedue,
1494                 }
1495             );
1496
1497             # it's NOT a renewal
1498             if ( $actualissue and not $switch_onsite_checkout ) {
1499                 # This book is currently on loan, but not to the person
1500                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1501                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1502                 return unless $allowed;
1503                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1504                 # AddReturn certainly has side-effects, like onloan => undef
1505                 $item_object->discard_changes;
1506             }
1507
1508             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1509
1510             # Starting process for transfer job (checking transfert and validate it if we have one)
1511             if ( my $transfer = $item_object->get_transfer ) {
1512                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1513                 $transfer->set(
1514                     {
1515                         datearrived => dt_from_string,
1516                         tobranch    => C4::Context->userenv->{branch},
1517                         comments    => 'Forced branchtransfer'
1518                     }
1519                 )->store;
1520                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1521                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1522                     if ( $hold ) { # Is this really needed?
1523                         $hold->set( { found => undef } )->store;
1524                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1525                     }
1526                 }
1527             }
1528
1529             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1530             unless ($auto_renew) {
1531                 my $rule = Koha::CirculationRules->get_effective_rule(
1532                     {
1533                         categorycode => $borrower->{categorycode},
1534                         itemtype     => $item_object->effective_itemtype,
1535                         branchcode   => $branchcode,
1536                         rule_name    => 'auto_renew'
1537                     }
1538                 );
1539
1540                 $auto_renew = $rule->rule_value if $rule;
1541             }
1542
1543             my $issue_attributes = {
1544                 borrowernumber  => $borrower->{'borrowernumber'},
1545                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1546                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1547                 branchcode      => C4::Context->userenv->{'branch'},
1548                 onsite_checkout => $onsite_checkout,
1549                 auto_renew      => $auto_renew ? 1 : 0,
1550             };
1551
1552             # Get ID of logged in user.  if called from a batch job,
1553             # no user session exists and C4::Context->userenv() returns
1554             # the scalar '0'. Only do this if the syspref says so
1555             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1556                 my $userenv = C4::Context->userenv();
1557                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1558                 if ($usernumber) {
1559                     $issue_attributes->{issuer_id} = $usernumber;
1560                 }
1561             }
1562
1563             # In the case that the borrower has an on-site checkout
1564             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1565             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1566             if ($issue) {
1567                 $issue->set($issue_attributes)->store;
1568             }
1569             else {
1570                 $issue = Koha::Checkout->new(
1571                     {
1572                         itemnumber => $item_object->itemnumber,
1573                         %$issue_attributes,
1574                     }
1575                 )->store;
1576             }
1577             $issue->discard_changes;
1578             C4::Auth::track_login_daily( $borrower->{userid} );
1579             if ( $item_object->location && $item_object->location eq 'CART'
1580                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1581             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1582                 CartToShelf( $item_object->itemnumber );
1583             }
1584
1585             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1586                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1587             }
1588
1589             # Record if item was lost
1590             my $was_lost = $item_object->itemlost;
1591
1592             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1593             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1594             $item_object->itemlost(0);
1595             $item_object->onloan($datedue->ymd());
1596             $item_object->datelastborrowed( dt_from_string()->ymd() );
1597             $item_object->datelastseen( dt_from_string()->ymd() );
1598             $item_object->store({log_action => 0});
1599
1600             # If the item was lost, it has now been found, charge the overdue if necessary
1601             if ($was_lost) {
1602                 if ( $item_object->{_charge} ) {
1603                     $actualissue //= Koha::Old::Checkouts->search(
1604                         { itemnumber => $item_unblessed->{itemnumber} },
1605                         {
1606                             order_by => { '-desc' => 'returndate' },
1607                             rows     => 1
1608                         }
1609                     )->single;
1610                     unless ( exists( $borrower->{branchcode} ) ) {
1611                         my $patron = $actualissue->patron;
1612                         $borrower = $patron->unblessed;
1613                     }
1614                     _CalculateAndUpdateFine(
1615                         {
1616                             issue       => $actualissue,
1617                             item        => $item_unblessed,
1618                             borrower    => $borrower,
1619                             return_date => $issuedate
1620                         }
1621                     );
1622                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1623                         $item_object->itemnumber, undef, 'RENEWED' );
1624                 }
1625             }
1626
1627             # If it costs to borrow this book, charge it to the patron's account.
1628             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1629             if ( $charge && $charge > 0 ) {
1630                 AddIssuingCharge( $issue, $charge, 'RENT' );
1631             }
1632
1633             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1634             if ( $itemtype_object ) {
1635                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1636                 if ( $accumulate_charge > 0 ) {
1637                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1638                     $charge += $accumulate_charge;
1639                     $item_unblessed->{charge} = $charge;
1640                 }
1641             }
1642
1643             # Record the fact that this book was issued.
1644             C4::Stats::UpdateStats(
1645                 {
1646                     branch => C4::Context->userenv->{'branch'},
1647                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1648                     amount         => $charge,
1649                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1650                     itemnumber     => $item_object->itemnumber,
1651                     itemtype       => $item_object->effective_itemtype,
1652                     location       => $item_object->location,
1653                     borrowernumber => $borrower->{'borrowernumber'},
1654                     ccode          => $item_object->ccode,
1655                 }
1656             );
1657
1658             # Send a checkout slip.
1659             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1660             my %conditions        = (
1661                 branchcode   => $branchcode,
1662                 categorycode => $borrower->{categorycode},
1663                 item_type    => $item_object->effective_itemtype,
1664                 notification => 'CHECKOUT',
1665             );
1666             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1667                 SendCirculationAlert(
1668                     {
1669                         type     => 'CHECKOUT',
1670                         item     => $item_object->unblessed,
1671                         borrower => $borrower,
1672                         branch   => $branchcode,
1673                     }
1674                 );
1675             }
1676             logaction(
1677                 "CIRCULATION", "ISSUE",
1678                 $borrower->{'borrowernumber'},
1679                 $item_object->itemnumber,
1680             ) if C4::Context->preference("IssueLog");
1681
1682             Koha::Plugins->call('after_circ_action', {
1683                 action  => 'checkout',
1684                 payload => {
1685                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1686                     checkout => $issue->get_from_storage
1687                 }
1688             });
1689         }
1690     }
1691     return $issue;
1692 }
1693
1694 =head2 GetLoanLength
1695
1696   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1697
1698 Get loan length for an itemtype, a borrower type and a branch
1699
1700 =cut
1701
1702 sub GetLoanLength {
1703     my ( $categorycode, $itemtype, $branchcode ) = @_;
1704
1705     # Initialize default values
1706     my $rules = {
1707         issuelength   => 0,
1708         renewalperiod => 0,
1709         lengthunit    => 'days',
1710     };
1711
1712     my $found = Koha::CirculationRules->get_effective_rules( {
1713         branchcode => $branchcode,
1714         categorycode => $categorycode,
1715         itemtype => $itemtype,
1716         rules => [
1717             'issuelength',
1718             'renewalperiod',
1719             'lengthunit'
1720         ],
1721     } );
1722
1723     # Search for rules!
1724     foreach my $rule_name (keys %$found) {
1725         $rules->{$rule_name} = $found->{$rule_name};
1726     }
1727
1728     return $rules;
1729 }
1730
1731
1732 =head2 GetHardDueDate
1733
1734   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1735
1736 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1737
1738 =cut
1739
1740 sub GetHardDueDate {
1741     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1742
1743     my $rules = Koha::CirculationRules->get_effective_rules(
1744         {
1745             categorycode => $borrowertype,
1746             itemtype     => $itemtype,
1747             branchcode   => $branchcode,
1748             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1749         }
1750     );
1751
1752     if ( defined( $rules->{hardduedate} ) ) {
1753         if ( $rules->{hardduedate} ) {
1754             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1755         }
1756         else {
1757             return ( undef, undef );
1758         }
1759     }
1760 }
1761
1762 =head2 GetBranchBorrowerCircRule
1763
1764   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1765
1766 Retrieves circulation rule attributes that apply to the given
1767 branch and patron category, regardless of item type.
1768 The return value is a hashref containing the following key:
1769
1770 patron_maxissueqty - maximum number of loans that a
1771 patron of the given category can have at the given
1772 branch.  If the value is undef, no limit.
1773
1774 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1775 patron of the given category can have at the given
1776 branch.  If the value is undef, no limit.
1777
1778 This will check for different branch/category combinations in the following order:
1779 branch and category
1780 branch only
1781 category only
1782 default branch and category
1783
1784 If no rule has been found in the database, it will default to
1785 the buillt in rule:
1786
1787 patron_maxissueqty - undef
1788 patron_maxonsiteissueqty - undef
1789
1790 C<$branchcode> and C<$categorycode> should contain the
1791 literal branch code and patron category code, respectively - no
1792 wildcards.
1793
1794 =cut
1795
1796 sub GetBranchBorrowerCircRule {
1797     my ( $branchcode, $categorycode ) = @_;
1798
1799     # Initialize default values
1800     my $rules = {
1801         patron_maxissueqty       => undef,
1802         patron_maxonsiteissueqty => undef,
1803     };
1804
1805     # Search for rules!
1806     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1807         my $rule = Koha::CirculationRules->get_effective_rule(
1808             {
1809                 categorycode => $categorycode,
1810                 itemtype     => undef,
1811                 branchcode   => $branchcode,
1812                 rule_name    => $rule_name,
1813             }
1814         );
1815
1816         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1817     }
1818
1819     return $rules;
1820 }
1821
1822 =head2 GetBranchItemRule
1823
1824   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1825
1826 Retrieves circulation rule attributes that apply to the given
1827 branch and item type, regardless of patron category.
1828
1829 The return value is a hashref containing the following keys:
1830
1831 holdallowed => Hold policy for this branch and itemtype. Possible values:
1832   not_allowed:           No holds allowed.
1833   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1834   from_any_library:      Holds allowed from any patron.
1835   from_local_hold_group: Holds allowed from libraries in hold group
1836
1837 returnbranch => branch to which to return item.  Possible values:
1838   noreturn: do not return, let item remain where checked in (floating collections)
1839   homebranch: return to item's home branch
1840   holdingbranch: return to issuer branch
1841
1842 This searches branchitemrules in the following order:
1843
1844   * Same branchcode and itemtype
1845   * Same branchcode, itemtype '*'
1846   * branchcode '*', same itemtype
1847   * branchcode and itemtype '*'
1848
1849 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1850
1851 =cut
1852
1853 sub GetBranchItemRule {
1854     my ( $branchcode, $itemtype ) = @_;
1855
1856     # Search for rules!
1857     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1858         {
1859             branchcode => $branchcode,
1860             itemtype   => $itemtype,
1861             rule_name  => 'holdallowed',
1862         }
1863     );
1864     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1865         {
1866             branchcode => $branchcode,
1867             itemtype   => $itemtype,
1868             rule_name  => 'hold_fulfillment_policy',
1869         }
1870     );
1871     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1872         {
1873             branchcode => $branchcode,
1874             itemtype   => $itemtype,
1875             rule_name  => 'returnbranch',
1876         }
1877     );
1878
1879     # built-in default circulation rule
1880     my $rules;
1881     $rules->{holdallowed} = defined $holdallowed_rule
1882         ? $holdallowed_rule->rule_value
1883         : 'from_any_library';
1884     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1885         ? $hold_fulfillment_policy_rule->rule_value
1886         : 'any';
1887     $rules->{returnbranch} = defined $returnbranch_rule
1888         ? $returnbranch_rule->rule_value
1889         : 'homebranch';
1890
1891     return $rules;
1892 }
1893
1894 =head2 AddReturn
1895
1896   ($doreturn, $messages, $iteminformation, $borrower) =
1897       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1898
1899 Returns a book.
1900
1901 =over 4
1902
1903 =item C<$barcode> is the bar code of the book being returned.
1904
1905 =item C<$branch> is the code of the branch where the book is being returned.
1906
1907 =item C<$exemptfine> indicates that overdue charges for the item will be
1908 removed. Optional.
1909
1910 =item C<$return_date> allows the default return date to be overridden
1911 by the given return date. Optional.
1912
1913 =back
1914
1915 C<&AddReturn> returns a list of four items:
1916
1917 C<$doreturn> is true iff the return succeeded.
1918
1919 C<$messages> is a reference-to-hash giving feedback on the operation.
1920 The keys of the hash are:
1921
1922 =over 4
1923
1924 =item C<BadBarcode>
1925
1926 No item with this barcode exists. The value is C<$barcode>.
1927
1928 =item C<NotIssued>
1929
1930 The book is not currently on loan. The value is C<$barcode>.
1931
1932 =item C<withdrawn>
1933
1934 This book has been withdrawn/cancelled. The value should be ignored.
1935
1936 =item C<Wrongbranch>
1937
1938 This book has was returned to the wrong branch.  The value is a hashref
1939 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1940 contain the branchcode of the incorrect and correct return library, respectively.
1941
1942 =item C<ResFound>
1943
1944 The item was reserved. The value is a reference-to-hash whose keys are
1945 fields from the reserves table of the Koha database, and
1946 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1947 either C<Waiting>, C<Reserved>, or 0.
1948
1949 =item C<WasReturned>
1950
1951 Value 1 if return is successful.
1952
1953 =item C<NeedsTransfer>
1954
1955 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1956
1957 =back
1958
1959 C<$iteminformation> is a reference-to-hash, giving information about the
1960 returned item from the issues table.
1961
1962 C<$borrower> is a reference-to-hash, giving information about the
1963 patron who last borrowed the book.
1964
1965 =cut
1966
1967 sub AddReturn {
1968     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1969
1970     if ($branch and not Koha::Libraries->find($branch)) {
1971         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1972         undef $branch;
1973     }
1974     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1975     my $return_date_specified = !!$return_date;
1976     $return_date //= dt_from_string();
1977     my $messages;
1978     my $patron;
1979     my $doreturn       = 1;
1980     my $validTransfer = 1;
1981     my $stat_type = 'return';
1982
1983     # get information on item
1984     my $item = Koha::Items->find({ barcode => $barcode });
1985     unless ($item) {
1986         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1987     }
1988
1989     my $itemnumber = $item->itemnumber;
1990     my $itemtype = $item->effective_itemtype;
1991
1992     my $issue  = $item->checkout;
1993     if ( $issue ) {
1994         $patron = $issue->patron
1995             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1996                 . Dumper($issue->unblessed) . "\n";
1997     } else {
1998         $messages->{'NotIssued'} = $barcode;
1999         $item->onloan(undef)->store({skip_record_index=>1}) if defined $item->onloan;
2000
2001         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2002         $doreturn = 0;
2003         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2004         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2005         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2006            $messages->{'LocalUse'} = 1;
2007            $stat_type = 'localuse';
2008         }
2009     }
2010
2011         # full item data, but no borrowernumber or checkout info (no issue)
2012     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
2013         # get the proper branch to which to return the item
2014     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2015         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2016     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2017
2018     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2019     my $patron_unblessed = $patron ? $patron->unblessed : {};
2020
2021     my $update_loc_rules = Koha::Config::SysPrefs->find('UpdateItemLocationOnCheckin')->get_yaml_pref_hash();
2022     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2023     if ($update_loc_rules) {
2024         if (defined $update_loc_rules->{_ALL_}) {
2025             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2026             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2027             if (
2028                 ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) ||
2029                 (!defined $item->location && $update_loc_rules->{_ALL_} ne "")
2030                ) {
2031                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2032                 $item->location($update_loc_rules->{_ALL_})->store({skip_record_index=>1});
2033             }
2034         }
2035         else {
2036             foreach my $key ( keys %$update_loc_rules ) {
2037                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2038                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2039                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2040                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2041                     $item->location($update_loc_rules->{$key})->store({skip_record_index=>1});
2042                     last;
2043                 }
2044             }
2045         }
2046     }
2047
2048     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2049     if ($yaml) {
2050         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2051         my $rules;
2052         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2053         if ($@) {
2054             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2055         }
2056         else {
2057             foreach my $key ( keys %$rules ) {
2058                 if ( $item->notforloan eq $key ) {
2059                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2060                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1 });
2061                     last;
2062                 }
2063             }
2064         }
2065     }
2066
2067     # check if the return is allowed at this branch
2068     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2069     unless ($returnallowed){
2070         $messages->{'Wrongbranch'} = {
2071             Wrongbranch => $branch,
2072             Rightbranch => $message
2073         };
2074         $doreturn = 0;
2075         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2076         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2077         return ( $doreturn, $messages, $issue, $patron_unblessed);
2078     }
2079
2080     if ( $item->withdrawn ) { # book has been cancelled
2081         $messages->{'withdrawn'} = 1;
2082         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2083     }
2084
2085     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2086         $doreturn = 0;
2087     }
2088
2089     # case of a return of document (deal with issues and holdingbranch)
2090     if ($doreturn) {
2091         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2092         $patron or warn "AddReturn without current borrower";
2093
2094         if ($patron) {
2095             eval {
2096                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1} );
2097             };
2098             unless ( $@ ) {
2099                 if (
2100                     (
2101                         C4::Context->preference('CalculateFinesOnReturn')
2102                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2103                     )
2104                     && !$item->itemlost
2105                   )
2106                 {
2107                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2108                 }
2109             } else {
2110                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2111
2112                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2113                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2114
2115                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2116             }
2117
2118             # FIXME is the "= 1" right?  This could be the borrower hash.
2119             $messages->{'WasReturned'} = 1;
2120
2121         } else {
2122             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1 });
2123         }
2124     }
2125
2126     # the holdingbranch is updated if the document is returned to another location.
2127     # this is always done regardless of whether the item was on loan or not
2128     if ($item->holdingbranch ne $branch) {
2129         $item->holdingbranch($branch)->store({ skip_record_index => 1 });
2130     }
2131
2132     my $item_was_lost = $item->itemlost;
2133     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2134     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1 } ); # will unset itemlost if needed
2135
2136     # fix up the accounts.....
2137     if ($item_was_lost) {
2138         $messages->{'WasLost'} = 1;
2139         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2140             $messages->{'LostItemFeeRefunded'} = 1 if $updated_item->{_refunded};
2141             $messages->{'LostItemFeeRestored'} = 1 if $updated_item->{_restored};
2142
2143             if ( $updated_item->{_charge} ) {
2144                 $issue //= Koha::Old::Checkouts->search(
2145                     { itemnumber => $item->itemnumber },
2146                     { order_by   => { '-desc' => 'returndate' }, rows => 1 } )
2147                   ->single;
2148                 unless ( exists( $patron_unblessed->{branchcode} ) ) {
2149                     my $patron = $issue->patron;
2150                     $patron_unblessed = $patron->unblessed;
2151                 }
2152                 _CalculateAndUpdateFine(
2153                     {
2154                         issue       => $issue,
2155                         item        => $item->unblessed,
2156                         borrower    => $patron_unblessed,
2157                         return_date => $return_date
2158                     }
2159                 );
2160                 _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2161                     $item->itemnumber, undef, 'RETURNED' );
2162                 $messages->{'LostItemFeeCharged'} = 1;
2163             }
2164         }
2165     }
2166
2167     # check if we have a transfer for this document
2168     my $transfer = $item->get_transfer;
2169
2170     # if we have a transfer to complete, we update the line of transfers with the datearrived
2171     if ($transfer) {
2172         $validTransfer = 0;
2173         if ( $transfer->in_transit ) {
2174             if ( $transfer->tobranch eq $branch ) {
2175                 $transfer->receive;
2176                 $messages->{'TransferArrived'} = $transfer->frombranch;
2177                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2178                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2179             }
2180             else {
2181                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2182                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2183                 $messages->{'TransferTrigger'}   = $transfer->reason;
2184             }
2185         }
2186         else {
2187             if ( $transfer->tobranch eq $branch ) {
2188                 $transfer->receive;
2189                 $messages->{'TransferArrived'} = $transfer->frombranch;
2190                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2191                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2192             }
2193             else {
2194                 $messages->{'WasTransfered'}   = $transfer->tobranch;
2195                 $messages->{'TransferTrigger'} = $transfer->reason;
2196             }
2197         }
2198     }
2199
2200     # fix up the overdues in accounts...
2201     if ($borrowernumber) {
2202         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2203         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2204
2205         if ( $issue and $issue->is_overdue($return_date) ) {
2206         # fix fine days
2207             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2208             if ($reminder){
2209                 $messages->{'PrevDebarred'} = $debardate;
2210             } else {
2211                 $messages->{'Debarred'} = $debardate if $debardate;
2212             }
2213         # there's no overdue on the item but borrower had been previously debarred
2214         } elsif ( $issue->date_due and $patron->debarred ) {
2215              if ( $patron->debarred eq "9999-12-31") {
2216                 $messages->{'ForeverDebarred'} = $patron->debarred;
2217              } else {
2218                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2219                   $borrower_debar_dt->truncate(to => 'day');
2220                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2221                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2222                       $messages->{'PrevDebarred'} = $patron->debarred;
2223                   }
2224              }
2225         }
2226     }
2227
2228     # find reserves.....
2229     # launch the Checkreserves routine to find any holds
2230     my ($resfound, $resrec);
2231     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2232     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2233     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2234     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2235         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2236         $resfound = 'Reserved';
2237         $resrec = $hold->unblessed;
2238     }
2239     if ($resfound) {
2240           $resrec->{'ResFound'} = $resfound;
2241         $messages->{'ResFound'} = $resrec;
2242     }
2243
2244     # Record the fact that this book was returned.
2245     C4::Stats::UpdateStats({
2246         branch         => $branch,
2247         type           => $stat_type,
2248         itemnumber     => $itemnumber,
2249         itemtype       => $itemtype,
2250         location       => $item->location,
2251         borrowernumber => $borrowernumber,
2252         ccode          => $item->ccode,
2253     });
2254
2255     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2256     if ( $patron ) {
2257         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2258         my %conditions = (
2259             branchcode   => $branch,
2260             categorycode => $patron->categorycode,
2261             item_type    => $itemtype,
2262             notification => 'CHECKIN',
2263         );
2264         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2265             SendCirculationAlert({
2266                 type     => 'CHECKIN',
2267                 item     => $item->unblessed,
2268                 borrower => $patron->unblessed,
2269                 branch   => $branch,
2270                 issue    => $issue
2271             });
2272         }
2273
2274         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2275             if C4::Context->preference("ReturnLog");
2276         }
2277
2278     # Check if this item belongs to a biblio record that is attached to an
2279     # ILL request, if it is we need to update the ILL request's status
2280     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2281         my $request = Koha::Illrequests->find(
2282             { biblio_id => $item->biblio->biblionumber }
2283         );
2284         $request->status('RET') if $request;
2285     }
2286
2287     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2288     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2289         && ( $doreturn or $messages->{'NotIssued'} )
2290         and !$resfound
2291         and ( $branch ne $returnbranch )
2292         and not $messages->{'WrongTransfer'}
2293         and not $messages->{'WasTransfered'} )
2294     {
2295         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2296         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2297             (C4::Context->preference("UseBranchTransferLimits") and
2298              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2299            )) {
2300             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2301             $messages->{'WasTransfered'} = $returnbranch;
2302             $messages->{'TransferTrigger'} = $transfer_trigger;
2303         } else {
2304             $messages->{'NeedsTransfer'} = $returnbranch;
2305             $messages->{'TransferTrigger'} = $transfer_trigger;
2306         }
2307     }
2308
2309     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2310         my $claims = Koha::Checkouts::ReturnClaims->search(
2311            {
2312                itemnumber => $item->id,
2313                resolution => undef,
2314            }
2315         );
2316
2317         if ( $claims->count ) {
2318             $messages->{ReturnClaims} = $claims;
2319         }
2320     }
2321
2322     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2323     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2324
2325     if ( $doreturn and $issue ) {
2326         my $checkin = Koha::Old::Checkouts->find($issue->id);
2327
2328         Koha::Plugins->call('after_circ_action', {
2329             action  => 'checkin',
2330             payload => {
2331                 checkout=> $checkin
2332             }
2333         });
2334     }
2335
2336     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2337 }
2338
2339 =head2 MarkIssueReturned
2340
2341   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2342
2343 Unconditionally marks an issue as being returned by
2344 moving the C<issues> row to C<old_issues> and
2345 setting C<returndate> to the current date.
2346
2347 if C<$returndate> is specified (in iso format), it is used as the date
2348 of the return.
2349
2350 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2351 the old_issue is immediately anonymised
2352
2353 Ideally, this function would be internal to C<C4::Circulation>,
2354 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2355 and offline_circ/process_koc.pl.
2356
2357 The last optional parameter allos passing skip_record_index to the item store call.
2358
2359 =cut
2360
2361 sub MarkIssueReturned {
2362     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2363
2364     # Retrieve the issue
2365     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2366
2367     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2368
2369     my $issue_id = $issue->issue_id;
2370
2371     my $anonymouspatron;
2372     if ( $privacy && $privacy == 2 ) {
2373         # The default of 0 will not work due to foreign key constraints
2374         # The anonymisation will fail if AnonymousPatron is not a valid entry
2375         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2376         # Note that a warning should appear on the about page (System information tab).
2377         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2378         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2379             unless Koha::Patrons->find( $anonymouspatron );
2380     }
2381
2382     my $schema = Koha::Database->schema;
2383
2384     # FIXME Improve the return value and handle it from callers
2385     $schema->txn_do(sub {
2386
2387         my $patron = Koha::Patrons->find( $borrowernumber );
2388
2389         # Update the returndate value
2390         if ( $returndate ) {
2391             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2392         }
2393         else {
2394             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2395         }
2396
2397         # Create the old_issues entry
2398         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2399
2400         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2401         if ( $privacy && $privacy == 2) {
2402             $old_checkout->borrowernumber($anonymouspatron)->store;
2403         }
2404
2405         # And finally delete the issue
2406         $issue->delete;
2407
2408         $issue->item->onloan(undef)->store({ log_action => 0, skip_record_index => $params->{skip_record_index} });
2409
2410         if ( C4::Context->preference('StoreLastBorrower') ) {
2411             my $item = Koha::Items->find( $itemnumber );
2412             $item->last_returned_by( $patron );
2413         }
2414
2415         # Remove any OVERDUES related debarment if the borrower has no overdues
2416         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2417           && $patron->debarred
2418           && !$patron->has_overdues
2419           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2420         ) {
2421             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2422         }
2423
2424     });
2425
2426     return $issue_id;
2427 }
2428
2429 =head2 _debar_user_on_return
2430
2431     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2432
2433 C<$borrower> borrower hashref
2434
2435 C<$item> item hashref
2436
2437 C<$datedue> date due DateTime object
2438
2439 C<$returndate> DateTime object representing the return time
2440
2441 Internal function, called only by AddReturn that calculates and updates
2442  the user fine days, and debars them if necessary.
2443
2444 Should only be called for overdue returns
2445
2446 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2447 to ease testing.
2448
2449 =cut
2450
2451 sub _calculate_new_debar_dt {
2452     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2453
2454     my $branchcode = _GetCircControlBranch( $item, $borrower );
2455     my $circcontrol = C4::Context->preference('CircControl');
2456     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2457         {   categorycode => $borrower->{categorycode},
2458             itemtype     => $item->{itype},
2459             branchcode   => $branchcode,
2460             rules => [
2461                 'finedays',
2462                 'lengthunit',
2463                 'firstremind',
2464                 'maxsuspensiondays',
2465                 'suspension_chargeperiod',
2466             ]
2467         }
2468     );
2469     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2470     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2471     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2472
2473     return unless $finedays;
2474
2475     # finedays is in days, so hourly loans must multiply by 24
2476     # thus 1 hour late equals 1 day suspension * finedays rate
2477     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2478
2479     # grace period is measured in the same units as the loan
2480     my $grace =
2481       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2482
2483     my $deltadays = DateTime::Duration->new(
2484         days => $chargeable_units
2485     );
2486
2487     if ( $deltadays->subtract($grace)->is_positive() ) {
2488         my $suspension_days = $deltadays * $finedays;
2489
2490         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2491             # No need to / 1 and do not consider / 0
2492             $suspension_days = DateTime::Duration->new(
2493                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2494             );
2495         }
2496
2497         # If the max suspension days is < than the suspension days
2498         # the suspension days is limited to this maximum period.
2499         my $max_sd = $issuing_rule->{maxsuspensiondays};
2500         if ( defined $max_sd && $max_sd ne '' ) {
2501             $max_sd = DateTime::Duration->new( days => $max_sd );
2502             $suspension_days = $max_sd
2503               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2504         }
2505
2506         my ( $has_been_extended );
2507         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2508             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2509             if ( $debarment ) {
2510                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2511                 $has_been_extended = 1;
2512             }
2513         }
2514
2515         my $new_debar_dt;
2516         # Use the calendar or not to calculate the debarment date
2517         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2518             my $calendar = Koha::Calendar->new(
2519                 branchcode => $branchcode,
2520                 days_mode  => 'Calendar'
2521             );
2522             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2523         }
2524         else {
2525             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2526         }
2527         return $new_debar_dt;
2528     }
2529     return;
2530 }
2531
2532 sub _debar_user_on_return {
2533     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2534
2535     $return_date //= dt_from_string();
2536
2537     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2538
2539     return unless $new_debar_dt;
2540
2541     Koha::Patron::Debarments::AddUniqueDebarment({
2542         borrowernumber => $borrower->{borrowernumber},
2543         expiration     => $new_debar_dt->ymd(),
2544         type           => 'SUSPENSION',
2545     });
2546     # if borrower was already debarred but does not get an extra debarment
2547     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2548     my ($new_debarment_str, $is_a_reminder);
2549     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2550         $is_a_reminder = 1;
2551         $new_debarment_str = $borrower->{debarred};
2552     } else {
2553         $new_debarment_str = $new_debar_dt->ymd();
2554     }
2555     # FIXME Should return a DateTime object
2556     return $new_debarment_str, $is_a_reminder;
2557 }
2558
2559 =head2 _FixOverduesOnReturn
2560
2561    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2562
2563 C<$borrowernumber> borrowernumber
2564
2565 C<$itemnumber> itemnumber
2566
2567 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2568
2569 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2570
2571 Internal function
2572
2573 =cut
2574
2575 sub _FixOverduesOnReturn {
2576     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2577     unless( $borrowernumber ) {
2578         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2579         return;
2580     }
2581     unless( $item ) {
2582         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2583         return;
2584     }
2585     unless( $status ) {
2586         warn "_FixOverduesOnReturn() not supplied valid status";
2587         return;
2588     }
2589
2590     my $schema = Koha::Database->schema;
2591
2592     my $result = $schema->txn_do(
2593         sub {
2594             # check for overdue fine
2595             my $accountlines = Koha::Account::Lines->search(
2596                 {
2597                     borrowernumber  => $borrowernumber,
2598                     itemnumber      => $item,
2599                     debit_type_code => 'OVERDUE',
2600                     status          => 'UNRETURNED'
2601                 }
2602             );
2603             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2604
2605             my $accountline = $accountlines->next;
2606             my $payments = $accountline->credits;
2607
2608             my $amountoutstanding = $accountline->amountoutstanding;
2609             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2610                 $accountline->delete;
2611                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2612             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2613                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2614                 my $credit = $account->add_credit(
2615                     {
2616                         amount     => $amountoutstanding,
2617                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2618                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2619                         interface  => C4::Context->interface,
2620                         type       => 'FORGIVEN',
2621                         item_id    => $item
2622                     }
2623                 );
2624
2625                 $credit->apply({ debits => [ $accountline ] });
2626
2627                 if (C4::Context->preference("FinesLog")) {
2628                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2629                 }
2630             }
2631
2632             $accountline->status($status);
2633             return $accountline->store();
2634         }
2635     );
2636
2637     return $result;
2638 }
2639
2640 =head2 _GetCircControlBranch
2641
2642    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2643
2644 Internal function :
2645
2646 Return the library code to be used to determine which circulation
2647 policy applies to a transaction.  Looks up the CircControl and
2648 HomeOrHoldingBranch system preferences.
2649
2650 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2651
2652 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2653
2654 =cut
2655
2656 sub _GetCircControlBranch {
2657     my ($item, $borrower) = @_;
2658     my $circcontrol = C4::Context->preference('CircControl');
2659     my $branch;
2660
2661     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2662         $branch= C4::Context->userenv->{'branch'};
2663     } elsif ($circcontrol eq 'PatronLibrary') {
2664         $branch=$borrower->{branchcode};
2665     } else {
2666         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2667         $branch = $item->{$branchfield};
2668         # default to item home branch if holdingbranch is used
2669         # and is not defined
2670         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2671             $branch = $item->{homebranch};
2672         }
2673     }
2674     return $branch;
2675 }
2676
2677 =head2 GetOpenIssue
2678
2679   $issue = GetOpenIssue( $itemnumber );
2680
2681 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2682
2683 C<$itemnumber> is the item's itemnumber
2684
2685 Returns a hashref
2686
2687 =cut
2688
2689 sub GetOpenIssue {
2690   my ( $itemnumber ) = @_;
2691   return unless $itemnumber;
2692   my $dbh = C4::Context->dbh;
2693   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2694   $sth->execute( $itemnumber );
2695   return $sth->fetchrow_hashref();
2696
2697 }
2698
2699 =head2 GetUpcomingDueIssues
2700
2701   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2702
2703 =cut
2704
2705 sub GetUpcomingDueIssues {
2706     my $params = shift;
2707
2708     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2709     my $dbh = C4::Context->dbh;
2710     my $statement;
2711     $statement = q{
2712         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2713         FROM issues
2714         LEFT JOIN items USING (itemnumber)
2715         LEFT JOIN branches ON branches.branchcode =
2716     };
2717     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2718     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2719     my @bind_parameters = ( $params->{'days_in_advance'} );
2720
2721     my $sth = $dbh->prepare( $statement );
2722     $sth->execute( @bind_parameters );
2723     my $upcoming_dues = $sth->fetchall_arrayref({});
2724
2725     return $upcoming_dues;
2726 }
2727
2728 =head2 CanBookBeRenewed
2729
2730   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2731
2732 Find out whether a borrowed item may be renewed.
2733
2734 C<$borrowernumber> is the borrower number of the patron who currently
2735 has the item on loan.
2736
2737 C<$itemnumber> is the number of the item to renew.
2738
2739 C<$override_limit>, if supplied with a true value, causes
2740 the limit on the number of times that the loan can be renewed
2741 (as controlled by the item type) to be ignored. Overriding also allows
2742 to renew sooner than "No renewal before" and to manually renew loans
2743 that are automatically renewed.
2744
2745 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2746 item must currently be on loan to the specified borrower; renewals
2747 must be allowed for the item's type; and the borrower must not have
2748 already renewed the loan. $error will contain the reason the renewal can not proceed
2749
2750 =cut
2751
2752 sub CanBookBeRenewed {
2753     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2754
2755     my $auto_renew = "no";
2756
2757     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2758     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2759     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2760     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2761
2762     my $patron = $issue->patron or return;
2763
2764     # override_limit will override anything else except on_reserve
2765     unless ( $override_limit ){
2766         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2767         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2768             {
2769                 categorycode => $patron->categorycode,
2770                 itemtype     => $item->effective_itemtype,
2771                 branchcode   => $branchcode,
2772                 rules => [
2773                     'renewalsallowed',
2774                     'lengthunit',
2775                     'unseen_renewals_allowed'
2776                 ]
2777             }
2778         );
2779
2780         return ( 0, "too_many" )
2781           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2782
2783         return ( 0, "too_unseen" )
2784           if C4::Context->preference('UnseenRenewals') &&
2785             $issuing_rule->{unseen_renewals_allowed} &&
2786             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2787
2788         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2789         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2790         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2791         my $restricted  = $patron->is_debarred;
2792         my $hasoverdues = $patron->has_overdues;
2793
2794         if ( $restricted and $restrictionblockrenewing ) {
2795             return ( 0, 'restriction');
2796         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2797             return ( 0, 'overdue');
2798         }
2799
2800         $auto_renew = _CanBookBeAutoRenewed({
2801             patron     => $patron,
2802             item       => $item,
2803             branchcode => $branchcode,
2804             issue      => $issue
2805         });
2806         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_soon' && $cron;
2807         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
2808         # extra notices being sent. Cron also implies no override
2809         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
2810         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
2811         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
2812     }
2813
2814     my ( $resfound, $resrec, $possible_reserves ) = C4::Reserves::CheckReserves($itemnumber);
2815
2816     # If next hold is non priority, then check if any hold with priority (non_priority = 0) exists for the same biblionumber.
2817     if ( $resfound && $resrec->{non_priority} ) {
2818         $resfound = Koha::Holds->search(
2819             { biblionumber => $resrec->{biblionumber}, non_priority => 0 } )
2820           ->count > 0;
2821     }
2822
2823
2824
2825     # This item can fill one or more unfilled reserve, can those unfilled reserves
2826     # all be filled by other available items?
2827     if ( $resfound
2828         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2829     {
2830         my $item_holds = Koha::Holds->search( { itemnumber => $itemnumber, found => undef } )->count();
2831         if ($item_holds) {
2832             # There is an item level hold on this item, no other item can fill the hold
2833             $resfound = 1;
2834         }
2835         else {
2836
2837             # Get all other items that could possibly fill reserves
2838             # FIXME We could join reserves (or more tables) here to eliminate some checks later
2839             my $items = Koha::Items->search({
2840                 biblionumber => $resrec->{biblionumber},
2841                 onloan       => undef,
2842                 notforloan   => 0,
2843                 -not         => { itemnumber => $itemnumber }
2844             });
2845             my $item_count = $items->count();
2846
2847             # Get all other reserves that could have been filled by this item
2848             my @borrowernumbers = map { $_->{borrowernumber} } @$possible_reserves;
2849             # Note: fetching the patrons in this manner means that a patron with 2 holds will
2850             # not block renewal if one reserve can be satisfied i.e. each patron is checked once
2851             my $patrons = Koha::Patrons->search({
2852                 borrowernumber => { -in => \@borrowernumbers }
2853             });
2854             my $patron_count = $patrons->count();
2855
2856             return ( 0, "on_reserve" ) if ($patron_count > $item_count);
2857             # We cannot possibly fill all reserves if we don't have enough items
2858
2859             # If we can fill each hold that has been found with the available items on the record
2860             # then the patron can renew. If we cannot, they cannot renew.
2861             # FIXME This code does not check whether the item we are renewing can fill
2862             # any of the existing reserves.
2863             my $reservable = 0;
2864             my %matched_items;
2865             my $seen = 0;
2866             PATRON: while ( my $patron = $patrons->next ) {
2867                 # If there is a reserve that cannot be filled we are done
2868                 return ( 0, "on_reserve" ) if ( $seen > $reservable );
2869                 my $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron });
2870                 while ( my $other_item = $items->next ) {
2871                     next if defined $matched_items{$other_item->itemnumber};
2872                     next if IsItemOnHoldAndFound( $other_item->itemnumber );
2873                     next unless IsAvailableForItemLevelRequest($other_item, $patron, undef, $items_any_available);
2874                     next unless CanItemBeReserved($patron->borrowernumber,$other_item->itemnumber,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
2875                     # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
2876                     # CanItemBeReserved checks 'rules' and 'policies' which means
2877                     # items will fill holds at checkin that are rejected here
2878                     $reservable++;
2879                     if ($reservable >= $patron_count) {
2880                         $resfound = 0;
2881                         last PATRON;
2882                     }
2883                     $matched_items{$other_item->itemnumber} = 1;
2884                     last;
2885                 }
2886                 $items->reset;
2887                 $seen++;
2888             }
2889         }
2890     }
2891
2892     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2893     return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2894     if ( GetSoonestRenewDate($borrowernumber, $itemnumber) > dt_from_string() ){
2895         return (0, "too_soon") unless $override_limit;
2896     }
2897
2898     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
2899
2900     return ( 1, undef );
2901 }
2902
2903 =head2 AddRenewal
2904
2905   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen]);
2906
2907 Renews a loan.
2908
2909 C<$borrowernumber> is the borrower number of the patron who currently
2910 has the item.
2911
2912 C<$itemnumber> is the number of the item to renew.
2913
2914 C<$branch> is the library where the renewal took place (if any).
2915            The library that controls the circ policies for the renewal is retrieved from the issues record.
2916
2917 C<$datedue> can be a DateTime object used to set the due date.
2918
2919 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2920 this parameter is not supplied, lastreneweddate is set to the current date.
2921
2922 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
2923 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
2924 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
2925 syspref)
2926
2927 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2928 from the book's item type.
2929
2930 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
2931 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
2932 fallback to a true value
2933
2934 =cut
2935
2936 sub AddRenewal {
2937     my $borrowernumber  = shift;
2938     my $itemnumber      = shift or return;
2939     my $branch          = shift;
2940     my $datedue         = shift;
2941     my $lastreneweddate = shift || dt_from_string();
2942     my $skipfinecalc    = shift;
2943     my $seen            = shift;
2944
2945     # Fallback on a 'seen' renewal
2946     $seen = defined $seen && $seen == 0 ? 0 : 1;
2947
2948     my $item_object   = Koha::Items->find($itemnumber) or return;
2949     my $biblio = $item_object->biblio;
2950     my $issue  = $item_object->checkout;
2951     my $item_unblessed = $item_object->unblessed;
2952
2953     my $dbh = C4::Context->dbh;
2954
2955     return unless $issue;
2956
2957     $borrowernumber ||= $issue->borrowernumber;
2958
2959     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2960         carp 'Invalid date passed to AddRenewal.';
2961         return;
2962     }
2963
2964     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
2965     my $patron_unblessed = $patron->unblessed;
2966
2967     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
2968
2969     my $schema = Koha::Database->schema;
2970     $schema->txn_do(sub{
2971
2972         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
2973             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
2974         }
2975         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
2976
2977         # If the due date wasn't specified, calculate it by adding the
2978         # book's loan length to today's date or the current due date
2979         # based on the value of the RenewalPeriodBase syspref.
2980         my $itemtype = $item_object->effective_itemtype;
2981         unless ($datedue) {
2982
2983             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
2984                                             dt_from_string( $issue->date_due, 'sql' ) :
2985                                             dt_from_string();
2986             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
2987         }
2988
2989         my $fees = Koha::Charges::Fees->new(
2990             {
2991                 patron    => $patron,
2992                 library   => $circ_library,
2993                 item      => $item_object,
2994                 from_date => dt_from_string( $issue->date_due, 'sql' ),
2995                 to_date   => dt_from_string($datedue),
2996             }
2997         );
2998
2999         # Increment the unseen renewals, if appropriate
3000         # We only do so if the syspref is enabled and
3001         # a maximum value has been set in the circ rules
3002         my $unseen_renewals = $issue->unseen_renewals;
3003         if (C4::Context->preference('UnseenRenewals')) {
3004             my $rule = Koha::CirculationRules->get_effective_rule(
3005                 {   categorycode => $patron->categorycode,
3006                     itemtype     => $item_object->effective_itemtype,
3007                     branchcode   => $circ_library->branchcode,
3008                     rule_name    => 'unseen_renewals_allowed'
3009                 }
3010             );
3011             if (!$seen && $rule && $rule->rule_value) {
3012                 $unseen_renewals++;
3013             } else {
3014                 # If the renewal is seen, unseen should revert to 0
3015                 $unseen_renewals = 0;
3016             }
3017         }
3018
3019         # Update the issues record to have the new due date, and a new count
3020         # of how many times it has been renewed.
3021         my $renews = ( $issue->renewals || 0 ) + 1;
3022         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3023
3024         eval{
3025             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3026         };
3027         if( $sth->err ){
3028             Koha::Exceptions::Checkout::FailedRenewal->throw(
3029                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3030             );
3031         }
3032
3033         # Update the renewal count on the item, and tell zebra to reindex
3034         $renews = ( $item_object->renewals || 0 ) + 1;
3035         $item_object->renewals($renews);
3036         $item_object->onloan($datedue);
3037         $item_object->store({ log_action => 0 });
3038
3039         # Charge a new rental fee, if applicable
3040         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3041         if ( $charge > 0 ) {
3042             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3043         }
3044
3045         # Charge a new accumulate rental fee, if applicable
3046         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3047         if ( $itemtype_object ) {
3048             my $accumulate_charge = $fees->accumulate_rentalcharge();
3049             if ( $accumulate_charge > 0 ) {
3050                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3051             }
3052             $charge += $accumulate_charge;
3053         }
3054
3055         # Send a renewal slip according to checkout alert preferencei
3056         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3057             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3058             my %conditions        = (
3059                 branchcode   => $branch,
3060                 categorycode => $patron->categorycode,
3061                 item_type    => $itemtype,
3062                 notification => 'CHECKOUT',
3063             );
3064             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3065                 SendCirculationAlert(
3066                     {
3067                         type     => 'RENEWAL',
3068                         item     => $item_unblessed,
3069                         borrower => $patron->unblessed,
3070                         branch   => $branch,
3071                     }
3072                 );
3073             }
3074         }
3075
3076         # Remove any OVERDUES related debarment if the borrower has no overdues
3077         if ( $patron
3078           && $patron->is_debarred
3079           && ! $patron->has_overdues
3080           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3081         ) {
3082             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3083         }
3084
3085         # Add the renewal to stats
3086         C4::Stats::UpdateStats(
3087             {
3088                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3089                 type           => 'renew',
3090                 amount         => $charge,
3091                 itemnumber     => $itemnumber,
3092                 itemtype       => $itemtype,
3093                 location       => $item_object->location,
3094                 borrowernumber => $borrowernumber,
3095                 ccode          => $item_object->ccode,
3096             }
3097         );
3098
3099         #Log the renewal
3100         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3101
3102         Koha::Plugins->call('after_circ_action', {
3103             action  => 'renewal',
3104             payload => {
3105                 checkout  => $issue->get_from_storage
3106             }
3107         });
3108     });
3109
3110     return $datedue;
3111 }
3112
3113 sub GetRenewCount {
3114     # check renewal status
3115     my ( $bornum, $itemno ) = @_;
3116     my $dbh           = C4::Context->dbh;
3117     my $renewcount    = 0;
3118     my $unseencount    = 0;
3119     my $renewsallowed = 0;
3120     my $unseenallowed = 0;
3121     my $renewsleft    = 0;
3122     my $unseenleft    = 0;
3123
3124     my $patron = Koha::Patrons->find( $bornum );
3125     my $item   = Koha::Items->find($itemno);
3126
3127     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3128
3129     # Look in the issues table for this item, lent to this borrower,
3130     # and not yet returned.
3131
3132     # FIXME - I think this function could be redone to use only one SQL call.
3133     my $sth = $dbh->prepare(
3134         "select * from issues
3135                                 where (borrowernumber = ?)
3136                                 and (itemnumber = ?)"
3137     );
3138     $sth->execute( $bornum, $itemno );
3139     my $data = $sth->fetchrow_hashref;
3140     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3141     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3142     # $item and $borrower should be calculated
3143     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3144
3145     my $rules = Koha::CirculationRules->get_effective_rules(
3146         {
3147             categorycode => $patron->categorycode,
3148             itemtype     => $item->effective_itemtype,
3149             branchcode   => $branchcode,
3150             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3151         }
3152     );
3153     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3154     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3155         $rules->{unseen_renewals_allowed} :
3156         0;
3157     $renewsleft    = $renewsallowed - $renewcount;
3158     $unseenleft    = $unseenallowed - $unseencount;
3159     if($renewsleft < 0){ $renewsleft = 0; }
3160     if($unseenleft < 0){ $unseenleft = 0; }
3161     return (
3162         $renewcount,
3163         $renewsallowed,
3164         $renewsleft,
3165         $unseencount,
3166         $unseenallowed,
3167         $unseenleft
3168     );
3169 }
3170
3171 =head2 GetSoonestRenewDate
3172
3173   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3174
3175 Find out the soonest possible renew date of a borrowed item.
3176
3177 C<$borrowernumber> is the borrower number of the patron who currently
3178 has the item on loan.
3179
3180 C<$itemnumber> is the number of the item to renew.
3181
3182 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3183 renew date, based on the value "No renewal before" of the applicable
3184 issuing rule. Returns the current date if the item can already be
3185 renewed, and returns undefined if the borrower, loan, or item
3186 cannot be found.
3187
3188 =cut
3189
3190 sub GetSoonestRenewDate {
3191     my ( $borrowernumber, $itemnumber ) = @_;
3192
3193     my $dbh = C4::Context->dbh;
3194
3195     my $item      = Koha::Items->find($itemnumber)      or return;
3196     my $itemissue = $item->checkout or return;
3197
3198     $borrowernumber ||= $itemissue->borrowernumber;
3199     my $patron = Koha::Patrons->find( $borrowernumber )
3200       or return;
3201
3202     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3203     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3204         {   categorycode => $patron->categorycode,
3205             itemtype     => $item->effective_itemtype,
3206             branchcode   => $branchcode,
3207             rules => [
3208                 'norenewalbefore',
3209                 'lengthunit',
3210             ]
3211         }
3212     );
3213
3214     my $now = dt_from_string;
3215
3216     if ( defined $issuing_rule->{norenewalbefore}
3217         and $issuing_rule->{norenewalbefore} ne "" )
3218     {
3219         my $soonestrenewal =
3220           dt_from_string( $itemissue->date_due )->subtract(
3221             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3222
3223         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3224             and $issuing_rule->{lengthunit} eq 'days' )
3225         {
3226             $soonestrenewal->truncate( to => 'day' );
3227         }
3228         return $soonestrenewal if $now < $soonestrenewal;
3229     } elsif ( $itemissue->auto_renew && $patron->autorenew_checkouts ) {
3230         # Checkouts with auto-renewing fall back to due date
3231         my $soonestrenewal = dt_from_string( $itemissue->date_due );
3232         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3233             and $issuing_rule->{lengthunit} eq 'days' )
3234         {
3235             $soonestrenewal->truncate( to => 'day' );
3236         }
3237         return $soonestrenewal;
3238     }
3239     return $now;
3240 }
3241
3242 =head2 GetLatestAutoRenewDate
3243
3244   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3245
3246 Find out the latest possible auto renew date of a borrowed item.
3247
3248 C<$borrowernumber> is the borrower number of the patron who currently
3249 has the item on loan.
3250
3251 C<$itemnumber> is the number of the item to renew.
3252
3253 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3254 auto renew date, based on the value "No auto renewal after" and the "No auto
3255 renewal after (hard limit) of the applicable issuing rule.
3256 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3257 or item cannot be found.
3258
3259 =cut
3260
3261 sub GetLatestAutoRenewDate {
3262     my ( $borrowernumber, $itemnumber ) = @_;
3263
3264     my $dbh = C4::Context->dbh;
3265
3266     my $item      = Koha::Items->find($itemnumber)  or return;
3267     my $itemissue = $item->checkout                 or return;
3268
3269     $borrowernumber ||= $itemissue->borrowernumber;
3270     my $patron = Koha::Patrons->find( $borrowernumber )
3271       or return;
3272
3273     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3274     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3275         {
3276             categorycode => $patron->categorycode,
3277             itemtype     => $item->effective_itemtype,
3278             branchcode   => $branchcode,
3279             rules => [
3280                 'no_auto_renewal_after',
3281                 'no_auto_renewal_after_hard_limit',
3282                 'lengthunit',
3283             ]
3284         }
3285     );
3286
3287     return unless $circulation_rules;
3288     return
3289       if ( not $circulation_rules->{no_auto_renewal_after}
3290             or $circulation_rules->{no_auto_renewal_after} eq '' )
3291       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3292              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3293
3294     my $maximum_renewal_date;
3295     if ( $circulation_rules->{no_auto_renewal_after} ) {
3296         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3297         $maximum_renewal_date->add(
3298             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3299         );
3300     }
3301
3302     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3303         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3304         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3305     }
3306     return $maximum_renewal_date;
3307 }
3308
3309
3310 =head2 GetIssuingCharges
3311
3312   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3313
3314 Calculate how much it would cost for a given patron to borrow a given
3315 item, including any applicable discounts.
3316
3317 C<$itemnumber> is the item number of item the patron wishes to borrow.
3318
3319 C<$borrowernumber> is the patron's borrower number.
3320
3321 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3322 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3323 if it's a video).
3324
3325 =cut
3326
3327 sub GetIssuingCharges {
3328
3329     # calculate charges due
3330     my ( $itemnumber, $borrowernumber ) = @_;
3331     my $charge = 0;
3332     my $dbh    = C4::Context->dbh;
3333     my $item_type;
3334
3335     # Get the book's item type and rental charge (via its biblioitem).
3336     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3337         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3338     $charge_query .= (C4::Context->preference('item-level_itypes'))
3339         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3340         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3341
3342     $charge_query .= ' WHERE items.itemnumber =?';
3343
3344     my $sth = $dbh->prepare($charge_query);
3345     $sth->execute($itemnumber);
3346     if ( my $item_data = $sth->fetchrow_hashref ) {
3347         $item_type = $item_data->{itemtype};
3348         $charge    = $item_data->{rentalcharge};
3349         if ($charge) {
3350             # FIXME This should follow CircControl
3351             my $branch = C4::Context::mybranch();
3352             my $patron = Koha::Patrons->find( $borrowernumber );
3353             my $discount = Koha::CirculationRules->get_effective_rule({
3354                 categorycode => $patron->categorycode,
3355                 branchcode   => $branch,
3356                 itemtype     => $item_type,
3357                 rule_name    => 'rentaldiscount'
3358             });
3359             if ($discount) {
3360                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3361             }
3362             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3363         }
3364     }
3365
3366     return ( $charge, $item_type );
3367 }
3368
3369 =head2 AddIssuingCharge
3370
3371   &AddIssuingCharge( $checkout, $charge, $type )
3372
3373 =cut
3374
3375 sub AddIssuingCharge {
3376     my ( $checkout, $charge, $type ) = @_;
3377
3378     # FIXME What if checkout does not exist?
3379
3380     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3381     my $accountline = $account->add_debit(
3382         {
3383             amount      => $charge,
3384             note        => undef,
3385             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3386             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3387             interface   => C4::Context->interface,
3388             type        => $type,
3389             item_id     => $checkout->itemnumber,
3390             issue_id    => $checkout->issue_id,
3391         }
3392     );
3393 }
3394
3395 =head2 GetTransfers
3396
3397   GetTransfers($itemnumber);
3398
3399 =cut
3400
3401 sub GetTransfers {
3402     my ($itemnumber) = @_;
3403
3404     my $dbh = C4::Context->dbh;
3405
3406     my $query = '
3407         SELECT datesent,
3408                frombranch,
3409                tobranch,
3410                branchtransfer_id,
3411                daterequested,
3412                reason
3413         FROM branchtransfers
3414         WHERE itemnumber = ?
3415           AND datearrived IS NULL
3416           AND datecancelled IS NULL
3417         ';
3418     my $sth = $dbh->prepare($query);
3419     $sth->execute($itemnumber);
3420     my @row = $sth->fetchrow_array();
3421     return @row;
3422 }
3423
3424 =head2 GetTransfersFromTo
3425
3426   @results = GetTransfersFromTo($frombranch,$tobranch);
3427
3428 Returns the list of pending transfers between $from and $to branch
3429
3430 =cut
3431
3432 sub GetTransfersFromTo {
3433     my ( $frombranch, $tobranch ) = @_;
3434     return unless ( $frombranch && $tobranch );
3435     my $dbh   = C4::Context->dbh;
3436     my $query = "
3437         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3438         FROM   branchtransfers
3439         WHERE  frombranch=?
3440           AND  tobranch=?
3441           AND datecancelled IS NULL
3442           AND datesent IS NOT NULL
3443           AND datearrived IS NULL
3444     ";
3445     my $sth = $dbh->prepare($query);
3446     $sth->execute( $frombranch, $tobranch );
3447     my @gettransfers;
3448
3449     while ( my $data = $sth->fetchrow_hashref ) {
3450         push @gettransfers, $data;
3451     }
3452     return (@gettransfers);
3453 }
3454
3455 =head2 SendCirculationAlert
3456
3457 Send out a C<check-in> or C<checkout> alert using the messaging system.
3458
3459 B<Parameters>:
3460
3461 =over 4
3462
3463 =item type
3464
3465 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3466
3467 =item item
3468
3469 Hashref of information about the item being checked in or out.
3470
3471 =item borrower
3472
3473 Hashref of information about the borrower of the item.
3474
3475 =item branch
3476
3477 The branchcode from where the checkout or check-in took place.
3478
3479 =back
3480
3481 B<Example>:
3482
3483     SendCirculationAlert({
3484         type     => 'CHECKOUT',
3485         item     => $item,
3486         borrower => $borrower,
3487         branch   => $branch,
3488     });
3489
3490 =cut
3491
3492 sub SendCirculationAlert {
3493     my ($opts) = @_;
3494     my ($type, $item, $borrower, $branch, $issue) =
3495         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3496     my %message_name = (
3497         CHECKIN  => 'Item_Check_in',
3498         CHECKOUT => 'Item_Checkout',
3499         RENEWAL  => 'Item_Checkout',
3500     );
3501     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3502         borrowernumber => $borrower->{borrowernumber},
3503         message_name   => $message_name{$type},
3504     });
3505
3506
3507     my $tables = {
3508         items => $item->{itemnumber},
3509         biblio      => $item->{biblionumber},
3510         biblioitems => $item->{biblionumber},
3511         borrowers   => $borrower,
3512         branches    => $branch,
3513     };
3514
3515     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3516     # See C4::Letters:: _parseletter_sth
3517     if( $type eq 'CHECKIN' ){
3518         $tables->{old_issues} = $issue->issue_id;
3519     } else {
3520         $tables->{issues} = $item->{itemnumber};
3521     }
3522
3523     my $schema = Koha::Database->new->schema;
3524     my @transports = keys %{ $borrower_preferences->{transports} };
3525
3526     # From the MySQL doc:
3527     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3528     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3529     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3530     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3531
3532     for my $mtt (@transports) {
3533         my $letter =  C4::Letters::GetPreparedLetter (
3534             module => 'circulation',
3535             letter_code => $type,
3536             branchcode => $branch,
3537             message_transport_type => $mtt,
3538             lang => $borrower->{lang},
3539             tables => $tables,
3540         ) or next;
3541
3542         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3543         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3544         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3545         unless ( $message ) {
3546             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3547             C4::Message->enqueue($letter, $borrower, $mtt);
3548         } else {
3549             $message->append($letter);
3550             $message->update;
3551         }
3552         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3553     }
3554
3555     return;
3556 }
3557
3558 =head2 updateWrongTransfer
3559
3560   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3561
3562 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3563
3564 =cut
3565
3566 sub updateWrongTransfer {
3567         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3568
3569     # first step: cancel the original transfer
3570     my $item = Koha::Items->find($itemNumber);
3571     my $transfer = $item->get_transfer;
3572     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3573
3574     # second step: create a new transfer to the right location
3575     my $new_transfer = $item->request_transfer(
3576         {
3577             to            => $transfer->to_library,
3578             reason        => $transfer->reason,
3579             comment       => $transfer->comments,
3580             ignore_limits => 1,
3581             enqueue       => 1
3582         }
3583     );
3584
3585     return $new_transfer;
3586 }
3587
3588 =head2 CalcDateDue
3589
3590 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3591
3592 this function calculates the due date given the start date and configured circulation rules,
3593 checking against the holidays calendar as per the daysmode circulation rule.
3594 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3595 C<$itemtype>  = itemtype code of item in question
3596 C<$branch>  = location whose calendar to use
3597 C<$borrower> = Borrower object
3598 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3599
3600 =cut
3601
3602 sub CalcDateDue {
3603     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3604
3605     $isrenewal ||= 0;
3606
3607     # loanlength now a href
3608     my $loanlength =
3609             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3610
3611     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3612             ? qq{renewalperiod}
3613             : qq{issuelength};
3614
3615     my $datedue;
3616     if ( $startdate ) {
3617         if (ref $startdate ne 'DateTime' ) {
3618             $datedue = dt_from_string($datedue);
3619         } else {
3620             $datedue = $startdate->clone;
3621         }
3622     } else {
3623         $datedue = dt_from_string()->truncate( to => 'minute' );
3624     }
3625
3626
3627     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3628         {
3629             categorycode => $borrower->{categorycode},
3630             itemtype     => $itemtype,
3631             branchcode   => $branch,
3632         }
3633     );
3634
3635     # calculate the datedue as normal
3636     if ( $daysmode eq 'Days' )
3637     {    # ignoring calendar
3638         if ( $loanlength->{lengthunit} eq 'hours' ) {
3639             $datedue->add( hours => $loanlength->{$length_key} );
3640         } else {    # days
3641             $datedue->add( days => $loanlength->{$length_key} );
3642             $datedue->set_hour(23);
3643             $datedue->set_minute(59);
3644         }
3645     } else {
3646         my $dur;
3647         if ($loanlength->{lengthunit} eq 'hours') {
3648             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3649         }
3650         else { # days
3651             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3652         }
3653         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3654         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3655         if ($loanlength->{lengthunit} eq 'days') {
3656             $datedue->set_hour(23);
3657             $datedue->set_minute(59);
3658         }
3659     }
3660
3661     # if Hard Due Dates are used, retrieve them and apply as necessary
3662     my ( $hardduedate, $hardduedatecompare ) =
3663       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3664     if ($hardduedate) {    # hardduedates are currently dates
3665         $hardduedate->truncate( to => 'minute' );
3666         $hardduedate->set_hour(23);
3667         $hardduedate->set_minute(59);
3668         my $cmp = DateTime->compare( $hardduedate, $datedue );
3669
3670 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3671 # if the calculated date is before the 'after' Hard Due Date (floor), override
3672 # if the hard due date is set to 'exactly', overrride
3673         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3674             $datedue = $hardduedate->clone;
3675         }
3676
3677         # in all other cases, keep the date due as it is
3678
3679     }
3680
3681     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3682     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3683         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3684         if( $expiry_dt ) { #skip empty expiry date..
3685             $expiry_dt->set( hour => 23, minute => 59);
3686             my $d1= $datedue->clone->set_time_zone('floating');
3687             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3688                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3689             }
3690         }
3691         if ( $daysmode ne 'Days' ) {
3692           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3693           if ( $calendar->is_holiday($datedue) ) {
3694               # Don't return on a closed day
3695               $datedue = $calendar->prev_open_days( $datedue, 1 );
3696           }
3697         }
3698     }
3699
3700     return $datedue;
3701 }
3702
3703
3704 sub CheckValidBarcode{
3705 my ($barcode) = @_;
3706 my $dbh = C4::Context->dbh;
3707 my $query=qq|SELECT count(*)
3708              FROM items
3709              WHERE barcode=?
3710             |;
3711 my $sth = $dbh->prepare($query);
3712 $sth->execute($barcode);
3713 my $exist=$sth->fetchrow ;
3714 return $exist;
3715 }
3716
3717 =head2 IsBranchTransferAllowed
3718
3719   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3720
3721 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3722
3723 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3724 Koha::Item->can_be_transferred.
3725
3726 =cut
3727
3728 sub IsBranchTransferAllowed {
3729         my ( $toBranch, $fromBranch, $code ) = @_;
3730
3731         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3732
3733         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3734         my $dbh = C4::Context->dbh;
3735
3736         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3737         $sth->execute( $toBranch, $fromBranch, $code );
3738         my $limit = $sth->fetchrow_hashref();
3739
3740         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3741         if ( $limit->{'limitId'} ) {
3742                 return 0;
3743         } else {
3744                 return 1;
3745         }
3746 }
3747
3748 =head2 CreateBranchTransferLimit
3749
3750   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3751
3752 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3753
3754 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3755
3756 =cut
3757
3758 sub CreateBranchTransferLimit {
3759    my ( $toBranch, $fromBranch, $code ) = @_;
3760    return unless defined($toBranch) && defined($fromBranch);
3761    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3762
3763    my $dbh = C4::Context->dbh;
3764
3765    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3766    return $sth->execute( $code, $toBranch, $fromBranch );
3767 }
3768
3769 =head2 DeleteBranchTransferLimits
3770
3771     my $result = DeleteBranchTransferLimits($frombranch);
3772
3773 Deletes all the library transfer limits for one library.  Returns the
3774 number of limits deleted, 0e0 if no limits were deleted, or undef if
3775 no arguments are supplied.
3776
3777 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3778     fromBranch => $fromBranch
3779     })->delete.
3780
3781 =cut
3782
3783 sub DeleteBranchTransferLimits {
3784     my $branch = shift;
3785     return unless defined $branch;
3786     my $dbh    = C4::Context->dbh;
3787     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3788     return $sth->execute($branch);
3789 }
3790
3791 sub ReturnLostItem{
3792     my ( $borrowernumber, $itemnum ) = @_;
3793     MarkIssueReturned( $borrowernumber, $itemnum );
3794 }
3795
3796 =head2 LostItem
3797
3798   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3799
3800 The final optional parameter, C<$params>, expected to contain
3801 'skip_record_index' key, which relayed down to Koha::Item/store,
3802 there it prevents calling of ModZebra index_records,
3803 which takes most of the time in batch adds/deletes: index_records better
3804 to be called later in C<additem.pl> after the whole loop.
3805
3806 $params:
3807     skip_record_index => 1|0
3808
3809 =cut
3810
3811 sub LostItem{
3812     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3813
3814     unless ( $mark_lost_from ) {
3815         # Temporary check to avoid regressions
3816         die q|LostItem called without $mark_lost_from, check the API.|;
3817     }
3818
3819     my $mark_returned;
3820     if ( $force_mark_returned ) {
3821         $mark_returned = 1;
3822     } else {
3823         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3824         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3825     }
3826
3827     my $dbh = C4::Context->dbh();
3828     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3829                            FROM issues
3830                            JOIN items USING (itemnumber)
3831                            JOIN biblio USING (biblionumber)
3832                            WHERE issues.itemnumber=?");
3833     $sth->execute($itemnumber);
3834     my $issues=$sth->fetchrow_hashref();
3835
3836     # If a borrower lost the item, add a replacement cost to the their record
3837     if ( my $borrowernumber = $issues->{borrowernumber} ){
3838         my $patron = Koha::Patrons->find( $borrowernumber );
3839
3840         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3841         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3842
3843         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3844             C4::Accounts::chargelostitem(
3845                 $borrowernumber,
3846                 $itemnumber,
3847                 $issues->{'replacementprice'},
3848                 sprintf( "%s %s %s",
3849                     $issues->{'title'}          || q{},
3850                     $issues->{'barcode'}        || q{},
3851                     $issues->{'itemcallnumber'} || q{},
3852                 ),
3853             );
3854             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3855             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3856         }
3857
3858         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
3859     }
3860
3861     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
3862     my $item = Koha::Items->find($itemnumber);
3863     my $transfers = $item->get_transfers;
3864     while (my $transfer = $transfers->next) {
3865         $transfer->cancel({ reason => 'ItemLost', force => 1 });
3866     }
3867 }
3868
3869 sub GetOfflineOperations {
3870     my $dbh = C4::Context->dbh;
3871     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3872     $sth->execute(C4::Context->userenv->{'branch'});
3873     my $results = $sth->fetchall_arrayref({});
3874     return $results;
3875 }
3876
3877 sub GetOfflineOperation {
3878     my $operationid = shift;
3879     return unless $operationid;
3880     my $dbh = C4::Context->dbh;
3881     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3882     $sth->execute( $operationid );
3883     return $sth->fetchrow_hashref;
3884 }
3885
3886 sub AddOfflineOperation {
3887     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3888     my $dbh = C4::Context->dbh;
3889     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3890     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3891     return "Added.";
3892 }
3893
3894 sub DeleteOfflineOperation {
3895     my $dbh = C4::Context->dbh;
3896     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3897     $sth->execute( shift );
3898     return "Deleted.";
3899 }
3900
3901 sub ProcessOfflineOperation {
3902     my $operation = shift;
3903
3904     my $report;
3905     if ( $operation->{action} eq 'return' ) {
3906         $report = ProcessOfflineReturn( $operation );
3907     } elsif ( $operation->{action} eq 'issue' ) {
3908         $report = ProcessOfflineIssue( $operation );
3909     } elsif ( $operation->{action} eq 'payment' ) {
3910         $report = ProcessOfflinePayment( $operation );
3911     }
3912
3913     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3914
3915     return $report;
3916 }
3917
3918 sub ProcessOfflineReturn {
3919     my $operation = shift;
3920
3921     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3922
3923     if ( $item ) {
3924         my $itemnumber = $item->itemnumber;
3925         my $issue = GetOpenIssue( $itemnumber );
3926         if ( $issue ) {
3927             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
3928             ModDateLastSeen( $itemnumber, $leave_item_lost );
3929             MarkIssueReturned(
3930                 $issue->{borrowernumber},
3931                 $itemnumber,
3932                 $operation->{timestamp},
3933             );
3934             $item->renewals(0);
3935             $item->onloan(undef);
3936             $item->store({ log_action => 0 });
3937             return "Success.";
3938         } else {
3939             return "Item not issued.";
3940         }
3941     } else {
3942         return "Item not found.";
3943     }
3944 }
3945
3946 sub ProcessOfflineIssue {
3947     my $operation = shift;
3948
3949     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3950
3951     if ( $patron ) {
3952         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3953         unless ($item) {
3954             return "Barcode not found.";
3955         }
3956         my $itemnumber = $item->itemnumber;
3957         my $issue = GetOpenIssue( $itemnumber );
3958
3959         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
3960             MarkIssueReturned(
3961                 $issue->{borrowernumber},
3962                 $itemnumber,
3963                 $operation->{timestamp},
3964             );
3965         }
3966         AddIssue(
3967             $patron->unblessed,
3968             $operation->{'barcode'},
3969             undef,
3970             undef,
3971             $operation->{timestamp},
3972             undef,
3973         );
3974         return "Success.";
3975     } else {
3976         return "Borrower not found.";
3977     }
3978 }
3979
3980 sub ProcessOfflinePayment {
3981     my $operation = shift;
3982
3983     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
3984
3985     $patron->account->pay(
3986         {
3987             amount     => $operation->{amount},
3988             library_id => $operation->{branchcode},
3989             interface  => 'koc'
3990         }
3991     );
3992
3993     return "Success.";
3994 }
3995
3996 =head2 TransferSlip
3997
3998   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
3999
4000   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4001
4002 =cut
4003
4004 sub TransferSlip {
4005     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4006
4007     my $item =
4008       $itemnumber
4009       ? Koha::Items->find($itemnumber)
4010       : Koha::Items->find( { barcode => $barcode } );
4011
4012     $item or return;
4013
4014     return C4::Letters::GetPreparedLetter (
4015         module => 'circulation',
4016         letter_code => 'TRANSFERSLIP',
4017         branchcode => $branch,
4018         tables => {
4019             'branches'    => $to_branch,
4020             'biblio'      => $item->biblionumber,
4021             'items'       => $item->unblessed,
4022         },
4023     );
4024 }
4025
4026 =head2 CheckIfIssuedToPatron
4027
4028   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4029
4030   Return 1 if any record item is issued to patron, otherwise return 0
4031
4032 =cut
4033
4034 sub CheckIfIssuedToPatron {
4035     my ($borrowernumber, $biblionumber) = @_;
4036
4037     my $dbh = C4::Context->dbh;
4038     my $query = q|
4039         SELECT COUNT(*) FROM issues
4040         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4041         WHERE items.biblionumber = ?
4042         AND issues.borrowernumber = ?
4043     |;
4044     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4045     return 1 if $is_issued;
4046     return;
4047 }
4048
4049 =head2 IsItemIssued
4050
4051   IsItemIssued( $itemnumber )
4052
4053   Return 1 if the item is on loan, otherwise return 0
4054
4055 =cut
4056
4057 sub IsItemIssued {
4058     my $itemnumber = shift;
4059     my $dbh = C4::Context->dbh;
4060     my $sth = $dbh->prepare(q{
4061         SELECT COUNT(*)
4062         FROM issues
4063         WHERE itemnumber = ?
4064     });
4065     $sth->execute($itemnumber);
4066     return $sth->fetchrow;
4067 }
4068
4069 =head2 GetAgeRestriction
4070
4071   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4072   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4073
4074   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4075   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4076
4077 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4078 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4079 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4080          Negative days mean the borrower has gone past the age restriction age.
4081
4082 =cut
4083
4084 sub GetAgeRestriction {
4085     my ($record_restrictions, $borrower) = @_;
4086     my $markers = C4::Context->preference('AgeRestrictionMarker');
4087
4088     return unless $record_restrictions;
4089     # Split $record_restrictions to something like FSK 16 or PEGI 6
4090     my @values = split ' ', uc($record_restrictions);
4091     return unless @values;
4092
4093     # Search first occurrence of one of the markers
4094     my @markers = split /\|/, uc($markers);
4095     return unless @markers;
4096
4097     my $index            = 0;
4098     my $restriction_year = 0;
4099     for my $value (@values) {
4100         $index++;
4101         for my $marker (@markers) {
4102             $marker =~ s/^\s+//;    #remove leading spaces
4103             $marker =~ s/\s+$//;    #remove trailing spaces
4104             if ( $marker eq $value ) {
4105                 if ( $index <= $#values ) {
4106                     $restriction_year += $values[$index];
4107                 }
4108                 last;
4109             }
4110             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4111
4112                 # Perhaps it is something like "K16" (as in Finland)
4113                 $restriction_year += $1;
4114                 last;
4115             }
4116         }
4117         last if ( $restriction_year > 0 );
4118     }
4119
4120     #Check if the borrower is age restricted for this material and for how long.
4121     if ($restriction_year && $borrower) {
4122         if ( $borrower->{'dateofbirth'} ) {
4123             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4124             $alloweddate[0] += $restriction_year;
4125
4126             #Prevent runime eror on leap year (invalid date)
4127             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4128                 $alloweddate[2] = 28;
4129             }
4130
4131             #Get how many days the borrower has to reach the age restriction
4132             my @Today = split /-/, dt_from_string()->ymd();
4133             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4134             #Negative days means the borrower went past the age restriction age
4135             return ($restriction_year, $daysToAgeRestriction);
4136         }
4137     }
4138
4139     return ($restriction_year);
4140 }
4141
4142
4143 =head2 GetPendingOnSiteCheckouts
4144
4145 =cut
4146
4147 sub GetPendingOnSiteCheckouts {
4148     my $dbh = C4::Context->dbh;
4149     return $dbh->selectall_arrayref(q|
4150         SELECT
4151           items.barcode,
4152           items.biblionumber,
4153           items.itemnumber,
4154           items.itemnotes,
4155           items.itemcallnumber,
4156           items.location,
4157           issues.date_due,
4158           issues.branchcode,
4159           issues.date_due < NOW() AS is_overdue,
4160           biblio.author,
4161           biblio.title,
4162           borrowers.firstname,
4163           borrowers.surname,
4164           borrowers.cardnumber,
4165           borrowers.borrowernumber
4166         FROM items
4167         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4168         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4169         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4170         WHERE issues.onsite_checkout = 1
4171     |, { Slice => {} } );
4172 }
4173
4174 sub GetTopIssues {
4175     my ($params) = @_;
4176
4177     my ($count, $branch, $itemtype, $ccode, $newness)
4178         = @$params{qw(count branch itemtype ccode newness)};
4179
4180     my $dbh = C4::Context->dbh;
4181     my $query = q{
4182         SELECT * FROM (
4183         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4184           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4185           i.ccode, SUM(i.issues) AS count
4186         FROM biblio b
4187         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4188         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4189     };
4190
4191     my (@where_strs, @where_args);
4192
4193     if ($branch) {
4194         push @where_strs, 'i.homebranch = ?';
4195         push @where_args, $branch;
4196     }
4197     if ($itemtype) {
4198         if (C4::Context->preference('item-level_itypes')){
4199             push @where_strs, 'i.itype = ?';
4200             push @where_args, $itemtype;
4201         } else {
4202             push @where_strs, 'bi.itemtype = ?';
4203             push @where_args, $itemtype;
4204         }
4205     }
4206     if ($ccode) {
4207         push @where_strs, 'i.ccode = ?';
4208         push @where_args, $ccode;
4209     }
4210     if ($newness) {
4211         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4212         push @where_args, $newness;
4213     }
4214
4215     if (@where_strs) {
4216         $query .= 'WHERE ' . join(' AND ', @where_strs);
4217     }
4218
4219     $query .= q{
4220         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4221           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4222           i.ccode
4223         ORDER BY count DESC
4224     };
4225
4226     $query .= q{ ) xxx WHERE count > 0 };
4227     $count = int($count);
4228     if ($count > 0) {
4229         $query .= "LIMIT $count";
4230     }
4231
4232     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4233
4234     return @$rows;
4235 }
4236
4237 =head2 Internal methods
4238
4239 =cut
4240
4241 sub _CalculateAndUpdateFine {
4242     my ($params) = @_;
4243
4244     my $borrower    = $params->{borrower};
4245     my $item        = $params->{item};
4246     my $issue       = $params->{issue};
4247     my $return_date = $params->{return_date};
4248
4249     unless ($borrower) { carp "No borrower passed in!" && return; }
4250     unless ($item)     { carp "No item passed in!"     && return; }
4251     unless ($issue)    { carp "No issue passed in!"    && return; }
4252
4253     my $datedue = dt_from_string( $issue->date_due );
4254
4255     # we only need to calculate and change the fines if we want to do that on return
4256     # Should be on for hourly loans
4257     my $control = C4::Context->preference('CircControl');
4258     my $control_branchcode =
4259         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4260       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4261       :                                     $issue->branchcode;
4262
4263     my $date_returned = $return_date ? $return_date : dt_from_string();
4264
4265     my ( $amount, $unitcounttotal, $unitcount  ) =
4266       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4267
4268     if ( C4::Context->preference('finesMode') eq 'production' ) {
4269         if ( $amount > 0 ) {
4270             C4::Overdues::UpdateFine({
4271                 issue_id       => $issue->issue_id,
4272                 itemnumber     => $issue->itemnumber,
4273                 borrowernumber => $issue->borrowernumber,
4274                 amount         => $amount,
4275                 due            => output_pref($datedue),
4276             });
4277         }
4278         elsif ($return_date) {
4279
4280             # Backdated returns may have fines that shouldn't exist,
4281             # so in this case, we need to drop those fines to 0
4282
4283             C4::Overdues::UpdateFine({
4284                 issue_id       => $issue->issue_id,
4285                 itemnumber     => $issue->itemnumber,
4286                 borrowernumber => $issue->borrowernumber,
4287                 amount         => 0,
4288                 due            => output_pref($datedue),
4289             });
4290         }
4291     }
4292 }
4293
4294 sub _CanBookBeAutoRenewed {
4295     my ( $params ) = @_;
4296     my $patron = $params->{patron};
4297     my $item = $params->{item};
4298     my $branchcode = $params->{branchcode};
4299     my $issue = $params->{issue};
4300
4301     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4302
4303     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4304         {
4305             categorycode => $patron->categorycode,
4306             itemtype     => $item->effective_itemtype,
4307             branchcode   => $branchcode,
4308             rules => [
4309                 'no_auto_renewal_after',
4310                 'no_auto_renewal_after_hard_limit',
4311                 'lengthunit',
4312                 'norenewalbefore',
4313             ]
4314         }
4315     );
4316
4317     if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
4318         return 'auto_account_expired';
4319     }
4320
4321     if ( defined $issuing_rule->{no_auto_renewal_after}
4322             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4323         # Get issue_date and add no_auto_renewal_after
4324         # If this is greater than today, it's too late for renewal.
4325         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4326         $maximum_renewal_date->add(
4327             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4328         );
4329         my $now = dt_from_string;
4330         if ( $now >= $maximum_renewal_date ) {
4331             return "auto_too_late";
4332         }
4333     }
4334     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4335                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4336         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4337         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4338             return "auto_too_late";
4339         }
4340     }
4341
4342     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4343         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4344         my $amountoutstanding =
4345           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4346           ? $patron->account->balance
4347           : $patron->account->outstanding_debits->total_outstanding;
4348         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4349             return "auto_too_much_oweing";
4350         }
4351     }
4352
4353     if ( GetSoonestRenewDate( $patron->id, $item->id ) > dt_from_string() )
4354     {
4355         return "auto_too_soon";
4356     }
4357
4358     return "ok";
4359 }
4360
4361 sub _item_denied_renewal {
4362     my ($params) = @_;
4363
4364     my $item = $params->{item};
4365     return unless $item;
4366
4367     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4368     return unless $denyingrules;
4369     foreach my $field (keys %$denyingrules) {
4370         my $val = $item->$field;
4371         if( !defined $val) {
4372             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4373                 return 1;
4374             }
4375         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4376            # If the results matches the values in the syspref
4377            # We return true if match found
4378             return 1;
4379         }
4380     }
4381     return 0;
4382 }
4383
4384 1;
4385
4386 __END__
4387
4388 =head1 AUTHOR
4389
4390 Koha Development Team <http://koha-community.org/>
4391
4392 =cut