misc/cronjobs/advance_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 LibLime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 advance_notices.pl - cron script to put item due reminders into message queue
  23
  24 =head1 SYNOPSIS
  25
  26 ./advance_notices.pl -c
  27
  28 or, in crontab:
  29 0 1 * * * advance_notices.pl -c
  30
  31 =head1 DESCRIPTION
  32
  33 This script prepares pre-due and item due reminders to be sent to
  34 patrons. It queues them in the message queue, which is processed by
  35 the process_message_queue.pl cronjob. The type and timing of the
  36 messages can be configured by the patrons in their "My Alerts" tab in
  37 the OPAC.
  38
  39 =cut
  40
  41 use strict;
  42 use warnings;
  43 use Getopt::Long;
  44 use Pod::Usage;
  45 use Data::Dumper;
  46 BEGIN {
  47     # find Koha's Perl modules
  48     # test carefully before changing this
  49     use FindBin;
  50     eval { require "$FindBin::Bin/../kohalib.pl" };
  51 }
  52 use Koha::Script -cron;
  53 use C4::Biblio;
  54 use C4::Context;
  55 use C4::Letters;
  56 use C4::Members;
  57 use C4::Members::Messaging;
  58 use C4::Overdues;
  59 use Koha::DateUtils;
  60 use C4::Log;
  61 use Koha::Items;
  62 use Koha::Libraries;
  63 use Koha::Patrons;
  64
  65 =head1 NAME
  66
  67 advance_notices.pl - prepare messages to be sent to patrons for nearly due, or due, items
  68
  69 =head1 SYNOPSIS
  70
  71 advance_notices.pl
  72   [ -n ][ -m <number of days> ][ --itemscontent <comma separated field list> ][ -c ]
  73
  74 =head1 OPTIONS
  75
  76 =over 8
  77
  78 =item B<--help>
  79
  80 Print a brief help message and exits.
  81
  82 =item B<--man>
  83
  84 Prints the manual page and exits.
  85
  86 =item B<-v>
  87
  88 Verbose. Without this flag set, only fatal errors are reported.
  89
  90 =item B<-n>
  91
  92 Do not send any email. Advanced or due notices that would have been sent to
  93 the patrons are printed to standard out.
  94
  95 =item B<-m>
  96
  97 Defines the maximum number of days in advance to send advance notices.
  98
  99 =item B<-c>
 100
 101 Confirm flag: Add this option. The script will only print a usage
 102 statement otherwise.
 103
 104 =item B<--itemscontent>
 105
 106 comma separated list of fields that get substituted into templates in
 107 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 108 defaults to date_due,title,author,barcode
 109
 110 Other possible values come from fields in the biblios, items and
 111 issues tables.
 112
 113 =item B<--digest-per-branch>
 114
 115 Flag to indicate that generation of message digests should be
 116 performed separately for each branch.
 117
 118 A patron could potentially have loans at several different branches
 119 There is no natural branch to set as the sender on the aggregated
 120 message in this situation so the default behavior is to use the
 121 borrowers home branch.  This could surprise to the borrower when
 122 message sender is a library where they have not borrowed anything.
 123
 124 Enabling this flag ensures that the issuing library is the sender of
 125 the digested message.  It has no effect unless the borrower has
 126 chosen 'Digests only' on the advance messages.
 127
 128 =item B<-library>
 129
 130 select notices for one specific library. Use the value in the
 131 branches.branchcode table. This option can be repeated in order
 132 to select notices for a group of libraries.
 133
 134 =item B<--owning>
 135
 136 Use the address information from the item homebranch library instead of the issuing library.
 137
 138 =back
 139
 140 =head1 DESCRIPTION
 141
 142 This script is designed to alert patrons when items are due, or coming due
 143
 144 =head2 Configuration
 145
 146 This script pays attention to the advanced notice configuration
 147 performed by borrowers in the OPAC, or by staff in the patron detail page of the intranet. The content of the messages is configured in Tools -> Notices and slips. Advanced notices use the PREDUE template, due notices use DUE. More information about the use of this
 148 section of Koha is available in the Koha manual.
 149
 150 =head2 Outgoing emails
 151
 152 Typically, messages are prepared for each patron with due
 153 items, and who have selected (or the library has elected for them) Advance or Due notices.
 154
 155 These emails are staged in the outgoing message queue, as are messages
 156 produced by other features of Koha. This message queue must be
 157 processed regularly by the
 158 F<misc/cronjobs/process_message_queue.pl> program.
 159
 160 In the event that the C<-n> flag is passed to this program, no emails
 161 are sent. Instead, messages are sent on standard output from this
 162 program. They may be redirected to a file if desired.
 163
 164 =head2 Templates
 165
 166 Templates can contain variables enclosed in double angle brackets like
 167 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 168 specific to the overdue items or relevant patron. Available variables
 169 are:
 170
 171 =over
 172
 173 =item E<lt>E<lt>items.contentE<gt>E<gt>
 174
 175 one line for each item, each line containing a tab separated list of
 176 date due, title, author, barcode
 177
 178 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 179
 180 any field from the borrowers table
 181
 182 =item E<lt>E<lt>branches.*E<gt>E<gt>
 183
 184 any field from the branches table
 185
 186 =back
 187
 188 =head1 SEE ALSO
 189
 190 The F<misc/cronjobs/overdue_notices.pl> program allows you to send
 191 messages to patrons when their messages are overdue.
 192
 193 =cut
 194
 195 binmode( STDOUT, ':encoding(UTF-8)' );
 196
 197 # These are defaults for command line options.
 198 my $confirm;                                                        # -c: Confirm that the user has read and configured this script.
 199 my $nomail;                                                         # -n: No mail. Will not send any emails.
 200 my $mindays     = 0;                                                # -m: Maximum number of days in advance to send notices
 201 my $maxdays     = 30;                                               # -e: the End of the time period
 202 my $verbose     = 0;                                                # -v: verbose
 203 my $digest_per_branch = 0;                                          # -digest-per-branch: Prepare and send digests per branch
 204 my @branchcodes; # Branch(es) passed as parameter
 205 my $owning_library = 0;
 206 my $itemscontent = join(',',qw( date_due title author barcode ));
 207
 208 my $help    = 0;
 209 my $man     = 0;
 210
 211 GetOptions(
 212             'help|?'         => \$help,
 213             'man'            => \$man,
 214             'library=s'      => \@branchcodes,
 215             'owning'         => \$owning_library,
 216             'c'              => \$confirm,
 217             'n'              => \$nomail,
 218             'm:i'            => \$maxdays,
 219             'v'              => \$verbose,
 220             'digest-per-branch' => \$digest_per_branch,
 221             'itemscontent=s' => \$itemscontent,
 222        )or pod2usage(2);
 223 pod2usage(1) if $help;
 224 pod2usage( -verbose => 2 ) if $man;
 225
 226 # Since advance notice options are not visible in the web-interface
 227 # unless EnhancedMessagingPreferences is on, let the user know that
 228 # this script probably isn't going to do much
 229 if ( ! C4::Context->preference('EnhancedMessagingPreferences') ) {
 230     warn <<'END_WARN';
 231
 232 The "EnhancedMessagingPreferences" syspref is off.
 233 Therefore, it is unlikely that this script will actually produce any messages to be sent.
 234 To change this, edit the "EnhancedMessagingPreferences" syspref.
 235
 236 END_WARN
 237 }
 238 unless ($confirm) {
 239      pod2usage(1);
 240 }
 241 cronlogaction();
 242
 243 my %branches = map { $_ => 1 } @branchcodes if @branchcodes;
 244
 245 # The fields that will be substituted into <<items.content>>
 246 my @item_content_fields = split(/,/,$itemscontent);
 247
 248 warn 'getting upcoming due issues' if $verbose;
 249 my $upcoming_dues = C4::Circulation::GetUpcomingDueIssues( {
 250     days_in_advance => $maxdays,
 251     owning_library => $owning_library
 252  } );
 253 warn 'found ' . scalar( @$upcoming_dues ) . ' issues' if $verbose;
 254
 255 # hash of borrowernumber to number of items upcoming
 256 # for patrons wishing digests only.
 257 my $upcoming_digest = {};
 258 my $due_digest = {};
 259
 260 my $dbh = C4::Context->dbh();
 261 my $sth = $dbh->prepare(<<'END_SQL');
 262 SELECT biblio.*, items.*, issues.*
 263   FROM issues,items,biblio
 264   WHERE items.itemnumber=issues.itemnumber
 265     AND biblio.biblionumber=items.biblionumber
 266     AND issues.borrowernumber = ?
 267     AND issues.itemnumber = ?
 268     AND (TO_DAYS(date_due)-TO_DAYS(NOW()) = ?)
 269 END_SQL
 270
 271 my $admin_adress = C4::Context->preference('KohaAdminEmailAddress');
 272
 273 my @letters;
 274 UPCOMINGITEM: foreach my $upcoming ( @$upcoming_dues ) {
 275     @letters = ();
 276     warn 'examining ' . $upcoming->{'itemnumber'} . ' upcoming due items' if $verbose;
 277
 278     my $from_address = $upcoming->{branchemail} || $admin_adress;
 279
 280     my $borrower_preferences;
 281     if ( 0 == $upcoming->{'days_until_due'} ) {
 282         # This item is due today. Send an 'item due' message.
 283         $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences( { borrowernumber => $upcoming->{'borrowernumber'},
 284                                                                                    message_name   => 'item_due' } );
 285         next unless $borrower_preferences;
 286
 287         if ( $borrower_preferences->{'wants_digest'} ) {
 288             # cache this one to process after we've run through all of the items.
 289             if ($digest_per_branch) {
 290                 $due_digest->{ $upcoming->{branchcode} }->{ $upcoming->{borrowernumber} }->{email} = $from_address;
 291                 $due_digest->{ $upcoming->{branchcode} }->{ $upcoming->{borrowernumber} }->{count}++;
 292             } else {
 293                 $due_digest->{ $upcoming->{borrowernumber} }->{email} = $from_address;
 294                 $due_digest->{ $upcoming->{borrowernumber} }->{count}++;
 295             }
 296         } else {
 297             my $branchcode;
 298             if($owning_library) {
 299                 $branchcode = $upcoming->{'homebranch'};
 300             } else {
 301                 $branchcode = $upcoming->{'branchcode'};
 302             }
 303             # Skip this DUE if we specify list of libraries and this one is not part of it
 304             next if (@branchcodes && !$branches{$branchcode});
 305
 306             my $item = Koha::Items->find( $upcoming->{itemnumber} );
 307             my $letter_type = 'DUE';
 308             $sth->execute($upcoming->{'borrowernumber'},$upcoming->{'itemnumber'},'0');
 309             my $titles = "";
 310             while ( my $item_info = $sth->fetchrow_hashref()) {
 311                 $titles .= C4::Letters::get_item_content( { item => $item_info, item_content_fields => \@item_content_fields } );
 312             }
 313
 314             ## Get branch info for borrowers home library.
 315             foreach my $transport ( keys %{$borrower_preferences->{'transports'}} ) {
 316                 my $letter = parse_letter( { letter_code    => $letter_type,
 317                                       borrowernumber => $upcoming->{'borrowernumber'},
 318                                       branchcode     => $branchcode,
 319                                       biblionumber   => $item->biblionumber,
 320                                       itemnumber     => $upcoming->{'itemnumber'},
 321                                       substitute     => { 'items.content' => $titles },
 322                                       message_transport_type => $transport,
 323                                     } )
 324                     or warn "no letter of type '$letter_type' found for borrowernumber ".$upcoming->{'borrowernumber'}.". Please see sample_notices.sql";
 325                 push @letters, $letter if $letter;
 326             }
 327         }
 328     } else {
 329         $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences( { borrowernumber => $upcoming->{'borrowernumber'},
 330                                                                                    message_name   => 'advance_notice' } );
 331         next UPCOMINGITEM unless $borrower_preferences && exists $borrower_preferences->{'days_in_advance'};
 332         next UPCOMINGITEM unless $borrower_preferences->{'days_in_advance'} == $upcoming->{'days_until_due'};
 333
 334         if ( $borrower_preferences->{'wants_digest'} ) {
 335             # cache this one to process after we've run through all of the items.
 336             if ($digest_per_branch) {
 337                 $upcoming_digest->{ $upcoming->{branchcode} }->{ $upcoming->{borrowernumber} }->{email} = $from_address;
 338                 $upcoming_digest->{ $upcoming->{branchcode} }->{ $upcoming->{borrowernumber} }->{count}++;
 339             } else {
 340                 $upcoming_digest->{ $upcoming->{borrowernumber} }->{email} = $from_address;
 341                 $upcoming_digest->{ $upcoming->{borrowernumber} }->{count}++;
 342             }
 343         } else {
 344             my $branchcode;
 345             if($owning_library) {
 346                 $branchcode = $upcoming->{'homebranch'};
 347             } else {
 348                 $branchcode = $upcoming->{'branchcode'};
 349             }
 350             # Skip this PREDUE if we specify list of libraries and this one is not part of it
 351             next if (@branchcodes && !$branches{$branchcode});
 352
 353             my $item = Koha::Items->find( $upcoming->{itemnumber} );
 354             my $letter_type = 'PREDUE';
 355             $sth->execute($upcoming->{'borrowernumber'},$upcoming->{'itemnumber'},$borrower_preferences->{'days_in_advance'});
 356             my $titles = "";
 357             while ( my $item_info = $sth->fetchrow_hashref()) {
 358                 $titles .= C4::Letters::get_item_content( { item => $item_info, item_content_fields => \@item_content_fields } );
 359             }
 360
 361             ## Get branch info for borrowers home library.
 362             foreach my $transport ( keys %{$borrower_preferences->{'transports'}} ) {
 363                 my $letter = parse_letter( { letter_code    => $letter_type,
 364                                       borrowernumber => $upcoming->{'borrowernumber'},
 365                                       branchcode     => $branchcode,
 366                                       biblionumber   => $item->biblionumber,
 367                                       itemnumber     => $upcoming->{'itemnumber'},
 368                                       substitute     => { 'items.content' => $titles },
 369                                       message_transport_type => $transport,
 370                                     } )
 371                     or warn "no letter of type '$letter_type' found for borrowernumber ".$upcoming->{'borrowernumber'}.". Please see sample_notices.sql";
 372                 push @letters, $letter if $letter;
 373             }
 374         }
 375     }
 376
 377     # If we have prepared a letter, send it.
 378     if ( @letters ) {
 379       if ($nomail) {
 380         for my $letter ( @letters ) {
 381             local $, = "\f";
 382             print $letter->{'content'};
 383         }
 384       }
 385       else {
 386         for my $letter ( @letters ) {
 387             C4::Letters::EnqueueLetter( { letter                 => $letter,
 388                                           borrowernumber         => $upcoming->{'borrowernumber'},
 389                                           from_address           => $from_address,
 390                                           message_transport_type => $letter->{message_transport_type} } );
 391         }
 392       }
 393     }
 394 }
 395
 396
 397
 398 # Now, run through all the people that want digests and send them
 399
 400 my $sth_digest = $dbh->prepare(<<'END_SQL');
 401 SELECT biblio.*, items.*, issues.*
 402   FROM issues,items,biblio
 403   WHERE items.itemnumber=issues.itemnumber
 404     AND biblio.biblionumber=items.biblionumber
 405     AND issues.borrowernumber = ?
 406     AND (TO_DAYS(date_due)-TO_DAYS(NOW()) = ?)
 407 END_SQL
 408
 409 if ($digest_per_branch) {
 410     while (my ($branchcode, $digests) = each %$upcoming_digest) {
 411         send_digests({
 412             sth => $sth_digest,
 413             digests => $digests,
 414             letter_code => 'PREDUEDGST',
 415             message_name => 'advance_notice',
 416             branchcode => $branchcode,
 417             get_item_info => sub {
 418                 my $params = shift;
 419                 $params->{sth}->execute($params->{borrowernumber},
 420                                         $params->{borrower_preferences}->{'days_in_advance'});
 421                 return sub {
 422                     $params->{sth}->fetchrow_hashref;
 423                 };
 424             }
 425         });
 426     }
 427
 428     while (my ($branchcode, $digests) = each %$due_digest) {
 429         send_digests({
 430             sth => $sth_digest,
 431             digests => $due_digest,
 432             letter_code => 'DUEDGST',
 433             branchcode => $branchcode,
 434             message_name => 'item_due',
 435             get_item_info => sub {
 436                 my $params = shift;
 437                 $params->{sth}->execute($params->{borrowernumber}, 0);
 438                 return sub {
 439                     $params->{sth}->fetchrow_hashref;
 440                 };
 441             }
 442         });
 443     }
 444 } else {
 445     send_digests({
 446         sth => $sth_digest,
 447         digests => $upcoming_digest,
 448         letter_code => 'PREDUEDGST',
 449         message_name => 'advance_notice',
 450         get_item_info => sub {
 451             my $params = shift;
 452             $params->{sth}->execute($params->{borrowernumber},
 453                                     $params->{borrower_preferences}->{'days_in_advance'});
 454             return sub {
 455                 $params->{sth}->fetchrow_hashref;
 456             };
 457         }
 458     });
 459
 460     send_digests({
 461         sth => $sth_digest,
 462         digests => $due_digest,
 463         letter_code => 'DUEDGST',
 464         message_name => 'item_due',
 465         get_item_info => sub {
 466             my $params = shift;
 467             $params->{sth}->execute($params->{borrowernumber}, 0);
 468             return sub {
 469                 $params->{sth}->fetchrow_hashref;
 470             };
 471         }
 472     });
 473 }
 474
 475 =head1 METHODS
 476
 477 =head2 parse_letter
 478
 479 =cut
 480
 481 sub parse_letter {
 482     my $params = shift;
 483
 484     foreach my $required ( qw( letter_code borrowernumber ) ) {
 485         return unless exists $params->{$required};
 486     }
 487     my $patron = Koha::Patrons->find( $params->{borrowernumber} );
 488
 489     my %table_params = ( 'borrowers' => $params->{'borrowernumber'} );
 490
 491     if ( my $p = $params->{'branchcode'} ) {
 492         $table_params{'branches'} = $p;
 493     }
 494     if ( my $p = $params->{'itemnumber'} ) {
 495         $table_params{'issues'} = $p;
 496         $table_params{'items'} = $p;
 497     }
 498     if ( my $p = $params->{'biblionumber'} ) {
 499         $table_params{'biblio'} = $p;
 500         $table_params{'biblioitems'} = $p;
 501     }
 502
 503     return C4::Letters::GetPreparedLetter (
 504         module => 'circulation',
 505         letter_code => $params->{'letter_code'},
 506         branchcode => $table_params{'branches'},
 507         lang => $patron->lang,
 508         substitute => $params->{'substitute'},
 509         tables     => \%table_params,
 510         message_transport_type => $params->{message_transport_type},
 511     );
 512 }
 513
 514 =head2 get_branch_info
 515
 516 =cut
 517
 518 sub get_branch_info {
 519     my ( $borrowernumber ) = @_;
 520
 521     ## Get branch info for borrowers home library.
 522     my $patron = Koha::Patrons->find( $borrowernumber );
 523     my $branch = $patron->library->unblessed;
 524     my %branch_info;
 525     foreach my $key( keys %$branch ) {
 526         $branch_info{"branches.$key"} = $branch->{$key};
 527     }
 528
 529     return %branch_info;
 530 }
 531
 532 =head2 send_digests
 533
 534     send_digests({
 535         digests => ...,
 536         sth => ...,
 537         letter_code => ...,
 538         get_item_info => ...,
 539     })
 540
 541 Enqueue digested letters (or print them if -n was passed at command line).
 542
 543 Parameters:
 544
 545 =over 4
 546
 547 =item C<$digests>
 548
 549 Reference to the array of digested messages.
 550
 551 =item C<$sth>
 552
 553 Prepared statement handle for fetching overdue issues.
 554
 555 =item C<$letter_code>
 556
 557 String that denote the letter code.
 558
 559 =item C<$get_item_info>
 560
 561 Subroutine for executing prepared statement.  Takes parameters $sth,
 562 $borrowernumber and $borrower_parameters and return a generator
 563 function that produce the matching rows.
 564
 565 =back
 566
 567 =cut
 568
 569 sub send_digests {
 570     my $params = shift;
 571
 572     PATRON: while ( my ( $borrowernumber, $digest ) = each %{$params->{digests}} ) {
 573         @letters = ();
 574         my $count = $digest->{count};
 575         my $from_address = $digest->{email};
 576
 577         my %branch_info;
 578         my $branchcode;
 579
 580         if (defined($params->{branchcode})) {
 581             %branch_info = ();
 582             $branchcode = $params->{branchcode};
 583         } else {
 584             ## Get branch info for borrowers home library.
 585             %branch_info = get_branch_info( $borrowernumber );
 586             $branchcode = $branch_info{'branches.branchcode'};
 587         }
 588
 589         my $borrower_preferences =
 590             C4::Members::Messaging::GetMessagingPreferences(
 591                 {
 592                     borrowernumber => $borrowernumber,
 593                     message_name   => $params->{message_name}
 594                 }
 595             );
 596
 597         next PATRON unless $borrower_preferences; # how could this happen?
 598
 599         my $next_item_info = $params->{get_item_info}->({
 600             sth => $params->{sth},
 601             borrowernumber => $borrowernumber,
 602             borrower_preferences => $borrower_preferences
 603         });
 604         my $titles = "";
 605         while ( my $item_info = $next_item_info->()) {
 606             $titles .= C4::Letters::get_item_content( { item => $item_info, item_content_fields => \@item_content_fields } );
 607         }
 608
 609         foreach my $transport ( keys %{ $borrower_preferences->{'transports'} } ) {
 610             my $letter = parse_letter(
 611                 {
 612                     letter_code    => $params->{letter_code},
 613                     borrowernumber => $borrowernumber,
 614                     substitute     => {
 615                         count           => $count,
 616                         'items.content' => $titles,
 617                         %branch_info
 618                     },
 619                     branchcode     => $branchcode,
 620                     message_transport_type => $transport
 621                 }
 622             );
 623             unless ( $letter ){
 624                 warn "no letter of type '$params->{letter_type}' found for borrowernumber $borrowernumber. Please see sample_notices.sql";
 625                 next;
 626             }
 627             push @letters, $letter if $letter;
 628         }
 629
 630         if ( @letters ) {
 631             if ($nomail) {
 632                 for my $letter ( @letters ) {
 633                     local $, = "\f";
 634                     print $letter->{'content'};
 635                 }
 636             }
 637             else {
 638                 for my $letter ( @letters ) {
 639                     C4::Letters::EnqueueLetter( { letter                 => $letter,
 640                                                   borrowernumber         => $borrowernumber,
 641                                                   from_address           => $from_address,
 642                                                   message_transport_type => $letter->{message_transport_type} } );
 643                 }
 644             }
 645         }
 646     }
 647 }
 648
 649
 650 1;
 651
 652 __END__