Koha/Item.pm

   1 package Koha::Item;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use List::MoreUtils qw( any );
  23 use Try::Tiny qw( catch try );
  24
  25 use Koha::Database;
  26 use Koha::DateUtils qw( dt_from_string output_pref );
  27
  28 use C4::Context;
  29 use C4::Circulation qw( barcodedecode GetBranchItemRule );
  30 use C4::Reserves;
  31 use C4::ClassSource qw( GetClassSort );
  32 use C4::Log qw( logaction );
  33
  34 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  35 use Koha::Biblio::ItemGroups;
  36 use Koha::Checkouts;
  37 use Koha::CirculationRules;
  38 use Koha::CoverImages;
  39 use Koha::Exceptions::Item::Transfer;
  40 use Koha::Item::Attributes;
  41 use Koha::Item::Transfer::Limits;
  42 use Koha::Item::Transfers;
  43 use Koha::ItemTypes;
  44 use Koha::Libraries;
  45 use Koha::Patrons;
  46 use Koha::Plugins;
  47 use Koha::Recalls;
  48 use Koha::Result::Boolean;
  49 use Koha::SearchEngine::Indexer;
  50 use Koha::StockRotationItem;
  51 use Koha::StockRotationRotas;
  52 use Koha::TrackedLinks;
  53
  54 use base qw(Koha::Object);
  55
  56 =head1 NAME
  57
  58 Koha::Item - Koha Item object class
  59
  60 =head1 API
  61
  62 =head2 Class methods
  63
  64 =cut
  65
  66 =head3 store
  67
  68     $item->store;
  69
  70 $params can take an optional 'skip_record_index' parameter.
  71 If set, the reindexation process will not happen (index_records not called)
  72
  73 NOTE: This is a temporary fix to answer a performance issue when lot of items
  74 are added (or modified) at the same time.
  75 The correct way to fix this is to make the ES reindexation process async.
  76 You should not turn it on if you do not understand what it is doing exactly.
  77
  78 =cut
  79
  80 sub store {
  81     my $self = shift;
  82     my $params = @_ ? shift : {};
  83
  84     my $log_action = $params->{log_action} // 1;
  85
  86     # We do not want to oblige callers to pass this value
  87     # Dev conveniences vs performance?
  88     unless ( $self->biblioitemnumber ) {
  89         $self->biblioitemnumber( $self->biblio->biblioitem->biblioitemnumber );
  90     }
  91
  92     # See related changes from C4::Items::AddItem
  93     unless ( $self->itype ) {
  94         $self->itype($self->biblio->biblioitem->itemtype);
  95     }
  96
  97     $self->barcode( C4::Circulation::barcodedecode( $self->barcode ) );
  98
  99     my $today  = dt_from_string;
 100     my $action = 'create';
 101
 102     unless ( $self->in_storage ) { #AddItem
 103
 104         unless ( $self->permanent_location ) {
 105             $self->permanent_location($self->location);
 106         }
 107
 108         my $default_location = C4::Context->preference('NewItemsDefaultLocation');
 109         unless ( $self->location || !$default_location ) {
 110             $self->permanent_location( $self->location || $default_location )
 111               unless $self->permanent_location;
 112             $self->location($default_location);
 113         }
 114
 115         unless ( $self->replacementpricedate ) {
 116             $self->replacementpricedate($today);
 117         }
 118         unless ( $self->datelastseen ) {
 119             $self->datelastseen($today);
 120         }
 121
 122         unless ( $self->dateaccessioned ) {
 123             $self->dateaccessioned($today);
 124         }
 125
 126         if (   $self->itemcallnumber
 127             or $self->cn_source )
 128         {
 129             my $cn_sort = GetClassSort( $self->cn_source, $self->itemcallnumber, "" );
 130             $self->cn_sort($cn_sort);
 131         }
 132
 133     } else { # ModItem
 134
 135         $action = 'modify';
 136
 137         my %updated_columns = $self->_result->get_dirty_columns;
 138         return $self->SUPER::store unless %updated_columns;
 139
 140         # Retrieve the item for comparison if we need to
 141         my $pre_mod_item = (
 142                  exists $updated_columns{itemlost}
 143               or exists $updated_columns{withdrawn}
 144               or exists $updated_columns{damaged}
 145         ) ? $self->get_from_storage : undef;
 146
 147         # Update *_on  fields if needed
 148         # FIXME: Why not for AddItem as well?
 149         my @fields = qw( itemlost withdrawn damaged );
 150         for my $field (@fields) {
 151
 152             # If the field is defined but empty or 0, we are
 153             # removing/unsetting and thus need to clear out
 154             # the 'on' field
 155             if (   exists $updated_columns{$field}
 156                 && defined( $self->$field )
 157                 && !$self->$field )
 158             {
 159                 my $field_on = "${field}_on";
 160                 $self->$field_on(undef);
 161             }
 162             # If the field has changed otherwise, we much update
 163             # the 'on' field
 164             elsif (exists $updated_columns{$field}
 165                 && $updated_columns{$field}
 166                 && !$pre_mod_item->$field )
 167             {
 168                 my $field_on = "${field}_on";
 169                 $self->$field_on(dt_from_string);
 170             }
 171         }
 172
 173         if (   exists $updated_columns{itemcallnumber}
 174             or exists $updated_columns{cn_source} )
 175         {
 176             my $cn_sort = GetClassSort( $self->cn_source, $self->itemcallnumber, "" );
 177             $self->cn_sort($cn_sort);
 178         }
 179
 180
 181         if (    exists $updated_columns{location}
 182             and $self->location ne 'CART'
 183             and $self->location ne 'PROC'
 184             and not exists $updated_columns{permanent_location} )
 185         {
 186             $self->permanent_location( $self->location );
 187         }
 188
 189         # If item was lost and has now been found,
 190         # reverse any list item charges if necessary.
 191         if (    exists $updated_columns{itemlost}
 192             and $updated_columns{itemlost} <= 0
 193             and $pre_mod_item->itemlost > 0 )
 194         {
 195             $self->_set_found_trigger($pre_mod_item);
 196         }
 197
 198     }
 199
 200     my $result = $self->SUPER::store;
 201     if ( $log_action && C4::Context->preference("CataloguingLog") ) {
 202         $action eq 'create'
 203           ? logaction( "CATALOGUING", "ADD", $self->itemnumber, "item" )
 204           : logaction( "CATALOGUING", "MODIFY", $self->itemnumber, $self );
 205     }
 206     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 207     $indexer->index_records( $self->biblionumber, "specialUpdate", "biblioserver" )
 208         unless $params->{skip_record_index};
 209     $self->get_from_storage->_after_item_action_hooks({ action => $action });
 210
 211     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 212         {
 213             biblio_ids => [ $self->biblionumber ]
 214         }
 215     ) unless $params->{skip_holds_queue} or !C4::Context->preference('RealTimeHoldsQueue');
 216
 217     return $result;
 218 }
 219
 220 =head3 delete
 221
 222 =cut
 223
 224 sub delete {
 225     my $self = shift;
 226     my $params = @_ ? shift : {};
 227
 228     # FIXME check the item has no current issues
 229     # i.e. raise the appropriate exception
 230
 231     # Get the item group so we can delete it later if it has no items left
 232     my $item_group = C4::Context->preference('EnableItemGroups') ? $self->item_group : undef;
 233
 234     my $result = $self->SUPER::delete;
 235
 236     # Delete the item gorup if it has no items left
 237     $item_group->delete if ( $item_group && $item_group->items->count == 0 );
 238
 239     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 240     $indexer->index_records( $self->biblionumber, "specialUpdate", "biblioserver" )
 241         unless $params->{skip_record_index};
 242
 243     $self->_after_item_action_hooks({ action => 'delete' });
 244
 245     logaction( "CATALOGUING", "DELETE", $self->itemnumber, "item" )
 246       if C4::Context->preference("CataloguingLog");
 247
 248     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 249         {
 250             biblio_ids => [ $self->biblionumber ]
 251         }
 252     ) unless $params->{skip_holds_queue} or !C4::Context->preference('RealTimeHoldsQueue');
 253
 254     return $result;
 255 }
 256
 257 =head3 safe_delete
 258
 259 =cut
 260
 261 sub safe_delete {
 262     my $self = shift;
 263     my $params = @_ ? shift : {};
 264
 265     my $safe_to_delete = $self->safe_to_delete;
 266     return $safe_to_delete unless $safe_to_delete;
 267
 268     $self->move_to_deleted;
 269
 270     return $self->delete($params);
 271 }
 272
 273 =head3 safe_to_delete
 274
 275 returns 1 if the item is safe to delete,
 276
 277 "book_on_loan" if the item is checked out,
 278
 279 "not_same_branch" if the item is blocked by independent branches,
 280
 281 "book_reserved" if the there are holds aganst the item, or
 282
 283 "linked_analytics" if the item has linked analytic records.
 284
 285 "last_item_for_hold" if the item is the last one on a record on which a biblio-level hold is placed
 286
 287 =cut
 288
 289 sub safe_to_delete {
 290     my ($self) = @_;
 291
 292     my $error;
 293
 294     $error = "book_on_loan" if $self->checkout;
 295
 296     $error = "not_same_branch"
 297       if defined C4::Context->userenv
 298       and !C4::Context->IsSuperLibrarian()
 299       and C4::Context->preference("IndependentBranches")
 300       and ( C4::Context->userenv->{branch} ne $self->homebranch );
 301
 302     # check it doesn't have a waiting reserve
 303     $error = "book_reserved"
 304       if $self->holds->search( { found => [ 'W', 'T' ] } )->count;
 305
 306     $error = "linked_analytics"
 307       if C4::Items::GetAnalyticsCount( $self->itemnumber ) > 0;
 308
 309     $error = "last_item_for_hold"
 310       if $self->biblio->items->count == 1
 311       && $self->biblio->holds->search(
 312           {
 313               itemnumber => undef,
 314           }
 315         )->count;
 316
 317     if ( $error ) {
 318         return Koha::Result::Boolean->new(0)->add_message({ message => $error });
 319     }
 320
 321     return Koha::Result::Boolean->new(1);
 322 }
 323
 324 =head3 move_to_deleted
 325
 326 my $is_moved = $item->move_to_deleted;
 327
 328 Move an item to the deleteditems table.
 329 This can be done before deleting an item, to make sure the data are not completely deleted.
 330
 331 =cut
 332
 333 sub move_to_deleted {
 334     my ($self) = @_;
 335     my $item_infos = $self->unblessed;
 336     delete $item_infos->{timestamp}; #This ensures the timestamp date in deleteditems will be set to the current timestamp
 337     $item_infos->{deleted_on} = dt_from_string;
 338     return Koha::Database->new->schema->resultset('Deleteditem')->create($item_infos);
 339 }
 340
 341
 342 =head3 effective_itemtype
 343
 344 Returns the itemtype for the item based on whether item level itemtypes are set or not.
 345
 346 =cut
 347
 348 sub effective_itemtype {
 349     my ( $self ) = @_;
 350
 351     return $self->_result()->effective_itemtype();
 352 }
 353
 354 =head3 home_branch
 355
 356 =cut
 357
 358 sub home_branch {
 359     my ($self) = @_;
 360
 361     my $hb_rs = $self->_result->homebranch;
 362
 363     return Koha::Library->_new_from_dbic( $hb_rs );
 364 }
 365
 366 =head3 holding_branch
 367
 368 =cut
 369
 370 sub holding_branch {
 371     my ($self) = @_;
 372
 373     my $hb_rs = $self->_result->holdingbranch;
 374
 375     return Koha::Library->_new_from_dbic( $hb_rs );
 376 }
 377
 378 =head3 biblio
 379
 380 my $biblio = $item->biblio;
 381
 382 Return the bibliographic record of this item
 383
 384 =cut
 385
 386 sub biblio {
 387     my ( $self ) = @_;
 388     my $biblio_rs = $self->_result->biblio;
 389     return Koha::Biblio->_new_from_dbic( $biblio_rs );
 390 }
 391
 392 =head3 biblioitem
 393
 394 my $biblioitem = $item->biblioitem;
 395
 396 Return the biblioitem record of this item
 397
 398 =cut
 399
 400 sub biblioitem {
 401     my ( $self ) = @_;
 402     my $biblioitem_rs = $self->_result->biblioitem;
 403     return Koha::Biblioitem->_new_from_dbic( $biblioitem_rs );
 404 }
 405
 406 =head3 checkout
 407
 408 my $checkout = $item->checkout;
 409
 410 Return the checkout for this item
 411
 412 =cut
 413
 414 sub checkout {
 415     my ( $self ) = @_;
 416     my $checkout_rs = $self->_result->issue;
 417     return unless $checkout_rs;
 418     return Koha::Checkout->_new_from_dbic( $checkout_rs );
 419 }
 420
 421 =head3 item_group
 422
 423 my $item_group = $item->item_group;
 424
 425 Return the item group for this item
 426
 427 =cut
 428
 429 sub item_group {
 430     my ( $self ) = @_;
 431
 432     my $item_group_item = $self->_result->item_group_item;
 433     return unless $item_group_item;
 434
 435     my $item_group_rs = $item_group_item->item_group;
 436     return unless $item_group_rs;
 437
 438     my $item_group = Koha::Biblio::ItemGroup->_new_from_dbic( $item_group_rs );
 439     return $item_group;
 440 }
 441
 442 =head3 return_claims
 443
 444   my $return_claims = $item->return_claims;
 445
 446 Return any return_claims associated with this item
 447
 448 =cut
 449
 450 sub return_claims {
 451     my ( $self, $params, $attrs ) = @_;
 452     my $claims_rs = $self->_result->return_claims->search($params, $attrs);
 453     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $claims_rs );
 454 }
 455
 456 =head3 return_claim
 457
 458   my $return_claim = $item->return_claim;
 459
 460 Returns the most recent unresolved return_claims associated with this item
 461
 462 =cut
 463
 464 sub return_claim {
 465     my ($self) = @_;
 466     my $claims_rs =
 467       $self->_result->return_claims->search( { resolution => undef },
 468         { order_by => { '-desc' => 'created_on' }, rows => 1 } )->single;
 469     return unless $claims_rs;
 470     return Koha::Checkouts::ReturnClaim->_new_from_dbic($claims_rs);
 471 }
 472
 473 =head3 holds
 474
 475 my $holds = $item->holds();
 476 my $holds = $item->holds($params);
 477 my $holds = $item->holds({ found => 'W'});
 478
 479 Return holds attached to an item, optionally accept a hashref of params to pass to search
 480
 481 =cut
 482
 483 sub holds {
 484     my ( $self,$params ) = @_;
 485     my $holds_rs = $self->_result->reserves->search($params);
 486     return Koha::Holds->_new_from_dbic( $holds_rs );
 487 }
 488
 489 =head3 request_transfer
 490
 491   my $transfer = $item->request_transfer(
 492     {
 493         to     => $to_library,
 494         reason => $reason,
 495         [ ignore_limits => 0, enqueue => 1, replace => 1 ]
 496     }
 497   );
 498
 499 Add a transfer request for this item to the given branch for the given reason.
 500
 501 An exception will be thrown if the BranchTransferLimits would prevent the requested
 502 transfer, unless 'ignore_limits' is passed to override the limits.
 503
 504 An exception will be thrown if an active transfer (i.e pending arrival date) is found;
 505 The caller should catch such cases and retry the transfer request as appropriate passing
 506 an appropriate override.
 507
 508 Overrides
 509 * enqueue - Used to queue up the transfer when the existing transfer is found to be in transit.
 510 * replace - Used to replace the existing transfer request with your own.
 511
 512 =cut
 513
 514 sub request_transfer {
 515     my ( $self, $params ) = @_;
 516
 517     # check for mandatory params
 518     my @mandatory = ( 'to', 'reason' );
 519     for my $param (@mandatory) {
 520         unless ( defined( $params->{$param} ) ) {
 521             Koha::Exceptions::MissingParameter->throw(
 522                 error => "The $param parameter is mandatory" );
 523         }
 524     }
 525
 526     Koha::Exceptions::Item::Transfer::Limit->throw()
 527       unless ( $params->{ignore_limits}
 528         || $self->can_be_transferred( { to => $params->{to} } ) );
 529
 530     my $request = $self->get_transfer;
 531     Koha::Exceptions::Item::Transfer::InQueue->throw( transfer => $request )
 532       if ( $request && !$params->{enqueue} && !$params->{replace} );
 533
 534     $request->cancel( { reason => $params->{reason}, force => 1 } )
 535       if ( defined($request) && $params->{replace} );
 536
 537     my $transfer = Koha::Item::Transfer->new(
 538         {
 539             itemnumber    => $self->itemnumber,
 540             daterequested => dt_from_string,
 541             frombranch    => $self->holdingbranch,
 542             tobranch      => $params->{to}->branchcode,
 543             reason        => $params->{reason},
 544             comments      => $params->{comment}
 545         }
 546     )->store();
 547
 548     return $transfer;
 549 }
 550
 551 =head3 get_transfer
 552
 553   my $transfer = $item->get_transfer;
 554
 555 Return the active transfer request or undef
 556
 557 Note: Transfers are retrieved in a Modified FIFO (First In First Out) order
 558 whereby the most recently sent, but not received, transfer will be returned
 559 if it exists, otherwise the oldest unsatisfied transfer will be returned.
 560
 561 This allows for transfers to queue, which is the case for stock rotation and
 562 rotating collections where a manual transfer may need to take precedence but
 563 we still expect the item to end up at a final location eventually.
 564
 565 =cut
 566
 567 sub get_transfer {
 568     my ($self) = @_;
 569
 570     return $self->get_transfers->search( {}, { rows => 1 } )->next;
 571 }
 572
 573 =head3 get_transfers
 574
 575   my $transfer = $item->get_transfers;
 576
 577 Return the list of outstanding transfers (i.e requested but not yet cancelled
 578 or received).
 579
 580 Note: Transfers are retrieved in a Modified FIFO (First In First Out) order
 581 whereby the most recently sent, but not received, transfer will be returned
 582 first if it exists, otherwise requests are in oldest to newest request order.
 583
 584 This allows for transfers to queue, which is the case for stock rotation and
 585 rotating collections where a manual transfer may need to take precedence but
 586 we still expect the item to end up at a final location eventually.
 587
 588 =cut
 589
 590 sub get_transfers {
 591     my ($self) = @_;
 592
 593     my $transfer_rs = $self->_result->branchtransfers;
 594
 595     return Koha::Item::Transfers
 596                 ->_new_from_dbic($transfer_rs)
 597                 ->filter_by_current
 598                 ->search( {}, { order_by => [ { -desc => 'datesent' }, { -asc => 'daterequested' } ], } );
 599 }
 600
 601 =head3 last_returned_by
 602
 603 Gets and sets the last borrower to return an item.
 604
 605 Accepts and returns Koha::Patron objects
 606
 607 $item->last_returned_by( $borrowernumber );
 608
 609 $last_returned_by = $item->last_returned_by();
 610
 611 =cut
 612
 613 sub last_returned_by {
 614     my ( $self, $borrower ) = @_;
 615
 616     my $items_last_returned_by_rs = Koha::Database->new()->schema()->resultset('ItemsLastBorrower');
 617
 618     if ($borrower) {
 619         return $items_last_returned_by_rs->update_or_create(
 620             { borrowernumber => $borrower->borrowernumber, itemnumber => $self->id } );
 621     }
 622     else {
 623         unless ( $self->{_last_returned_by} ) {
 624             my $result = $items_last_returned_by_rs->single( { itemnumber => $self->id } );
 625             if ($result) {
 626                 $self->{_last_returned_by} = Koha::Patrons->find( $result->get_column('borrowernumber') );
 627             }
 628         }
 629
 630         return $self->{_last_returned_by};
 631     }
 632 }
 633
 634 =head3 can_article_request
 635
 636 my $bool = $item->can_article_request( $borrower )
 637
 638 Returns true if item can be specifically requested
 639
 640 $borrower must be a Koha::Patron object
 641
 642 =cut
 643
 644 sub can_article_request {
 645     my ( $self, $borrower ) = @_;
 646
 647     my $rule = $self->article_request_type($borrower);
 648
 649     return 1 if $rule && $rule ne 'no' && $rule ne 'bib_only';
 650     return q{};
 651 }
 652
 653 =head3 hidden_in_opac
 654
 655 my $bool = $item->hidden_in_opac({ [ rules => $rules ] })
 656
 657 Returns true if item fields match the hidding criteria defined in $rules.
 658 Returns false otherwise.
 659
 660 Takes HASHref that can have the following parameters:
 661     OPTIONAL PARAMETERS:
 662     $rules : { <field> => [ value_1, ... ], ... }
 663
 664 Note: $rules inherits its structure from the parsed YAML from reading
 665 the I<OpacHiddenItems> system preference.
 666
 667 =cut
 668
 669 sub hidden_in_opac {
 670     my ( $self, $params ) = @_;
 671
 672     my $rules = $params->{rules} // {};
 673
 674     return 1
 675         if C4::Context->preference('hidelostitems') and
 676            $self->itemlost > 0;
 677
 678     my $hidden_in_opac = 0;
 679
 680     foreach my $field ( keys %{$rules} ) {
 681
 682         if ( any { $self->$field eq $_ } @{ $rules->{$field} } ) {
 683             $hidden_in_opac = 1;
 684             last;
 685         }
 686     }
 687
 688     return $hidden_in_opac;
 689 }
 690
 691 =head3 can_be_transferred
 692
 693 $item->can_be_transferred({ to => $to_library, from => $from_library })
 694 Checks if an item can be transferred to given library.
 695
 696 This feature is controlled by two system preferences:
 697 UseBranchTransferLimits to enable / disable the feature
 698 BranchTransferLimitsType to use either an itemnumber or ccode as an identifier
 699                          for setting the limitations
 700
 701 Takes HASHref that can have the following parameters:
 702     MANDATORY PARAMETERS:
 703     $to   : Koha::Library
 704     OPTIONAL PARAMETERS:
 705     $from : Koha::Library  # if not given, item holdingbranch
 706                            # will be used instead
 707
 708 Returns 1 if item can be transferred to $to_library, otherwise 0.
 709
 710 To find out whether at least one item of a Koha::Biblio can be transferred, please
 711 see Koha::Biblio->can_be_transferred() instead of using this method for
 712 multiple items of the same biblio.
 713
 714 =cut
 715
 716 sub can_be_transferred {
 717     my ($self, $params) = @_;
 718
 719     my $to   = $params->{to};
 720     my $from = $params->{from};
 721
 722     $to   = $to->branchcode;
 723     $from = defined $from ? $from->branchcode : $self->holdingbranch;
 724
 725     return 1 if $from eq $to; # Transfer to current branch is allowed
 726     return 1 unless C4::Context->preference('UseBranchTransferLimits');
 727
 728     my $limittype = C4::Context->preference('BranchTransferLimitsType');
 729     return Koha::Item::Transfer::Limits->search({
 730         toBranch => $to,
 731         fromBranch => $from,
 732         $limittype => $limittype eq 'itemtype'
 733                         ? $self->effective_itemtype : $self->ccode
 734     })->count ? 0 : 1;
 735
 736 }
 737
 738 =head3 pickup_locations
 739
 740 $pickup_locations = $item->pickup_locations( {patron => $patron } )
 741
 742 Returns possible pickup locations for this item, according to patron's home library (if patron is defined and holds are allowed only from hold groups)
 743 and if item can be transferred to each pickup location.
 744
 745 =cut
 746
 747 sub pickup_locations {
 748     my ($self, $params) = @_;
 749
 750     my $patron = $params->{patron};
 751
 752     my $circ_control_branch =
 753       C4::Reserves::GetReservesControlBranch( $self->unblessed(), $patron->unblessed );
 754     my $branchitemrule =
 755       C4::Circulation::GetBranchItemRule( $circ_control_branch, $self->itype );
 756
 757     if(defined $patron) {
 758         return Koha::Libraries->new()->empty if $branchitemrule->{holdallowed} eq 'from_local_hold_group' && !$self->home_branch->validate_hold_sibling( {branchcode => $patron->branchcode} );
 759         return Koha::Libraries->new()->empty if $branchitemrule->{holdallowed} eq 'from_home_library' && $self->home_branch->branchcode ne $patron->branchcode;
 760     }
 761
 762     my $pickup_libraries = Koha::Libraries->search();
 763     if ($branchitemrule->{hold_fulfillment_policy} eq 'holdgroup') {
 764         $pickup_libraries = $self->home_branch->get_hold_libraries;
 765     } elsif ($branchitemrule->{hold_fulfillment_policy} eq 'patrongroup') {
 766         my $plib = Koha::Libraries->find({ branchcode => $patron->branchcode});
 767         $pickup_libraries = $plib->get_hold_libraries;
 768     } elsif ($branchitemrule->{hold_fulfillment_policy} eq 'homebranch') {
 769         $pickup_libraries = Koha::Libraries->search({ branchcode => $self->homebranch });
 770     } elsif ($branchitemrule->{hold_fulfillment_policy} eq 'holdingbranch') {
 771         $pickup_libraries = Koha::Libraries->search({ branchcode => $self->holdingbranch });
 772     };
 773
 774     return $pickup_libraries->search(
 775         {
 776             pickup_location => 1
 777         },
 778         {
 779             order_by => ['branchname']
 780         }
 781     ) unless C4::Context->preference('UseBranchTransferLimits');
 782
 783     my $limittype = C4::Context->preference('BranchTransferLimitsType');
 784     my ($ccode, $itype) = (undef, undef);
 785     if( $limittype eq 'ccode' ){
 786         $ccode = $self->ccode;
 787     } else {
 788         $itype = $self->itype;
 789     }
 790     my $limits = Koha::Item::Transfer::Limits->search(
 791         {
 792             fromBranch => $self->holdingbranch,
 793             ccode      => $ccode,
 794             itemtype   => $itype,
 795         },
 796         { columns => ['toBranch'] }
 797     );
 798
 799     return $pickup_libraries->search(
 800         {
 801             pickup_location => 1,
 802             branchcode      => {
 803                 '-not_in' => $limits->_resultset->as_query
 804             }
 805         },
 806         {
 807             order_by => ['branchname']
 808         }
 809     );
 810 }
 811
 812 =head3 article_request_type
 813
 814 my $type = $item->article_request_type( $borrower )
 815
 816 returns 'yes', 'no', 'bib_only', or 'item_only'
 817
 818 $borrower must be a Koha::Patron object
 819
 820 =cut
 821
 822 sub article_request_type {
 823     my ( $self, $borrower ) = @_;
 824
 825     my $branch_control = C4::Context->preference('HomeOrHoldingBranch');
 826     my $branchcode =
 827         $branch_control eq 'homebranch'    ? $self->homebranch
 828       : $branch_control eq 'holdingbranch' ? $self->holdingbranch
 829       :                                      undef;
 830     my $borrowertype = $borrower->categorycode;
 831     my $itemtype = $self->effective_itemtype();
 832     my $rule = Koha::CirculationRules->get_effective_rule(
 833         {
 834             rule_name    => 'article_requests',
 835             categorycode => $borrowertype,
 836             itemtype     => $itemtype,
 837             branchcode   => $branchcode
 838         }
 839     );
 840
 841     return q{} unless $rule;
 842     return $rule->rule_value || q{}
 843 }
 844
 845 =head3 current_holds
 846
 847 =cut
 848
 849 sub current_holds {
 850     my ( $self ) = @_;
 851     my $attributes = { order_by => 'priority' };
 852     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 853     my $params = {
 854         itemnumber => $self->itemnumber,
 855         suspend => 0,
 856         -or => [
 857             reservedate => { '<=' => $dtf->format_date(dt_from_string) },
 858             waitingdate => { '!=' => undef },
 859         ],
 860     };
 861     my $hold_rs = $self->_result->reserves->search( $params, $attributes );
 862     return Koha::Holds->_new_from_dbic($hold_rs);
 863 }
 864
 865 =head3 stockrotationitem
 866
 867   my $sritem = Koha::Item->stockrotationitem;
 868
 869 Returns the stock rotation item associated with the current item.
 870
 871 =cut
 872
 873 sub stockrotationitem {
 874     my ( $self ) = @_;
 875     my $rs = $self->_result->stockrotationitem;
 876     return 0 if !$rs;
 877     return Koha::StockRotationItem->_new_from_dbic( $rs );
 878 }
 879
 880 =head3 add_to_rota
 881
 882   my $item = $item->add_to_rota($rota_id);
 883
 884 Add this item to the rota identified by $ROTA_ID, which means associating it
 885 with the first stage of that rota.  Should this item already be associated
 886 with a rota, then we will move it to the new rota.
 887
 888 =cut
 889
 890 sub add_to_rota {
 891     my ( $self, $rota_id ) = @_;
 892     Koha::StockRotationRotas->find($rota_id)->add_item($self->itemnumber);
 893     return $self;
 894 }
 895
 896 =head3 has_pending_hold
 897
 898   my $is_pending_hold = $item->has_pending_hold();
 899
 900 This method checks the tmp_holdsqueue to see if this item has been selected for a hold, but not filled yet and returns true or false
 901
 902 =cut
 903
 904 sub has_pending_hold {
 905     my ( $self ) = @_;
 906     my $pending_hold = $self->_result->tmp_holdsqueues;
 907     return $pending_hold->count ? 1: 0;
 908 }
 909
 910 =head3 has_pending_recall {
 911
 912   my $has_pending_recall
 913
 914 Return if whether has pending recall of not.
 915
 916 =cut
 917
 918 sub has_pending_recall {
 919     my ( $self ) = @_;
 920
 921     # FIXME Must be moved to $self->recalls
 922     return Koha::Recalls->search(
 923         {
 924             item_id   => $self->itemnumber,
 925             status    => 'waiting',
 926         }
 927     )->count;
 928 }
 929
 930 =head3 as_marc_field
 931
 932     my $field = $item->as_marc_field;
 933
 934 This method returns a MARC::Field object representing the Koha::Item object
 935 with the current mappings configuration.
 936
 937 =cut
 938
 939 sub as_marc_field {
 940     my ( $self ) = @_;
 941
 942     my ( $itemtag, $itemtagsubfield) = C4::Biblio::GetMarcFromKohaField( "items.itemnumber" );
 943
 944     my $tagslib = C4::Biblio::GetMarcStructure( 1, $self->biblio->frameworkcode, { unsafe => 1 });
 945
 946     my @subfields;
 947
 948     my $item_field = $tagslib->{$itemtag};
 949
 950     my $more_subfields = $self->additional_attributes->to_hashref;
 951     foreach my $subfield (
 952         sort {
 953                $a->{display_order} <=> $b->{display_order}
 954             || $a->{subfield} cmp $b->{subfield}
 955         } grep { ref($_) && %$_ } values %$item_field
 956     ){
 957
 958         my $kohafield = $subfield->{kohafield};
 959         my $tagsubfield = $subfield->{tagsubfield};
 960         my $value;
 961         if ( defined $kohafield ) {
 962             next if $kohafield !~ m{^items\.}; # That would be weird!
 963             ( my $attribute = $kohafield ) =~ s|^items\.||;
 964             $value = $self->$attribute # This call may fail if a kohafield is not a DB column but we don't want to add extra work for that there
 965                 if defined $self->$attribute and $self->$attribute ne '';
 966         } else {
 967             $value = $more_subfields->{$tagsubfield}
 968         }
 969
 970         next unless defined $value
 971             and $value ne q{};
 972
 973         if ( $subfield->{repeatable} ) {
 974             my @values = split '\|', $value;
 975             push @subfields, ( $tagsubfield => $_ ) for @values;
 976         }
 977         else {
 978             push @subfields, ( $tagsubfield => $value );
 979         }
 980
 981     }
 982
 983     return unless @subfields;
 984
 985     return MARC::Field->new(
 986         "$itemtag", ' ', ' ', @subfields
 987     );
 988 }
 989
 990 =head3 renewal_branchcode
 991
 992 Returns the branchcode to be recorded in statistics renewal of the item
 993
 994 =cut
 995
 996 sub renewal_branchcode {
 997
 998     my ($self, $params ) = @_;
 999
1000     my $interface = C4::Context->interface;
1001     my $branchcode;
1002     if ( $interface eq 'opac' ){
1003         my $renewal_branchcode = C4::Context->preference('OpacRenewalBranch');
1004         if( !defined $renewal_branchcode || $renewal_branchcode eq 'opacrenew' ){
1005             $branchcode = 'OPACRenew';
1006         }
1007         elsif ( $renewal_branchcode eq 'itemhomebranch' ) {
1008             $branchcode = $self->homebranch;
1009         }
1010         elsif ( $renewal_branchcode eq 'patronhomebranch' ) {
1011             $branchcode = $self->checkout->patron->branchcode;
1012         }
1013         elsif ( $renewal_branchcode eq 'checkoutbranch' ) {
1014             $branchcode = $self->checkout->branchcode;
1015         }
1016         else {
1017             $branchcode = "";
1018         }
1019     } else {
1020         $branchcode = ( C4::Context->userenv && defined C4::Context->userenv->{branch} )
1021             ? C4::Context->userenv->{branch} : $params->{branch};
1022     }
1023     return $branchcode;
1024 }
1025
1026 =head3 cover_images
1027
1028 Return the cover images associated with this item.
1029
1030 =cut
1031
1032 sub cover_images {
1033     my ( $self ) = @_;
1034
1035     my $cover_image_rs = $self->_result->cover_images;
1036     return unless $cover_image_rs;
1037     return Koha::CoverImages->_new_from_dbic($cover_image_rs);
1038 }
1039
1040 =head3 columns_to_str
1041
1042     my $values = $items->columns_to_str;
1043
1044 Return a hashref with the string representation of the different attribute of the item.
1045
1046 This is meant to be used for display purpose only.
1047
1048 =cut
1049
1050 sub columns_to_str {
1051     my ( $self ) = @_;
1052
1053     my $frameworkcode = $self->biblio->frameworkcode;
1054     my $tagslib = C4::Biblio::GetMarcStructure(1, $frameworkcode);
1055     my ( $itemtagfield, $itemtagsubfield) = C4::Biblio::GetMarcFromKohaField( "items.itemnumber" );
1056
1057     my $columns_info = $self->_result->result_source->columns_info;
1058
1059     my $mss = C4::Biblio::GetMarcSubfieldStructure( $frameworkcode, { unsafe => 1 } );
1060     my $values = {};
1061     for my $column ( keys %$columns_info ) {
1062
1063         next if $column eq 'more_subfields_xml';
1064
1065         my $value = $self->$column;
1066         # Maybe we need to deal with datetime columns here, but so far we have damaged_on, itemlost_on and withdrawn_on, and they are not linked with kohafield
1067
1068         if ( not defined $value or $value eq "" ) {
1069             $values->{$column} = $value;
1070             next;
1071         }
1072
1073         my $subfield =
1074           exists $mss->{"items.$column"}
1075           ? @{ $mss->{"items.$column"} }[0] # Should we deal with several subfields??
1076           : undef;
1077
1078         $values->{$column} =
1079             $subfield
1080           ? $subfield->{authorised_value}
1081               ? C4::Biblio::GetAuthorisedValueDesc( $itemtagfield,
1082                   $subfield->{tagsubfield}, $value, '', $tagslib )
1083               : $value
1084           : $value;
1085     }
1086
1087     my $marc_more=
1088       $self->more_subfields_xml
1089       ? MARC::Record->new_from_xml( $self->more_subfields_xml, 'UTF-8' )
1090       : undef;
1091
1092     my $more_values;
1093     if ( $marc_more ) {
1094         my ( $field ) = $marc_more->fields;
1095         for my $sf ( $field->subfields ) {
1096             my $subfield_code = $sf->[0];
1097             my $value = $sf->[1];
1098             my $subfield = $tagslib->{$itemtagfield}->{$subfield_code};
1099             next unless $subfield; # We have the value but it's not mapped, data lose! No regression however.
1100             $value =
1101               $subfield->{authorised_value}
1102               ? C4::Biblio::GetAuthorisedValueDesc( $itemtagfield,
1103                 $subfield->{tagsubfield}, $value, '', $tagslib )
1104               : $value;
1105
1106             push @{$more_values->{$subfield_code}}, $value;
1107         }
1108
1109         while ( my ( $k, $v ) = each %$more_values ) {
1110             $values->{$k} = join ' | ', @$v;
1111         }
1112     }
1113
1114     return $values;
1115 }
1116
1117 =head3 additional_attributes
1118
1119     my $attributes = $item->additional_attributes;
1120     $attributes->{k} = 'new k';
1121     $item->update({ more_subfields => $attributes->to_marcxml });
1122
1123 Returns a Koha::Item::Attributes object that represents the non-mapped
1124 attributes for this item.
1125
1126 =cut
1127
1128 sub additional_attributes {
1129     my ($self) = @_;
1130
1131     return Koha::Item::Attributes->new_from_marcxml(
1132         $self->more_subfields_xml,
1133     );
1134 }
1135
1136 =head3 _set_found_trigger
1137
1138     $self->_set_found_trigger
1139
1140 Finds the most recent lost item charge for this item and refunds the patron
1141 appropriately, taking into account any payments or writeoffs already applied
1142 against the charge.
1143
1144 Internal function, not exported, called only by Koha::Item->store.
1145
1146 =cut
1147
1148 sub _set_found_trigger {
1149     my ( $self, $pre_mod_item ) = @_;
1150
1151     # Reverse any lost item charges if necessary.
1152     my $no_refund_after_days =
1153       C4::Context->preference('NoRefundOnLostReturnedItemsAge');
1154     if ($no_refund_after_days) {
1155         my $today = dt_from_string();
1156         my $lost_age_in_days =
1157           dt_from_string( $pre_mod_item->itemlost_on )->delta_days($today)
1158           ->in_units('days');
1159
1160         return $self unless $lost_age_in_days < $no_refund_after_days;
1161     }
1162
1163     my $lostreturn_policy = Koha::CirculationRules->get_lostreturn_policy(
1164         {
1165             item          => $self,
1166             return_branch => C4::Context->userenv
1167             ? C4::Context->userenv->{'branch'}
1168             : undef,
1169         }
1170       );
1171
1172     if ( $lostreturn_policy ) {
1173
1174         # refund charge made for lost book
1175         my $lost_charge = Koha::Account::Lines->search(
1176             {
1177                 itemnumber      => $self->itemnumber,
1178                 debit_type_code => 'LOST',
1179                 status          => [ undef, { '<>' => 'FOUND' } ]
1180             },
1181             {
1182                 order_by => { -desc => [ 'date', 'accountlines_id' ] },
1183                 rows     => 1
1184             }
1185         )->single;
1186
1187         if ( $lost_charge ) {
1188
1189             my $patron = $lost_charge->patron;
1190             if ( $patron ) {
1191
1192                 my $account = $patron->account;
1193
1194                 # Credit outstanding amount
1195                 my $credit_total = $lost_charge->amountoutstanding;
1196
1197                 # Use cases
1198                 if (
1199                     $lost_charge->amount > $lost_charge->amountoutstanding &&
1200                     $lostreturn_policy ne "refund_unpaid"
1201                 ) {
1202                     # some amount has been cancelled. collect the offsets that are not writeoffs
1203                     # this works because the only way to subtract from this kind of a debt is
1204                     # using the UI buttons 'Pay' and 'Write off'
1205
1206                     # We don't credit any payments if return policy is
1207                     # "refund_unpaid"
1208                     #
1209                     # In that case only unpaid/outstanding amount
1210                     # will be credited which settles the debt without
1211                     # creating extra credits
1212
1213                     my $credit_offsets = $lost_charge->debit_offsets(
1214                         {
1215                             'credit_id'               => { '!=' => undef },
1216                             'credit.credit_type_code' => { '!=' => 'Writeoff' }
1217                         },
1218                         { join => 'credit' }
1219                     );
1220
1221                     my $total_to_refund = ( $credit_offsets->count > 0 ) ?
1222                         # credits are negative on the DB
1223                         $credit_offsets->total * -1 :
1224                         0;
1225                     # Credit the outstanding amount, then add what has been
1226                     # paid to create a net credit for this amount
1227                     $credit_total += $total_to_refund;
1228                 }
1229
1230                 my $credit;
1231                 if ( $credit_total > 0 ) {
1232                     my $branchcode =
1233                       C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1234                     $credit = $account->add_credit(
1235                         {
1236                             amount      => $credit_total,
1237                             description => 'Item found ' . $self->itemnumber,
1238                             type        => 'LOST_FOUND',
1239                             interface   => C4::Context->interface,
1240                             library_id  => $branchcode,
1241                             item_id     => $self->itemnumber,
1242                             issue_id    => $lost_charge->issue_id
1243                         }
1244                     );
1245
1246                     $credit->apply( { debits => [$lost_charge] } );
1247                     $self->add_message(
1248                         {
1249                             type    => 'info',
1250                             message => 'lost_refunded',
1251                             payload => { credit_id => $credit->id }
1252                         }
1253                     );
1254                 }
1255
1256                 # Update the account status
1257                 $lost_charge->status('FOUND');
1258                 $lost_charge->store();
1259
1260                 # Reconcile balances if required
1261                 if ( C4::Context->preference('AccountAutoReconcile') ) {
1262                     $account->reconcile_balance;
1263                 }
1264             }
1265         }
1266
1267         # restore fine for lost book
1268         if ( $lostreturn_policy eq 'restore' ) {
1269             my $lost_overdue = Koha::Account::Lines->search(
1270                 {
1271                     itemnumber      => $self->itemnumber,
1272                     debit_type_code => 'OVERDUE',
1273                     status          => 'LOST'
1274                 },
1275                 {
1276                     order_by => { '-desc' => 'date' },
1277                     rows     => 1
1278                 }
1279             )->single;
1280
1281             if ( $lost_overdue ) {
1282
1283                 my $patron = $lost_overdue->patron;
1284                 if ($patron) {
1285                     my $account = $patron->account;
1286
1287                     # Update status of fine
1288                     $lost_overdue->status('FOUND')->store();
1289
1290                     # Find related forgive credit
1291                     my $refund = $lost_overdue->credits(
1292                         {
1293                             credit_type_code => 'FORGIVEN',
1294                             itemnumber       => $self->itemnumber,
1295                             status           => [ { '!=' => 'VOID' }, undef ]
1296                         },
1297                         { order_by => { '-desc' => 'date' }, rows => 1 }
1298                     )->single;
1299
1300                     if ( $refund ) {
1301                         # Revert the forgive credit
1302                         $refund->void({ interface => 'trigger' });
1303                         $self->add_message(
1304                             {
1305                                 type    => 'info',
1306                                 message => 'lost_restored',
1307                                 payload => { refund_id => $refund->id }
1308                             }
1309                         );
1310                     }
1311
1312                     # Reconcile balances if required
1313                     if ( C4::Context->preference('AccountAutoReconcile') ) {
1314                         $account->reconcile_balance;
1315                     }
1316                 }
1317             }
1318         } elsif ( $lostreturn_policy eq 'charge' ) {
1319             $self->add_message(
1320                 {
1321                     type    => 'info',
1322                     message => 'lost_charge',
1323                 }
1324             );
1325         }
1326     }
1327
1328     return $self;
1329 }
1330
1331 =head3 public_read_list
1332
1333 This method returns the list of publicly readable database fields for both API and UI output purposes
1334
1335 =cut
1336
1337 sub public_read_list {
1338     return [
1339         'itemnumber',     'biblionumber',    'homebranch',
1340         'holdingbranch',  'location',        'collectioncode',
1341         'itemcallnumber', 'copynumber',      'enumchron',
1342         'barcode',        'dateaccessioned', 'itemnotes',
1343         'onloan',         'uri',             'itype',
1344         'notforloan',     'damaged',         'itemlost',
1345         'withdrawn',      'restricted'
1346     ];
1347 }
1348
1349 =head3 to_api
1350
1351 Overloaded to_api method to ensure item-level itypes is adhered to.
1352
1353 =cut
1354
1355 sub to_api {
1356     my ($self, $params) = @_;
1357
1358     my $response = $self->SUPER::to_api($params);
1359     my $overrides = {};
1360
1361     $overrides->{effective_item_type_id} = $self->effective_itemtype;
1362     $overrides->{effective_not_for_loan_status} = $self->notforloan ? $self->notforloan : $self->itemtype->notforloan;
1363
1364     return { %$response, %$overrides };
1365 }
1366
1367 =head3 to_api_mapping
1368
1369 This method returns the mapping for representing a Koha::Item object
1370 on the API.
1371
1372 =cut
1373
1374 sub to_api_mapping {
1375     return {
1376         itemnumber               => 'item_id',
1377         biblionumber             => 'biblio_id',
1378         biblioitemnumber         => undef,
1379         barcode                  => 'external_id',
1380         dateaccessioned          => 'acquisition_date',
1381         booksellerid             => 'acquisition_source',
1382         homebranch               => 'home_library_id',
1383         price                    => 'purchase_price',
1384         replacementprice         => 'replacement_price',
1385         replacementpricedate     => 'replacement_price_date',
1386         datelastborrowed         => 'last_checkout_date',
1387         datelastseen             => 'last_seen_date',
1388         stack                    => undef,
1389         notforloan               => 'not_for_loan_status',
1390         damaged                  => 'damaged_status',
1391         damaged_on               => 'damaged_date',
1392         itemlost                 => 'lost_status',
1393         itemlost_on              => 'lost_date',
1394         withdrawn                => 'withdrawn',
1395         withdrawn_on             => 'withdrawn_date',
1396         itemcallnumber           => 'callnumber',
1397         coded_location_qualifier => 'coded_location_qualifier',
1398         issues                   => 'checkouts_count',
1399         renewals                 => 'renewals_count',
1400         reserves                 => 'holds_count',
1401         restricted               => 'restricted_status',
1402         itemnotes                => 'public_notes',
1403         itemnotes_nonpublic      => 'internal_notes',
1404         holdingbranch            => 'holding_library_id',
1405         timestamp                => 'timestamp',
1406         location                 => 'location',
1407         permanent_location       => 'permanent_location',
1408         onloan                   => 'checked_out_date',
1409         cn_source                => 'call_number_source',
1410         cn_sort                  => 'call_number_sort',
1411         ccode                    => 'collection_code',
1412         materials                => 'materials_notes',
1413         uri                      => 'uri',
1414         itype                    => 'item_type_id',
1415         more_subfields_xml       => 'extended_subfields',
1416         enumchron                => 'serial_issue_number',
1417         copynumber               => 'copy_number',
1418         stocknumber              => 'inventory_number',
1419         new_status               => 'new_status',
1420         deleted_on               => undef,
1421     };
1422 }
1423
1424 =head3 itemtype
1425
1426     my $itemtype = $item->itemtype;
1427
1428     Returns Koha object for effective itemtype
1429
1430 =cut
1431
1432 sub itemtype {
1433     my ( $self ) = @_;
1434
1435     return Koha::ItemTypes->find( $self->effective_itemtype );
1436 }
1437
1438 =head3 orders
1439
1440   my $orders = $item->orders();
1441
1442 Returns a Koha::Acquisition::Orders object
1443
1444 =cut
1445
1446 sub orders {
1447     my ( $self ) = @_;
1448
1449     my $orders = $self->_result->item_orders;
1450     return Koha::Acquisition::Orders->_new_from_dbic($orders);
1451 }
1452
1453 =head3 tracked_links
1454
1455   my $tracked_links = $item->tracked_links();
1456
1457 Returns a Koha::TrackedLinks object
1458
1459 =cut
1460
1461 sub tracked_links {
1462     my ( $self ) = @_;
1463
1464     my $tracked_links = $self->_result->linktrackers;
1465     return Koha::TrackedLinks->_new_from_dbic($tracked_links);
1466 }
1467
1468 =head3 move_to_biblio
1469
1470   $item->move_to_biblio($to_biblio[, $params]);
1471
1472 Move the item to another biblio and update any references in other tables.
1473
1474 The final optional parameter, C<$params>, is expected to contain the
1475 'skip_record_index' key, which is relayed down to Koha::Item->store.
1476 There it prevents calling index_records, which takes most of the
1477 time in batch adds/deletes. The caller must take care of calling
1478 index_records separately.
1479
1480 $params:
1481     skip_record_index => 1|0
1482
1483 Returns undef if the move failed or the biblionumber of the destination record otherwise
1484
1485 =cut
1486
1487 sub move_to_biblio {
1488     my ( $self, $to_biblio, $params ) = @_;
1489
1490     $params //= {};
1491
1492     return if $self->biblionumber == $to_biblio->biblionumber;
1493
1494     my $from_biblionumber = $self->biblionumber;
1495     my $to_biblionumber = $to_biblio->biblionumber;
1496
1497     # Own biblionumber and biblioitemnumber
1498     $self->set({
1499         biblionumber => $to_biblionumber,
1500         biblioitemnumber => $to_biblio->biblioitem->biblioitemnumber
1501     })->store({ skip_record_index => $params->{skip_record_index} });
1502
1503     unless ($params->{skip_record_index}) {
1504         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
1505         $indexer->index_records( $from_biblionumber, "specialUpdate", "biblioserver" );
1506     }
1507
1508     # Acquisition orders
1509     $self->orders->update({ biblionumber => $to_biblionumber }, { no_triggers => 1 });
1510
1511     # Holds
1512     $self->holds->update({ biblionumber => $to_biblionumber }, { no_triggers => 1 });
1513
1514     # hold_fill_target (there's no Koha object available yet)
1515     my $hold_fill_target = $self->_result->hold_fill_target;
1516     if ($hold_fill_target) {
1517         $hold_fill_target->update({ biblionumber => $to_biblionumber });
1518     }
1519
1520     # tmp_holdsqueues - Can't update with DBIx since the table is missing a primary key
1521     # and can't even fake one since the significant columns are nullable.
1522     my $storage = $self->_result->result_source->storage;
1523     $storage->dbh_do(
1524         sub {
1525             my ($storage, $dbh, @cols) = @_;
1526
1527             $dbh->do("UPDATE tmp_holdsqueue SET biblionumber=? WHERE itemnumber=?", undef, $to_biblionumber, $self->itemnumber);
1528         }
1529     );
1530
1531     # tracked_links
1532     $self->tracked_links->update({ biblionumber => $to_biblionumber }, { no_triggers => 1 });
1533
1534     return $to_biblionumber;
1535 }
1536
1537 =head3 bundle_items
1538
1539   my $bundle_items = $item->bundle_items;
1540
1541 Returns the items associated with this bundle
1542
1543 =cut
1544
1545 sub bundle_items {
1546     my ($self) = @_;
1547
1548     if ( !$self->{_bundle_items_cached} ) {
1549         my $bundle_items = Koha::Items->search(
1550             { 'item_bundles_item.host' => $self->itemnumber },
1551             { join                     => 'item_bundles_item' } );
1552         $self->{_bundle_items}        = $bundle_items;
1553         $self->{_bundle_items_cached} = 1;
1554     }
1555
1556     return $self->{_bundle_items};
1557 }
1558
1559 =head3 is_bundle
1560
1561   my $is_bundle = $item->is_bundle;
1562
1563 Returns whether the item is a bundle or not
1564
1565 =cut
1566
1567 sub is_bundle {
1568     my ($self) = @_;
1569     return $self->bundle_items->count ? 1 : 0;
1570 }
1571
1572 =head3 bundle_host
1573
1574   my $bundle = $item->bundle_host;
1575
1576 Returns the bundle item this item is attached to
1577
1578 =cut
1579
1580 sub bundle_host {
1581     my ($self) = @_;
1582
1583     my $bundle_items_rs = $self->_result->item_bundles_item;
1584     return unless $bundle_items_rs;
1585     return Koha::Item->_new_from_dbic($bundle_items_rs->host);
1586 }
1587
1588 =head3 in_bundle
1589
1590   my $in_bundle = $item->in_bundle;
1591
1592 Returns whether this item is currently in a bundle
1593
1594 =cut
1595
1596 sub in_bundle {
1597     my ($self) = @_;
1598     return $self->bundle_host ? 1 : 0;
1599 }
1600
1601 =head3 add_to_bundle
1602
1603   my $link = $item->add_to_bundle($bundle_item);
1604
1605 Adds the bundle_item passed to this item
1606
1607 =cut
1608
1609 sub add_to_bundle {
1610     my ( $self, $bundle_item ) = @_;
1611
1612     my $schema = Koha::Database->new->schema;
1613
1614     my $BundleNotLoanValue = C4::Context->preference('BundleNotLoanValue');
1615
1616     try {
1617         $schema->txn_do(
1618             sub {
1619                 $self->_result->add_to_item_bundles_hosts(
1620                     { item => $bundle_item->itemnumber } );
1621
1622                 $bundle_item->notforloan($BundleNotLoanValue)->store();
1623             }
1624         );
1625     }
1626     catch {
1627
1628         # FIXME: See if we can move the below copy/paste from Koha::Object::store into it's own class and catch at a lower level in the Schema instantiation, take inspiration from DBIx::Error
1629         if ( ref($_) eq 'DBIx::Class::Exception' ) {
1630             if ( $_->{msg} =~ /Cannot add or update a child row: a foreign key constraint fails/ ) {
1631                 # FK constraints
1632                 # FIXME: MySQL error, if we support more DB engines we should implement this for each
1633                 if ( $_->{msg} =~ /FOREIGN KEY \(`(?<column>.*?)`\)/ ) {
1634                     Koha::Exceptions::Object::FKConstraint->throw(
1635                         error     => 'Broken FK constraint',
1636                         broken_fk => $+{column}
1637                     );
1638                 }
1639             }
1640             elsif (
1641                 $_->{msg} =~ /Duplicate entry '(.*?)' for key '(?<key>.*?)'/ )
1642             {
1643                 Koha::Exceptions::Object::DuplicateID->throw(
1644                     error        => 'Duplicate ID',
1645                     duplicate_id => $+{key}
1646                 );
1647             }
1648             elsif ( $_->{msg} =~
1649 /Incorrect (?<type>\w+) value: '(?<value>.*)' for column \W?(?<property>\S+)/
1650               )
1651             {    # The optional \W in the regex might be a quote or backtick
1652                 my $type     = $+{type};
1653                 my $value    = $+{value};
1654                 my $property = $+{property};
1655                 $property =~ s/['`]//g;
1656                 Koha::Exceptions::Object::BadValue->throw(
1657                     type     => $type,
1658                     value    => $value,
1659                     property => $property =~ /(\w+\.\w+)$/
1660                     ? $1
1661                     : $property
1662                     ,    # results in table.column without quotes or backtics
1663                 );
1664             }
1665
1666             # Catch-all for foreign key breakages. It will help find other use cases
1667             $_->rethrow();
1668         }
1669         else {
1670             $_;
1671         }
1672     };
1673 }
1674
1675 =head3 remove_from_bundle
1676
1677 Remove this item from any bundle it may have been attached to.
1678
1679 =cut
1680
1681 sub remove_from_bundle {
1682     my ($self) = @_;
1683
1684     my $bundle_item_rs = $self->_result->item_bundles_item;
1685     if ( $bundle_item_rs ) {
1686         $bundle_item_rs->delete;
1687         $self->notforloan(0)->store();
1688         return 1;
1689     }
1690     return 0;
1691 }
1692
1693 =head2 Internal methods
1694
1695 =head3 _after_item_action_hooks
1696
1697 Helper method that takes care of calling all plugin hooks
1698
1699 =cut
1700
1701 sub _after_item_action_hooks {
1702     my ( $self, $params ) = @_;
1703
1704     my $action = $params->{action};
1705
1706     Koha::Plugins->call(
1707         'after_item_action',
1708         {
1709             action  => $action,
1710             item    => $self,
1711             item_id => $self->itemnumber,
1712         }
1713     );
1714 }
1715
1716 =head3 recall
1717
1718     my $recall = $item->recall;
1719
1720 Return the relevant recall for this item
1721
1722 =cut
1723
1724 sub recall {
1725     my ( $self ) = @_;
1726     my @recalls = Koha::Recalls->search(
1727         {
1728             biblio_id => $self->biblionumber,
1729             completed => 0,
1730         },
1731         { order_by => { -asc => 'created_date' } }
1732     )->as_list;
1733     foreach my $recall (@recalls) {
1734         if ( $recall->item_level and $recall->item_id == $self->itemnumber ){
1735             return $recall;
1736         }
1737     }
1738     # no item-level recall to return, so return earliest biblio-level
1739     # FIXME: eventually this will be based on priority
1740     return $recalls[0];
1741 }
1742
1743 =head3 can_be_recalled
1744
1745     if ( $item->can_be_recalled({ patron => $patron_object }) ) # do recall
1746
1747 Does item-level checks and returns if items can be recalled by this borrower
1748
1749 =cut
1750
1751 sub can_be_recalled {
1752     my ( $self, $params ) = @_;
1753
1754     return 0 if !( C4::Context->preference('UseRecalls') );
1755
1756     # check if this item is not for loan, withdrawn or lost
1757     return 0 if ( $self->notforloan != 0 );
1758     return 0 if ( $self->itemlost != 0 );
1759     return 0 if ( $self->withdrawn != 0 );
1760
1761     # check if this item is not checked out - if not checked out, can't be recalled
1762     return 0 if ( !defined( $self->checkout ) );
1763
1764     my $patron = $params->{patron};
1765
1766     my $branchcode = C4::Context->userenv->{'branch'};
1767     if ( $patron ) {
1768         $branchcode = C4::Circulation::_GetCircControlBranch( $self->unblessed, $patron->unblessed );
1769     }
1770
1771     # Check the circulation rule for each relevant itemtype for this item
1772     my $rule = Koha::CirculationRules->get_effective_rules({
1773         branchcode => $branchcode,
1774         categorycode => $patron ? $patron->categorycode : undef,
1775         itemtype => $self->effective_itemtype,
1776         rules => [
1777             'recalls_allowed',
1778             'recalls_per_record',
1779             'on_shelf_recalls',
1780         ],
1781     });
1782
1783     # check recalls allowed has been set and is not zero
1784     return 0 if ( !defined($rule->{recalls_allowed}) || $rule->{recalls_allowed} == 0 );
1785
1786     if ( $patron ) {
1787         # check borrower has not reached open recalls allowed limit
1788         return 0 if ( $patron->recalls->filter_by_current->count >= $rule->{recalls_allowed} );
1789
1790         # check borrower has not reach open recalls allowed per record limit
1791         return 0 if ( $patron->recalls->filter_by_current->search({ biblio_id => $self->biblionumber })->count >= $rule->{recalls_per_record} );
1792
1793         # check if this patron has already recalled this item
1794         return 0 if ( Koha::Recalls->search({ item_id => $self->itemnumber, patron_id => $patron->borrowernumber })->filter_by_current->count > 0 );
1795
1796         # check if this patron has already checked out this item
1797         return 0 if ( Koha::Checkouts->search({ itemnumber => $self->itemnumber, borrowernumber => $patron->borrowernumber })->count > 0 );
1798
1799         # check if this patron has already reserved this item
1800         return 0 if ( Koha::Holds->search({ itemnumber => $self->itemnumber, borrowernumber => $patron->borrowernumber })->count > 0 );
1801     }
1802
1803     # check item availability
1804     # items are unavailable for recall if they are lost, withdrawn or notforloan
1805     my @items = Koha::Items->search({ biblionumber => $self->biblionumber, itemlost => 0, withdrawn => 0, notforloan => 0 })->as_list;
1806
1807     # if there are no available items at all, no recall can be placed
1808     return 0 if ( scalar @items == 0 );
1809
1810     my $checked_out_count = 0;
1811     foreach (@items) {
1812         if ( Koha::Checkouts->search({ itemnumber => $_->itemnumber })->count > 0 ){ $checked_out_count++; }
1813     }
1814
1815     # can't recall if on shelf recalls only allowed when all unavailable, but items are still available for checkout
1816     return 0 if ( $rule->{on_shelf_recalls} eq 'all' && $checked_out_count < scalar @items );
1817
1818     # can't recall if no items have been checked out
1819     return 0 if ( $checked_out_count == 0 );
1820
1821     # can recall
1822     return 1;
1823 }
1824
1825 =head3 can_be_waiting_recall
1826
1827     if ( $item->can_be_waiting_recall ) { # allocate item as waiting for recall
1828
1829 Checks item type and branch of circ rules to return whether this item can be used to fill a recall.
1830 At this point the item has already been recalled. We are now at the checkin and set waiting stage.
1831
1832 =cut
1833
1834 sub can_be_waiting_recall {
1835     my ( $self ) = @_;
1836
1837     return 0 if !( C4::Context->preference('UseRecalls') );
1838
1839     # check if this item is not for loan, withdrawn or lost
1840     return 0 if ( $self->notforloan != 0 );
1841     return 0 if ( $self->itemlost != 0 );
1842     return 0 if ( $self->withdrawn != 0 );
1843
1844     my $branchcode = $self->holdingbranch;
1845     if ( C4::Context->preference('CircControl') eq 'PickupLibrary' and C4::Context->userenv and C4::Context->userenv->{'branch'} ) {
1846         $branchcode = C4::Context->userenv->{'branch'};
1847     } else {
1848         $branchcode = ( C4::Context->preference('HomeOrHoldingBranch') eq 'homebranch' ) ? $self->homebranch : $self->holdingbranch;
1849     }
1850
1851     # Check the circulation rule for each relevant itemtype for this item
1852     my $rule = Koha::CirculationRules->get_effective_rules({
1853         branchcode => $branchcode,
1854         categorycode => undef,
1855         itemtype => $self->effective_itemtype,
1856         rules => [
1857             'recalls_allowed',
1858         ],
1859     });
1860
1861     # check recalls allowed has been set and is not zero
1862     return 0 if ( !defined($rule->{recalls_allowed}) || $rule->{recalls_allowed} == 0 );
1863
1864     # can recall
1865     return 1;
1866 }
1867
1868 =head3 check_recalls
1869
1870     my $recall = $item->check_recalls;
1871
1872 Get the most relevant recall for this item.
1873
1874 =cut
1875
1876 sub check_recalls {
1877     my ( $self ) = @_;
1878
1879     my @recalls = Koha::Recalls->search(
1880         {   biblio_id => $self->biblionumber,
1881             item_id   => [ $self->itemnumber, undef ]
1882         },
1883         { order_by => { -asc => 'created_date' } }
1884     )->filter_by_current->as_list;
1885
1886     my $recall;
1887     # iterate through relevant recalls to find the best one.
1888     # if we come across a waiting recall, use this one.
1889     # if we have iterated through all recalls and not found a waiting recall, use the first recall in the array, which should be the oldest recall.
1890     foreach my $r ( @recalls ) {
1891         if ( $r->waiting ) {
1892             $recall = $r;
1893             last;
1894         }
1895     }
1896     unless ( defined $recall ) {
1897         $recall = $recalls[0];
1898     }
1899
1900     return $recall;
1901 }
1902
1903 =head3 is_notforloan
1904
1905     my $is_notforloan = $item->is_notforloan;
1906
1907 Determine whether or not this item is "notforloan" based on
1908 the item's notforloan status or its item type
1909
1910 =cut
1911
1912 sub is_notforloan {
1913     my ( $self ) = @_;
1914     my $is_notforloan = 0;
1915
1916     if ( $self->notforloan ){
1917         $is_notforloan = 1;
1918     }
1919     else {
1920         my $itemtype = $self->itemtype;
1921         if ($itemtype){
1922             if ( $itemtype->notforloan ){
1923                 $is_notforloan = 1;
1924             }
1925         }
1926     }
1927
1928     return $is_notforloan;
1929 }
1930
1931 =head3 _type
1932
1933 =cut
1934
1935 sub _type {
1936     return 'Item';
1937 }
1938
1939 =head1 AUTHOR
1940
1941 Kyle M Hall <kyle@bywatersolutions.com>
1942
1943 =cut
1944
1945 1;