misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl -w
   2
   3 # Copyright 2008 Liblime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along with
  17 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  18 # Suite 330, Boston, MA  02111-1307 USA
  19
  20 use strict;
  21 use warnings;
  22
  23 BEGIN {
  24
  25     # find Koha's Perl modules
  26     # test carefully before changing this
  27     use FindBin;
  28     eval { require "$FindBin::Bin/../kohalib.pl" };
  29 }
  30
  31 use C4::Context;
  32 use C4::Dates qw/format_date/;
  33 use C4::Debug;
  34 use C4::Letters;
  35
  36 use Getopt::Long;
  37 use Pod::Usage;
  38 use Text::CSV_XS;
  39
  40 =head1 NAME
  41
  42 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  43
  44 =head1 SYNOPSIS
  45
  46 overdue_notices.pl [ -n ] [ -library <branchcode> ] [ -library <branchcode>...] [ -max <number of days> ] [ -csv [ <filename> ] ] [ -itemscontent <field list> ]
  47
  48  Options:
  49    -help                          brief help message
  50    -man                           full documentation
  51    -n                             No email will be sent
  52    -max          <days>           maximum days overdue to deal with
  53    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  54    -csv          <filename>       populate CSV file
  55    -itemscontent <list of fields> item information in templates
  56
  57 =head1 OPTIONS
  58
  59 =over 8
  60
  61 =item B<-help>
  62
  63 Print a brief help message and exits.
  64
  65 =item B<-man>
  66
  67 Prints the manual page and exits.
  68
  69 =item B<-v>
  70
  71 Verbose. Without this flag set, only fatal errors are reported.
  72
  73 =item B<-n>
  74
  75 Do not send any email. Overdue notices that would have been sent to
  76 the patrons or to the admin are printed to standard out. CSV data (if
  77 the -csv flag is set) is written to standard out or to any csv
  78 filename given.
  79
  80 =item B<-max>
  81
  82 Items older than max days are assumed to be handled somewhere else,
  83 probably the F<longoverdues.pl> script. They are therefore ignored by
  84 this program. No notices are sent for them, and they are not added to
  85 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
  86
  87 =item B<-library>
  88
  89 select overdues for one specific library. Use the value in the
  90 branches.branchcode table. This option can be repeated in order
  91 to select overdues for a group of libraries.
  92
  93 =item B<-csv>
  94
  95 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
  96 sent to standard out or to a filename if provided. Otherwise, only
  97 overdues that could not be emailed are sent in CSV format to the admin.
  98
  99 =item B<-itemscontent>
 100
 101 comma separated list of fields that get substituted into templates in
 102 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 103 defaults to issuedate,title,barcode,author
 104
 105 Other possible values come from fields in the biblios, items, and
 106 issues tables.
 107
 108 =item B<-t> | B<--triggered>
 109
 110 This option causes a notice to be generated if and only if
 111 an item is overdue by the number of days defined in a notice trigger.
 112
 113 By default, a notice is sent each time the script runs, which is suitable for
 114 less frequent run cron script, but requires syncing notice triggers with
 115 the  cron schedule to ensure proper behavior.
 116 Add the --triggered option for daily cron, at the risk of no notice
 117 being generated if the cron fails to run on time.
 118
 119 =item B<-list-all>
 120
 121 Default items.content lists only those items that fall in the
 122 range of the currently processing notice.
 123 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 124
 125 =back
 126
 127 =head1 DESCRIPTION
 128
 129 This script is designed to alert patrons and administrators of overdue
 130 items.
 131
 132 =head2 Configuration
 133
 134 This script pays attention to the overdue notice configuration
 135 performed in the "Overdue notice/status triggers" section of the
 136 "Tools" area of the staff interface to Koha. There, you can choose
 137 which letter templates are sent out after a configurable number of
 138 days to patrons of each library. More information about the use of this
 139 section of Koha is available in the Koha manual.
 140
 141 The templates used to craft the emails are defined in the "Tools:
 142 Notices" section of the staff interface to Koha.
 143
 144 =head2 Outgoing emails
 145
 146 Typically, messages are prepared for each patron with overdue
 147 items. Messages for whom there is no email address on file are
 148 collected and sent as attachments in a single email to each library
 149 administrator, or if that is not set, then to the email address in the
 150 C<KohaAdminEmailAddress> system preference.
 151
 152 These emails are staged in the outgoing message queue, as are messages
 153 produced by other features of Koha. This message queue must be
 154 processed regularly by the
 155 F<misc/cronjobs/process_message_queue.pl> program.
 156
 157 In the event that the C<-n> flag is passed to this program, no emails
 158 are sent. Instead, messages are sent on standard output from this
 159 program. They may be redirected to a file if desired.
 160
 161 =head2 Templates
 162
 163 Templates can contain variables enclosed in double angle brackets like
 164 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 165 specific to the overdue items or relevant patron. Available variables
 166 are:
 167
 168 =over
 169
 170 =item E<lt>E<lt>bibE<gt>E<gt>
 171
 172 the name of the library
 173
 174 =item E<lt>E<lt>items.contentE<gt>E<gt>
 175
 176 one line for each item, each line containing a tab separated list of
 177 title, author, barcode, issuedate
 178
 179 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 180
 181 any field from the borrowers table
 182
 183 =item E<lt>E<lt>branches.*E<gt>E<gt>
 184
 185 any field from the branches table
 186
 187 =back
 188
 189 =head2 CSV output
 190
 191 The C<-csv> command line option lets you specify a file to which
 192 overdues data should be output in CSV format.
 193
 194 With the C<-n> flag set, data about all overdues is written to the
 195 file. Without that flag, only information about overdues that were
 196 unable to be sent directly to the patrons will be written. In other
 197 words, this CSV file replaces the data that is typically sent to the
 198 administrator email address.
 199
 200 =head1 USAGE EXAMPLES
 201
 202 C<overdue_notices.pl> - In this most basic usage, with no command line
 203 arguments, all libraries are procesed individually, and notices are
 204 prepared for all patrons with overdue items for whom we have email
 205 addresses. Messages for those patrons for whom we have no email
 206 address are sent in a single attachment to the library administrator's
 207 email address, or to the address in the KohaAdminEmailAddress system
 208 preference.
 209
 210 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 211 populates F</tmp/overdues.csv> with information about all overdue
 212 items.
 213
 214 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 215 overdues in the last 2 weeks for the MAIN library.
 216
 217 =head1 SEE ALSO
 218
 219 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 220 messages to patrons in advance of thier items becoming due, or to
 221 alert them of items that have just become due.
 222
 223 =cut
 224
 225 # These variables are set by command line options.
 226 # They are initially set to default values.
 227 my $help    = 0;
 228 my $man     = 0;
 229 my $verbose = 0;
 230 my $nomail  = 0;
 231 my $MAX     = 90;
 232 my @branchcodes; # Branch(es) passed as parameter
 233 my $csvfilename;
 234 my $triggered = 0;
 235 my $listall = 0;
 236 my $itemscontent = join( ',', qw( issuedate title barcode author ) );
 237
 238 GetOptions(
 239     'help|?'         => \$help,
 240     'man'            => \$man,
 241     'v'              => \$verbose,
 242     'n'              => \$nomail,
 243     'max=s'          => \$MAX,
 244     'library=s'      => \@branchcodes,
 245     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 246     'itemscontent=s' => \$itemscontent,
 247     'list-all'      => \$listall,
 248     't|triggered'             => \$triggered,
 249 ) or pod2usage(2);
 250 pod2usage(1) if $help;
 251 pod2usage( -verbose => 2 ) if $man;
 252
 253 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 254     warn qq(using "$csvfilename" as filename, that seems odd);
 255 }
 256
 257 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 258 my @branches;                                                                   # Branches passed as parameter with overdue rules
 259 my $branchcount = scalar(@overduebranches);
 260
 261 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 262 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 263
 264 if ($branchcount) {
 265     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 266 } else {
 267     die 'No branches with active overduerules';
 268 }
 269
 270 if (@branchcodes) {
 271     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 272
 273     # Getting libraries which have overdue rules
 274     my %seen = map { $_ => 1 } @branchcodes;
 275     @branches = grep { $seen{$_} } @overduebranches;
 276
 277
 278     if (@branches) {
 279
 280         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 281         $verbose and warn "$branch_word @branches have overdue rules\n";
 282
 283     } else {
 284
 285         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 286         ( scalar grep { '' eq $_ } @branches )
 287           or die "No active overduerules for DEFAULT either!";
 288         $verbose and warn "Falling back on default rules for @branchcodes\n";
 289         @branches = ('');
 290     }
 291 }
 292
 293 # these are the fields that will be substituted into <<item.content>>
 294 my @item_content_fields = split( /,/, $itemscontent );
 295
 296 my $dbh = C4::Context->dbh();
 297 binmode( STDOUT, ":utf8" );
 298
 299 our $csv;       # the Text::CSV_XS object
 300 our $csv_fh;    # the filehandle to the CSV file.
 301 if ( defined $csvfilename ) {
 302     my $sep_char = C4::Context->preference('delimiter') || ',';
 303     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 304     if ( $csvfilename eq '' ) {
 305         $csv_fh = *STDOUT;
 306     } else {
 307         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 308     }
 309     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email itemcount itemsinfo)) ) {
 310         print $csv_fh $csv->string, "\n";
 311     } else {
 312         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 313     }
 314 }
 315
 316 foreach my $branchcode (@branches) {
 317
 318     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 319     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 320     my @output_chunks;    # may be sent to mail or stdout or csv file.
 321
 322     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 323
 324     my $sth2 = $dbh->prepare( <<'END_SQL' );
 325 SELECT biblio.*, items.*, issues.*, TO_DAYS(NOW())-TO_DAYS(date_due) AS days_overdue
 326   FROM issues,items,biblio
 327   WHERE items.itemnumber=issues.itemnumber
 328     AND biblio.biblionumber   = items.biblionumber
 329     AND issues.borrowernumber = ?
 330     AND TO_DAYS(NOW())-TO_DAYS(date_due) BETWEEN ? and ?
 331 END_SQL
 332
 333     my $rqoverduerules = $dbh->prepare("SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ");
 334     $rqoverduerules->execute($branchcode);
 335     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 336     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 337       PERIOD: foreach my $i ( 1 .. 3 ) {
 338
 339             $verbose and warn "branch '$branchcode', pass $i\n";
 340             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 341             my $maxdays = (
 342                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 343                 ? $overdue_rules->{ "delay" . ( $i + 1 ) }
 344                 : ($MAX)
 345             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 346
 347             if ( !$overdue_rules->{"letter$i"} ) {
 348                 $verbose and warn "No letter$i code for branch '$branchcode'";
 349                 next PERIOD;
 350             }
 351
 352             # $letter->{'content'} is the text of the mail that is sent.
 353             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 354             # The following fields are available :
 355             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 356             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode>
 357
 358             my $borrower_sql = <<'END_SQL';
 359 SELECT COUNT(*), issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, MIN(date_due) as longest_issue
 360 FROM   issues,borrowers,categories
 361 WHERE  issues.borrowernumber=borrowers.borrowernumber
 362 AND    borrowers.categorycode=categories.categorycode
 363 END_SQL
 364             my @borrower_parameters;
 365             if ($branchcode) {
 366                 $borrower_sql .= ' AND issues.branchcode=? ';
 367                 push @borrower_parameters, $branchcode;
 368             }
 369             if ( $overdue_rules->{categorycode} ) {
 370                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 371                 push @borrower_parameters, $overdue_rules->{categorycode};
 372             }
 373             $borrower_sql .= '  AND categories.overduenoticerequired=1
 374                                 GROUP BY issues.borrowernumber ';
 375             if($triggered) {
 376                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) = ?';
 377                 push @borrower_parameters, $mindays;
 378             } else {
 379                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) BETWEEN ? and ? ' ;
 380                 push @borrower_parameters, $mindays, $maxdays;
 381             }
 382
 383             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 384                 my $sth = $dbh->prepare($borrower_sql);
 385             $sth->execute(@borrower_parameters);
 386             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 387
 388             while( my ( $itemcount, $borrowernumber, $firstname, $lastname, $address1, $address2, $city, $postcode, $email ) = $sth->fetchrow ) {
 389                 $verbose and warn "borrower $firstname, $lastname ($borrowernumber) has $itemcount items triggering level $i.";
 390
 391                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"} );
 392                 unless ($letter) {
 393                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 394
 395                     # might as well skip while PERIOD, no other borrowers are going to work.
 396                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 397                     next PERIOD;
 398                 }
 399
 400                 if ( $overdue_rules->{"debarred$i"} ) {
 401
 402                     #action taken is debarring
 403                     C4::Members::DebarMember($borrowernumber);
 404                     $verbose and warn "debarring $borrowernumber $firstname $lastname\n";
 405                 }
 406                 $sth2->execute( ($listall) ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ) );
 407                 my $itemcount = 0;
 408                 my $titles = "";
 409                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 410                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 411                     $titles .= join("\t", @item_info) . "\n";
 412                     $itemcount++;
 413                 }
 414                 $sth2->finish;
 415
 416                 $letter = parse_letter(
 417                     {   letter         => $letter,
 418                         borrowernumber => $borrowernumber,
 419                         branchcode     => $branchcode,
 420                         substitute     => {
 421                             bib             => $branch_details->{'branchname'},
 422                             'items.content' => $titles
 423                         }
 424                     }
 425                 );
 426
 427                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 428                 if (@misses) {
 429                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 430                 }
 431                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # Now that we've warned about them, remove them.
 432                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # 2nd pass for the double nesting.
 433
 434                 if ($nomail) {
 435
 436                     push @output_chunks,
 437                       prepare_letter_for_printing(
 438                         {   letter         => $letter,
 439                             borrowernumber => $borrowernumber,
 440                             firstname      => $firstname,
 441                             lastname       => $lastname,
 442                             address1       => $address1,
 443                             address2       => $address2,
 444                             city           => $city,
 445                             postcode       => $postcode,
 446                             email          => $email,
 447                             itemcount      => $itemcount,
 448                             titles         => $titles,
 449                             outputformat   => defined $csvfilename ? 'csv' : '',
 450                         }
 451                       );
 452                 } else {
 453                     if ($email) {
 454                         C4::Letters::EnqueueLetter(
 455                             {   letter                 => $letter,
 456                                 borrowernumber         => $borrowernumber,
 457                                 message_transport_type => 'email',
 458                                 from_address           => $admin_email_address,
 459                             }
 460                         );
 461                     } else {
 462
 463                         # If we don't have an email address for this patron, send it to the admin to deal with.
 464                         push @output_chunks,
 465                           prepare_letter_for_printing(
 466                             {   letter         => $letter,
 467                                 borrowernumber => $borrowernumber,
 468                                 firstname      => $firstname,
 469                                 lastname       => $lastname,
 470                                 address1       => $address1,
 471                                 address2       => $address2,
 472                                 city           => $city,
 473                                 postcode       => $postcode,
 474                                 email          => $email,
 475                                 itemcount      => $itemcount,
 476                                 titles         => $titles,
 477                                 outputformat   => defined $csvfilename ? 'csv' : '',
 478                             }
 479                           );
 480                     }
 481                 }
 482             }
 483             $sth->finish;
 484         }
 485     }
 486
 487     if (@output_chunks) {
 488         if ($nomail) {
 489             if ( defined $csvfilename ) {
 490                 print $csv_fh @output_chunks;
 491             } else {
 492                 local $, = "\f";    # pagebreak
 493                 print @output_chunks;
 494             }
 495         } else {
 496             my $attachment = {
 497                 filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 498                 type => 'text/plain',
 499                 content => join( "\n", @output_chunks )
 500             };
 501
 502             my $letter = {
 503                 title   => 'Overdue Notices',
 504                 content => 'These messages were not sent directly to the patrons.',
 505             };
 506             C4::Letters::EnqueueLetter(
 507                 {   letter                 => $letter,
 508                     borrowernumber         => undef,
 509                     message_transport_type => 'email',
 510                     attachments            => [$attachment],
 511                     to_address             => $admin_email_address,
 512                 }
 513             );
 514         }
 515     }
 516
 517 }
 518 if ($csvfilename) {
 519
 520     # note that we're not testing on $csv_fh to prevent closing
 521     # STDOUT.
 522     close $csv_fh;
 523 }
 524
 525 =head1 INTERNAL METHODS
 526
 527 These methods are internal to the operation of overdue_notices.pl.
 528
 529 =head2 parse_letter
 530
 531 parses the letter template, replacing the placeholders with data
 532 specific to this patron, biblio, or item
 533
 534 named parameters:
 535   letter - required hashref
 536   borrowernumber - required integer
 537   substitute - optional hashref of other key/value pairs that should
 538     be substituted in the letter content
 539
 540 returns the C<letter> hashref, with the content updated to reflect the
 541 substituted keys and values.
 542
 543
 544 =cut
 545
 546 sub parse_letter {
 547     my $params = shift;
 548     foreach my $required (qw( letter borrowernumber )) {
 549         return unless exists $params->{$required};
 550     }
 551
 552     if ( $params->{'substitute'} ) {
 553         while ( my ( $key, $replacedby ) = each %{ $params->{'substitute'} } ) {
 554             my $replacefield = "<<$key>>";
 555
 556             $params->{'letter'}->{title}   =~ s/$replacefield/$replacedby/g;
 557             $params->{'letter'}->{content} =~ s/$replacefield/$replacedby/g;
 558         }
 559     }
 560
 561     C4::Letters::parseletter( $params->{'letter'}, 'borrowers', $params->{'borrowernumber'} );
 562
 563     if ( $params->{'branchcode'} ) {
 564         C4::Letters::parseletter( $params->{'letter'}, 'branches', $params->{'branchcode'} );
 565     }
 566
 567     if ( $params->{'biblionumber'} ) {
 568         C4::Letters::parseletter( $params->{'letter'}, 'biblio',      $params->{'biblionumber'} );
 569         C4::Letters::parseletter( $params->{'letter'}, 'biblioitems', $params->{'biblionumber'} );
 570     }
 571
 572     return $params->{'letter'};
 573 }
 574
 575 =head2 prepare_letter_for_printing
 576
 577 returns a string of text appropriate for printing in the event that an
 578 overdue notice will not be sent to the patron's email
 579 address. Depending on the desired output format, this may be a CSV
 580 string, or a human-readable representation of the notice.
 581
 582 required parameters:
 583   letter
 584   borrowernumber
 585
 586 optional parameters:
 587   outputformat
 588
 589 =cut
 590
 591 sub prepare_letter_for_printing {
 592     my $params = shift;
 593
 594     return unless ref $params eq 'HASH';
 595
 596     foreach my $required_parameter (qw( letter borrowernumber )) {
 597         return unless defined $params->{$required_parameter};
 598     }
 599
 600     my $return;
 601     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 602         if ($csv->combine(
 603                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 604                 $params->{'city'},      $params->{'email'},    $params->{'itemcount'}, $params->{'titles'}
 605             )
 606           ) {
 607             return $csv->string, "\n";
 608         } else {
 609             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 610         }
 611     } else {
 612         $return .= "$params->{'letter'}->{'content'}\n";
 613
 614         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 615     }
 616     return $return;
 617 }
 618