catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output qw( output_html_with_http_headers pagination_bar );
 144 use C4::Auth qw( get_template_and_user );
 145 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 146 use C4::Languages qw( getlanguage getLanguages );
 147 use C4::Koha qw( getitemtypeimagelocation GetAuthorisedValues );
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = CGI->new;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 my @params = $cgi->multi_param("limit");
 172 if ((@params>=1) || (defined $cgi->param("q") && $cgi->param("q") ne "" ) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 173     $template_name = 'catalogue/results.tt';
 174     $template_type = 'results';
 175 }
 176 else {
 177     $template_name = 'catalogue/advsearch.tt';
 178     $template_type = 'advsearch';
 179 }
 180 # load the template
 181 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 182     template_name => $template_name,
 183     query => $cgi,
 184     type => "intranet",
 185     flagsrequired   => { catalogue => 1 },
 186     }
 187 );
 188
 189 my $lang = C4::Languages::getlanguage($cgi);
 190
 191 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 192     $template->param('UNIMARC' => 1);
 193 }
 194
 195 if($cgi->cookie("holdfor")){
 196     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 197     if ( $holdfor_patron ) { # may have been deleted in the meanwhile
 198         $template->param(
 199             holdfor => $cgi->cookie("holdfor"),
 200             holdfor_surname => $holdfor_patron->surname,
 201             holdfor_firstname => $holdfor_patron->firstname,
 202             holdfor_cardnumber => $holdfor_patron->cardnumber,
 203         );
 204     }
 205 }
 206
 207 if($cgi->cookie("holdforclub")){
 208     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 209     if ( $holdfor_club ) { # May have been deleted in the meanwhile
 210         $template->param(
 211             holdforclub => $cgi->cookie("holdforclub"),
 212             holdforclub_name => $holdfor_club->name,
 213         );
 214     }
 215 }
 216
 217 if($cgi->cookie("searchToOrder")){
 218     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 219     $template->param(
 220         searchtoorder_basketno => $basketno,
 221         searchtoorder_vendorid => $vendorid
 222     );
 223 }
 224
 225 # get biblionumbers stored in the cart
 226 my @cart_list;
 227
 228 if($cgi->cookie("intranet_bib_list")){
 229     my $cart_list = $cgi->cookie("intranet_bib_list");
 230     @cart_list = split(/\//, $cart_list);
 231 }
 232
 233 my @search_groups =
 234   Koha::Library::Groups->get_search_groups( { interface => 'staff' } )->as_list;
 235
 236 $template->param(
 237     search_groups    => \@search_groups,
 238 );
 239
 240 # load the Type stuff
 241 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 242 my $advancedsearchesloop = prepare_adv_search_types($types);
 243 $template->param(advancedsearchesloop => $advancedsearchesloop);
 244
 245 $template->param( searchid => scalar $cgi->param('searchid'), );
 246
 247 # The following should only be loaded if we're bringing up the advanced search template
 248 if ( $template_type eq 'advsearch' ) {
 249
 250     # load the servers (used for searching -- to do federated searching, etc.)
 251     my $primary_servers_loop;# = displayPrimaryServers();
 252     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 253
 254     my $secondary_servers_loop;
 255     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 256
 257     # set the default sorting
 258     if (   C4::Context->preference('defaultSortField')
 259         && C4::Context->preference('defaultSortOrder') ) {
 260         my $default_sort_by =
 261             C4::Context->preference('defaultSortField') . '_'
 262           . C4::Context->preference('defaultSortOrder');
 263         $template->param( sort_by => $default_sort_by  );
 264     }
 265
 266     # determine what to display next to the search boxes (ie, boolean option
 267     # shouldn't appear on the first one, scan indexes should, adding a new
 268     # box should only appear on the last, etc.
 269     my @search_boxes_array;
 270     my $search_boxes_count = 3; # begin with 3 boxes
 271     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 272     for (my $i=1;$i<=$search_boxes_count;$i++) {
 273         # if it's the first one, don't display boolean option, but show scan indexes
 274         if ($i==1) {
 275             push @search_boxes_array, {scan_index => 1};
 276         }
 277         # if it's the last one, show the 'add field' box
 278         elsif ($i==$search_boxes_count) {
 279             push @search_boxes_array,
 280                 {
 281                 boolean => 1,
 282                 add_field => 1,
 283                 };
 284         }
 285         else {
 286             push @search_boxes_array,
 287                 {
 288                 boolean => 1,
 289                 };
 290         }
 291
 292     }
 293     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 294                       search_boxes_loop => \@search_boxes_array);
 295
 296     # load the language limits (for search)
 297     my $languages_limit_loop = getLanguages($lang, 1);
 298     $template->param(search_languages_loop => $languages_limit_loop,);
 299
 300     # Expanded search options in advanced search:
 301     # use the global setting by default, but let the user override it
 302     {
 303         my $expanded = $cgi->param('expanded_options');
 304         $expanded = C4::Context->preference("expandedSearchOption") || 0
 305             if !defined($expanded) || $expanded !~ /^0|1$/;
 306         $template->param( expanded_options => $expanded );
 307     }
 308
 309     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 310
 311     output_html_with_http_headers $cgi, $cookie, $template->output;
 312     exit;
 313 }
 314
 315 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 316
 317 # Fetch the paramater list as a hash in scalar context:
 318 #  * returns paramater list as tied hash ref
 319 #  * we can edit the values by changing the key
 320 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 321 my $params = $cgi->Vars;
 322 # Params that can have more than one value
 323 # sort by is used to sort the query
 324 # in theory can have more than one but generally there's just one
 325 my @sort_by;
 326 my $default_sort_by;
 327 if (   C4::Context->preference('defaultSortField')
 328     && C4::Context->preference('defaultSortOrder') ) {
 329     $default_sort_by =
 330         C4::Context->preference('defaultSortField') . '_'
 331       . C4::Context->preference('defaultSortOrder');
 332 }
 333
 334 @sort_by = $cgi->multi_param('sort_by');
 335 $sort_by[0] = $default_sort_by unless $sort_by[0];
 336 foreach my $sort (@sort_by) {
 337     $template->param($sort => 1) if $sort;
 338 }
 339 $template->param('sort_by' => $sort_by[0]);
 340
 341 # Use the servers defined, or just search our local catalog(default)
 342 my @servers = $cgi->multi_param('server');
 343 unless (@servers) {
 344     #FIXME: this should be handled using Context.pm
 345     @servers = ("biblioserver");
 346     # @servers = C4::Context->config("biblioserver");
 347 }
 348 # operators include boolean and proximity operators and are used
 349 # to evaluate multiple operands
 350 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 351
 352 # indexes are query qualifiers, like 'title', 'author', etc. They
 353 # can be single or multiple parameters separated by comma: kw,right-Truncation
 354 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 355
 356 # if a simple index (only one)  display the index used in the top search box
 357 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 358     my $idx = "ms_".$indexes[0];
 359     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 360     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 361     $template->param($idx => 1);
 362 }
 363
 364 # an operand can be a single term, a phrase, or a complete ccl query
 365 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 366
 367 # if a simple search, display the value in the search box
 368 my $basic_search = 0;
 369 if ($operands[0] && !$operands[1]) {
 370     my $ms_query = $operands[0];
 371     $ms_query =~ s/ #\S+//;
 372     $template->param(ms_value => $ms_query);
 373     $basic_search=1;
 374 }
 375
 376 # limits are use to limit to results to a pre-defined category such as branch or language
 377 my @limits = map uri_unescape($_), $cgi->multi_param('limit');
 378 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 379 my %is_nolimit = map { $_ => 1 } @nolimits;
 380 @limits = grep { not $is_nolimit{$_} } @limits;
 381
 382 my $available;
 383 foreach my $limit(@limits) {
 384     if ($limit =~/available/) {
 385         $available = 1;
 386     }
 387 }
 388 $template->param(available => $available);
 389
 390 # append year limits if they exist
 391 my $limit_yr;
 392 my $limit_yr_value;
 393 if ($params->{'limit-yr'}) {
 394     if ($params->{'limit-yr'} =~ /\d{4}/) {
 395         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 396         $limit_yr_value = $params->{'limit-yr'};
 397     }
 398     push @limits,$limit_yr;
 399     #FIXME: Should return a error to the user, incorect date format specified
 400 }
 401
 402 # convert indexes and operands to corresponding parameter names for the z3950 search
 403 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 404 my $z3950par;
 405 my $indexes2z3950 = {
 406     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 407     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 408     ti=>'title', 'ti,phr'=>'title', se=>'title'
 409 };
 410 for (my $ii = 0; $ii < @operands; ++$ii)
 411 {
 412     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 413     if (defined $name && defined $operands[$ii])
 414     {
 415         $z3950par ||= {};
 416         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 417     }
 418 }
 419
 420
 421 # Params that can only have one value
 422 my $scan = $params->{'scan'};
 423 my $count = C4::Context->preference('numSearchResults') || 20;
 424 my $results_per_page = $params->{'count'} || $count;
 425 my $offset = $params->{'offset'} || 0;
 426 my $whole_record = $params->{'whole_record'} || 0;
 427 my $weight_search = $params->{'advsearch'} ? $params->{'weight_search'} || 0 : 1;
 428 $offset = 0 if $offset < 0;
 429 my $page = $cgi->param('page') || 1;
 430 #my $offset = ($page-1)*$results_per_page;
 431
 432 # Define some global variables
 433 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 434
 435 my $builder = Koha::SearchEngine::QueryBuilder->new(
 436     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 437 my $searcher = Koha::SearchEngine::Search->new(
 438     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 439
 440 ## I. BUILD THE QUERY
 441 (
 442     $error,             $query, $simple_query, $query_cgi,
 443     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 444     $query_type
 445   )
 446   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 447     \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 448
 449 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 450
 451 ## parse the query_cgi string and put it into a form suitable for <input>s
 452 my @query_inputs;
 453 my $scan_index_to_use;
 454 my $scan_search_term_to_use;
 455
 456 if ($query_cgi) {
 457     for my $this_cgi ( split('&', $query_cgi) ) {
 458         next unless $this_cgi;
 459         $this_cgi =~ m/(.*?)=(.*)/;
 460         my $input_name = $1;
 461         my $input_value = $2;
 462         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 463         if ($input_name eq 'idx') {
 464             # The form contains multiple fields, so take the first value as the scan index
 465             $scan_index_to_use = $input_value unless $scan_index_to_use;
 466         }
 467         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 468             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 469         }
 470     }
 471 }
 472
 473 $template->param ( QUERY_INPUTS => \@query_inputs,
 474                    scan_index_to_use => $scan_index_to_use,
 475                    scan_search_term_to_use => $scan_search_term_to_use );
 476
 477 ## parse the limit_cgi string and put it into a form suitable for <input>s
 478 my @limit_inputs;
 479 if ($limit_cgi) {
 480     for my $this_cgi ( split('&', $limit_cgi) ) {
 481         next unless $this_cgi;
 482         # handle special case limit-yr
 483         if ($this_cgi =~ /yr,st-numeric/) {
 484             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 485             next;
 486         }
 487         $this_cgi =~ m/(.*=)(.*)/;
 488         my $input_name = $1;
 489         my $input_value = $2;
 490         $input_name =~ s/=$//;
 491         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 492     }
 493 }
 494 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 495
 496 ## II. DO THE SEARCH AND GET THE RESULTS
 497 my $total = 0; # the total results for the whole set
 498 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 499 my $results_hashref;
 500
 501 eval {
 502     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 503     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 504         $query,            $simple_query, \@sort_by,       \@servers,
 505         $results_per_page, $offset,       undef,           $itemtypes,
 506         $query_type,       $scan
 507     );
 508 };
 509
 510 if ($@ || $error) {
 511     my $query_error = q{};
 512     $query_error .= $error if $error;
 513     $query_error .= $@ if $@;
 514     $template->param(query_error => $query_error);
 515     output_html_with_http_headers $cgi, $cookie, $template->output;
 516     exit;
 517 }
 518
 519 # At this point, each server has given us a result set
 520 # now we build that set for template display
 521 my @sup_results_array;
 522 for (my $i=0;$i<@servers;$i++) {
 523     my $server = $servers[$i];
 524     if ($server =~/biblioserver/) { # this is the local bibliographic server
 525         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 526         if ( $hits == 0 && $basic_search ){
 527             $operands[0] = '"'.$operands[0].'"'; #quote it
 528             ## I. BUILD THE QUERY
 529             (
 530                 $error,             $query, $simple_query, $query_cgi,
 531                 $query_desc,        $limit, $limit_cgi,    $limit_desc,
 532                 $query_type
 533               )
 534               = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 535                 \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 536             my $quoted_results_hashref;
 537             eval {
 538                 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 539                 ( $error, $quoted_results_hashref, $facets ) = $searcher->search_compat(
 540                     $query,            $simple_query, \@sort_by,       ['biblioserver'],
 541                     $results_per_page, $offset,       undef,           $itemtypes,
 542                     $query_type,       $scan
 543                 );
 544             };
 545             my $quoted_hits = $quoted_results_hashref->{$server}->{"hits"} // 0;
 546             if ( $quoted_hits ){
 547                 $results_hashref->{'biblioserver'} = $quoted_results_hashref->{'biblioserver'};
 548                 $hits = $quoted_hits;
 549             }
 550         }
 551         my $page = $cgi->param('page') || 0;
 552         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 553                                        $results_hashref->{$server}->{"RECORDS"});
 554         $total = $total + $hits;
 555
 556         # Search history
 557         if (C4::Context->preference('EnableSearchHistory')) {
 558             unless ( $offset ) {
 559                 my $path_info = $cgi->url(-path_info=>1);
 560                 my $query_cgi_history = $cgi->url(-query=>1);
 561                 $query_cgi_history =~ s/^$path_info\?//;
 562                 $query_cgi_history =~ s/;/&/g;
 563                 my $query_desc_history = $query_desc;
 564                 $query_desc_history .= ", $limit_desc"
 565                     if $limit_desc;
 566
 567                 C4::Search::History::add({
 568                     userid => $borrowernumber,
 569                     sessionid => $cgi->cookie("CGISESSID"),
 570                     query_desc => $query_desc_history,
 571                     query_cgi => $query_cgi_history,
 572                     total => $total,
 573                     type => "biblio",
 574                 });
 575             }
 576             $template->param( EnableSearchHistory => 1 );
 577         }
 578
 579         ## If there's just one result, redirect to the detail page unless doing an index scan
 580         if ($total == 1 && !$scan) {
 581             my $biblionumber = $newresults[0]->{biblionumber};
 582             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 583             my $views = { C4::Search::enabled_staff_search_views };
 584             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 585                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&found1=1");
 586             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 587                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&found1=1");
 588             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 589                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&found1=1");
 590             } else {
 591                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&found1=1");
 592             }
 593             exit;
 594         }
 595
 596         # set up parameters if user wishes to re-run the search
 597         # as a Z39.50 search
 598         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 599
 600         if ($hits) {
 601             $template->param(total => $hits);
 602             if ($limit_cgi) {
 603                 my $limit_cgi_not_availablity = $limit_cgi;
 604                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 605                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 606             }
 607             $template->param(limit_cgi => $limit_cgi);
 608             $template->param(query_cgi => $query_cgi);
 609             $template->param(query_desc => $query_desc);
 610             $template->param(limit_desc => $limit_desc);
 611             $template->param(offset     => $offset);
 612             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 613             if ($query_desc || $limit_desc) {
 614                 $template->param(searchdesc => 1);
 615             }
 616             $template->param(results_per_page =>  $results_per_page);
 617             # must define a value for size if not present in DB
 618             # in order to avoid problems generated by the default size value in TT
 619             foreach my $line (@newresults) {
 620                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 621                 # while we're checking each line, see if item is in the cart
 622                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 623                     $line->{'incart'} = 1;
 624                 }
 625             }
 626             my( $page_numbers, $hits_to_paginate, $pages, $current_page_number, $previous_page_offset, $next_page_offset, $last_page_offset ) =
 627                 Koha::SearchEngine::Search->pagination_bar(
 628                     {
 629                         hits              => $hits,
 630                         max_result_window => $searcher->max_result_window,
 631                         results_per_page  => $results_per_page,
 632                         offset            => $offset,
 633                         sort_by           => \@sort_by
 634                     }
 635                 );
 636             $template->param( hits_to_paginate => $hits_to_paginate );
 637             $template->param(SEARCH_RESULTS => \@newresults);
 638             # FIXME: no previous_page_offset when pages < 2
 639             $template->param(   PAGE_NUMBERS => $page_numbers,
 640                                 last_page_offset => $last_page_offset,
 641                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 642             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 643         }
 644
 645
 646         # no hits
 647         else {
 648             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 649         }
 650
 651     } # end of the if local
 652
 653     # asynchronously search the authority server
 654     elsif ($server =~/authorityserver/) { # this is the local authority server
 655         my @inner_sup_results_array;
 656         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 657             my $marc_record_object = C4::Search::new_record_from_zebra(
 658                 'authorityserver',
 659                 $sup_record
 660             );
 661             # warn "Authority Found: ".$marc_record_object->as_formatted();
 662             push @inner_sup_results_array, {
 663                 'title' => $marc_record_object->field(100)->subfield('a'),
 664                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 665             };
 666         }
 667         push @sup_results_array, {  servername => $server,
 668                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 669     }
 670     # FIXME: can add support for other targets as needed here
 671     $template->param(           outer_sup_results_loop => \@sup_results_array);
 672 } #/end of the for loop
 673 #$template->param(FEDERATED_RESULTS => \@results_array);
 674
 675 my $gotonumber = $cgi->param('gotoNumber');
 676 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 677     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 678 }
 679 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 680 my $gotopage = $cgi->param('gotoPage');
 681 $template->{'VARS'}->{'gotoPage'} = $gotopage
 682   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 683
 684 for my $facet ( @$facets ) {
 685     for my $entry ( @{ $facet->{facets} } ) {
 686         my $index = $entry->{type_link_value};
 687         my $value = $entry->{facet_link_value};
 688         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 689     }
 690 }
 691
 692 $template->param(
 693             #classlist => $classlist,
 694             total => $total,
 695             opacfacets => 1,
 696             facets_loop => $facets,
 697             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 698             scan => $scan,
 699             search_error => $error,
 700 );
 701
 702 if ($query_desc || $limit_desc) {
 703     $template->param(searchdesc => 1);
 704 }
 705
 706 # VI. BUILD THE TEMPLATE
 707
 708 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 709     {
 710         borrowernumber => $borrowernumber,
 711         add_allowed    => 1,
 712         public         => 0,
 713     }
 714 );
 715 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 716     {
 717         borrowernumber => $borrowernumber,
 718         add_allowed    => 1,
 719         public         => 1,
 720     }
 721 );
 722
 723
 724 $template->param(
 725     add_to_some_private_shelves => $some_private_shelves,
 726     add_to_some_public_shelves  => $some_public_shelves,
 727 );
 728
 729 output_html_with_http_headers $cgi, $cookie, $template->output;
 730
 731
 732 =head2 prepare_adv_search_types
 733
 734     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 735     my @advanced_search_types = prepare_adv_search_types($type);
 736
 737 Different types can be searched for in the advanced search. This takes the
 738 system preference that defines these types and parses it into an arrayref for
 739 the template.
 740
 741 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 742 It also accounts for the "item-level_itypes" system preference.
 743
 744 =cut
 745
 746 sub prepare_adv_search_types {
 747     my ($types) = @_;
 748
 749     my @advanced_search_types = split( /\|/, $types );
 750
 751     # the index parameter is different for item-level itemtypes
 752     my $itype_or_itemtype =
 753       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 754     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 755
 756     my ( $cnt, @result );
 757     foreach my $advanced_srch_type (@advanced_search_types) {
 758         $advanced_srch_type =~ s/^\s*//;
 759         $advanced_srch_type =~ s/\s*$//;
 760         if ( $advanced_srch_type eq 'itemtypes' ) {
 761
 762        # itemtype is a special case, since it's not defined in authorized values
 763             my @itypesloop;
 764             foreach my $thisitemtype (
 765                 sort {
 766                     $itemtypes->{$a}->{'translated_description'}
 767                       cmp $itemtypes->{$b}->{'translated_description'}
 768                 } keys %$itemtypes
 769               )
 770             {
 771                 my %row = (
 772                     number      => $cnt++,
 773                     ccl         => "$itype_or_itemtype,phr",
 774                     code        => $thisitemtype,
 775                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 776                     imageurl    => getitemtypeimagelocation(
 777                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 778                     ),
 779                 );
 780                 push @itypesloop, \%row;
 781             }
 782             my %search_code = (
 783                 advanced_search_type => $advanced_srch_type,
 784                 code_loop            => \@itypesloop
 785             );
 786             push @result, \%search_code;
 787         }
 788         else {
 789             # covers all the other cases: non-itemtype authorized values
 790             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 791             my @authvalueloop;
 792             for my $thisitemtype (@$advsearchtypes) {
 793                 my %row = (
 794                     number      => $cnt++,
 795                     ccl         => $advanced_srch_type,
 796                     code        => $thisitemtype->{authorised_value},
 797                     description => $thisitemtype->{'lib'},
 798                     imageurl    => getitemtypeimagelocation(
 799                         'intranet', $thisitemtype->{'imageurl'}
 800                     ),
 801                 );
 802                 push @authvalueloop, \%row;
 803             }
 804             my %search_code = (
 805                 advanced_search_type => $advanced_srch_type,
 806                 code_loop            => \@authvalueloop
 807             );
 808             push @result, \%search_code;
 809         }
 810     }
 811     return \@result;
 812 }