Koha/Items.pm

   1 package Koha::Items;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use Koha::Database;
  25
  26 use Koha::Item;
  27 use Koha::CirculationRules;
  28
  29 use base qw(Koha::Objects);
  30
  31 =head1 NAME
  32
  33 Koha::Items - Koha Item object set class
  34
  35 =head1 API
  36
  37 =head2 Class methods
  38
  39 =cut
  40
  41 =head3 filter_by_for_hold
  42
  43     my $filtered_items = $items->filter_by_for_hold;
  44
  45 Return the items of the set that are *potentially* holdable.
  46
  47 Caller has the responsibility to call C4::Reserves::CanItemBeReserved before
  48 placing a hold on one of those items.
  49
  50 =cut
  51
  52 sub filter_by_for_hold {
  53     my ($self) = @_;
  54
  55     my @hold_not_allowed_itypes = Koha::CirculationRules->search(
  56         {
  57             rule_name    => 'holdallowed',
  58             branchcode   => undef,
  59             categorycode => undef,
  60             rule_value   => 'not_allowed',
  61         }
  62     )->get_column('itemtype');
  63
  64     return $self->search(
  65         {
  66             itemlost   => 0,
  67             withdrawn  => 0,
  68             notforloan => { '<=' => 0 }, # items with negative or zero notforloan value are holdable
  69             ( C4::Context->preference('AllowHoldsOnDamagedItems' ) ? () : ( damaged => 0 ) ),
  70             itype        => { -not_in => \@hold_not_allowed_itypes },
  71         }
  72     );
  73 }
  74
  75 =head3 filter_by_visible_in_opac
  76
  77     my $filered_items = $items->filter_by_visible_in_opac(
  78         {
  79             [ patron => $patron ]
  80         }
  81     );
  82
  83 Returns a new resultset, containing those items that are not expected to be hidden in OPAC
  84 for the passed I<Koha::Patron> object that is passed.
  85
  86 The I<OpacHiddenItems>, I<hidelostitems> and I<OpacHiddenItemsExceptions> system preferences
  87 are honoured.
  88
  89 =cut
  90
  91 sub filter_by_visible_in_opac {
  92     my ($self, $params) = @_;
  93
  94     my $patron = $params->{patron};
  95
  96     my $result = $self;
  97
  98     # Filter out OpacHiddenItems unless disabled by OpacHiddenItemsExceptions
  99     unless ( $patron and $patron->category->override_hidden_items ) {
 100         my $rules = C4::Context->yaml_preference('OpacHiddenItems') // {};
 101
 102         my $rules_params;
 103         foreach my $field ( keys %$rules ) {
 104             $rules_params->{$field} =
 105               [ { '-not_in' => $rules->{$field} }, undef ];
 106         }
 107
 108         $result = $result->search( $rules_params );
 109     }
 110
 111     if (C4::Context->preference('hidelostitems')) {
 112         $result = $result->filter_out_lost;
 113     }
 114
 115     return $result;
 116 }
 117
 118 =head3 filter_out_lost
 119
 120     my $filered_items = $items->filter_out_lost;
 121
 122 Returns a new resultset, containing those items that are not marked as lost.
 123
 124 =cut
 125
 126 sub filter_out_lost {
 127     my ($self) = @_;
 128
 129     my $params = { itemlost => 0 };
 130
 131     return $self->search( $params );
 132 }
 133
 134 =head2 Internal methods
 135
 136 =head3 _type
 137
 138 =cut
 139
 140 sub _type {
 141     return 'Item';
 142 }
 143
 144 =head3 object_class
 145
 146 =cut
 147
 148 sub object_class {
 149     return 'Koha::Item';
 150 }
 151
 152 =head1 AUTHOR
 153
 154 Kyle M Hall <kyle@bywatersolutions.com>
 155 Tomas Cohen Arazi <tomascohen@theke.io>
 156 Martin Renvoize <martin.renvoize@ptfs-europe.com>
 157
 158 =cut
 159
 160 1;