Koha/Patron/Discharge.pm

   1 package Koha::Patron::Discharge;
   2
   3 use Modern::Perl;
   4 use CGI;
   5 use File::Temp qw( :POSIX );
   6 use Carp;
   7
   8 use C4::Templates qw ( gettemplate );
   9 use C4::Members qw( GetPendingIssues );
  10 use C4::Reserves qw( CancelReserve );
  11
  12 use Koha::Database;
  13 use Koha::DateUtils qw( dt_from_string output_pref );
  14 use Koha::Patrons;
  15
  16 my $rs = Koha::Database->new->schema->resultset('Discharge');
  17
  18 sub count {
  19     my ($params) = @_;
  20     my $values = {};
  21
  22     if( $params->{borrowernumber} ) {
  23         $values->{borrower} = $params->{borrowernumber};
  24     }
  25     if( $params->{pending} ) {
  26         $values->{needed} = { '!=', undef };
  27         $values->{validated} = undef;
  28     }
  29     elsif( $params->{validated} ) {
  30         $values->{validated} = { '!=', undef };
  31     }
  32
  33     return $rs->search( $values )->count;
  34 }
  35
  36 sub can_be_discharged {
  37     my ($params) = @_;
  38     return unless $params->{borrowernumber};
  39
  40     my $issues = GetPendingIssues( $params->{borrowernumber} );
  41     if( @$issues ) {
  42         return 0;
  43     }
  44     else {
  45         return 1;
  46     }
  47 }
  48
  49 sub is_discharged {
  50     my ($params) = @_;
  51     return unless $params->{borrowernumber};
  52     my $borrowernumber = $params->{borrowernumber};
  53
  54     my $restricted = Koha::Patrons->find( $borrowernumber )->is_debarred;
  55     my $validated = get_validated({borrowernumber => $borrowernumber});
  56
  57     if ($restricted && $validated) {
  58         return 1;
  59     } else {
  60         return 0;
  61     }
  62 }
  63
  64 sub request {
  65     my ($params) = @_;
  66     my $borrowernumber = $params->{borrowernumber};
  67     return unless $borrowernumber;
  68     return unless can_be_discharged({ borrowernumber => $borrowernumber });
  69
  70     return $rs->create({
  71         borrower => $borrowernumber,
  72         needed   => dt_from_string,
  73     });
  74 }
  75
  76 sub discharge {
  77     my ($params) = @_;
  78     my $borrowernumber = $params->{borrowernumber};
  79     return unless $borrowernumber and can_be_discharged( { borrowernumber => $borrowernumber } );
  80
  81     # Cancel reserves
  82     my $patron = Koha::Patrons->find( $borrowernumber );
  83     my $holds = $patron->holds;
  84     while ( my $hold = $holds->next ) {
  85         CancelReserve( { reserve_id => $hold->reserve_id } );
  86     }
  87
  88     # Debar the member
  89     Koha::Patron::Debarments::AddDebarment({
  90         borrowernumber => $borrowernumber,
  91         type           => 'DISCHARGE',
  92     });
  93
  94     # Generate the discharge
  95     my $discharge = $rs->search({ borrower => $borrowernumber }, { order_by => { -desc => 'needed' }, rows => 1 });
  96     if( $discharge->count > 0 ) {
  97         $discharge->update({ validated => dt_from_string });
  98     }
  99     else {
 100         $rs->create({
 101             borrower  => $borrowernumber,
 102             validated => dt_from_string,
 103         });
 104     }
 105 }
 106
 107 sub generate_as_pdf {
 108     my ($params) = @_;
 109     return unless $params->{borrowernumber};
 110
 111     my $patron = Koha::Patrons->find( $params->{borrowernumber} );
 112     my $letter = C4::Letters::GetPreparedLetter(
 113         module      => 'members',
 114         letter_code => 'DISCHARGE',
 115         lang        => $patron->lang,
 116         tables      => { borrowers => $params->{borrowernumber}, branches => $params->{'branchcode'}, },
 117     );
 118
 119     my $today = output_pref( dt_from_string() );
 120     $letter->{'title'}   =~ s/<<today>>/$today/g;
 121     $letter->{'content'} =~ s/<<today>>/$today/g;
 122
 123     my $tmpl = C4::Templates::gettemplate('batch/print-notices.tt', 'intranet', new CGI);
 124     $tmpl->param(
 125         stylesheet => C4::Context->preference("NoticeCSS"),
 126         today      => $today,
 127         messages   => [$letter],
 128     );
 129
 130     my $html_path = tmpnam() . '.html';
 131     my $pdf_path = tmpnam() . '.pdf';
 132     my $html_content = $tmpl->output;
 133     open my $html_fh, '>:encoding(utf8)', $html_path;
 134     say $html_fh $html_content;
 135     close $html_fh;
 136     my $output = eval { require PDF::FromHTML; return; } || $@;
 137     if ($output && $params->{testing}) {
 138         carp $output;
 139         $pdf_path = undef;
 140     }
 141     elsif ($output) {
 142         die $output;
 143     }
 144     else {
 145         my $pdf = PDF::FromHTML->new( encoding => 'utf-8' );
 146         $pdf->load_file( $html_path );
 147         $pdf->convert;
 148         $pdf->write_file( $pdf_path );
 149     }
 150
 151     return $pdf_path;
 152 }
 153
 154 sub get_pendings {
 155     my ($params)       = @_;
 156     my $branchcode     = $params->{branchcode};
 157     my $borrowernumber = $params->{borrowernumber};
 158
 159     my $cond = {
 160         'me.needed'    => { '!=', undef },
 161         'me.validated' => undef,
 162         ( defined $borrowernumber ? ( 'me.borrower' => $borrowernumber ) : () ),
 163         ( defined $branchcode ? ( 'borrower.branchcode' => $branchcode ) : () ),
 164     };
 165
 166     my @rs = $rs->search( $cond, { join => 'borrower' } );
 167     return \@rs;
 168 }
 169
 170 sub get_validated {
 171     my ($params)       = @_;
 172     my $branchcode     = $params->{branchcode};
 173     my $borrowernumber = $params->{borrowernumber};
 174
 175     my $cond = {
 176         'me.validated' => { '!=', undef },
 177         ( defined $borrowernumber ? ( 'me.borrower' => $borrowernumber ) : () ),
 178         ( defined $branchcode ? ( 'borrower.branchcode' => $branchcode ) : () ),
 179     };
 180
 181     my @rs = $rs->search( $cond, { join => 'borrower' } );
 182     return \@rs;
 183 }
 184
 185
 186 1;