opac/opac-request-article.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright ByWater Solutions 2015
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Auth qw( get_template_and_user );
  25 use C4::Output qw( output_html_with_http_headers );
  26
  27 use Koha::Biblios;
  28 use Koha::Logger;
  29 use Koha::Patrons;
  30
  31 use Scalar::Util qw( blessed );
  32 use Try::Tiny;
  33
  34 my $cgi = CGI->new;
  35
  36 # If ArticleRequests is disabled, leave immediately
  37 if ( !C4::Context->preference('ArticleRequests') ) {
  38     print $cgi->redirect("/cgi-bin/koha/errors/404.pl");
  39     exit;
  40 }
  41
  42 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  43     {
  44         template_name   => "opac-request-article.tt",
  45         query           => $cgi,
  46         type            => "opac",
  47     }
  48 );
  49
  50 my $action = $cgi->param('action') || q{};
  51 my $biblionumber = $cgi->param('biblionumber');
  52 my $biblio = Koha::Biblios->find($biblionumber);
  53 if( !$biblio ) {
  54     print $cgi->redirect("/cgi-bin/koha/errors/404.pl");
  55     exit;
  56 }
  57
  58 if ( $action eq 'create' ) {
  59     my $branchcode = $cgi->param('branchcode');
  60
  61     my $itemnumber   = $cgi->param('itemnumber')   || undef;
  62     my $title        = $cgi->param('title')        || undef;
  63     my $author       = $cgi->param('author')       || undef;
  64     my $volume       = $cgi->param('volume')       || undef;
  65     my $issue        = $cgi->param('issue')        || undef;
  66     my $date         = $cgi->param('date')         || undef;
  67     my $pages        = $cgi->param('pages')        || undef;
  68     my $chapters     = $cgi->param('chapters')     || undef;
  69     my $patron_notes = $cgi->param('patron_notes') || undef;
  70     my $format       = $cgi->param('format')       || undef;
  71     my $toc_request  = $cgi->param('toc_request');
  72
  73
  74     my $success;
  75
  76     try {
  77         my $ar = Koha::ArticleRequest->new(
  78             {
  79                 borrowernumber => $borrowernumber,
  80                 biblionumber   => $biblionumber,
  81                 branchcode     => $branchcode,
  82                 itemnumber     => $itemnumber,
  83                 title          => $title,
  84                 author         => $author,
  85                 volume         => $volume,
  86                 issue          => $issue,
  87                 date           => $date,
  88                 pages          => $pages,
  89                 chapters       => $chapters,
  90                 patron_notes   => $patron_notes,
  91                 format         => $format,
  92                 toc_request    => $toc_request ? 1 : 0,
  93             }
  94         )->request;
  95         $success = 1;
  96     } catch {
  97         if ( blessed $_ and $_->isa('Koha::Exceptions::ArticleRequest::LimitReached') ) {
  98             $template->param(
  99                 error_message => 'article_request_limit_reached'
 100             );
 101         }
 102         else {
 103             Koha::Logger->get->debug("Unhandled exception when placing an article request ($_)");
 104             $template->param(
 105                 error_message => 'article_request_unhandled_exception'
 106             );
 107         }
 108     };
 109
 110     if ( $success ) {
 111         print $cgi->redirect("/cgi-bin/koha/opac-user.pl?opac-user-article-requests=1");
 112         exit;
 113     }
 114 # Should we redirect?
 115 }
 116 elsif ( !$action && C4::Context->preference('ArticleRequestsOpacHostRedirection') ) {
 117   # Conditions: no items, host item entry (MARC21 773)
 118   my ( $host, $pageinfo ) = $biblio->get_marc_host( { no_items => 1 } );
 119   if ($host) {
 120       $template->param(
 121           pageinfo => $pageinfo,
 122           title    => $biblio->title,
 123           author   => $biblio->author
 124       );
 125       $biblio = $host;
 126   }
 127 }
 128
 129 my $patron = Koha::Patrons->find($borrowernumber);
 130
 131 if(!$patron->can_request_article) {
 132     $template->param(
 133         error_message => 'article_request_limit_reached'
 134     );
 135 }
 136
 137 $template->param( article_request_fee => $patron->article_request_fee )
 138   if $action ne 'create';
 139
 140 $template->param(
 141     biblio => $biblio,
 142     patron => $patron,
 143     action => $action
 144 );
 145
 146 output_html_with_http_headers $cgi, $cookie, $template->output, undef, { force_no_caching => 1 };