C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use Carp qw( croak );
  22
  23 use C4::Context;
  24 use C4::Members::Messaging;
  25 use C4::Auth qw( checkpw_internal );
  26 use C4::Letters qw( GetPreparedLetter EnqueueLetter SendQueuedMessages );
  27 use Koha::Patrons;
  28 use Koha::AuthUtils qw( hash_password );
  29 use Net::LDAP;
  30 use Net::LDAP::Filter;
  31
  32 our (@ISA, @EXPORT_OK);
  33 BEGIN {
  34         require Exporter;
  35         @ISA    = qw(Exporter);
  36         @EXPORT_OK = qw( checkpw_ldap );
  37 }
  38
  39 # Redefine checkpw_ldap:
  40 # connect to LDAP (named or anonymous)
  41 # ~ retrieves $userid from KOHA_CONF mapping
  42 # ~ then compares $password with userPassword
  43 # ~ then gets the LDAP entry
  44 # ~ and calls the memberadd if necessary
  45
  46 sub ldapserver_error {
  47         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  48 }
  49
  50 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  51 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  52 # since Bug 28278 we need to skip id in <ldapserver id="ldapserver"> which generates additional hash level
  53 if ( exists $ldap->{ldapserver} ) {
  54     $ldap = $ldap->{ldapserver}         or die ldapserver_error('id="ldapserver"');
  55 }
  56 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  57 my $base      = $ldap->{base}           or die ldapserver_error('base');
  58 $ldapname     = $ldap->{user}           ;
  59 $ldappassword = $ldap->{pass}           ;
  60 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  61 my @mapkeys = keys %mapping;
  62 #warn "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  63 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  64 #warn "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  65
  66 my %categorycode_conversions;
  67 my $default_categorycode;
  68 if(defined $ldap->{categorycode_mapping}) {
  69     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  70     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  71         $categorycode_conversions{$cat->{value}} = $cat->{content};
  72     }
  73 }
  74
  75 my %config = (
  76     anonymous => defined ($ldap->{anonymous_bind}) ? $ldap->{anonymous_bind} : 1,
  77     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  78     welcome   => defined($ldap->{welcome}) ? $ldap->{welcome} : 0,  #    send welcome notice when patron is added via replicate
  79     update    => defined($ldap->{update}) ? $ldap->{update} : 1,  # update from LDAP to Koha database for existing user
  80 );
  81
  82 sub description {
  83         my $result = shift or return;
  84         return "LDAP error #" . $result->code
  85                         . ": " . $result->error_name . "\n"
  86                         . "# " . $result->error_text . "\n";
  87 }
  88
  89 sub search_method {
  90     my $db     = shift or return;
  91     my $userid = shift or return;
  92         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  93         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  94         my $search = $db->search(
  95                   base => $base,
  96                 filter => $filter,
  97                 # attrs => ['*'],
  98     );
  99     die "LDAP search failed to return object : " . $search->error if $search->code;
 100
 101         my $count = $search->count;
 102         if ($search->code > 0) {
 103                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 104                 return 0;
 105         }
 106     if ($count == 0) {
 107         warn sprintf("LDAP Auth rejected : search with filter '%s' returns no hit\n", $filter->as_string);
 108         return 0;
 109     }
 110     return $search;
 111 }
 112
 113 sub checkpw_ldap {
 114     my ($userid, $password) = @_;
 115     my @hosts = split(',', $prefhost);
 116     my $db = Net::LDAP->new(\@hosts);
 117     unless ( $db ) {
 118         warn "LDAP connexion failed";
 119         return 0;
 120     }
 121
 122     my $userldapentry;
 123
 124     # first, LDAP authentication
 125     if ( $ldap->{auth_by_bind} ) {
 126         my $principal_name;
 127         if ( $config{anonymous} ) {
 128
 129             # Perform an anonymous bind
 130             my $res = $db->bind;
 131             if ( $res->code ) {
 132                 warn "Anonymous LDAP bind failed: " . description($res);
 133                 return 0;
 134             }
 135
 136             # Perform a LDAP search for the given username
 137             my $search = search_method( $db, $userid )
 138               or return 0;    # warnings are in the sub
 139             $userldapentry = $search->shift_entry;
 140             $principal_name = $userldapentry->dn;
 141         }
 142         else {
 143             $principal_name = $ldap->{principal_name};
 144             if ( $principal_name and $principal_name =~ /\%/ ) {
 145                 $principal_name = sprintf( $principal_name, $userid );
 146             }
 147             else {
 148                 $principal_name = $userid;
 149             }
 150         }
 151
 152         # Perform a LDAP bind for the given username using the matched DN
 153         my $res = $db->bind( $principal_name, password => $password );
 154         if ( $res->code ) {
 155             if ( $config{anonymous} ) {
 156                 # With anonymous_bind approach we can be sure we have found the correct user
 157                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 158                 # or password changed). We should not fall back to local accounts in this case.
 159                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 160                 return -1;
 161             } else {
 162                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 163                 # at all, and thus we should fall back to local logins to restore previous behaviour
 164                 # see bug 12831
 165                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 166                 return 0;
 167             }
 168         }
 169         if ( !defined($userldapentry)
 170             && ( $config{update} or $config{replicate} ) )
 171         {
 172             my $search = search_method( $db, $userid ) or return 0;
 173             $userldapentry = $search->shift_entry;
 174         }
 175     } else {
 176         my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 177                 if ($res->code) {               # connection refused
 178                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 179                         return 0;
 180                 }
 181         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 182         # Handle multiple branches. Same login exists several times in different branches.
 183         my $bind_ok = 0;
 184         while (my $entry = $search->shift_entry) {
 185             my $user_ldap_bind_ret = $db->bind($entry->dn, password => $password);
 186             unless ($user_ldap_bind_ret->code) {
 187                 $userldapentry = $entry;
 188                 $bind_ok = 1;
 189                 last;
 190             }
 191         }
 192
 193         unless ($bind_ok) {
 194             warn "LDAP Auth rejected : invalid password for user '$userid'.";
 195             return -1;
 196         }
 197
 198
 199     }
 200
 201     # To get here, LDAP has accepted our user's login attempt.
 202     # But we still have work to do.  See perldoc below for detailed breakdown.
 203
 204     my (%borrower);
 205         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 206
 207     my $patron;
 208     if (( $borrowernumber and $config{update}   ) or
 209         (!$borrowernumber and $config{replicate})   ) {
 210         %borrower = ldap_entry_2_hash($userldapentry,$cardnumber);
 211         #warn "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 212     }
 213
 214     if ($borrowernumber) {
 215         if ($config{update}) { # A1, B1
 216             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 217             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 218         } else { # C1, D1
 219             # maybe update just the password?
 220                 return(1, $cardnumber, $local_userid);
 221         }
 222     } elsif ($config{replicate}) { # A2, C2
 223         my @columns = Koha::Patrons->columns;
 224         $patron = Koha::Patron->new(
 225             {
 226                 map { exists( $borrower{$_} ) ? ( $_ => $borrower{$_} ) : () } @columns
 227             }
 228         )->store;
 229         die "Insert of new patron failed" unless $patron;
 230         $borrowernumber = $patron->borrowernumber;
 231         C4::Members::Messaging::SetMessagingPreferencesFromDefaults(
 232             {
 233                 borrowernumber => $borrowernumber,
 234                 categorycode   => $borrower{'categorycode'}
 235             }
 236         );
 237
 238         # Send welcome email if enabled
 239         if ( $config{welcome} ) {
 240             my $emailaddr = $patron->notice_email_address;
 241
 242             # if we manage to find a valid email address, send notice
 243             if ($emailaddr) {
 244                 my $letter = C4::Letters::GetPreparedLetter(
 245                     module      => 'members',
 246                     letter_code => 'WELCOME',
 247                     branchcode  => $patron->branchcode,
 248                     lang        => $patron->lang || 'default',
 249                     tables      => {
 250                         'branches'  => $patron->branchcode,
 251                         'borrowers' => $patron->borrowernumber,
 252                     },
 253                     want_librarian => 1,
 254                 ) or return;
 255
 256                 my $message_id = C4::Letters::EnqueueLetter(
 257                     {
 258                         letter                 => $letter,
 259                         borrowernumber         => $patron->id,
 260                         to_address             => $emailaddr,
 261                         message_transport_type => 'email'
 262                     }
 263                 );
 264
 265                 C4::Letters::SendQueuedMessages( { message_id => $message_id } ) if $message_id;
 266             }
 267         }
 268    } else {
 269         return 0;   # B2, D2
 270     }
 271     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 272         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 273         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 274         while ( my $attribute_type = $attribute_types->next ) {
 275             my $code = $attribute_type->code;
 276             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 277                 next;
 278             }
 279             $patron = Koha::Patrons->find($borrowernumber);
 280             if ( $patron ) { # Should not be needed, but we are in C4::Auth LDAP...
 281                 eval {
 282                     my $attribute = Koha::Patron::Attribute->new({code => $code, attribute => $borrower{$code}});
 283                     $patron->extended_attributes([$attribute->unblessed]);
 284                 };
 285                 if ($@) { # FIXME Test if Koha::Exceptions::Patron::Attribute::NonRepeatable
 286                     warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 287                 }
 288             }
 289         }
 290     }
 291     return(1, $cardnumber, $userid, $patron);
 292 }
 293
 294 # Pass LDAP entry object and local cardnumber (userid).
 295 # Returns borrower hash.
 296 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 297 # Ensure that mandatory fields are correctly filled!
 298 #
 299 sub ldap_entry_2_hash {
 300         my $userldapentry = shift;
 301         my %borrower = ( cardnumber => shift );
 302         my %memberhash;
 303         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 304     #foreach (keys %$userldapentry) {
 305     #    print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 306     #}
 307         my $x = $userldapentry->{attrs} or return;
 308         foreach (keys %$x) {
 309                 $memberhash{$_} = join ' ', @{$x->{$_}};
 310         #warn sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 311         }
 312     #warn "Finished \%memberhash has ", scalar(keys %memberhash), " keys\n", "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 313         foreach my $key (keys %mapping) {
 314                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 315         #warn "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 316                 unless (defined $data) {
 317             $data = $mapping{$key}->{content} || undef;
 318                 }
 319         $borrower{$key} = $data;
 320         }
 321         $borrower{initials} = $memberhash{initials} ||
 322                 ( substr($borrower{'firstname'},0,1)
 323                 . substr($borrower{ 'surname' },0,1)
 324                 . " ");
 325
 326     # categorycode conversions
 327     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 328         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 329     }
 330     elsif($default_categorycode) {
 331         $borrower{categorycode} = $default_categorycode;
 332     }
 333
 334         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 335         my $dbh = C4::Context->dbh;
 336         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 337         $sth->execute( uc($borrower{'categorycode'}) );
 338         unless ( my $row = $sth->fetchrow_hashref ) {
 339                 my $default = $mapping{'categorycode'}->{content};
 340         #warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 341                 $borrower{'categorycode'} = $default
 342         }
 343
 344         return %borrower;
 345 }
 346
 347 sub exists_local {
 348         my $arg = shift;
 349         my $dbh = C4::Context->dbh;
 350         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 351
 352         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 353         $sth->execute($arg);
 354     #warn "Userid '$arg' exists_local? %s\n", $sth->rows;
 355         ($sth->rows == 1) and return $sth->fetchrow;
 356
 357         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 358         $sth->execute($arg);
 359     #warn "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 360         ($sth->rows == 1) and return $sth->fetchrow;
 361         return 0;
 362 }
 363
 364 # This function performs a password update, given the userid, borrowerid,
 365 # and digested password. It will verify that things are correct and return the
 366 # borrowers cardnumber. The idea is that it is used to keep the local
 367 # passwords in sync with the LDAP passwords.
 368 #
 369 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 370 #
 371 # Note: if the LDAP config has the update_password tag set to a false value,
 372 # then this will not update the password, it will simply return the cardnumber.
 373 sub _do_changepassword {
 374     my ($userid, $borrowerid, $password) = @_;
 375
 376     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 377
 378         # We don't store the password in the database
 379         my $sth = C4::Context->dbh->prepare(
 380             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 381         $sth->execute($borrowerid);
 382         die "Unable to access borrowernumber "
 383             . "with userid=$userid, "
 384             . "borrowernumber=$borrowerid"
 385           if !$sth->rows;
 386         my ($cardnum) = $sth->fetchrow;
 387         $sth = C4::Context->dbh->prepare(
 388             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 389         $sth->execute($borrowerid);
 390         return $cardnum;
 391     }
 392
 393     my $digest = hash_password($password);
 394     #warn "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 395     Koha::Patrons->find($borrowerid)->set_password({ password => $password, skip_validation => 1 });
 396
 397     my ($ok, $cardnum) = checkpw_internal($userid, $password);
 398     return $cardnum if $ok;
 399
 400     warn "Password mismatch after update to borrowernumber=$borrowerid";
 401     return;
 402 }
 403
 404 sub update_local {
 405     my $userid     = shift or croak "No userid";
 406     my $password   = shift or croak "No password";
 407     my $borrowerid = shift or croak "No borrowerid";
 408     my $borrower   = shift or croak "No borrower record";
 409
 410     # skip extended patron attributes in 'borrowers' attribute update
 411     my @keys = keys %$borrower;
 412     if (C4::Context->preference('ExtendedPatronAttributes')) {
 413         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 414         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 415         while ( my $attribute_type = $attribute_types->next ) {
 416            my $code = $attribute_type->code;
 417            @keys = grep { $_ ne $code } @keys;
 418            #warn "ignoring extended patron attribute '%s' in update_local()\n", $code;
 419         }
 420     }
 421
 422     my $dbh = C4::Context->dbh;
 423     my $query = "UPDATE  borrowers\nSET     " .
 424         join(',', map {"$_=?"} @keys) .
 425         "\nWHERE   borrowernumber=? ";
 426     my $sth = $dbh->prepare($query);
 427     #warn $query, "\n", join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 428     #warn "\nuserid = $userid\n";
 429     $sth->execute(
 430         ((map {$borrower->{$_}} @keys), $borrowerid)
 431     );
 432
 433     # MODIFY PASSWORD/LOGIN if password was mapped
 434     _do_changepassword($userid, $borrowerid, $password) if exists( $borrower->{'password'} );
 435 }
 436
 437 1;
 438 __END__
 439
 440 =head1 NAME
 441
 442 C4::Auth - Authenticates Koha users
 443
 444 =head1 SYNOPSIS
 445
 446   use C4::Auth_with_ldap;
 447
 448 =head1 LDAP Configuration
 449
 450     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 451         working LDAP servers.
 452         To use it :
 453            * Modify ldapserver element in KOHA_CONF
 454            * Establish field mapping in <mapping> element.
 455
 456         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 457         the username would match the "uid" field, and the password should match the "userpassword" field.
 458
 459         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 460         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 461
 462         mysql> show COLUMNS from borrowers;
 463                 +---------------------+--------------+------+-----+---------+----------------+
 464                 | Field               | Type         | Null | Key | Default | Extra          |
 465                 +---------------------+--------------+------+-----+---------+----------------+
 466                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 467                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 468                 | surname             | mediumtext   | NO   |     | NULL    |                |
 469                 | firstname           | text         | YES  |     | NULL    |                |
 470                 | title               | mediumtext   | YES  |     | NULL    |                |
 471                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 472                 | initials            | text         | YES  |     | NULL    |                |
 473                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 474                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 475                 | address             | mediumtext   | NO   |     | NULL    |                |
 476                 | address2            | text         | YES  |     | NULL    |                |
 477                 | city                | mediumtext   | NO   |     | NULL    |                |
 478                 | state               | mediumtext   | YES  |     | NULL    |                |
 479                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 480                 | country             | text         | YES  |     | NULL    |                |
 481                 | email               | mediumtext   | YES  |     | NULL    |                |
 482                 | phone               | text         | YES  |     | NULL    |                |
 483                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 484                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 485                 | emailpro            | text         | YES  |     | NULL    |                |
 486                 | phonepro            | text         | YES  |     | NULL    |                |
 487                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 488                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 489                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 490                 | B_address2          | text         | YES  |     | NULL    |                |
 491                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 492                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 493                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 494                 | B_country           | text         | YES  |     | NULL    |                |
 495                 | B_email             | text         | YES  |     | NULL    |                |
 496                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 497                 | dateofbirth         | date         | YES  |     | NULL    |                |
 498                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 499                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 500                 | dateenrolled        | date         | YES  |     | NULL    |                |
 501                 | dateexpiry          | date         | YES  |     | NULL    |                |
 502                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 503                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 504                 | debarred            | date         | YES  |     | NULL    |                |
 505                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 506                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 507                 | contactfirstname    | text         | YES  |     | NULL    |                |
 508                 | contacttitle        | text         | YES  |     | NULL    |                |
 509                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 510                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 511                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 512                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 513                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 514                 | password            | varchar(30)  | YES  |     | NULL    |                |
 515                 | flags               | int(11)      | YES  |     | NULL    |                |
 516                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 517                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 518                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 519                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 520                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 521                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 522                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 523                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 524                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 525                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 526                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 527                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 528                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 529                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 530                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 531                 | privacy             | int(11)      | NO   |     | 1       |                |
 532                 +---------------------+--------------+------+-----+---------+----------------+
 533                 66 rows in set (0.00 sec)
 534                 Where Null="NO", the field is required.
 535
 536 =head1 KOHA_CONF and field mapping
 537
 538 Example XML stanza for LDAP configuration in KOHA_CONF.
 539
 540  <config>
 541   ...
 542   <useldapserver>1</useldapserver>
 543   <!-- LDAP SERVER (optional) -->
 544   <ldapserver id="ldapserver">
 545     <hostname>localhost</hostname>
 546     <base>dc=metavore,dc=com</base>
 547     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 548     <pass>metavore</pass>          <!-- password, if not anonymous -->
 549     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 550     <welcome>1</welcome>           <!-- send new users the welcome email when added via replicate -->
 551     <update>1</update>             <!-- update existing users in Koha database -->
 552     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 553                                         password comparison, e.g., to use Active Directory -->
 554     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 555                                             an anonymous bind, even when auth_by_bind is on -->
 556     <principal_name>%s@my_domain.com</principal_name>
 557                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 558                                         Not used with anonymous_bind. -->
 559     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 560                                               synced to the local database -->
 561     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 562       <firstname    is="givenname"      ></firstname>
 563       <surname      is="sn"             ></surname>
 564       <address      is="postaladdress"  ></address>
 565       <city         is="l"              >Athens, OH</city>
 566       <zipcode      is="postalcode"     ></zipcode>
 567       <branchcode   is="branch"         >MAIN</branchcode>
 568       <userid       is="uid"            ></userid>
 569       <password     is="userpassword"   ></password>
 570       <email        is="mail"           ></email>
 571       <categorycode is="employeetype"   >PT</categorycode>
 572       <phone        is="telephonenumber"></phone>
 573     </mapping>
 574   </ldapserver>
 575  </config>
 576
 577 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 578 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 579 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 580 patron).
 581
 582 =head1 CONFIGURATION
 583
 584 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 585 your configuration and the presence of a matching Koha user in your local DB:
 586
 587                          LOCAL_USER
 588  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 589    A1      1       1        1      OK : We're updating them anyway.
 590    A2      1       1        0      OK : We're adding them anyway.
 591    B1      1       0        1      OK : We update them.
 592    B2      1       0        0     FAIL: We cannot add new user.
 593    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 594    C2      0       1        0      OK : We add the new user.
 595    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 596    D2      0       0        0     FAIL: We cannot add new user.
 597
 598 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 599 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 600 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 601
 602 If you choose NOT to update local users, the borrowers table will not be affected at all.
 603 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 604 the local table never contained the LDAP values.
 605
 606 =head2 auth_by_bind
 607
 608 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 609
 610 =head2 principal_name
 611
 612 Provides an optional sprintf-style format for manipulating the userid before the bind.
 613 Even though the userPrincipalName is one intended target, any uniquely identifying
 614 attribute that the server allows to be used for binding could be used.
 615
 616 Currently, principal_name only operates when auth_by_bind is enabled.
 617
 618 =head2 update_password
 619
 620 If this tag is left out or set to a true value, then the user's LDAP password
 621 will be stored (hashed) in the local Koha database. If you don't want this
 622 to happen, then set the value of this to '0'. Note that if passwords are not
 623 stored locally, and the connection to the LDAP system fails, then the users
 624 will not be able to log in at all.
 625
 626 =head2 Active Directory
 627
 628 The auth_by_bind and principal_name settings are recommended for Active Directory.
 629
 630 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 631 we would typically under openldap.  Instead of:
 632
 633     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 634
 635 We might get:
 636
 637     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 638
 639 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 640 in Koha userids.  But the userPrincipalName should be consistent, something like:
 641
 642     userPrincipalName: barnes.7@my_company.com
 643
 644 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 645 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 646 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 647 like this:
 648     <principal_name>%s@core.my_company.com</principal_name>
 649
 650 The user of the previous example, barnes.7, would then attempt to bind as:
 651     barnes.7@core.my_company.com
 652
 653 =head1 SEE ALSO
 654
 655 CGI(3)
 656
 657 Net::LDAP()
 658
 659 XML::Simple()
 660
 661 Digest::MD5(3)
 662
 663 sprintf()
 664
 665 =cut
 666
 667 # For reference, here's an important difference in the data structure we rely on.
 668 # ========================================
 669 # Using attrs instead of {asn}->attributes
 670 # ========================================
 671 #
 672 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 673 #       LDAP key: ->{             cn}->{           sss} = sss
 674 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 675 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 676 #
 677 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 678 #       LDAP key: ->{      givenname}->{Steve} = Steve
 679 #