circ/circulation.pl

   1 #!/usr/bin/perl
   2
   3 # script to execute issuing of books
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # copyright 2010 BibLibre
   7 # Copyright 2011 PTFS-Europe Ltd.
   8 # Copyright 2012 software.coop and MJ Ray
   9 #
  10 # This file is part of Koha.
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 # FIXME There are too many calls to Koha::Patrons->find in this script
  26
  27 use Modern::Perl;
  28 use CGI qw ( -utf8 );
  29 use URI::Escape qw( uri_escape_utf8 );
  30 use DateTime;
  31 use DateTime::Duration;
  32 use Scalar::Util qw( looks_like_number );
  33 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  34 use C4::Auth qw( get_session get_template_and_user );
  35 use C4::Koha;
  36 use C4::Circulation qw( barcodedecode CanBookBeIssued AddIssue );
  37 use C4::Members;
  38 use C4::Biblio qw( TransformMarcToKoha );
  39 use C4::Search qw( new_record_from_zebra );
  40 use C4::Reserves;
  41 use Koha::Holds;
  42 use C4::Context;
  43 use CGI::Session;
  44 use Koha::AuthorisedValues;
  45 use Koha::CsvProfiles;
  46 use Koha::Patrons;
  47 use Koha::Patron::Debarments qw( GetDebarments );
  48 use Koha::DateUtils qw( dt_from_string output_pref );
  49 use Koha::Plugins;
  50 use Koha::Database;
  51 use Koha::BiblioFrameworks;
  52 use Koha::Items;
  53 use Koha::SearchEngine;
  54 use Koha::SearchEngine::Search;
  55 use Koha::Patron::Modifications;
  56 use Koha::Token;
  57
  58 use List::MoreUtils qw( uniq );
  59
  60 #
  61 # PARAMETERS READING
  62 #
  63 my $query = CGI->new;
  64
  65 my $override_high_holds     = $query->param('override_high_holds');
  66 my $override_high_holds_tmp = $query->param('override_high_holds_tmp');
  67
  68 my $sessionID = $query->cookie("CGISESSID") ;
  69 my $session = get_session($sessionID);
  70
  71 my $barcodes = [];
  72 my $barcode =  $query->param('barcode');
  73 my $findborrower;
  74 my $autoswitched;
  75 my $borrowernumber = $query->param('borrowernumber');
  76
  77 if (C4::Context->preference("AutoSwitchPatron") && $barcode) {
  78     my $new_barcode = $barcode;
  79     Koha::Plugins->call( 'patron_barcode_transform', \$new_barcode );
  80     if (Koha::Patrons->search( { cardnumber => $new_barcode} )->count() > 0) {
  81         $findborrower = $barcode;
  82         undef $barcode;
  83         undef $borrowernumber;
  84         $autoswitched = 1;
  85     }
  86 }
  87 $findborrower ||= $query->param('findborrower') || q{};
  88 $findborrower =~ s|,| |g;
  89
  90 # Barcode given by user could be '0'
  91 if ( $barcode || ( defined($barcode) && $barcode eq '0' ) ) {
  92     $barcodes = [ $barcode ];
  93 } else {
  94     my $filefh = $query->upload('uploadfile');
  95     if ( $filefh ) {
  96         while ( my $content = <$filefh> ) {
  97             $content =~ s/[\r\n]*$//g;
  98             push @$barcodes, $content if $content;
  99         }
 100     } elsif ( my $list = $query->param('barcodelist') ) {
 101         push @$barcodes, split( /\s\n/, $list );
 102         $barcodes = [ map { $_ =~ /^\s*$/ ? () : $_ } @$barcodes ];
 103     } else {
 104         @$barcodes = $query->multi_param('barcodes');
 105     }
 106 }
 107
 108 $barcodes = [ uniq @$barcodes ];
 109
 110 my $template_name = q|circ/circulation.tt|;
 111 my $patron = $borrowernumber ? Koha::Patrons->find( $borrowernumber ) : undef;
 112 my $batch = $query->param('batch');
 113 my $batch_allowed = 0;
 114 if ( $batch && C4::Context->preference('BatchCheckouts') ) {
 115     $template_name = q|circ/circulation_batch_checkouts.tt|;
 116     my @batch_category_codes = split ',', C4::Context->preference('BatchCheckoutsValidCategories');
 117     my $categorycode = $patron->categorycode;
 118     if ( $categorycode && grep { $_ eq $categorycode } @batch_category_codes ) {
 119         $batch_allowed = 1;
 120     } else {
 121         $barcodes = [];
 122     }
 123 }
 124
 125 my ( $template, $loggedinuser, $cookie ) = get_template_and_user (
 126     {
 127         template_name   => $template_name,
 128         query           => $query,
 129         type            => "intranet",
 130         flagsrequired   => { circulate => 'circulate_remaining_permissions' },
 131     }
 132 );
 133 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
 134
 135 my $force_allow_issue = $query->param('forceallow') || 0;
 136 if (!C4::Auth::haspermission( C4::Context->userenv->{id} , { circulate => 'force_checkout' } )) {
 137     $force_allow_issue = 0;
 138 }
 139 my $onsite_checkout = $query->param('onsite_checkout');
 140
 141 if (C4::Context->preference("OnSiteCheckoutAutoCheck") && $onsite_checkout eq "on") {
 142     $template->param(onsite_checkout => $onsite_checkout);
 143 }
 144
 145 my @failedrenews = $query->multi_param('failedrenew');    # expected to be itemnumbers
 146 our %renew_failed = ();
 147 for (@failedrenews) { $renew_failed{$_} = 1; }
 148
 149 my @failedreturns = $query->multi_param('failedreturn');
 150 our %return_failed = ();
 151 for (@failedreturns) { $return_failed{$_} = 1; }
 152
 153 my $searchtype = $query->param('searchtype') || q{contain};
 154
 155 my $branch = C4::Context->userenv->{'branch'};
 156
 157 if (C4::Context->preference("DisplayClearScreenButton")) {
 158     $template->param(DisplayClearScreenButton => 1);
 159 }
 160
 161 for my $barcode ( @$barcodes ) {
 162     $barcode = barcodedecode( $barcode ) if $barcode;
 163 }
 164
 165 my $stickyduedate  = $query->param('stickyduedate') || $session->param('stickyduedate');
 166 my $duedatespec    = $query->param('duedatespec')   || $session->param('stickyduedate');
 167 $duedatespec = eval { output_pref( { dt => dt_from_string( $duedatespec ), dateformat => 'iso' }); }
 168     if ( $duedatespec );
 169 my $restoreduedatespec  = $query->param('restoreduedatespec') || $duedatespec || $session->param('stickyduedate');
 170 if ( $restoreduedatespec && $restoreduedatespec eq "highholds_empty" ) {
 171     undef $restoreduedatespec;
 172 }
 173 my $issueconfirmed = $query->param('issueconfirmed');
 174 my $cancelreserve  = $query->param('cancelreserve');
 175 my $cancel_recall  = $query->param('cancel_recall');
 176 my $recall_id      = $query->param('recall_id');
 177 my $debt_confirmed = $query->param('debt_confirmed') || 0; # Don't show the debt error dialog twice
 178 my $charges        = $query->param('charges') || q{};
 179
 180 # Check if stickyduedate is turned off
 181 if ( @$barcodes ) {
 182     # was stickyduedate loaded from session?
 183     if ( $stickyduedate && ! $query->param("stickyduedate") ) {
 184         $session->clear( 'stickyduedate' );
 185         $stickyduedate  = $query->param('stickyduedate');
 186         $duedatespec    = $query->param('duedatespec');
 187     }
 188     $session->param('auto_renew', scalar $query->param('auto_renew'));
 189 }
 190 else {
 191     $session->clear('auto_renew');
 192 }
 193
 194 $template->param( auto_renew => $session->param('auto_renew') );
 195
 196 my ($datedue,$invalidduedate);
 197
 198 my $duedatespec_allow = C4::Context->preference('SpecifyDueDate');
 199 if( $onsite_checkout && !$duedatespec_allow ) {
 200     $datedue = output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 201     $datedue .= ' 23:59:00';
 202 } elsif( $duedatespec_allow ) {
 203     if ( $duedatespec ) {
 204         $datedue = eval { dt_from_string( $duedatespec ) };
 205         if (! $datedue ) {
 206             $invalidduedate = 1;
 207             $template->param( IMPOSSIBLE=>1, INVALID_DATE=>$duedatespec );
 208         }
 209     }
 210 }
 211
 212 my $inprocess = (@$barcodes == 0) ? '' : $query->param('inprocess');
 213 if ( @$barcodes == 0 && $charges eq 'yes' ) {
 214     $template->param(
 215         PAYCHARGES     => 'yes',
 216         borrowernumber => $borrowernumber
 217     );
 218 }
 219
 220 #
 221 # STEP 2 : FIND BORROWER
 222 # if there is a list of find borrowers....
 223 #
 224 my $message;
 225 if ($findborrower) {
 226     Koha::Plugins->call( 'patron_barcode_transform', \$findborrower );
 227     my $patron = Koha::Patrons->find( { cardnumber => $findborrower } );
 228     if ( $patron ) {
 229         $borrowernumber = $patron->borrowernumber;
 230     } else {
 231         print $query->redirect( "/cgi-bin/koha/members/member.pl?quicksearch=1&circsearch=1&searchmember=" . uri_escape_utf8($findborrower) );
 232         exit;
 233     }
 234 }
 235
 236 # get the borrower information.....
 237 my $balance = 0;
 238 $patron ||= Koha::Patrons->find( $borrowernumber ) if $borrowernumber;
 239 if ($patron) {
 240
 241     $template->param( borrowernumber => $patron->borrowernumber );
 242     output_and_exit_if_error( $query, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
 243
 244     my $overdues = $patron->get_overdues;
 245     my $issues = $patron->checkouts;
 246     $balance = $patron->account->balance;
 247
 248
 249     # if the expiry date is before today ie they have expired
 250     if ( $patron->is_expired ) {
 251         #borrowercard expired, no issues
 252         $template->param(
 253             noissues => ($force_allow_issue) ? 0 : "1",
 254             forceallow => $force_allow_issue,
 255             expired => "1",
 256         );
 257     }
 258     # check for NotifyBorrowerDeparture
 259     elsif ( $patron->is_going_to_expire ) {
 260         # borrower card soon to expire warn librarian
 261         $template->param( "warndeparture" => $patron->dateexpiry ,
 262                         );
 263         if (C4::Context->preference('ReturnBeforeExpiry')){
 264             $template->param("returnbeforeexpiry" => 1);
 265         }
 266     }
 267     $template->param(
 268         overduecount => $overdues->count,
 269         issuecount   => $issues->count,
 270         finetotal    => $balance,
 271     );
 272
 273     if ( $patron and $patron->is_debarred ) {
 274         $template->param(
 275             'userdebarred'    => $patron->debarred,
 276             'debarredcomment' => $patron->debarredcomment,
 277         );
 278
 279         if ( $patron->debarred ne "9999-12-31" ) {
 280             $template->param( 'userdebarreddate' => $patron->debarred );
 281         }
 282     }
 283
 284     # Calculate and display patron's age
 285     if ( !$patron->is_valid_age ) {
 286         $template->param( age_limitations => 1 );
 287         $template->param( age_low => $patron->category->dateofbirthrequired );
 288         $template->param( age_high => $patron->category->upperagelimit );
 289     }
 290
 291 }
 292
 293 #
 294 # STEP 3 : ISSUING
 295 #
 296 #
 297 if (@$barcodes) {
 298   my $checkout_infos;
 299   for my $barcode ( @$barcodes ) {
 300
 301     my $template_params = {
 302         barcode         => $barcode,
 303         onsite_checkout => $onsite_checkout,
 304     };
 305
 306     # always check for blockers on issuing
 307     my ( $error, $question, $alerts, $messages ) = CanBookBeIssued(
 308         $patron,
 309         $barcode, $datedue,
 310         $inprocess,
 311         undef,
 312         {
 313             onsite_checkout     => $onsite_checkout,
 314             override_high_holds => $override_high_holds || $override_high_holds_tmp || 0,
 315         }
 316     );
 317
 318     my $blocker = $invalidduedate ? 1 : 0;
 319
 320     $template_params->{alert} = $alerts;
 321     $template_params->{messages} = $messages;
 322
 323     my $item = Koha::Items->find({ barcode => $barcode });
 324
 325     my $biblio;
 326     if ( $item ) {
 327         $biblio = $item->biblio;
 328     }
 329
 330     # Fix for bug 7494: optional checkout-time fallback search for a book
 331
 332     if ( $error->{'UNKNOWN_BARCODE'}
 333         && C4::Context->preference("itemBarcodeFallbackSearch")
 334         && not $batch
 335     )
 336     {
 337      $template_params->{FALLBACK} = 1;
 338
 339         my $searcher = Koha::SearchEngine::Search->new({index => $Koha::SearchEngine::BIBLIOS_INDEX});
 340         my $query = "kw=" . $barcode;
 341         my ( $searcherror, $results, $total_hits ) = $searcher->simple_search_compat($query, 0, 10);
 342
 343         # if multiple hits, offer options to librarian
 344         if ( $total_hits > 0 ) {
 345             my @barcodes;
 346             foreach my $hit ( @{$results} ) {
 347                 my $chosen = # Maybe easier to retrieve the itemnumber from $hit?
 348                   TransformMarcToKoha( C4::Search::new_record_from_zebra('biblioserver',$hit) );
 349
 350                 # offer all barcodes individually
 351                 if ( $chosen->{barcode} ) {
 352                     push @barcodes, sort split(/\s*\|\s*/, $chosen->{barcode});
 353                 }
 354             }
 355             my $items = Koha::Items->search({ barcode => {-in => \@barcodes}});
 356             $template_params->{options} = $items;
 357         }
 358     }
 359
 360     # Only some errors will block when performing forced onsite checkout,
 361     # for other cases all errors will block
 362     my @blocking_error_codes = ($onsite_checkout and C4::Context->preference("OnSiteCheckoutsForce")) ?
 363         qw( UNKNOWN_BARCODE ) : (keys %$error);
 364
 365     foreach my $code ( @blocking_error_codes ) {
 366         if ($error->{$code}) {
 367             $template_params->{$code} = $error->{$code};
 368             $template_params->{IMPOSSIBLE} = 1;
 369             $blocker = 1;
 370         }
 371     }
 372
 373     delete $question->{'DEBT'} if ($debt_confirmed);
 374
 375     if( $item and ( !$blocker or $force_allow_issue ) ){
 376         my $confirm_required = 0;
 377         unless($issueconfirmed){
 378             #  Get the item title for more information
 379             my $materials = $item->materials;
 380             my $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({ frameworkcode => $biblio->frameworkcode, kohafield => 'items.materials', authorised_value => $materials });
 381             $materials = $descriptions->{lib} // $materials;
 382             $template_params->{ADDITIONAL_MATERIALS} = $materials;
 383             $template_params->{itemhomebranch} = $item->homebranch;
 384
 385             # pass needsconfirmation to template if issuing is possible and user hasn't yet confirmed.
 386             foreach my $needsconfirmation ( keys %$question ) {
 387                 $template_params->{$needsconfirmation} = $$question{$needsconfirmation};
 388                 $template_params->{getTitleMessageIteminfo} = $biblio->title;
 389                 $template_params->{getBarcodeMessageIteminfo} = $item->barcode;
 390                 $template_params->{NEEDSCONFIRMATION} = 1;
 391                 $confirm_required = 1;
 392             }
 393         }
 394         unless($confirm_required) {
 395             my $switch_onsite_checkout = exists $messages->{ONSITE_CHECKOUT_WILL_BE_SWITCHED};
 396             if ( C4::Context->preference('UseRecalls') && !$recall_id ) {
 397                 my $recall = Koha::Recalls->find(
 398                     {
 399                         biblio_id => $item->biblionumber,
 400                         item_id   => [ undef, $item->itemnumber ],
 401                         status    => [ 'requested', 'waiting' ],
 402                         completed => 0,
 403                         patron_id => $patron->borrowernumber,
 404                     }
 405                 );
 406                 $recall_id = ( $recall and $recall->id ) ? $recall->id : undef;
 407             }
 408             my $issue = AddIssue( $patron->unblessed, $barcode, $datedue, $cancelreserve, undef, undef, { onsite_checkout => $onsite_checkout, auto_renew => $session->param('auto_renew'), switch_onsite_checkout => $switch_onsite_checkout, cancel_recall => $cancel_recall, recall_id => $recall_id, } );
 409             $template_params->{issue} = $issue;
 410             $session->clear('auto_renew');
 411             $inprocess = 1;
 412         }
 413     }
 414
 415     if ($question->{RESERVE_WAITING} or $question->{RESERVED} or $question->{TRANSFERRED} or $question->{PROCESSING}){
 416         $template->param(
 417             reserveborrowernumber => $question->{'resborrowernumber'},
 418             reserve_id => $question->{reserve_id},
 419         );
 420     }
 421
 422
 423     # FIXME If the issue is confirmed, we launch another time checkouts->count, now display the issue count after issue
 424     $patron = Koha::Patrons->find( $borrowernumber );
 425     $template_params->{issuecount} = $patron->checkouts->count;
 426
 427     if ( $item ) {
 428         $template_params->{item} = $item;
 429         $template_params->{biblio} = $biblio;
 430         $template_params->{itembiblionumber} = $biblio->biblionumber;
 431     }
 432     push @$checkout_infos, $template_params;
 433   }
 434   unless ( $batch ) {
 435     $template->param( %{$checkout_infos->[0]} );
 436     $template->param( barcode => $barcodes->[0] );
 437   } else {
 438     my $confirmation_needed = grep { $_->{NEEDSCONFIRMATION} } @$checkout_infos;
 439     $template->param(
 440         checkout_infos => $checkout_infos,
 441         confirmation_needed => $confirmation_needed,
 442     );
 443   }
 444 }
 445
 446 ##################################################################################
 447 # BUILD HTML
 448 # show all reserves of this borrower, and the position of the reservation ....
 449 if ($patron) {
 450     my $holds = Koha::Holds->search( { borrowernumber => $borrowernumber } ); # FIXME must be Koha::Patron->holds
 451     my $waiting_holds = $holds->waiting;
 452     $template->param(
 453         holds_count  => $holds->count(),
 454         WaitingHolds => $waiting_holds,
 455     );
 456
 457     if ( C4::Context->preference('UseRecalls') ) {
 458         my $waiting_recalls = $patron->recalls->search({ status => 'waiting' });
 459         $template->param(
 460             recalls => $patron->recalls->filter_by_current->search({},{ order_by => { -asc => 'created_date' } }),
 461             specific_patron => 1,
 462             waiting_recalls => $waiting_recalls,
 463         );
 464     }
 465 }
 466
 467 if ( $patron ) {
 468     my $noissues;
 469     if ( $patron->gonenoaddress ) {
 470         $template->param( gonenoaddress => 1 );
 471         $noissues = 1;
 472     }
 473     if ( $patron->lost ) {
 474         $template->param( lost=> 1 );
 475         $noissues = 1;
 476     }
 477     if ( $patron->is_debarred ) {
 478         $template->param( is_debarred=> 1 );
 479         $noissues = 1;
 480     }
 481     my $account = $patron->account;
 482     if( ( my $owing = $account->non_issues_charges ) > 0 ) {
 483         my $noissuescharge = C4::Context->preference("noissuescharge") || 5; # FIXME If noissuescharge == 0 then 5, why??
 484         $noissues ||= ( not C4::Context->preference("AllowFineOverride") and ( $owing > $noissuescharge ) );
 485         $template->param(
 486             charges => 1,
 487             chargesamount => $owing,
 488         )
 489     } elsif ( $balance < 0 ) {
 490         $template->param(
 491             credits => 1,
 492             creditsamount => -$balance,
 493         );
 494     }
 495
 496     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 497     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 498     if ( $no_issues_charge_guarantors ) {
 499         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 500
 501         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors ) {
 502             $template->param(
 503                 charges_guarantors_guarantees => $guarantors_non_issues_charges
 504             );
 505             $noissues = 1 unless C4::Context->preference("allowfineoverride");
 506         }
 507     }
 508
 509     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 510     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 511     if ( defined $no_issues_charge_guarantees ) {
 512         my $guarantees_non_issues_charges = 0;
 513         my $guarantees = $patron->guarantee_relationships->guarantees;
 514         while ( my $g = $guarantees->next ) {
 515             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 516         }
 517         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees ) {
 518             $template->param(
 519                 charges_guarantees    => 1,
 520                 chargesamount_guarantees => $guarantees_non_issues_charges,
 521             );
 522             $noissues = 1 unless C4::Context->preference("allowfineoverride");
 523         }
 524     }
 525
 526     if ( $patron->has_overdues ) {
 527         $template->param( odues => 1 );
 528     }
 529
 530     if ( $patron->borrowernotes ) {
 531         my $borrowernotes = $patron->borrowernotes;
 532         $borrowernotes =~ s#\n#<br />#g;
 533         $template->param(
 534             notes =>1,
 535             notesmsg => $borrowernotes,
 536         )
 537     }
 538
 539     if ( $noissues ) {
 540         $template->param(
 541             noissues => ($force_allow_issue) ? 0 : 'true',
 542             forceallow => $force_allow_issue,
 543         );
 544     }
 545
 546     my $patron_messages = $patron->messages->search(
 547         {},
 548         {
 549            join => 'manager',
 550            '+select' => ['manager.surname', 'manager.firstname' ],
 551            '+as' => ['manager_surname', 'manager_firstname'],
 552         }
 553     );
 554     $template->param( patron_messages => $patron_messages );
 555
 556 }
 557
 558 my $fast_cataloging = 0;
 559 if ( Koha::BiblioFrameworks->find('FA') ) {
 560     $fast_cataloging = 1
 561 }
 562
 563 my $view = $batch
 564     ?'batch_checkout_view'
 565     : 'circview';
 566
 567 my @relatives;
 568 if ( $patron ) {
 569     if ( my @guarantors = $patron->guarantor_relationships()->guarantors->as_list ) {
 570         push( @relatives, $_->id ) for @guarantors;
 571         push( @relatives, $_->id ) for $patron->siblings->as_list;
 572     } else {
 573         push( @relatives, $_->id ) for $patron->guarantee_relationships()->guarantees->as_list;
 574     }
 575 }
 576 my $relatives_issues_count =
 577   Koha::Database->new()->schema()->resultset('Issue')
 578   ->count( { borrowernumber => \@relatives } );
 579
 580 if ( $patron ) {
 581     my $av = Koha::AuthorisedValues->search({ category => 'ROADTYPE', authorised_value => $patron->streettype });
 582     my $roadtype = $av->count ? $av->next->lib : '';
 583     $template->param(
 584         roadtype          => $roadtype,
 585         patron            => $patron,
 586         categoryname      => $patron->category->description,
 587         expiry            => $patron->dateexpiry,
 588     );
 589 }
 590
 591 # Restore date if changed by holds and/or save stickyduedate to session
 592 if ($restoreduedatespec || $stickyduedate) {
 593     $duedatespec = $restoreduedatespec || $duedatespec;
 594
 595     if ($stickyduedate) {
 596         $session->param( 'stickyduedate', $duedatespec );
 597     }
 598 } elsif (defined($duedatespec) && !defined($restoreduedatespec)) {
 599     undef $duedatespec;
 600 }
 601
 602 $template->param(
 603     borrowernumber    => $borrowernumber,
 604     branch            => $branch,
 605     was_renewed       => scalar $query->param('was_renewed') ? 1 : 0,
 606     barcodes          => $barcodes,
 607     stickyduedate     => $stickyduedate,
 608     duedatespec       => $duedatespec,
 609     restoreduedatespec => $restoreduedatespec,
 610     message           => $message,
 611     totaldue          => sprintf('%.2f', $balance), # FIXME not used in template?
 612     inprocess         => $inprocess,
 613     $view             => 1,
 614     batch_allowed     => $batch_allowed,
 615     batch             => $batch,
 616     AudioAlerts           => C4::Context->preference("AudioAlerts"),
 617     fast_cataloging   => $fast_cataloging,
 618     CircAutoPrintQuickSlip   => C4::Context->preference("CircAutoPrintQuickSlip"),
 619     RoutingSerials => C4::Context->preference('RoutingSerials'),
 620     relatives_issues_count => $relatives_issues_count,
 621     relatives_borrowernumbers => \@relatives,
 622 );
 623
 624
 625 if ( C4::Context->preference("ExportCircHistory") ) {
 626     $template->param(csv_profiles => Koha::CsvProfiles->search({ type => 'marc' }));
 627 }
 628
 629 my $has_modifications = Koha::Patron::Modifications->search( { borrowernumber => $borrowernumber } )->count;
 630 $template->param(
 631     debt_confirmed            => $debt_confirmed,
 632     SpecifyDueDate            => $duedatespec_allow,
 633     PatronAutoComplete      => C4::Context->preference("PatronAutoComplete"),
 634     debarments                => scalar GetDebarments({ borrowernumber => $borrowernumber }),
 635     todaysdate                => output_pref( { dt => dt_from_string()->set(hour => 23)->set(minute => 59), dateformat => 'sql' } ),
 636     has_modifications         => $has_modifications,
 637     override_high_holds       => $override_high_holds,
 638     nopermission              => scalar $query->param('nopermission'),
 639     autoswitched              => $autoswitched,
 640     logged_in_user            => $logged_in_user,
 641 );
 642
 643 # Generate CSRF token for upload and delete image buttons
 644 $template->param(
 645     csrf_token => Koha::Token->new->generate_csrf({ session_id => $query->cookie('CGISESSID'),}),
 646 );
 647
 648 output_html_with_http_headers $query, $cookie, $template->output;