Koha/REST/V1/BackgroundJobs.pm

   1 package Koha::REST::V1::BackgroundJobs;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious::Controller';
  21
  22 use Koha::BackgroundJobs;
  23
  24 use Try::Tiny;
  25
  26 =head1 API
  27
  28 =head2 Methods
  29
  30 =head3 list
  31
  32 Controller function that handles listing Koha::BackgroundJob objects
  33
  34 =cut
  35
  36 sub list {
  37     my $c = shift->openapi->valid_input or return;
  38
  39     return try {
  40
  41         my $only_current = delete $c->validation->output->{only_current};
  42
  43         my $bj_rs = Koha::BackgroundJobs->new;
  44
  45         if ($only_current) {
  46             $bj_rs = $bj_rs->filter_by_current;
  47         }
  48
  49         return $c->render(
  50             status  => 200,
  51             openapi => $c->objects->search($bj_rs)
  52         );
  53     } catch {
  54         $c->unhandled_exception($_);
  55     };
  56 }
  57
  58 =head3 get
  59
  60 Controller function that handles retrieving a single Koha::BackgroundJob object
  61
  62 =cut
  63
  64 sub get {
  65     my $c = shift->openapi->valid_input or return;
  66
  67     return try {
  68
  69         my $job_id = $c->validation->param('job_id');
  70         my $patron = $c->stash('koha.user');
  71
  72         my $can_manage_background_jobs =
  73           $patron->has_permission( { parameters => 'manage_background_jobs' } );
  74
  75         my $job = Koha::BackgroundJobs->find($job_id);
  76
  77         return $c->render(
  78             status  => 404,
  79             openapi => { error => "Object not found" }
  80         ) unless $job;
  81
  82         return $c->render(
  83             status  => 403,
  84             openapi => { error => "Cannot see background job info" }
  85           )
  86           if !$can_manage_background_jobs
  87           && $job->borrowernumber != $patron->borrowernumber;
  88
  89         return $c->render(
  90             status  => 200,
  91             openapi => $job->to_api
  92         );
  93     }
  94     catch {
  95         $c->unhandled_exception($_);
  96     };
  97 }
  98
  99 1;