opac/opac-ratings-ajax.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2011 KohaAloha, NZ
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 DESCRIPTION
  21
  22 A script that takes an ajax json query, and then inserts or modifies a star-rating.
  23
  24 =cut
  25
  26 use Modern::Perl;
  27
  28 use CGI qw ( -utf8 );
  29 use CGI::Cookie;  # need to check cookies before having CGI parse the POST request
  30
  31 use C4::Auth qw(:DEFAULT check_cookie_auth);
  32 use C4::Context;
  33 use C4::Debug;
  34 use C4::Output qw(:html :ajax pagination_bar);
  35
  36 use Koha::Ratings;
  37
  38 use JSON;
  39
  40 my $is_ajax = is_ajax();
  41
  42 my ( $query, $auth_status );
  43 if ($is_ajax) {
  44     ( $query, $auth_status ) = &ajax_auth_cgi( {} );
  45 }
  46 else {
  47     $query = CGI->new();
  48 }
  49
  50 my $biblionumber     = $query->param('biblionumber');
  51 my $rating_value     = $query->param('rating_value');
  52 my $rating_old_value = $query->param('rating_old_value');
  53
  54 my ( $template, $loggedinuser, $cookie );
  55 if ($is_ajax) {
  56     $loggedinuser = C4::Context->userenv->{'number'};
  57 }
  58 else {
  59     ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  60         {
  61             template_name   => "opac-detail.tt",
  62             query           => $query,
  63             type            => "opac",
  64             authnotrequired => 0,                    # auth required to add tags
  65         }
  66     );
  67 }
  68
  69 my $rating;
  70 $rating_value //= '';
  71
  72 if ( $rating_value eq '' ) {
  73     my $rating = Koha::Ratings->find( { biblionumber => $biblionumber, borrowernumber => $loggedinuser } );
  74     $rating->delete if $rating;
  75 }
  76
  77 elsif ( $rating_value and !$rating_old_value ) {
  78     Koha::Rating->new( { biblionumber => $biblionumber, borrowernumber => $loggedinuser, rating_value => $rating_value, })->store;
  79 }
  80
  81 elsif ( $rating_value ne $rating_old_value ) {
  82     my $rating = Koha::Ratings->find( { biblionumber => $biblionumber, borrowernumber => $loggedinuser });
  83     $rating->rating_value($rating_value)->store if $rating
  84 }
  85
  86 my $ratings = Koha::Ratings->search({ biblionumber => $biblionumber });
  87 my $my_rating = $ratings->search({ borrowernumber => $loggedinuser })->next;
  88 my $avg = $ratings->get_avg_rating;
  89
  90 my %js_reply = (
  91     rating_total   => $ratings->count,
  92     rating_avg     => $avg,
  93     rating_avg_int => sprintf("%.0f", $avg),
  94     rating_value   => $my_rating ? $my_rating->rating_value : undef,
  95     auth_status    => $auth_status,
  96
  97 );
  98
  99 my $json_reply = JSON->new->encode( \%js_reply );
 100
 101 #### $rating
 102 #### %js_reply
 103 #### $json_reply
 104
 105 output_ajax_with_http_headers( $query, $json_reply );
 106 exit;
 107
 108 # a ratings specific ajax return sub, returns CGI object, and an 'auth_success' value
 109 sub ajax_auth_cgi {
 110     my $needed_flags = shift;
 111     my %cookies      = CGI::Cookie->fetch;
 112     my $input        = CGI->new;
 113     my $sessid = $cookies{'CGISESSID'}->value || $input->param('CGISESSID');
 114     my ( $auth_status, $auth_sessid ) =
 115       check_cookie_auth( $sessid, $needed_flags );
 116     return $input, $auth_status;
 117 }