Koha/REST/Plugin/PluginRoutes.pm

   1 package Koha::REST::Plugin::PluginRoutes;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious::Plugin';
  21
  22 use Koha::Exceptions::Plugin;
  23 use Koha::Plugins;
  24
  25 use Clone qw(clone);
  26 use Try::Tiny;
  27
  28 =head1 NAME
  29
  30 Koha::REST::Plugin::PluginRoutes
  31
  32 =head1 API
  33
  34 =head2 Helper methods
  35
  36 =head3 register
  37
  38 =cut
  39
  40 sub register {
  41     my ( $self, $app, $config ) = @_;
  42
  43     my $spec      = $config->{spec};
  44     my $validator = $config->{validator};
  45
  46     my @plugins;
  47
  48     if ( C4::Context->config("enable_plugins") )
  49     {
  50         # plugin needs to define a namespace
  51         @plugins = Koha::Plugins->new()->GetPlugins(
  52             {
  53                 method => 'api_namespace',
  54             }
  55         );
  56     }
  57
  58     foreach my $plugin ( @plugins ) {
  59         $spec = inject_routes( $spec, $plugin, $validator );
  60     }
  61
  62     return $spec;
  63 }
  64
  65 =head3 inject_routes
  66
  67 =cut
  68
  69 sub inject_routes {
  70     my ( $spec, $plugin, $validator ) = @_;
  71
  72     return try {
  73
  74         my $backup_spec = merge_spec( clone($spec), $plugin );
  75         if ( spec_ok( $backup_spec, $validator ) ) {
  76             $spec = merge_spec( $spec, $plugin );
  77         }
  78         else {
  79             Koha::Exceptions::Plugin->throw(
  80                 "The resulting spec is invalid. Skipping " . $plugin->get_metadata->{name}
  81             );
  82         }
  83
  84         return $spec;
  85     }
  86     catch {
  87         warn "$_";
  88         return $spec;
  89     };
  90 }
  91
  92 =head3 merge_spec
  93
  94 =cut
  95
  96 sub merge_spec {
  97     my ( $spec, $plugin ) = @_;
  98
  99     if($plugin->can('api_routes')) {
 100         my $plugin_spec = $plugin->api_routes;
 101
 102         foreach my $route ( keys %{ $plugin_spec } ) {
 103             my $THE_route = '/contrib/' . $plugin->api_namespace . $route;
 104             if ( exists $spec->{ $THE_route } ) {
 105                 # Route exists, overwriting is forbidden
 106                 Koha::Exceptions::Plugin::ForbiddenAction->throw(
 107                     "Attempted to overwrite $THE_route"
 108                 );
 109             }
 110
 111             $spec->{'paths'}->{ $THE_route } = $plugin_spec->{ $route };
 112         }
 113     }
 114
 115     if($plugin->can('static_routes')) {
 116         my $plugin_spec = $plugin->static_routes;
 117
 118         foreach my $route ( keys %{ $plugin_spec } ) {
 119
 120             my $THE_route = '/contrib/' . $plugin->api_namespace . '/static'.$route;
 121             if ( exists $spec->{ $THE_route } ) {
 122                 # Route exists, overwriting is forbidden
 123                 Koha::Exceptions::Plugin::ForbiddenAction->throw(
 124                     "Attempted to overwrite $THE_route"
 125                 );
 126             }
 127
 128             $spec->{'paths'}->{ $THE_route } = $plugin_spec->{ $route };
 129         }
 130     }
 131     return $spec;
 132 }
 133
 134 =head3 spec_ok
 135
 136 =cut
 137
 138 sub spec_ok {
 139     my ( $spec, $validator ) = @_;
 140
 141     return try {
 142         $validator->load_and_validate_schema(
 143             $spec,
 144             {
 145                 allow_invalid_ref => 1,
 146             }
 147         );
 148         return 1;
 149     }
 150     catch {
 151         return 0;
 152     }
 153 }
 154
 155 1;