t/db_dependent/api/v1/biblios.t

   1 #!/usr/bin/env perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use utf8;
  21 use Encode;
  22
  23 use Test::More tests => 8;
  24 use Test::MockModule;
  25 use Test::Mojo;
  26 use Test::Warn;
  27
  28 use t::lib::Mocks;
  29 use t::lib::TestBuilder;
  30
  31 use C4::Auth;
  32 use C4::Circulation qw( AddIssue AddReturn );
  33
  34 use Koha::Biblios;
  35 use Koha::Database;
  36 use Koha::Checkouts;
  37 use Koha::Old::Checkouts;
  38
  39 my $schema  = Koha::Database->new->schema;
  40 my $builder = t::lib::TestBuilder->new;
  41
  42 t::lib::Mocks::mock_preference( 'RESTBasicAuth', 1 );
  43
  44 my $t = Test::Mojo->new('Koha::REST::V1');
  45
  46 subtest 'get() tests' => sub {
  47
  48     plan tests => 21;
  49
  50     $schema->storage->txn_begin;
  51
  52     my $patron = $builder->build_object(
  53         {
  54             class => 'Koha::Patrons',
  55             value => { flags => 0 }
  56         }
  57     );
  58     my $password = 'thePassword123';
  59     $patron->set_password( { password => $password, skip_validation => 1 } );
  60     $patron->discard_changes;
  61     my $userid = $patron->userid;
  62
  63     my $biblio = $builder->build_sample_biblio({
  64         title  => 'The unbearable lightness of being',
  65         author => 'Milan Kundera'
  66     });
  67     $t->get_ok("//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber)
  68       ->status_is(403);
  69
  70     $patron->flags(4)->store;
  71
  72     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
  73                 => { Accept => 'application/weird+format' } )
  74       ->status_is(400);
  75
  76     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
  77                  => { Accept => 'application/json' } )
  78       ->status_is(200)
  79       ->json_is( '/title', 'The unbearable lightness of being' )
  80       ->json_is( '/author', 'Milan Kundera' );
  81
  82     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
  83                  => { Accept => 'application/marcxml+xml' } )
  84       ->status_is(200);
  85
  86     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
  87                  => { Accept => 'application/marc-in-json' } )
  88       ->status_is(200);
  89
  90     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
  91                  => { Accept => 'application/marc' } )
  92       ->status_is(200);
  93
  94     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
  95                  => { Accept => 'text/plain' } )
  96       ->status_is(200)
  97       ->content_is($biblio->metadata->record->as_formatted);
  98
  99     $biblio->delete;
 100     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
 101                  => { Accept => 'application/marc' } )
 102       ->status_is(404)
 103       ->json_is( '/error', 'Object not found.' );
 104
 105     subtest 'marc-in-json encoding tests' => sub {
 106
 107         plan tests => 3;
 108
 109         my $title_with_diacritics = "L'insoutenable légèreté de l'être";
 110
 111         my $biblio = $builder->build_sample_biblio(
 112             {
 113                 title  => $title_with_diacritics,
 114                 author => "Milan Kundera"
 115             }
 116         );
 117
 118         my $result = $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
 119                     => { Accept => 'application/marc-in-json' } )
 120           ->status_is(200)->tx->res->body;
 121
 122         my $encoded_title  = Encode::encode( "UTF-8", $title_with_diacritics );
 123
 124         like( $result, qr/\Q$encoded_title/, "The title is not double encoded" );
 125     };
 126
 127     $schema->storage->txn_rollback;
 128 };
 129
 130 subtest 'get_items() tests' => sub {
 131
 132     plan tests => 8;
 133
 134     $schema->storage->txn_begin;
 135
 136     my $patron = $builder->build_object(
 137         {
 138             class => 'Koha::Patrons',
 139             value => { flags => 0 }
 140         }
 141     );
 142     my $password = 'thePassword123';
 143     $patron->set_password( { password => $password, skip_validation => 1 } );
 144     $patron->discard_changes;
 145     my $userid = $patron->userid;
 146
 147     my $biblio = $builder->build_sample_biblio();
 148     $t->get_ok("//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/items")
 149       ->status_is(403);
 150
 151     $patron->flags(4)->store;
 152
 153     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/items")
 154       ->status_is(200)
 155       ->json_is( '' => [], 'No items on the biblio' );
 156
 157     my $item_1 = $builder->build_sample_item({ biblionumber => $biblio->biblionumber });
 158     my $item_2 = $builder->build_sample_item({ biblionumber => $biblio->biblionumber });
 159
 160     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/items")
 161       ->status_is(200)
 162       ->json_is( '' => [ $item_1->to_api, $item_2->to_api ], 'The items are returned' );
 163
 164     $schema->storage->txn_rollback;
 165 };
 166
 167 subtest 'delete() tests' => sub {
 168
 169     plan tests => 9;
 170
 171     $schema->storage->txn_begin;
 172
 173     my $patron = $builder->build_object(
 174         {
 175             class => 'Koha::Patrons',
 176             value => { flags => 0 } # no permissions
 177         }
 178     );
 179     my $password = 'thePassword123';
 180     $patron->set_password( { password => $password, skip_validation => 1 } );
 181     my $userid = $patron->userid;
 182
 183     my $item      = $builder->build_sample_item();
 184     my $biblio_id = $item->biblionumber;
 185
 186     $t->delete_ok("//$userid:$password@/api/v1/biblios/$biblio_id")
 187       ->status_is(403, 'Not enough permissions makes it return the right code');
 188
 189     # Add permissions
 190     $builder->build(
 191         {
 192             source => 'UserPermission',
 193             value  => {
 194                 borrowernumber => $patron->borrowernumber,
 195                 module_bit     => 9,
 196                 code           => 'edit_catalogue'
 197             }
 198         }
 199     );
 200
 201
 202     # Bibs with items cannot be deleted
 203     $t->delete_ok("//$userid:$password@/api/v1/biblios/$biblio_id")
 204       ->status_is(409);
 205
 206     $item->delete();
 207
 208     # Bibs with no items can be deleted
 209     $t->delete_ok("//$userid:$password@/api/v1/biblios/$biblio_id")
 210       ->status_is(204, 'SWAGGER3.2.4')
 211       ->content_is('', 'SWAGGER3.3.4');
 212
 213     $t->delete_ok("//$userid:$password@/api/v1/biblios/$biblio_id")
 214       ->status_is(404);
 215
 216     $schema->storage->txn_rollback;
 217 };
 218
 219 subtest 'get_public() tests' => sub {
 220
 221     plan tests => 25;
 222
 223     $schema->storage->txn_begin;
 224
 225     my $category = $builder->build_object({ class => 'Koha::Patron::Categories' });
 226     my $patron = $builder->build_object(
 227         {
 228             class => 'Koha::Patrons',
 229             value => {
 230                 flags        => undef, # opac user
 231                 categorycode => $category->categorycode
 232             }
 233         }
 234     );
 235     my $password = 'thePassword123';
 236     $patron->set_password( { password => $password, skip_validation => 1 } );
 237     $patron->discard_changes;
 238     my $userid = $patron->userid;
 239
 240     my $biblio = $builder->build_sample_biblio({
 241         title  => 'The unbearable lightness of being',
 242         author => 'Milan Kundera'
 243     });
 244
 245     # Make sure author in shown in the OPAC
 246     my $subfields = Koha::MarcSubfieldStructures->search({ tagfield => '100' });
 247     while ( my $subfield = $subfields->next ) {
 248         $subfield->set({ hidden => -1 })->store;
 249     }
 250     Koha::Caches->get_instance()->flush_all;
 251
 252     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 253                 => { Accept => 'application/weird+format' } )
 254       ->status_is(400);
 255
 256     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 257                  => { Accept => 'text/plain' } )
 258       ->status_is(200)
 259       ->content_like( qr{100\s+_aMilan Kundera} )
 260       ->content_like( qr{245\s+_aThe unbearable lightness of being} );
 261
 262     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 263                  => { Accept => 'application/marcxml+xml' } )
 264       ->status_is(200);
 265
 266     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 267                  => { Accept => 'application/marc-in-json' } )
 268       ->status_is(200);
 269
 270     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 271                  => { Accept => 'application/marc' } )
 272       ->status_is(200);
 273
 274     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 275                  => { Accept => 'text/plain' } )
 276       ->status_is(200)
 277       ->content_is($biblio->metadata->record->as_formatted);
 278
 279     subtest 'anonymous access' => sub {
 280         plan tests => 9;
 281
 282         $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 283                  => { Accept => 'application/marcxml+xml' } )
 284           ->status_is(200);
 285
 286         $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 287                     => { Accept => 'application/marc-in-json' } )
 288         ->status_is(200);
 289
 290         $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 291                     => { Accept => 'application/marc' } )
 292         ->status_is(200);
 293
 294         $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 295                     => { Accept => 'text/plain' } )
 296         ->status_is(200)
 297         ->content_is($biblio->metadata->record->as_formatted);
 298     };
 299
 300     subtest 'marc-in-json encoding tests' => sub {
 301
 302         plan tests => 3;
 303
 304         my $title_with_diacritics = "L'insoutenable légèreté de l'être";
 305
 306         my $biblio = $builder->build_sample_biblio(
 307             {
 308                 title  => $title_with_diacritics,
 309                 author => "Milan Kundera"
 310             }
 311         );
 312
 313         my $result = $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 314                     => { Accept => 'application/marc-in-json' } )
 315           ->status_is(200)->tx->res->body;
 316
 317         my $encoded_title  = Encode::encode( "UTF-8", $title_with_diacritics );
 318
 319         like( $result, qr/\Q$encoded_title/, "The title is not double encoded" );
 320     };
 321
 322     # Hide author in OPAC
 323     $subfields = Koha::MarcSubfieldStructures->search({ tagfield => '100' });
 324     while ( my $subfield = $subfields->next ) {
 325         $subfield->set({ hidden => 1 })->store;
 326     }
 327
 328     Koha::Caches->get_instance()->flush_all;
 329
 330     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 331                  => { Accept => 'text/plain' } )
 332       ->status_is(200)
 333       ->content_unlike( qr{100\s+_aMilan Kundera} )
 334       ->content_like( qr{245\s+_aThe unbearable lightness of being} );
 335
 336     subtest 'hidden_in_opac tests' => sub {
 337
 338         plan tests => 6;
 339
 340         my $biblio_hidden_in_opac = 1;
 341
 342         my $biblio_class = Test::MockModule->new('Koha::Biblio');
 343         # force biblio hidden in OPAC
 344         $biblio_class->mock( 'hidden_in_opac', sub { return $biblio_hidden_in_opac; } );
 345
 346         $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 347                  => { Accept => 'text/plain' } )
 348           ->status_is(404, 'hidden_in_opac + anonymous => hidden');
 349
 350         my $category_override_hidden_items = 0;
 351         my $category_class = Test::MockModule->new('Koha::Patron::Category');
 352         $category_class->mock( 'override_hidden_items', sub { return $category_override_hidden_items; } );
 353         $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 354                  => { Accept => 'text/plain' } )
 355           ->status_is(404, "hidden_in_opac + patron whose category doesn't override => hidden");
 356
 357         # Make the category override
 358         $category_override_hidden_items = 1;
 359         $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 360                  => { Accept => 'text/plain' } )
 361           ->status_is(200, "hidden_in_opac + patron whose category that overrides => displayed");
 362
 363         t::lib::Mocks::mock_preference('OpacHiddenItems');
 364     };
 365
 366     $biblio->delete;
 367     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 368                  => { Accept => 'application/marc' } )
 369       ->status_is(404)
 370       ->json_is( '/error', 'Object not found.' );
 371
 372     $schema->storage->txn_rollback;
 373 };
 374
 375 subtest 'pickup_locations() tests' => sub {
 376
 377     plan tests => 16;
 378
 379     $schema->storage->txn_begin;
 380
 381     t::lib::Mocks::mock_preference( 'AllowHoldPolicyOverride', 0 );
 382
 383     # Small trick to ease testing
 384     Koha::Libraries->search->update({ pickup_location => 0 });
 385
 386     my $library_1 = $builder->build_object({ class => 'Koha::Libraries', value => { marcorgcode => 'A', pickup_location => 1 } });
 387     my $library_2 = $builder->build_object({ class => 'Koha::Libraries', value => { marcorgcode => 'B', pickup_location => 1 } });
 388     my $library_3 = $builder->build_object({ class => 'Koha::Libraries', value => { marcorgcode => 'C', pickup_location => 1 } });
 389
 390     my $library_1_api = $library_1->to_api();
 391     my $library_2_api = $library_2->to_api();
 392     my $library_3_api = $library_3->to_api();
 393
 394     $library_1_api->{needs_override} = Mojo::JSON->false;
 395     $library_2_api->{needs_override} = Mojo::JSON->false;
 396     $library_3_api->{needs_override} = Mojo::JSON->true;
 397
 398     my $patron = $builder->build_object(
 399         {
 400             class => 'Koha::Patrons',
 401             value => { userid => 'tomasito', flags => 0 }
 402         }
 403     );
 404     my $password = 'thePassword123';
 405     $patron->set_password( { password => $password, skip_validation => 1 } );
 406     my $userid = $patron->userid;
 407     $builder->build(
 408         {
 409             source => 'UserPermission',
 410             value  => {
 411                 borrowernumber => $patron->borrowernumber,
 412                 module_bit     => 6,
 413                 code           => 'place_holds',
 414             },
 415         }
 416     );
 417
 418     my $biblio_class = Test::MockModule->new('Koha::Biblio');
 419     $biblio_class->mock(
 420         'pickup_locations',
 421         sub {
 422             my ( $self, $params ) = @_;
 423             my $mock_patron = $params->{patron};
 424             is( $mock_patron->borrowernumber,
 425                 $patron->borrowernumber, 'Patron passed correctly' );
 426             return Koha::Libraries->search(
 427                 {
 428                     branchcode => {
 429                         '-in' => [
 430                             $library_1->branchcode,
 431                             $library_2->branchcode
 432                         ]
 433                     }
 434                 },
 435                 {   # we make sure no surprises in the order of the result
 436                     order_by => { '-asc' => 'marcorgcode' }
 437                 }
 438             );
 439         }
 440     );
 441
 442     my $biblio = $builder->build_sample_biblio;
 443
 444     $t->get_ok( "//$userid:$password@/api/v1/biblios/"
 445           . $biblio->id
 446           . "/pickup_locations?patron_id=" . $patron->id )
 447       ->json_is( [ $library_1_api, $library_2_api ] );
 448
 449     # filtering works!
 450     $t->get_ok( "//$userid:$password@/api/v1/biblios/"
 451           . $biblio->id
 452           . '/pickup_locations?'
 453           . 'patron_id=' . $patron->id . '&q={"marc_org_code": { "-like": "A%" }}' )
 454       ->json_is( [ $library_1_api ] );
 455
 456     t::lib::Mocks::mock_preference( 'AllowHoldPolicyOverride', 1 );
 457
 458     my $library_4 = $builder->build_object({ class => 'Koha::Libraries', value => { pickup_location => 0, marcorgcode => 'X' } });
 459     my $library_5 = $builder->build_object({ class => 'Koha::Libraries', value => { pickup_location => 1, marcorgcode => 'Y' } });
 460
 461     my $library_5_api = $library_5->to_api();
 462     $library_5_api->{needs_override} = Mojo::JSON->true;
 463
 464     $t->get_ok( "//$userid:$password@/api/v1/biblios/"
 465           . $biblio->id
 466           . "/pickup_locations?"
 467           . "patron_id=" . $patron->id . "&_order_by=marc_org_code" )
 468       ->json_is( [ $library_1_api, $library_2_api, $library_3_api, $library_5_api ] );
 469
 470     subtest 'Pagination and AllowHoldPolicyOverride tests' => sub {
 471
 472         plan tests => 27;
 473
 474         t::lib::Mocks::mock_preference( 'AllowHoldPolicyOverride', 1 );
 475
 476         $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->id . "/pickup_locations?" . "patron_id=" . $patron->id . "&_order_by=marc_org_code" . "&_per_page=1" )
 477           ->json_is( [$library_1_api] )
 478           ->header_is( 'X-Total-Count', '4', '4 is the count for libraries with pickup_location=1' )
 479           ->header_is( 'X-Base-Total-Count', '4', '4 is the count for libraries with pickup_location=1' )
 480           ->header_unlike( 'Link', qr|rel="prev"| )
 481           ->header_like( 'Link', qr#(_per_page=1.*\&_page=2.*|_page=2.*\&_per_page=1.*)>\; rel="next"# )
 482           ->header_like( 'Link', qr#(_per_page=1.*\&_page=1.*|_page=1.*\&_per_page=1).*>\; rel="first"# )
 483           ->header_like( 'Link', qr#(_per_page=1.*\&_page=4.*|_page=4.*\&_per_page=1).*>\; rel="last"# );
 484
 485         $t->get_ok( "//$userid:$password@/api/v1/biblios/"
 486               . $biblio->id
 487               . "/pickup_locations?"
 488               . "patron_id="
 489               . $patron->id
 490               . "&_order_by=marc_org_code"
 491               . "&_per_page=1&_page=3" )    # force the needs_override=1 check
 492           ->json_is( [$library_3_api] )
 493           ->header_is( 'X-Total-Count', '4', '4 is the count for libraries with pickup_location=1' )
 494           ->header_is( 'X-Base-Total-Count', '4', '4 is the count for libraries with pickup_location=1' )
 495           ->header_like( 'Link', qr#(_per_page=1.*\&_page=2.*|_page=2.*\&_per_page=1.*)>\; rel="prev"# )
 496           ->header_like( 'Link', qr#(_per_page=1.*\&_page=4.*|_page=4.*\&_per_page=1.*)>\; rel="next"# )
 497           ->header_like( 'Link', qr#(_per_page=1.*\&_page=1.*|_page=1.*\&_per_page=1).*>\; rel="first"# )
 498           ->header_like( 'Link', qr#(_per_page=1.*\&_page=4.*|_page=4.*\&_per_page=1).*>\; rel="last"# );
 499
 500         t::lib::Mocks::mock_preference( 'AllowHoldPolicyOverride', 0 );
 501
 502         $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->id . "/pickup_locations?" . "patron_id=" . $patron->id . "&_order_by=marc_org_code" . "&_per_page=1" )
 503           ->json_is( [$library_1_api] )
 504           ->header_is( 'X-Total-Count', '2' )
 505           ->header_is( 'X-Base-Total-Count', '2' )
 506           ->header_unlike( 'Link', qr|rel="prev"| )
 507           ->header_like( 'Link', qr#(_per_page=1.*\&_page=2.*|_page=2.*\&_per_page=1.*)>\; rel="next"# )
 508           ->header_like( 'Link', qr#(_per_page=1.*\&_page=1.*|_page=1.*\&_per_page=1).*>\; rel="first"# )
 509           ->header_like( 'Link', qr#(_per_page=1.*\&_page=2.*|_page=2.*\&_per_page=1).*>\; rel="last"# );
 510     };
 511
 512     my $deleted_patron = $builder->build_object({ class => 'Koha::Patrons' });
 513     my $deleted_patron_id = $deleted_patron->id;
 514     $deleted_patron->delete;
 515
 516     $t->get_ok( "//$userid:$password@/api/v1/biblios/"
 517           . $biblio->id
 518           . "/pickup_locations?"
 519           . "patron_id=" . $deleted_patron_id )
 520       ->status_is( 400 )
 521       ->json_is( '/error' => 'Patron not found' );
 522
 523     $biblio->delete;
 524
 525     $t->get_ok( "//$userid:$password@/api/v1/biblios/"
 526           . $biblio->id
 527           . "/pickup_locations?"
 528           . "patron_id=" . $patron->id )
 529       ->status_is( 404 )
 530       ->json_is( '/error' => 'Biblio not found' );
 531
 532     $schema->storage->txn_rollback;
 533 };
 534
 535 subtest 'get_items_public() tests' => sub {
 536
 537     plan tests => 15;
 538
 539     $schema->storage->txn_begin;
 540
 541     my $override_hidden_items = 0;
 542
 543     my $mocked_category = Test::MockModule->new('Koha::Patron::Category');
 544     $mocked_category->mock(
 545         'override_hidden_items',
 546         sub {
 547             return $override_hidden_items;
 548         }
 549     );
 550
 551     my $rules = undef;
 552
 553     my $mocked_context = Test::MockModule->new('C4::Context');
 554     $mocked_context->mock(
 555         'yaml_preference',
 556         sub {
 557             return $rules;
 558         }
 559     );
 560
 561     my $patron   = $builder->build_object( { class => 'Koha::Patrons' } );
 562     my $password = 'thePassword123';
 563     $patron->set_password( { password => $password, skip_validation => 1 } );
 564     $patron->discard_changes;
 565     my $userid = $patron->userid;
 566
 567     my $biblio = $builder->build_sample_biblio();
 568
 569     $t->get_ok(
 570         "//$userid:$password@/api/v1/public/biblios/" . $biblio->id . "/items" )
 571       ->status_is(200)->json_is( '' => [], 'No items on the biblio' );
 572
 573     my $item_1 = $builder->build_sample_item( { biblionumber => $biblio->id } );
 574     my $item_2 = $builder->build_sample_item(
 575         { biblionumber => $biblio->id, withdrawn => 1 } );
 576
 577     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/"
 578           . $biblio->biblionumber
 579           . "/items" )->status_is(200)->json_is(
 580         '' => [
 581             $item_1->to_api( { public => 1 } ),
 582             $item_2->to_api( { public => 1 } )
 583         ],
 584         'The items are returned'
 585           );
 586
 587     $rules = { withdrawn => ['1'] };
 588
 589     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/"
 590           . $biblio->biblionumber
 591           . "/items" )->status_is(200)->json_is(
 592         '' => [ $item_1->to_api( { public => 1 } ) ],
 593         'The items are returned, hidden one is not returned'
 594           );
 595
 596     $t->get_ok( "/api/v1/public/biblios/"
 597           . $biblio->biblionumber
 598           . "/items" )->status_is(200)->json_is(
 599         '' => [ $item_1->to_api( { public => 1 } ) ],
 600         'Anonymous user, items are returned, hidden one is not returned'
 601           );
 602
 603
 604     $override_hidden_items = 1;
 605
 606     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/"
 607           . $biblio->biblionumber
 608           . "/items" )->status_is(200)->json_is(
 609         '' => [
 610             $item_1->to_api( { public => 1 } ),
 611             $item_2->to_api( { public => 1 } )
 612         ],
 613         'The items are returned, the patron category has an override'
 614           );
 615
 616     $schema->storage->txn_rollback;
 617 };
 618
 619 subtest 'get_checkouts() tests' => sub {
 620
 621     plan tests => 14;
 622
 623     $schema->storage->txn_begin;
 624
 625     my $patron = $builder->build_object(
 626         {
 627             class => 'Koha::Patrons',
 628             value => { flags => 0 }
 629         }
 630     );
 631     my $password = 'thePassword123';
 632     $patron->set_password( { password => $password, skip_validation => 1 } );
 633     $patron->discard_changes;
 634     my $userid = $patron->userid;
 635
 636     my $biblio = $builder->build_sample_biblio();
 637     $t->get_ok("//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/checkouts")
 638       ->status_is(403);
 639
 640     $patron->flags(1)->store; # circulate permissions
 641
 642     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/checkouts")
 643       ->status_is(200)
 644       ->json_is( '' => [], 'No checkouts on the biblio' );
 645
 646     my $item_1 = $builder->build_sample_item({ biblionumber => $biblio->biblionumber });
 647     my $item_2 = $builder->build_sample_item({ biblionumber => $biblio->biblionumber });
 648
 649     AddIssue( $patron->unblessed, $item_1->barcode );
 650     AddIssue( $patron->unblessed, $item_2->barcode );
 651
 652     my $ret = $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/checkouts")
 653       ->status_is(200)
 654       ->tx->res->json;
 655
 656     my $checkout_1 = Koha::Checkouts->find({ itemnumber => $item_1->id });
 657     my $checkout_2 = Koha::Checkouts->find({ itemnumber => $item_2->id });
 658
 659     is_deeply( $ret, [ $checkout_1->to_api, $checkout_2->to_api ] );
 660
 661     AddReturn( $item_1->barcode );
 662
 663     $ret = $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/checkouts")
 664       ->status_is(200)
 665       ->tx->res->json;
 666
 667     is_deeply( $ret, [ $checkout_2->to_api ] );
 668
 669     $ret = $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/checkouts?checked_in=1")
 670       ->status_is(200)
 671       ->tx->res->json;
 672
 673     my $old_checkout_1 = Koha::Old::Checkouts->find( $checkout_1->id );
 674
 675     is_deeply( $ret, [ $old_checkout_1->to_api ] );
 676
 677     $schema->storage->txn_rollback;
 678 };
 679
 680 subtest 'set_rating() tests' => sub {
 681
 682     plan tests => 12;
 683
 684     $schema->storage->txn_begin;
 685
 686     my $patron = $builder->build_object(
 687         {
 688             class => 'Koha::Patrons',
 689             value => { flags => 0 }
 690         }
 691     );
 692     my $password = 'thePassword123';
 693     $patron->set_password( { password => $password, skip_validation => 1 } );
 694     $patron->discard_changes;
 695     my $userid = $patron->userid;
 696
 697     my $biblio = $builder->build_sample_biblio();
 698     $t->post_ok("/api/v1/public/biblios/" . $biblio->biblionumber . "/ratings" => json => { rating => 3 })
 699       ->status_is(403);
 700
 701     $t->post_ok("//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber . "/ratings" => json => { rating => 3 })
 702       ->status_is(200)
 703       ->json_is( '/rating', '3' )
 704       ->json_is( '/average', '3' )
 705       ->json_is( '/count', '1' );
 706
 707     $t->post_ok("//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber . "/ratings" => json => { rating => undef })
 708       ->status_is(200)
 709       ->json_is( '/rating', undef )
 710       ->json_is( '/average', '0' )
 711       ->json_is( '/count', '0' );
 712
 713     $schema->storage->txn_rollback;
 714
 715 };