C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use C4::Context;
  28 use C4::Stats qw( UpdateStats );
  29 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest );
  30 use C4::Biblio qw( UpdateTotalIssues );
  31 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  32 use C4::Accounts;
  33 use C4::ItemCirculationAlertPreference;
  34 use C4::Message;
  35 use C4::Log qw( logaction ); # logaction
  36 use C4::Overdues;
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits qw( CheckDigits );
  39
  40 use Data::Dumper qw( Dumper );
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Koha::Recalls;
  66 use Carp qw( carp );
  67 use List::MoreUtils qw( any );
  68 use Scalar::Util qw( looks_like_number blessed );
  69 use Date::Calc qw( Date_to_Days );
  70 our (@ISA, @EXPORT_OK);
  71 BEGIN {
  72
  73     require Exporter;
  74     @ISA = qw(Exporter);
  75
  76     # FIXME subs that should probably be elsewhere
  77     push @EXPORT_OK, qw(
  78       barcodedecode
  79       LostItem
  80       ReturnLostItem
  81       GetPendingOnSiteCheckouts
  82
  83       CanBookBeIssued
  84       checkHighHolds
  85       CanBookBeRenewed
  86       AddIssue
  87       GetLoanLength
  88       GetHardDueDate
  89       AddRenewal
  90       GetRenewCount
  91       GetSoonestRenewDate
  92       GetLatestAutoRenewDate
  93       GetIssuingCharges
  94       AddIssuingCharge
  95       GetBranchBorrowerCircRule
  96       GetBranchItemRule
  97       GetBiblioIssues
  98       GetUpcomingDueIssues
  99       CheckIfIssuedToPatron
 100       IsItemIssued
 101       GetAgeRestriction
 102       GetTopIssues
 103
 104       AddReturn
 105       MarkIssueReturned
 106
 107       transferbook
 108       TooMany
 109       GetTransfersFromTo
 110       updateWrongTransfer
 111       CalcDateDue
 112       CheckValidBarcode
 113       IsBranchTransferAllowed
 114       CreateBranchTransferLimit
 115       DeleteBranchTransferLimits
 116       TransferSlip
 117
 118       GetOfflineOperations
 119       GetOfflineOperation
 120       AddOfflineOperation
 121       DeleteOfflineOperation
 122       ProcessOfflineOperation
 123       ProcessOfflinePayment
 124       ProcessOfflineIssue
 125     );
 126     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 127 }
 128
 129 =head1 NAME
 130
 131 C4::Circulation - Koha circulation module
 132
 133 =head1 SYNOPSIS
 134
 135 use C4::Circulation;
 136
 137 =head1 DESCRIPTION
 138
 139 The functions in this module deal with circulation, issues, and
 140 returns, as well as general information about the library.
 141 Also deals with inventory.
 142
 143 =head1 FUNCTIONS
 144
 145 =head2 barcodedecode
 146
 147   $str = &barcodedecode($barcode, [$filter]);
 148
 149 Generic filter function for barcode string.
 150 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 151 Will do some manipulation of the barcode for systems that deliver a barcode
 152 to circulation.pl that differs from the barcode stored for the item.
 153 For proper functioning of this filter, calling the function on the
 154 correct barcode string (items.barcode) should return an unaltered barcode.
 155 Barcode is going to be automatically trimmed of leading/trailing whitespaces.
 156
 157 The optional $filter argument is to allow for testing or explicit
 158 behavior that ignores the System Pref.  Valid values are the same as the
 159 System Pref options.
 160
 161 =cut
 162
 163 # FIXME -- the &decode fcn below should be wrapped into this one.
 164 # FIXME -- these plugins should be moved out of Circulation.pm
 165 #
 166 sub barcodedecode {
 167     my ($barcode, $filter) = @_;
 168
 169     return unless defined $barcode;
 170
 171     my $branch = C4::Context::mybranch();
 172     $barcode =~ s/^\s+|\s+$//g;
 173     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 174     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 175     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 176         if ($filter eq 'whitespace') {
 177                 $barcode =~ s/\s//g;
 178         } elsif ($filter eq 'cuecat') {
 179                 chomp($barcode);
 180             my @fields = split( /\./, $barcode );
 181             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 182             ($#results == 2) and return $results[2];
 183         } elsif ($filter eq 'T-prefix') {
 184                 if ($barcode =~ /^[Tt](\d)/) {
 185                         (defined($1) and $1 eq '0') and return $barcode;
 186             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 187                 }
 188         return sprintf("T%07d", $barcode);
 189         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 190         # Why drop the nonzero digit after the T?
 191         # Why pass non-digits (or empty string) to "T%07d"?
 192         } elsif ($filter eq 'libsuite8') {
 193                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 194                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 195                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 196                         }else{
 197                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 198                         }
 199                 }
 200     } elsif ($filter eq 'EAN13') {
 201         my $ean = CheckDigits('ean');
 202         if ( $ean->is_valid($barcode) ) {
 203             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 204             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 205         } else {
 206             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 207         }
 208         }
 209     return $barcode;    # return barcode, modified or not
 210 }
 211
 212 =head2 _decode
 213
 214   $str = &_decode($chunk);
 215
 216 Decodes a segment of a string emitted by a CueCat barcode scanner and
 217 returns it.
 218
 219 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 220 or Javascript based decoding on the client side.
 221
 222 =cut
 223
 224 sub _decode {
 225     my ($encoded) = @_;
 226     my $seq =
 227       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 228     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 229     my $l = ( $#s + 1 ) % 4;
 230     if ($l) {
 231         if ( $l == 1 ) {
 232             # warn "Error: Cuecat decode parsing failed!";
 233             return;
 234         }
 235         $l = 4 - $l;
 236         $#s += $l;
 237     }
 238     my $r = '';
 239     while ( $#s >= 0 ) {
 240         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 241         $r .=
 242             chr( ( $n >> 16 ) ^ 67 )
 243          .chr( ( $n >> 8 & 255 ) ^ 67 )
 244          .chr( ( $n & 255 ) ^ 67 );
 245         @s = @s[ 4 .. $#s ];
 246     }
 247     $r = substr( $r, 0, length($r) - $l );
 248     return $r;
 249 }
 250
 251 =head2 transferbook
 252
 253   ($dotransfer, $messages, $iteminformation) = &transferbook({
 254                                                    from_branch => $frombranch
 255                                                    to_branch => $tobranch,
 256                                                    barcode => $barcode,
 257                                                    ignore_reserves => $ignore_reserves,
 258                                                    trigger => $trigger
 259                                                 });
 260
 261 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 262
 263 C<$fbr> is the code for the branch initiating the transfer.
 264 C<$tbr> is the code for the branch to which the item should be transferred.
 265
 266 C<$barcode> is the barcode of the item to be transferred.
 267
 268 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 269 Otherwise, if an item is reserved, the transfer fails.
 270
 271 C<$trigger> is the enum value for what triggered the transfer.
 272
 273 Returns three values:
 274
 275 =over
 276
 277 =item $dotransfer
 278
 279 is true if the transfer was successful.
 280
 281 =item $messages
 282
 283 is a reference-to-hash which may have any of the following keys:
 284
 285 =over
 286
 287 =item C<BadBarcode>
 288
 289 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 290
 291 =item C<DestinationEqualsHolding>
 292
 293 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 294
 295 =item C<WasReturned>
 296
 297 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 298
 299 =item C<ResFound>
 300
 301 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 302
 303 =item C<WasTransferred>
 304
 305 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 306
 307 =item C<RecallPlacedAtHoldingBranch>
 308
 309 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 310
 311 =item C<RecallFound>
 312
 313 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 314
 315 =back
 316
 317 =back
 318
 319 =cut
 320
 321 sub transferbook {
 322     my $params = shift;
 323     my $tbr      = $params->{to_branch};
 324     my $fbr      = $params->{from_branch};
 325     my $ignoreRs = $params->{ignore_reserves};
 326     my $barcode  = $params->{barcode};
 327     my $trigger  = $params->{trigger};
 328     my $messages;
 329     my $dotransfer      = 1;
 330     my $item = $barcode ? Koha::Items->find( { barcode => $barcode } ) : undef;
 331
 332     Koha::Exceptions::MissingParameter->throw(
 333         "Missing mandatory parameter: from_branch")
 334       unless $fbr;
 335
 336     Koha::Exceptions::MissingParameter->throw(
 337         "Missing mandatory parameter: to_branch")
 338       unless $tbr;
 339
 340     # bad barcode..
 341     unless ( $item ) {
 342         $messages->{'BadBarcode'} = $barcode;
 343         $dotransfer = 0;
 344         return ( $dotransfer, $messages );
 345     }
 346
 347     my $itemnumber = $item->itemnumber;
 348     # get branches of book...
 349     my $hbr = $item->homebranch;
 350
 351     # if using Branch Transfer Limits
 352     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 353         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 354         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 355             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 356                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 357                 $dotransfer = 0;
 358             }
 359         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 360             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 361             $dotransfer = 0;
 362         }
 363     }
 364
 365     # can't transfer book if is already there....
 366     if ( $fbr eq $tbr ) {
 367         $messages->{'DestinationEqualsHolding'} = 1;
 368         $dotransfer = 0;
 369     }
 370
 371     # check if it is still issued to someone, return it...
 372     my $issue = $item->checkout;
 373     if ( $issue ) {
 374         AddReturn( $barcode, $fbr );
 375         $messages->{'WasReturned'} = $issue->borrowernumber;
 376     }
 377
 378     # find reserves.....
 379     # That'll save a database query.
 380     my ( $resfound, $resrec, undef ) =
 381       CheckReserves( $item );
 382     if ( $resfound ) {
 383         $resrec->{'ResFound'} = $resfound;
 384         $messages->{'ResFound'} = $resrec;
 385         $dotransfer = 0 unless $ignoreRs;
 386     }
 387
 388     # find recall
 389     if ( C4::Context->preference('UseRecalls') ) {
 390         my $recall = Koha::Recalls->find({ item_id => $itemnumber, status => 'in_transit' });
 391         if ( defined $recall ) {
 392             # do a transfer if the recall branch is different to the item holding branch
 393             if ( $recall->pickup_library_id eq $fbr ) {
 394                 $dotransfer = 0;
 395                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 396             } else {
 397                 $dotransfer = 1;
 398                 $messages->{'RecallFound'} = $recall;
 399             }
 400         }
 401     }
 402
 403     #actually do the transfer....
 404     if ($dotransfer) {
 405         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 406
 407         # don't need to update MARC anymore, we do it in batch now
 408         $messages->{'WasTransfered'} = $tbr;
 409
 410     }
 411     ModDateLastSeen( $itemnumber );
 412     return ( $dotransfer, $messages );
 413 }
 414
 415
 416 sub TooMany {
 417     my ($patron, $item, $params) = @_;
 418     my $onsite_checkout = $params->{onsite_checkout} || 0;
 419     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 420     my $cat_borrower    = $patron->categorycode;
 421     my $dbh             = C4::Context->dbh;
 422     # Get which branchcode we need
 423     my $branch = _GetCircControlBranch($item, $patron);
 424     my $type = $item->effective_itemtype;
 425
 426     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 427     $type_object = Koha::ItemTypes->find( $type );
 428     $parent_type = $type_object->parent_type if $type_object;
 429     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 430     # Find any children if we are a parent_type;
 431
 432     # given branch, patron category, and item type, determine
 433     # applicable issuing rule
 434
 435     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 436         {
 437             categorycode => $cat_borrower,
 438             itemtype     => $parent_type,
 439             branchcode   => $branch,
 440             rule_name    => 'maxissueqty',
 441         }
 442     ) if $parent_type;
 443     # If the parent rule is for default type we discount it
 444     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 445
 446     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 447         {
 448             categorycode => $cat_borrower,
 449             itemtype     => $type,
 450             branchcode   => $branch,
 451             rule_name    => 'maxissueqty',
 452         }
 453     );
 454
 455     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 456         {
 457             categorycode => $cat_borrower,
 458             itemtype     => $type,
 459             branchcode   => $branch,
 460             rule_name    => 'maxonsiteissueqty',
 461         }
 462     );
 463
 464     # if a rule is found and has a loan limit set, count
 465     # how many loans the patron already has that meet that
 466     # rule
 467     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 468
 469         my $checkouts;
 470         if ( $maxissueqty_rule->branchcode ) {
 471             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 472                 $checkouts = $patron->checkouts->search(
 473                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 474             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 475                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 476             } else {
 477                 my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
 478                 $checkouts = $patron->checkouts->search(
 479                     { "item.$branch_type" => $maxissueqty_rule->branchcode } );
 480             }
 481         } else {
 482             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 483         }
 484         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 485
 486         my $sum_checkouts;
 487         my $rule_itemtype = $maxissueqty_rule->itemtype;
 488
 489         my @types;
 490         unless ( $rule_itemtype ) {
 491             # matching rule has the default item type, so count only
 492             # those existing loans that don't fall under a more
 493             # specific rule
 494             @types = Koha::CirculationRules->search(
 495                 {
 496                     branchcode => $maxissueqty_rule->branchcode,
 497                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 498                     itemtype  => { '!=' => undef },
 499                     rule_name => 'maxissueqty'
 500                 }
 501             )->get_column('itemtype');
 502         } else {
 503             if ( $parent_maxissueqty_rule ) {
 504                 # if we have a parent item type then we count loans of the
 505                 # specific item type or its siblings or parent
 506                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 507                 @types = $children->get_column('itemtype');
 508                 push @types, $parent_type;
 509             } elsif ( $child_types ) {
 510                 # If we are a parent type, we need to count all child types and our own type
 511                 @types = $child_types->get_column('itemtype');
 512                 push @types, $type; # And don't forget to count our own types
 513             } else {
 514                 # Otherwise only count the specific itemtype
 515                 push @types, $type;
 516             }
 517         }
 518
 519         while ( my $c = $checkouts->next ) {
 520             my $itemtype = $c->item->effective_itemtype;
 521
 522             unless ( $rule_itemtype ) {
 523                 next if grep {$_ eq $itemtype} @types;
 524             } else {
 525                 next unless grep {$_ eq $itemtype} @types;
 526             }
 527
 528             $sum_checkouts->{total}++;
 529             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 530             $sum_checkouts->{itemtype}->{$itemtype}++;
 531         }
 532
 533         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 534         my $checkout_count = $sum_checkouts->{total} || 0;
 535         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 536
 537         my $checkout_rules = {
 538             checkout_count               => $checkout_count,
 539             onsite_checkout_count        => $onsite_checkout_count,
 540             onsite_checkout              => $onsite_checkout,
 541             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 542             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 543             switch_onsite_checkout       => $switch_onsite_checkout,
 544             circulation_rule             => $maxissueqty_rule,
 545             onsite_circulation_rule      => $maxonsiteissueqty_rule,
 546         };
 547         # If parent rules exists
 548         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 549             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 550             my $qty_over = _check_max_qty($checkout_rules);
 551             return $qty_over if defined $qty_over;
 552
 553             # If the parent rule is less than or equal to the child, we only need check the parent
 554             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 555                 $checkout_rules->{checkout_count} = $checkout_count_type;
 556                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 557                 my $qty_over = _check_max_qty($checkout_rules);
 558                 return $qty_over if defined $qty_over;
 559             }
 560         } else {
 561             my $qty_over = _check_max_qty($checkout_rules);
 562             return $qty_over if defined $qty_over;
 563         }
 564     }
 565
 566     # Now count total loans against the limit for the branch
 567     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 568     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 569         my $checkouts;
 570         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 571             $checkouts = $patron->checkouts->search(
 572                 { 'me.branchcode' => $branch} );
 573         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 574             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 575         } else {
 576             my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
 577             $checkouts = $patron->checkouts->search(
 578                 { "item.$branch_type" => $branch},
 579                 { prefetch            => 'item' } );
 580         }
 581
 582         my $checkout_count = $checkouts->count;
 583         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 584         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 585         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 586
 587         my $qty_over = _check_max_qty(
 588             {
 589                 checkout_count               => $checkout_count,
 590                 onsite_checkout_count        => $onsite_checkout_count,
 591                 onsite_checkout              => $onsite_checkout,
 592                 max_checkouts_allowed        => $max_checkouts_allowed,
 593                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 594                 switch_onsite_checkout       => $switch_onsite_checkout,
 595                 circulation_rule             => $branch_borrower_circ_rule,
 596             }
 597         );
 598         return $qty_over if defined $qty_over;
 599     }
 600
 601     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 602         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 603     }
 604
 605     # OK, the patron can issue !!!
 606     return;
 607 }
 608
 609 sub _check_max_qty {
 610     my $params                       = shift;
 611     my $checkout_count               = $params->{checkout_count};
 612     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 613     my $onsite_checkout              = $params->{onsite_checkout};
 614     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 615     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 616     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 617     my $circulation_rule             = $params->{circulation_rule};
 618     my $onsite_circulation_rule      = $params->{onsite_circulation_rule};
 619
 620     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 621         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 622         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 623             return {
 624                 reason           => 'TOO_MANY_ONSITE_CHECKOUTS',
 625                 count            => $onsite_checkout_count,
 626                 max_allowed      => $max_onsite_checkouts_allowed,
 627                 circulation_rule => $onsite_circulation_rule,
 628             };
 629         }
 630     }
 631     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 632         if ( $max_checkouts_allowed eq '' ) { return; }
 633         my $delta = $switch_onsite_checkout ? 1 : 0;
 634         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 635             return {
 636                 reason           => 'TOO_MANY_CHECKOUTS',
 637                 count            => $checkout_count,
 638                 max_allowed      => $max_checkouts_allowed,
 639                 circulation_rule => $circulation_rule,
 640             };
 641         }
 642     }
 643     elsif ( not $onsite_checkout ) {
 644         if ( $max_checkouts_allowed eq '' ) { return; }
 645         if (
 646             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 647         {
 648             return {
 649                 reason           => 'TOO_MANY_CHECKOUTS',
 650                 count            => $checkout_count - $onsite_checkout_count,
 651                 max_allowed      => $max_checkouts_allowed,
 652                 circulation_rule => $circulation_rule,
 653             };
 654         }
 655     }
 656
 657     return;
 658 }
 659
 660 =head2 CanBookBeIssued
 661
 662   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 663                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 664
 665 Check if a book can be issued.
 666
 667 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 668
 669 IMPORTANT: The assumption by users of this routine is that causes blocking
 670 the issue are keyed by uppercase labels and other returned
 671 data is keyed in lower case!
 672
 673 =over 4
 674
 675 =item C<$patron> is a Koha::Patron
 676
 677 =item C<$barcode> is the bar code of the book being issued.
 678
 679 =item C<$duedates> is a DateTime object.
 680
 681 =item C<$inprocess> boolean switch
 682
 683 =item C<$ignore_reserves> boolean switch
 684
 685 =item C<$params> Hashref of additional parameters
 686
 687 Available keys:
 688     override_high_holds - Ignore high holds
 689     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 690     item                - Optionally pass the object for the item we are checking out to save a lookup
 691
 692 =back
 693
 694 Returns :
 695
 696 =over 4
 697
 698 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 699 Possible values are :
 700
 701 =back
 702
 703 =head3 INVALID_DATE
 704
 705 sticky due date is invalid
 706
 707 =head3 GNA
 708
 709 borrower gone with no address
 710
 711 =head3 CARD_LOST
 712
 713 borrower declared it's card lost
 714
 715 =head3 DEBARRED
 716
 717 borrower debarred
 718
 719 =head3 UNKNOWN_BARCODE
 720
 721 barcode unknown
 722
 723 =head3 NOT_FOR_LOAN
 724
 725 item is not for loan
 726
 727 =head3 WTHDRAWN
 728
 729 item withdrawn.
 730
 731 =head3 RESTRICTED
 732
 733 item is restricted (set by ??)
 734
 735 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 736 could be prevented, but ones that can be overriden by the operator.
 737
 738 Possible values are :
 739
 740 =head3 DEBT
 741
 742 borrower has debts.
 743
 744 =head3 RENEW_ISSUE
 745
 746 renewing, not issuing
 747
 748 =head3 ISSUED_TO_ANOTHER
 749
 750 issued to someone else.
 751
 752 =head3 RESERVED
 753
 754 reserved for someone else.
 755
 756 =head3 TRANSFERRED
 757
 758 reserved and being transferred for someone else.
 759
 760 =head3 INVALID_DATE
 761
 762 sticky due date is invalid or due date in the past
 763
 764 =head3 TOO_MANY
 765
 766 if the borrower borrows to much things
 767
 768 =head3 RECALLED
 769
 770 recalled by someone else
 771
 772 =cut
 773
 774 sub CanBookBeIssued {
 775     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 776     my %needsconfirmation;    # filled with problems that needs confirmations
 777     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 778     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 779     my %messages;             # filled with information messages that should be displayed.
 780
 781     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 782     my $override_high_holds = $params->{override_high_holds} || 0;
 783
 784     my $item_object = $params->{item}
 785       // Koha::Items->find( { barcode => $barcode } );
 786
 787     # MANDATORY CHECKS - unless item exists, nothing else matters
 788     unless ( $item_object ) {
 789         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 790     }
 791     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 792
 793     my $item_unblessed = $item_object->unblessed; # Transition...
 794     my $issue = $item_object->checkout;
 795     my $biblio = $item_object->biblio;
 796
 797     my $biblioitem = $biblio->biblioitem;
 798     my $effective_itemtype = $item_object->effective_itemtype;
 799     my $dbh             = C4::Context->dbh;
 800     my $patron_unblessed = $patron->unblessed;
 801
 802     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_object, $patron) );
 803
 804     my $now = dt_from_string();
 805     $duedate ||= CalcDateDue( $now, $effective_itemtype, $circ_library->branchcode, $patron );
 806     if (DateTime->compare($duedate,$now) == -1 ) { # duedate cannot be before now
 807          $needsconfirmation{INVALID_DATE} = $duedate;
 808     }
 809
 810     my $fees = Koha::Charges::Fees->new(
 811         {
 812             patron    => $patron,
 813             library   => $circ_library,
 814             item      => $item_object,
 815             to_date   => $duedate,
 816         }
 817     );
 818
 819     #
 820     # BORROWER STATUS
 821     #
 822     if ( $patron->category->category_type eq 'X' && ( $item_object->barcode ) ) {
 823
 824         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 825         C4::Stats::UpdateStats(
 826             {
 827                 branch         => C4::Context->userenv->{'branch'},
 828                 type           => 'localuse',
 829                 itemnumber     => $item_object->itemnumber,
 830                 itemtype       => $effective_itemtype,
 831                 borrowernumber => $patron->borrowernumber,
 832                 ccode          => $item_object->ccode,
 833                 categorycode   => $patron->categorycode,
 834                 location       => $item_object->location,
 835                 interface      => C4::Context->interface,
 836             }
 837         );
 838         my $block_lost_return = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
 839         ModDateLastSeen( $item_object->itemnumber, $block_lost_return );    # FIXME Move to Koha::Item
 840         return ( { STATS => 1, }, {} );
 841     }
 842
 843     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 844         $issuingimpossible{GNA} = 1;
 845     }
 846
 847     if ( $patron->lost && $patron->lost == 1 ) {
 848         $issuingimpossible{CARD_LOST} = 1;
 849     }
 850     if ( $patron->is_debarred ) {
 851         $issuingimpossible{DEBARRED} = 1;
 852     }
 853
 854     if ( $patron->is_expired ) {
 855         $issuingimpossible{EXPIRED} = 1;
 856     }
 857
 858     #
 859     # BORROWER STATUS
 860     #
 861
 862     # DEBTS
 863     my $account = $patron->account;
 864     my $balance = $account->balance;
 865     my $non_issues_charges = $account->non_issues_charges;
 866     my $other_charges = $balance - $non_issues_charges;
 867
 868     my $amountlimit = C4::Context->preference("noissuescharge");
 869     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 870     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 871
 872     # Check the debt of this patrons guarantees
 873     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 874     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 875     if ( defined $no_issues_charge_guarantees ) {
 876         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 877         my $guarantees_non_issues_charges = 0;
 878         foreach my $g ( @guarantees ) {
 879             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 880         }
 881
 882         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 883             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 884         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 885             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 886         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 887             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 888         }
 889     }
 890
 891     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 892     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 893     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 894     if ( defined $no_issues_charge_guarantors ) {
 895         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 896
 897         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 898             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 899         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 900             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 901         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 902             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 903         }
 904     }
 905
 906     if ( C4::Context->preference("IssuingInProcess") ) {
 907         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 908             $issuingimpossible{DEBT} = $non_issues_charges;
 909         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 910             $needsconfirmation{DEBT} = $non_issues_charges;
 911         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 912             $needsconfirmation{DEBT} = $non_issues_charges;
 913         }
 914     }
 915     else {
 916         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 917             $needsconfirmation{DEBT} = $non_issues_charges;
 918         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 919             $issuingimpossible{DEBT} = $non_issues_charges;
 920         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 921             $needsconfirmation{DEBT} = $non_issues_charges;
 922         }
 923     }
 924
 925     if ($balance > 0 && $other_charges > 0) {
 926         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 927     }
 928
 929     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 930     $patron_unblessed = $patron->unblessed;
 931
 932     if ( my $debarred_date = $patron->is_debarred ) {
 933          # patron has accrued fine days or has a restriction. $count is a date
 934         if ($debarred_date eq '9999-12-31') {
 935             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 936         }
 937         else {
 938             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 939         }
 940     } elsif ( my $num_overdues = $patron->has_overdues ) {
 941         ## patron has outstanding overdue loans
 942         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 943             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 944         }
 945         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 946             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 947         }
 948     }
 949
 950     # Additional Materials Check
 951     if ( C4::Context->preference("CircConfirmItemParts")
 952         && $item_object->materials )
 953     {
 954         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 955     }
 956
 957     #
 958     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 959     #
 960     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 961
 962         # Already issued to current borrower.
 963         # If it is an on-site checkout if it can be switched to a normal checkout
 964         # or ask whether the loan should be renewed
 965
 966         if ( $issue->onsite_checkout
 967                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 968             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 969         } else {
 970             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed($patron, $issue);
 971             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 972                 if ( $renewerror eq 'onsite_checkout' ) {
 973                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 974                 }
 975                 else {
 976                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 977                 }
 978             }
 979             else {
 980                 $needsconfirmation{RENEW_ISSUE} = 1;
 981             }
 982         }
 983     }
 984     elsif ( $issue ) {
 985
 986         # issued to someone else
 987
 988         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 989
 990         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 991
 992         if ( !$can_be_returned ) {
 993             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 994             $issuingimpossible{branch_to_return} = $message;
 995         } else {
 996             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 997                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 998             }
 999             else {
1000                 $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
1001                 $needsconfirmation{issued_firstname} = $patron->firstname;
1002                 $needsconfirmation{issued_surname} = $patron->surname;
1003                 $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
1004                 $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
1005             }
1006         }
1007     }
1008
1009     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
1010     #
1011     my $switch_onsite_checkout = (
1012           C4::Context->preference('SwitchOnSiteCheckouts')
1013       and $issue
1014       and $issue->onsite_checkout
1015       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1016     my $toomany = TooMany( $patron, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1017     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1018     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1019         if ( $toomany->{max_allowed} == 0 ) {
1020             $needsconfirmation{PATRON_CANT}                  = 1;
1021             $needsconfirmation{circulation_rule_PATRON_CANT} = $toomany->{circulation_rule};
1022         }
1023         if ( C4::Context->preference("AllowTooManyOverride") ) {
1024             $needsconfirmation{TOO_MANY}                  = $toomany->{reason};
1025             $needsconfirmation{current_loan_count}        = $toomany->{count};
1026             $needsconfirmation{max_loans_allowed}         = $toomany->{max_allowed};
1027             $needsconfirmation{circulation_rule_TOO_MANY} = $toomany->{circulation_rule};
1028         } else {
1029             $issuingimpossible{TOO_MANY}                  = $toomany->{reason};
1030             $issuingimpossible{current_loan_count}        = $toomany->{count};
1031             $issuingimpossible{max_loans_allowed}         = $toomany->{max_allowed};
1032             $needsconfirmation{circulation_rule_TOO_MANY} = $toomany->{circulation_rule};
1033         }
1034     }
1035
1036     #
1037     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1038     #
1039     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1040     if ( $patron->wants_check_for_previous_checkout && $patron->do_check_for_previous_checkout($item_unblessed) ) {
1041         $needsconfirmation{PREVISSUE} = 1;
1042     }
1043
1044     #
1045     # ITEM CHECKING
1046     #
1047     if ( $item_object->notforloan )
1048     {
1049         if(!C4::Context->preference("AllowNotForLoanOverride")){
1050             $issuingimpossible{NOT_FOR_LOAN} = 1;
1051             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1052         }else{
1053             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1054             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1055         }
1056     }
1057     else {
1058         # we have to check itemtypes.notforloan also
1059         if (C4::Context->preference('item-level_itypes')){
1060             # this should probably be a subroutine
1061             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1062             $sth->execute($effective_itemtype);
1063             my $notforloan=$sth->fetchrow_hashref();
1064             if ($notforloan->{'notforloan'}) {
1065                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1066                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1067                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1068                 } else {
1069                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1070                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1071                 }
1072             }
1073         }
1074         else {
1075             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1076             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1077                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1078                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1079                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1080                 } else {
1081                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1082                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1083                 }
1084             }
1085         }
1086     }
1087     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1088     {
1089         $issuingimpossible{WTHDRAWN} = 1;
1090     }
1091     if (   $item_object->restricted
1092         && $item_object->restricted == 1 )
1093     {
1094         $issuingimpossible{RESTRICTED} = 1;
1095     }
1096     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1097         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1098         my $code = $av->count ? $av->next->lib : '';
1099         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1100         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1101     }
1102     if ( C4::Context->preference("IndependentBranches") ) {
1103         my $userenv = C4::Context->userenv;
1104         unless ( C4::Context->IsSuperLibrarian() ) {
1105             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1106             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1107                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1108                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1109             }
1110             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1111               if ( $patron->branchcode ne $userenv->{branch} );
1112         }
1113     }
1114
1115     #
1116     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1117     #
1118     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1119     if ($rentalConfirmation) {
1120         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1121
1122         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1123         if ($itemtype_object) {
1124             my $accumulate_charge = $fees->accumulate_rentalcharge();
1125             if ( $accumulate_charge > 0 ) {
1126                 $rentalCharge += $accumulate_charge;
1127             }
1128         }
1129
1130         if ( $rentalCharge > 0 ) {
1131             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1132         }
1133     }
1134
1135     my $recall;
1136     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1137     # Only bother doing this if UseRecalls is enabled and the item is recallable
1138     # Don't look at recalls that are in transit
1139     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1140         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'created_date' } })->filter_by_current->as_list;
1141
1142         foreach my $r ( @recalls ) {
1143             if ( $r->item_id and
1144                 $r->item_id == $item_object->itemnumber and
1145                 $r->patron_id == $patron->borrowernumber and
1146                 ( $r->waiting or $r->requested ) ) {
1147                 $messages{RECALLED} = $r->id;
1148                 $recall = $r;
1149                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1150                 last;
1151             }
1152             elsif ( $r->item_id and
1153                 $r->item_id == $item_object->itemnumber and
1154                 $r->in_transit ) {
1155                 # recalled item is in transit
1156                 $issuingimpossible{RECALLED_INTRANSIT} = $r->pickup_library_id;
1157             }
1158             elsif ( $r->item_level and
1159                 $r->item_id == $item_object->itemnumber and
1160                 $r->patron_id != $patron->borrowernumber and
1161                 !$r->in_transit ) {
1162                 # this specific item has been recalled by a different patron
1163                 $needsconfirmation{RECALLED} = $r;
1164                 $recall = $r;
1165                 last;
1166             }
1167             elsif ( !$r->item_level and
1168                 $r->patron_id != $patron->borrowernumber and
1169                 !$r->in_transit ) {
1170                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1171                 $needsconfirmation{RECALLED} = $r;
1172                 $recall = $r;
1173                 last;
1174             }
1175         }
1176     }
1177
1178     unless ( $ignore_reserves || $recall ) {
1179         # See if the item is on reserve.
1180         my ( $restype, $res ) = CheckReserves( $item_object );
1181         if ($restype) {
1182             my $resbor = $res->{'borrowernumber'};
1183             if ( $resbor ne $patron->borrowernumber ) {
1184                 my $patron = Koha::Patrons->find( $resbor );
1185                 if ( $restype eq "Waiting" )
1186                 {
1187                     # The item is on reserve and waiting, but has been
1188                     # reserved by some other patron.
1189                     $needsconfirmation{RESERVE_WAITING} = 1;
1190                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1191                     $needsconfirmation{'ressurname'} = $patron->surname;
1192                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1193                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1194                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1195                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1196                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1197                 }
1198                 elsif ( $restype eq "Reserved" ) {
1199                     # The item is on reserve for someone else.
1200                     $needsconfirmation{RESERVED} = 1;
1201                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1202                     $needsconfirmation{'ressurname'} = $patron->surname;
1203                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1204                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1205                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1206                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1207                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1208                 }
1209                 elsif ( $restype eq "Transferred" ) {
1210                     # The item is determined hold being transferred for someone else.
1211                     $needsconfirmation{TRANSFERRED} = 1;
1212                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1213                     $needsconfirmation{'ressurname'} = $patron->surname;
1214                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1215                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1216                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1217                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1218                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1219                 }
1220                 elsif ( $restype eq "Processing" ) {
1221                     # The item is determined hold being processed for someone else.
1222                     $needsconfirmation{PROCESSING} = 1;
1223                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1224                     $needsconfirmation{'ressurname'} = $patron->surname;
1225                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1226                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1227                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1228                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1229                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1230                 }
1231             }
1232         }
1233     }
1234
1235     ## CHECK FOR BOOKINGS
1236     if (
1237         my $booking = $item_object->find_booking(
1238             {
1239                 checkout_date => $now,
1240                 due_date      => $duedate,
1241                 patron_id     => $patron->borrowernumber
1242             }
1243         )
1244         )
1245     {
1246         # Booked to this patron :)
1247         if ( $booking->patron_id == $patron->borrowernumber ) {
1248             if ( $now < dt_from_string( $booking->start_date ) ) {
1249                 $needsconfirmation{'BOOKED_EARLY'} = $booking;
1250             } else {
1251                 $alerts{'BOOKED'} = $booking;
1252             }
1253         }
1254
1255         # Booking starts before due date, reduce loan?
1256         elsif ( $duedate > dt_from_string( $booking->start_date ) ) {
1257             $needsconfirmation{'BOOKED_TO_ANOTHER'} = $booking;
1258         }
1259
1260         # Loan falls inside booking
1261         else {
1262             $issuingimpossible{'BOOKED_TO_ANOTHER'} = $booking;
1263         }
1264     }
1265
1266     ## CHECK AGE RESTRICTION
1267     my $agerestriction  = $biblioitem->agerestriction;
1268     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1269     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1270         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1271             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1272         }
1273         else {
1274             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1275         }
1276     }
1277
1278     ## check for high holds decreasing loan period
1279     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1280         my $check = checkHighHolds( $item_object, $patron );
1281
1282         if ( $check->{exceeded} ) {
1283             my $highholds = {
1284                 num_holds  => $check->{outstanding},
1285                 duration   => $check->{duration},
1286                 returndate => $check->{due_date},
1287             };
1288             if ($override_high_holds) {
1289                 $alerts{HIGHHOLDS} = $highholds;
1290             }
1291             else {
1292                 $needsconfirmation{HIGHHOLDS} = $highholds;
1293             }
1294         }
1295     }
1296
1297     if (
1298         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1299         # don't do the multiple loans per bib check if we've
1300         # already determined that we've got a loan on the same item
1301         !$issuingimpossible{NO_MORE_RENEWALS} &&
1302         !$needsconfirmation{RENEW_ISSUE}
1303     ) {
1304         # Check if borrower has already issued an item from the same biblio
1305         # Only if it's not a subscription
1306         my $biblionumber = $item_object->biblionumber;
1307         require C4::Serials;
1308         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1309         unless ($is_a_subscription) {
1310             # FIXME Should be $patron->checkouts($args);
1311             my $checkouts = Koha::Checkouts->search(
1312                 {
1313                     borrowernumber => $patron->borrowernumber,
1314                     biblionumber   => $biblionumber,
1315                 },
1316                 {
1317                     join => 'item',
1318                 }
1319             );
1320             # if we get here, we don't already have a loan on this item,
1321             # so if there are any loans on this bib, ask for confirmation
1322             if ( $checkouts->count ) {
1323                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1324             }
1325         }
1326     }
1327
1328     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1329 }
1330
1331 =head2 CanBookBeReturned
1332
1333   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1334
1335 Check whether the item can be returned to the provided branch
1336
1337 =over 4
1338
1339 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1340
1341 =item C<$branch> is the branchcode where the return is taking place
1342
1343 =back
1344
1345 Returns:
1346
1347 =over 4
1348
1349 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1350
1351 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1352
1353 =back
1354
1355 =cut
1356
1357 sub CanBookBeReturned {
1358   my ($item, $branch) = @_;
1359   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1360
1361   # assume return is allowed to start
1362   my $allowed = 1;
1363   my $message;
1364
1365   # identify all cases where return is forbidden
1366   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1367      $allowed = 0;
1368      $message = $item->{'homebranch'};
1369   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1370      $allowed = 0;
1371      $message = $item->{'holdingbranch'};
1372   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1373      $allowed = 0;
1374      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1375   }
1376
1377   return ($allowed, $message);
1378 }
1379
1380 =head2 CheckHighHolds
1381
1382     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1383     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1384     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1385
1386 =cut
1387
1388 sub checkHighHolds {
1389     my ( $item, $patron ) = @_;
1390     my $branchcode = _GetCircControlBranch( $item, $patron );
1391
1392     my $return_data = {
1393         exceeded    => 0,
1394         outstanding => 0,
1395         duration    => 0,
1396         due_date    => undef,
1397     };
1398
1399
1400     # Count holds on this record, ignoring the borrowers own holds as they would be filled by the checkout
1401     my $holds = Koha::Holds->search({
1402         biblionumber => $item->biblionumber,
1403         borrowernumber => { '!=' => $patron->borrowernumber }
1404     });
1405
1406     if ( $holds->count() ) {
1407         $return_data->{outstanding} = $holds->count();
1408
1409         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1410         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1411         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1412
1413         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1414
1415         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1416
1417             # static means just more than a given number of holds on the record
1418
1419             # If the number of holds is not above the threshold, we can stop here
1420             if ( $holds->count() <= $decreaseLoanHighHoldsValue ) {
1421                 return $return_data;
1422             }
1423         }
1424         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1425
1426             # dynamic means X more than the number of holdable items on the record
1427
1428             # let's get the items
1429             my @items = $holds->next()->biblio()->items()->as_list;
1430
1431             # Remove any items with status defined to be ignored even if the would not make item unholdable
1432             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1433                 @items = grep { !$_->$status } @items;
1434             }
1435
1436             # Remove any items that are not holdable for this patron
1437             # We need to ignore hold counts as the borrower's own hold that will be filled by the checkout
1438             # could prevent them from placing further holds
1439             @items = grep { CanItemBeReserved( $patron, $_, undef, { ignore_hold_counts => 1 } )->{status} eq 'OK' } @items;
1440
1441             my $items_count = scalar @items;
1442
1443             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1444
1445             # If the number of holds is less than the count of items we have
1446             # plus the number of holds allowed above that count, we can stop here
1447             if ( $holds->count() <= $threshold ) {
1448                 return $return_data;
1449             }
1450         }
1451
1452         my $issuedate = dt_from_string();
1453
1454         my $itype = $item->effective_itemtype;
1455         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1456             {
1457                 categorycode => $patron->categorycode,
1458                 itemtype     => $itype,
1459                 branchcode   => $branchcode,
1460             }
1461         );
1462         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1463
1464         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron );
1465
1466         my $rule = Koha::CirculationRules->get_effective_rule_value(
1467             {
1468                 categorycode => $patron->categorycode,
1469                 itemtype     => $item->effective_itemtype,
1470                 branchcode   => $branchcode,
1471                 rule_name    => 'decreaseloanholds',
1472             }
1473         );
1474
1475         my $duration;
1476         if ( defined($rule) && $rule ne '' ){
1477             # overrides decreaseLoanHighHoldsDuration syspref
1478             $duration = $rule;
1479         } else {
1480             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1481         }
1482         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1483         $reduced_datedue->set_hour($orig_due->hour);
1484         $reduced_datedue->set_minute($orig_due->minute);
1485         $reduced_datedue->truncate( to => 'minute' );
1486
1487         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1488             $return_data->{exceeded} = 1;
1489             $return_data->{duration} = $duration;
1490             $return_data->{due_date} = $reduced_datedue;
1491         }
1492     }
1493
1494     return $return_data;
1495 }
1496
1497 =head2 AddIssue
1498
1499   &AddIssue($patron, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1500
1501 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1502
1503 =over 4
1504
1505 =item C<$patron> is a patron object.
1506
1507 =item C<$barcode> is the barcode of the item being issued.
1508
1509 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1510 Calculated if empty.
1511
1512 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1513
1514 =item C<$issuedate> is a DateTime object for the date to issue the item (optional).
1515 Defaults to today.
1516
1517 AddIssue does the following things :
1518
1519   - step 01: check that there is a borrowernumber & a barcode provided
1520   - check for RENEWAL (book issued & being issued to the same patron)
1521       - renewal YES = Calculate Charge & renew
1522       - renewal NO  =
1523           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1524           * RESERVE PLACED ?
1525               - fill reserve if reserve to this patron
1526               - cancel reserve or not, otherwise
1527           * RECALL PLACED ?
1528               - fill recall if recall to this patron
1529               - cancel recall or not
1530               - revert recall's waiting status or not
1531           * TRANSFERT PENDING ?
1532               - complete the transfert
1533           * ISSUE THE BOOK
1534
1535 =back
1536
1537 =cut
1538
1539 sub AddIssue {
1540     my ( $patron, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1541
1542     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1543     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1544     my $auto_renew = $params && $params->{auto_renew};
1545     my $cancel_recall = $params && $params->{cancel_recall};
1546     my $recall_id = $params && $params->{recall_id};
1547     my $dbh          = C4::Context->dbh;
1548     my $barcodecheck = CheckValidBarcode($barcode);
1549
1550     my $issue;
1551
1552     if ( $datedue && ref $datedue ne 'DateTime' ) {
1553         $datedue = dt_from_string($datedue);
1554     }
1555
1556     # $issuedate defaults to today.
1557     if ( !defined $issuedate ) {
1558         $issuedate = dt_from_string();
1559     }
1560     else {
1561         if ( ref $issuedate ne 'DateTime' ) {
1562             $issuedate = dt_from_string($issuedate);
1563
1564         }
1565     }
1566
1567     # Stop here if the patron or barcode doesn't exist
1568     if ( $patron && $barcode && $barcodecheck ) {
1569         # find which item we issue
1570         my $item_object = Koha::Items->find({ barcode => $barcode })
1571           or return;    # if we don't get an Item, abort.
1572         my $item_unblessed = $item_object->unblessed;
1573
1574         my $branchcode = _GetCircControlBranch( $item_object, $patron );
1575
1576         # get actual issuing if there is one
1577         my $actualissue = $item_object->checkout;
1578
1579         # check if we just renew the issue.
1580         if ( $actualissue and $actualissue->borrowernumber eq $patron->borrowernumber
1581                 and not $switch_onsite_checkout ) {
1582             $datedue = AddRenewal(
1583                 {
1584                     borrowernumber => $patron->borrowernumber,
1585                     itemnumber     => $item_object->itemnumber,
1586                     branch         => $branchcode,
1587                     datedue        => $datedue,
1588                     lastreneweddate =>
1589                       $issuedate,    # here interpreted as the renewal date
1590                 }
1591             );
1592             $issue = $item_object->checkout;
1593         }
1594         else {
1595
1596             unless ($datedue) {
1597                 my $itype = $item_object->effective_itemtype;
1598                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $patron );
1599
1600             }
1601
1602             # Check if we need to use an exact due date set by the ILL module
1603             if ( C4::Context->preference('ILLModule') ) {
1604                 # Check if there is an ILL connected with the biblio of the item we are issuing
1605                 my $ill_request = Koha::Illrequests->search({
1606                     biblio_id => $item_object->biblionumber,
1607                     borrowernumber => $patron->borrowernumber,
1608                     completed => undef,
1609                     due_date => { '!=', undef },
1610                 })->next;
1611
1612                 if ( $ill_request and length( $ill_request->due_date ) > 0 ) {
1613                     my $ill_dt = dt_from_string( $ill_request->due_date );
1614                     $ill_dt->set_hour(23);
1615                     $ill_dt->set_minute(59);
1616                     $datedue = $ill_dt;
1617                 }
1618             }
1619
1620             $datedue->truncate( to => 'minute' );
1621
1622             my $library = Koha::Libraries->find( $branchcode );
1623             my $fees = Koha::Charges::Fees->new(
1624                 {
1625                     patron    => $patron,
1626                     library   => $library,
1627                     item      => $item_object,
1628                     to_date   => $datedue,
1629                 }
1630             );
1631
1632             # it's NOT a renewal
1633             if ( $actualissue and not $switch_onsite_checkout ) {
1634                 # This book is currently on loan, but not to the person
1635                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1636                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1637                 return unless $allowed;
1638                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1639                 # AddReturn certainly has side-effects, like onloan => undef
1640                 $item_object->discard_changes;
1641             }
1642
1643             if ( C4::Context->preference('UseRecalls') ) {
1644                 Koha::Recalls->move_recall(
1645                     {
1646                         action         => $cancel_recall,
1647                         recall_id      => $recall_id,
1648                         item           => $item_object,
1649                         borrowernumber => $patron->borrowernumber,
1650                     }
1651                 );
1652             }
1653
1654             C4::Reserves::MoveReserve( $item_object->itemnumber, $patron->borrowernumber, $cancelreserve );
1655
1656             # Starting process for transfer job (checking transfert and validate it if we have one)
1657             if ( my $transfer = $item_object->get_transfer ) {
1658                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1659                 $transfer->set(
1660                     {
1661                         datearrived => dt_from_string,
1662                         tobranch    => C4::Context->userenv->{branch},
1663                         comments    => 'Forced branchtransfer'
1664                     }
1665                 )->store;
1666                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1667                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1668                     if ( $hold ) { # Is this really needed?
1669                         $hold->set( { found => undef } )->store;
1670                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1671                     }
1672                 }
1673             }
1674
1675             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1676             unless ($auto_renew) {
1677                 my $rule = Koha::CirculationRules->get_effective_rule_value(
1678                     {
1679                         categorycode => $patron->categorycode,
1680                         itemtype     => $item_object->effective_itemtype,
1681                         branchcode   => $branchcode,
1682                         rule_name    => 'auto_renew'
1683                     }
1684                 );
1685
1686                 $auto_renew = $rule if defined $rule && $rule ne '';
1687             }
1688
1689             my $issue_attributes = {
1690                 borrowernumber  => $patron->borrowernumber,
1691                 issuedate       => $issuedate,
1692                 date_due        => $datedue,
1693                 branchcode      => C4::Context->userenv->{'branch'},
1694                 onsite_checkout => $onsite_checkout,
1695                 auto_renew      => $auto_renew ? 1 : 0,
1696             };
1697
1698             # Get ID of logged in user.  if called from a batch job,
1699             # no user session exists and C4::Context->userenv() returns
1700             # the scalar '0'. Only do this if the syspref says so
1701             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1702                 my $userenv = C4::Context->userenv();
1703                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1704                 if ($usernumber) {
1705                     $issue_attributes->{issuer_id} = $usernumber;
1706                 }
1707             }
1708
1709             # In the case that the borrower has an on-site checkout
1710             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1711             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1712             if ($issue) {
1713                 $issue->set($issue_attributes)->store;
1714             }
1715             else {
1716                 $issue = Koha::Checkout->new(
1717                     {
1718                         itemnumber => $item_object->itemnumber,
1719                         %$issue_attributes,
1720                     }
1721                 )->store;
1722
1723                 # Ensure item is no longer listed in the holds queue
1724                 $dbh->do(
1725                     q{DELETE tmp_holdsqueue, hold_fill_targets FROM tmp_holdsqueue LEFT JOIN hold_fill_targets USING ( itemnumber ) WHERE itemnumber = ?},
1726                     undef, $item_object->id
1727                 );
1728             }
1729             $issue->discard_changes;
1730             $patron->update_lastseen('check_out');
1731             if ( $item_object->location && $item_object->location eq 'CART'
1732                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1733             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1734                 CartToShelf( $item_object->itemnumber );
1735             }
1736
1737             # Update item location
1738             $item_object->location_update_trigger( 'checkout' );
1739
1740             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1741                 UpdateTotalIssues( $item_object->biblionumber, 1, undef, { skip_holds_queue => 1 } );
1742             }
1743
1744             # Record if item was lost
1745             my $was_lost = $item_object->itemlost;
1746
1747             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1748             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1749             $item_object->itemlost(0);
1750             $item_object->onloan($datedue->ymd());
1751             $item_object->datelastborrowed( dt_from_string()->ymd() );
1752             $item_object->datelastseen( dt_from_string() );
1753             $item_object->store( { log_action => 0, skip_holds_queue => 1 } );
1754
1755             # If the item was lost, it has now been found, charge the overdue if necessary
1756             if ($was_lost) {
1757                 if ( $item_object->{_charge} ) {
1758                     $actualissue //= Koha::Old::Checkouts->search(
1759                         { itemnumber => $item_object->itemnumber },
1760                         {
1761                             order_by => { '-desc' => 'returndate' },
1762                             rows     => 1
1763                         }
1764                     )->single;
1765                     unless ( $patron->branchcode ) {
1766                         $patron = $actualissue->patron;
1767                     }
1768                     _CalculateAndUpdateFine(
1769                         {
1770                             issue       => $actualissue,
1771                             item        => $item_unblessed,
1772                             borrower    => $patron->unblessed,
1773                             return_date => $issuedate
1774                         }
1775                     );
1776                     _FixOverduesOnReturn( $patron->borrowernumber,
1777                         $item_object->itemnumber, undef, 'RENEWED' );
1778                 }
1779             }
1780
1781             # If it costs to borrow this book, charge it to the patron's account.
1782             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1783             if ( $charge && $charge > 0 ) {
1784                 AddIssuingCharge( $issue, $charge, 'RENT' );
1785             }
1786
1787             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1788             if ( $itemtype_object ) {
1789                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1790                 if ( $accumulate_charge > 0 ) {
1791                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1792                     $charge += $accumulate_charge;
1793                     $item_unblessed->{charge} = $charge;
1794                 }
1795             }
1796
1797             my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckout');
1798             if ($yaml) {
1799                 $yaml = "$yaml\n\n";
1800
1801                 my $rules;
1802                 eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
1803                 if ($@) {
1804                     warn "Unable to parse UpdateNotForLoanStatusOnCheckout syspref : $@";
1805                 }
1806                 else {
1807                     foreach my $key ( keys %$rules ) {
1808                         if ( $item_object->notforloan eq $key ) {
1809                             $item_object->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1 });
1810                             last;
1811                         }
1812                     }
1813                 }
1814             }
1815
1816             # Record the fact that this book was issued.
1817             C4::Stats::UpdateStats(
1818                 {
1819                     branch => C4::Context->userenv->{'branch'},
1820                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1821                     amount         => $charge,
1822                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1823                     itemnumber     => $item_object->itemnumber,
1824                     itemtype       => $item_object->effective_itemtype,
1825                     location       => $item_object->location,
1826                     borrowernumber => $patron->borrowernumber,
1827                     ccode          => $item_object->ccode,
1828                     categorycode   => $patron->categorycode
1829                 }
1830             );
1831
1832             # Send a checkout slip.
1833             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1834             my %conditions        = (
1835                 branchcode   => $branchcode,
1836                 categorycode => $patron->categorycode,
1837                 item_type    => $item_object->effective_itemtype,
1838                 notification => 'CHECKOUT',
1839             );
1840             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1841                 SendCirculationAlert(
1842                     {
1843                         type     => 'CHECKOUT',
1844                         item     => $item_object->unblessed,
1845                         borrower => $patron->unblessed,
1846                         branch   => $branchcode,
1847                     }
1848                 );
1849             }
1850             logaction(
1851                 "CIRCULATION", "ISSUE",
1852                 $patron->borrowernumber,
1853                 $item_object->itemnumber,
1854             ) if C4::Context->preference("IssueLog");
1855
1856             Koha::Plugins->call('after_circ_action', {
1857                 action  => 'checkout',
1858                 payload => {
1859                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1860                     checkout => $issue->get_from_storage
1861                 }
1862             });
1863
1864             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1865                 {
1866                     biblio_ids => [ $item_object->biblionumber ]
1867                 }
1868             ) if C4::Context->preference('RealTimeHoldsQueue');
1869         }
1870     }
1871     return $issue;
1872 }
1873
1874 =head2 GetLoanLength
1875
1876   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1877
1878 Get loan length for an itemtype, a borrower type and a branch
1879
1880 =cut
1881
1882 sub GetLoanLength {
1883     my ( $categorycode, $itemtype, $branchcode ) = @_;
1884
1885     # Initialize default values
1886     my $rules = {
1887         issuelength   => 0,
1888         renewalperiod => 0,
1889         lengthunit    => 'days',
1890     };
1891
1892     my $found = Koha::CirculationRules->get_effective_rules( {
1893         branchcode => $branchcode,
1894         categorycode => $categorycode,
1895         itemtype => $itemtype,
1896         rules => [
1897             'issuelength',
1898             'renewalperiod',
1899             'lengthunit'
1900         ],
1901     } );
1902
1903     # Search for rules!
1904     foreach my $rule_name (keys %$found) {
1905         $rules->{$rule_name} = $found->{$rule_name};
1906     }
1907
1908     return $rules;
1909 }
1910
1911
1912 =head2 GetHardDueDate
1913
1914   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1915
1916 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1917
1918 =cut
1919
1920 sub GetHardDueDate {
1921     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1922
1923     my $rules = Koha::CirculationRules->get_effective_rules(
1924         {
1925             categorycode => $borrowertype,
1926             itemtype     => $itemtype,
1927             branchcode   => $branchcode,
1928             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1929         }
1930     );
1931
1932     if ( defined( $rules->{hardduedate} ) ) {
1933         if ( $rules->{hardduedate} ) {
1934             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1935         }
1936         else {
1937             return ( undef, undef );
1938         }
1939     }
1940 }
1941
1942 =head2 GetBranchBorrowerCircRule
1943
1944   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1945
1946 Retrieves circulation rule attributes that apply to the given
1947 branch and patron category, regardless of item type.
1948 The return value is a hashref containing the following key:
1949
1950 patron_maxissueqty - maximum number of loans that a
1951 patron of the given category can have at the given
1952 branch.  If the value is undef, no limit.
1953
1954 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1955 patron of the given category can have at the given
1956 branch.  If the value is undef, no limit.
1957
1958 This will check for different branch/category combinations in the following order:
1959 branch and category
1960 branch only
1961 category only
1962 default branch and category
1963
1964 If no rule has been found in the database, it will default to
1965 the buillt in rule:
1966
1967 patron_maxissueqty - undef
1968 patron_maxonsiteissueqty - undef
1969
1970 C<$branchcode> and C<$categorycode> should contain the
1971 literal branch code and patron category code, respectively - no
1972 wildcards.
1973
1974 =cut
1975
1976 sub GetBranchBorrowerCircRule {
1977     my ( $branchcode, $categorycode ) = @_;
1978
1979     # Initialize default values
1980     my $rules = {
1981         patron_maxissueqty       => undef,
1982         patron_maxonsiteissueqty => undef,
1983     };
1984
1985     # Search for rules!
1986     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1987         my $rule = Koha::CirculationRules->get_effective_rule(
1988             {
1989                 categorycode => $categorycode,
1990                 itemtype     => undef,
1991                 branchcode   => $branchcode,
1992                 rule_name    => $rule_name,
1993             }
1994         );
1995
1996         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1997     }
1998
1999     return $rules;
2000 }
2001
2002 =head2 GetBranchItemRule
2003
2004   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
2005
2006 Retrieves circulation rule attributes that apply to the given
2007 branch and item type, regardless of patron category.
2008
2009 The return value is a hashref containing the following keys:
2010
2011 holdallowed => Hold policy for this branch and itemtype. Possible values:
2012   not_allowed:           No holds allowed.
2013   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
2014   from_any_library:      Holds allowed from any patron.
2015   from_local_hold_group: Holds allowed from libraries in hold group
2016
2017 This searches branchitemrules in the following order:
2018
2019   * Same branchcode and itemtype
2020   * Same branchcode, itemtype '*'
2021   * branchcode '*', same itemtype
2022   * branchcode and itemtype '*'
2023
2024 Neither C<$branchcode> nor C<$itemtype> should be '*'.
2025
2026 =cut
2027
2028 sub GetBranchItemRule {
2029     my ( $branchcode, $itemtype ) = @_;
2030
2031     # Search for rules!
2032     my $rules = Koha::CirculationRules->get_effective_rules({
2033         branchcode => $branchcode,
2034         itemtype => $itemtype,
2035         rules => ['holdallowed', 'hold_fulfillment_policy']
2036     });
2037
2038     # built-in default circulation rule
2039     $rules->{holdallowed} //= 'from_any_library';
2040     $rules->{hold_fulfillment_policy} //= 'any';
2041
2042     return $rules;
2043 }
2044
2045 =head2 AddReturn
2046
2047   ($doreturn, $messages, $iteminformation, $borrower) =
2048       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] [,$skip_localuse ] );
2049
2050 Returns a book.
2051
2052 =over 4
2053
2054 =item C<$barcode> is the bar code of the book being returned.
2055
2056 =item C<$branch> is the code of the branch where the book is being returned.
2057
2058 =item C<$exemptfine> indicates that overdue charges for the item will be
2059 removed. Optional.
2060
2061 =item C<$return_date> allows the default return date to be overridden
2062 by the given return date. Optional.
2063
2064 =item C<$skip_localuse> indicated that localuse should not be recorded. Optional.
2065
2066 =back
2067
2068 C<&AddReturn> returns a list of four items:
2069
2070 C<$doreturn> is true iff the return succeeded.
2071
2072 C<$messages> is a reference-to-hash giving feedback on the operation.
2073 The keys of the hash are:
2074
2075 =over 4
2076
2077 =item C<BadBarcode>
2078
2079 No item with this barcode exists. The value is C<$barcode>.
2080
2081 =item C<NotIssued>
2082
2083 The book is not currently on loan. The value is C<$barcode>.
2084
2085 =item C<withdrawn>
2086
2087 This book has been withdrawn/cancelled. The value should be ignored.
2088
2089 =item C<Wrongbranch>
2090
2091 This book has was returned to the wrong branch.  The value is a hashref
2092 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
2093 contain the branchcode of the incorrect and correct return library, respectively.
2094
2095 =item C<ResFound>
2096
2097 The item was reserved. The value is a reference-to-hash whose keys are
2098 fields from the reserves table of the Koha database, and
2099 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2100 either C<Waiting>, C<Reserved>, or 0.
2101
2102 =item C<WasReturned>
2103
2104 Value 1 if return is successful.
2105
2106 =item C<NeedsTransfer>
2107
2108 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2109
2110 =item C<RecallFound>
2111
2112 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2113 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2114 branchcode.
2115
2116 =item C<TransferredRecall>
2117
2118 This item has been transferred to this branch to fill a recall. The recall object is returned.
2119
2120 =back
2121
2122 C<$iteminformation> is a reference-to-hash, giving information about the
2123 returned item from the issues table.
2124
2125 C<$borrower> is a reference-to-hash, giving information about the
2126 patron who last borrowed the book.
2127
2128 =cut
2129
2130 sub AddReturn {
2131     my ( $barcode, $branch, $exemptfine, $return_date, $skip_localuse ) = @_;
2132
2133     if ($branch and not Koha::Libraries->find($branch)) {
2134         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2135         undef $branch;
2136     }
2137     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2138     my $return_date_specified = !!$return_date;
2139     $return_date //= dt_from_string();
2140     my $messages;
2141     my $patron;
2142     my $doreturn       = 1;
2143     my $validTransfer = 1;
2144     my $stat_type = 'return';
2145
2146     # get information on item
2147     my $item = Koha::Items->find({ barcode => $barcode });
2148     unless ($item) {
2149         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2150     }
2151
2152     my $itemnumber = $item->itemnumber;
2153     my $itemtype = $item->effective_itemtype;
2154
2155     my $issue  = $item->checkout;
2156     if ( $issue ) {
2157         $patron = $issue->patron
2158             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2159                 . Dumper($issue->unblessed) . "\n";
2160     } else {
2161         $messages->{'NotIssued'} = $barcode;
2162         $item->onloan(undef)->store( { skip_record_index => 1, skip_holds_queue => 1 } ) if defined $item->onloan;
2163
2164         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2165         $doreturn = 0;
2166         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2167         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2168         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2169            $messages->{'LocalUse'} = 1;
2170            $stat_type = 'localuse';
2171         }
2172     }
2173
2174     if ( $item->withdrawn ) { # book has been cancelled
2175         $messages->{'withdrawn'} = 1;
2176
2177         # In the case where we block return of withdrawn, we should completely block the return
2178         # without updating item statuses, so we exit early
2179         return ( 0, $messages, $issue, ( $patron ? $patron->unblessed : {} ))
2180             if C4::Context->preference("BlockReturnOfWithdrawnItems");
2181     }
2182
2183
2184     # full item data, but no borrowernumber or checkout info (no issue)
2185     my $hbr = Koha::CirculationRules->get_return_branch_policy($item);
2186
2187     # check if returnbranch and homebranch belong to the same float group
2188     my $validate_float =
2189         Koha::Libraries->find( $item->homebranch )->validate_float_sibling( { branchcode => $branch } );
2190
2191     # get the proper branch to which to return the item
2192     my $returnbranch;
2193     if ( $hbr eq 'noreturn' ) {
2194         $returnbranch = $branch;
2195     } elsif ( $hbr eq 'returnbylibrarygroup' ) {
2196
2197         # if library isn't in same the float group, transfer item to homebranch
2198         $hbr          = 'homebranch';
2199         $returnbranch = $validate_float ? $branch : $item->$hbr;
2200     } else {
2201         $returnbranch = $item->$hbr;
2202     }
2203
2204     # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2205     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2206
2207     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2208     my $patron_unblessed = $patron ? $patron->unblessed : {};
2209
2210     # Update item location
2211     my $loc_messages = $item->location_update_trigger( 'checkin' );
2212     foreach my $loc_msg_key ( keys %$loc_messages ) {
2213         $messages->{ $loc_msg_key } = $loc_messages->{ $loc_msg_key };
2214     }
2215
2216     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2217     if ($yaml) {
2218         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2219         my $rules;
2220         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2221         if ($@) {
2222             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2223         }
2224         else {
2225             if ( defined $rules->{$item->itype} ) {
2226                 foreach my $notloan_rule_key (keys %{ $rules->{$item->itype}} ) {
2227                     if ( $item->notforloan eq $notloan_rule_key ) {
2228                         $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$item->itype}->{$notloan_rule_key} };
2229                         $item->notforloan( $rules->{ $item->itype }->{$notloan_rule_key} )
2230                             ->store( { log_action => 0, skip_record_index => 1, skip_holds_queue => 1 } )
2231                             unless $rules->{ $item->itype }->{$notloan_rule_key} eq 'ONLYMESSAGE';
2232                         last;
2233                     }
2234                 }
2235             } elsif ( defined $rules->{'_ALL_'} ) {
2236                 foreach my $notloan_rule_key (keys %{ $rules->{'_ALL_'}} ) {
2237                     if ( $item->notforloan eq $notloan_rule_key ) {
2238                         $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{'_ALL_'}->{$notloan_rule_key} };
2239                         $item->notforloan( $rules->{'_ALL_'}->{$notloan_rule_key} )
2240                             ->store( { log_action => 0, skip_record_index => 1, skip_holds_queue => 1 } )
2241                             unless $rules->{ '_ALL_' }->{$notloan_rule_key} eq 'ONLYMESSAGE';
2242                         last;
2243                     }
2244                 }
2245             }
2246         }
2247     }
2248
2249     # check if the return is allowed at this branch
2250     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2251     unless ($returnallowed){
2252         $messages->{'Wrongbranch'} = {
2253             Wrongbranch => $branch,
2254             Rightbranch => $message
2255         };
2256         $doreturn = 0;
2257         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2258         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2259         return ( $doreturn, $messages, $issue, $patron_unblessed);
2260     }
2261
2262     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2263         $doreturn = 0;
2264     }
2265
2266     # case of a return of document (deal with issues and holdingbranch)
2267     if ($doreturn) {
2268         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2269         $patron or warn "AddReturn without current borrower";
2270
2271         if ($patron) {
2272             eval {
2273                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1, skip_holds_queue => 1} );
2274             };
2275             unless ( $@ ) {
2276                 if (
2277                     (
2278                         C4::Context->preference('CalculateFinesOnReturn')
2279                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2280                     )
2281                     && !$item->itemlost
2282                   )
2283                 {
2284                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2285                 }
2286             } else {
2287                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2288
2289                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2290                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2291
2292                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2293             }
2294
2295             # FIXME is the "= 1" right?  This could be the borrower hash.
2296             $messages->{'WasReturned'} = 1;
2297
2298         } else {
2299             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1, skip_holds_queue => 1 });
2300         }
2301     }
2302
2303     # the holdingbranch is updated if the document is returned to another location.
2304     # this is always done regardless of whether the item was on loan or not
2305     if ($item->holdingbranch ne $branch) {
2306         $item->holdingbranch($branch)->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2307     }
2308
2309     my $item_was_lost = $item->itemlost;
2310     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2311     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1, skip_holds_queue => 1 } ); # will unset itemlost if needed
2312
2313     # fix up the accounts.....
2314     if ($item_was_lost) {
2315         $messages->{'WasLost'} = 1;
2316         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2317             my @object_messages = @{ $updated_item->object_messages };
2318             for my $message (@object_messages) {
2319                 $messages->{'LostItemFeeRefunded'} = 1
2320                   if $message->message eq 'lost_refunded';
2321                 $messages->{'ProcessingFeeRefunded'} = 1
2322                   if $message->message eq 'processing_refunded';
2323                 $messages->{'LostItemFeeRestored'} = 1
2324                   if $message->message eq 'lost_restored';
2325
2326                 if ( $message->message eq 'lost_charge' ) {
2327                     $issue //= Koha::Old::Checkouts->search(
2328                         { itemnumber => $item->itemnumber },
2329                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2330                     )->single;
2331                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2332                         my $patron = $issue->patron;
2333                         $patron_unblessed = $patron->unblessed;
2334                     }
2335                     _CalculateAndUpdateFine(
2336                         {
2337                             issue       => $issue,
2338                             item        => $item->unblessed,
2339                             borrower    => $patron_unblessed,
2340                             return_date => $return_date
2341                         }
2342                     );
2343                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2344                         $item->itemnumber, undef, 'RETURNED' );
2345                     $messages->{'LostItemFeeCharged'} = 1;
2346                 }
2347             }
2348         }
2349     }
2350
2351     # check if we have a transfer for this document
2352     my $transfer = $item->get_transfer;
2353
2354     # if we have a transfer to complete, we update the line of transfers with the datearrived
2355     if ($transfer) {
2356         $validTransfer = 0;
2357         if ( $transfer->in_transit ) {
2358             if ( $transfer->tobranch eq $branch ) {
2359                 $transfer->receive;
2360                 $messages->{'TransferArrived'} = $transfer->frombranch;
2361                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2362                 $validTransfer = 1
2363                   if defined $transfer->reason && $transfer->reason eq 'Reserve';
2364             }
2365             else {
2366                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2367                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2368                 $messages->{'TransferTrigger'}   = $transfer->reason;
2369             }
2370         }
2371         else {
2372             if ( $transfer->tobranch eq $branch ) {
2373                 $transfer->receive;
2374                 $messages->{'TransferArrived'} = $transfer->frombranch;
2375                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2376                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2377             }
2378             else {
2379                 $messages->{'TransferTrigger'} = $transfer->reason;
2380                 if ( $transfer->frombranch eq $branch ) {
2381                     $transfer->transit;
2382                     $messages->{'WasTransfered'}   = $transfer->tobranch;
2383                 }
2384                 else {
2385                     $messages->{'WrongTransfer'}     = $transfer->tobranch;
2386                     $messages->{'WrongTransferItem'} = $item->itemnumber;
2387                 }
2388             }
2389         }
2390     }
2391
2392     # fix up the overdues in accounts...
2393     if ($borrowernumber) {
2394         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2395         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2396
2397         if ( $issue and $issue->is_overdue($return_date) ) {
2398         # fix fine days
2399             my ($debardate,$reminder) = _debar_user_on_return( $patron, $item, dt_from_string($issue->date_due), $return_date );
2400             if ($debardate and $debardate ne "9999-12-31") {
2401                 if ($reminder){
2402                     $messages->{'PrevDebarred'} = $debardate;
2403                 } else {
2404                     $messages->{'Debarred'} = $debardate;
2405                 }
2406             } elsif ($patron->debarred) {
2407                 if ( $patron->debarred eq "9999-12-31") {
2408                     $messages->{'ForeverDebarred'} = $patron->debarred;
2409                 } else {
2410                     my $borrower_debar_dt = dt_from_string( $patron->debarred );
2411                     $borrower_debar_dt->truncate(to => 'day');
2412                     my $today_dt = $return_date->clone()->truncate(to => 'day');
2413                     if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2414                         $messages->{'PrevDebarred'} = $patron->debarred;
2415                     }
2416                 }
2417             }
2418         # there's no overdue on the item but borrower had been previously debarred
2419         } elsif ( $issue->date_due and $patron->debarred ) {
2420              if ( $patron->debarred eq "9999-12-31") {
2421                 $messages->{'ForeverDebarred'} = $patron->debarred;
2422              } else {
2423                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2424                   $borrower_debar_dt->truncate(to => 'day');
2425                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2426                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2427                       $messages->{'PrevDebarred'} = $patron->debarred;
2428                   }
2429              }
2430         }
2431     }
2432
2433     # find recalls...
2434     if ( C4::Context->preference('UseRecalls') ) {
2435         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2436         my $recall = undef;
2437         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2438         if ( defined $recall ) {
2439             $messages->{RecallFound} = $recall;
2440             if ( $recall->pickup_library_id ne $branch ) {
2441                 $messages->{RecallNeedsTransfer} = $branch;
2442             }
2443         }
2444     }
2445
2446     # find reserves.....
2447     # launch the Checkreserves routine to find any holds
2448     my ($resfound, $resrec);
2449     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2450     ($resfound, $resrec, undef) = CheckReserves( $item, $lookahead ) unless ( $item->withdrawn );
2451     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2452     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2453         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2454         $resfound = 'Reserved';
2455         $resrec = $hold->unblessed;
2456     }
2457     if ($resfound) {
2458           $resrec->{'ResFound'} = $resfound;
2459         $messages->{'ResFound'} = $resrec;
2460     }
2461
2462     # Record the fact that this book was returned.
2463     my $categorycode = $patron_unblessed ? $patron_unblessed->{categorycode} : undef;
2464     C4::Stats::UpdateStats({
2465         branch         => $branch,
2466         type           => $stat_type,
2467         itemnumber     => $itemnumber,
2468         itemtype       => $itemtype,
2469         location       => $item->location,
2470         borrowernumber => $borrowernumber,
2471         ccode          => $item->ccode,
2472         categorycode   => $categorycode,
2473         interface      => C4::Context->interface,
2474     }) unless ( $skip_localuse && $stat_type eq 'localuse' );
2475
2476     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2477     if ( $patron ) {
2478         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2479         my %conditions = (
2480             branchcode   => $branch,
2481             categorycode => $patron->categorycode,
2482             item_type    => $itemtype,
2483             notification => 'CHECKIN',
2484         );
2485         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2486             SendCirculationAlert({
2487                 type     => 'CHECKIN',
2488                 item     => $item->unblessed,
2489                 borrower => $patron->unblessed,
2490                 branch   => $branch,
2491                 issue    => $issue
2492             });
2493         }
2494
2495         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2496             if C4::Context->preference("ReturnLog");
2497
2498         #Update borrowers.lastseen
2499         $patron->update_lastseen('check_in');
2500     }
2501
2502     # Check if this item belongs to a biblio record that is attached to an
2503     # ILL request, if it is we need to update the ILL request's status
2504     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2505         my $request = Koha::Illrequests->find(
2506             { biblio_id => $item->biblio->biblionumber }
2507         );
2508         $request->status('RET') if $request;
2509     }
2510
2511     if ( C4::Context->preference('UseRecalls') ) {
2512         # all recalls that have triggered a transfer will have an allocated itemnumber
2513         my $transfer_recall = Koha::Recalls->find({ item_id => $item->itemnumber, status => 'in_transit' });
2514         if ( $transfer_recall and $transfer_recall->pickup_library_id eq $branch ) {
2515             $messages->{TransferredRecall} = $transfer_recall;
2516         }
2517     }
2518
2519     if ( $messages->{WasLost} and C4::Context->preference('BlockReturnOfLostItems') ) {
2520         $validTransfer = 0;
2521     }
2522
2523     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2524     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2525         && ( $doreturn or $messages->{'NotIssued'} )
2526         and !$resfound
2527         and ( $branch ne $returnbranch )
2528         and not $messages->{'WrongTransfer'}
2529         and not $messages->{'WasTransfered'}
2530         and not $messages->{TransferredRecall}
2531         and not $messages->{RecallNeedsTransfer} )
2532     {
2533         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2534         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2535             (C4::Context->preference("UseBranchTransferLimits") and
2536              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2537            )) {
2538             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2539             $messages->{'WasTransfered'} = $returnbranch;
2540             $messages->{'TransferTrigger'} = $transfer_trigger;
2541         } else {
2542             $messages->{'NeedsTransfer'} = $returnbranch;
2543             $messages->{'TransferTrigger'} = $transfer_trigger;
2544         }
2545     }
2546
2547     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2548         my $claims = Koha::Checkouts::ReturnClaims->search(
2549            {
2550                itemnumber => $item->id,
2551                resolution => undef,
2552            }
2553         );
2554
2555         if ( $claims->count ) {
2556             $messages->{ReturnClaims} = $claims;
2557         }
2558     }
2559
2560     # Check for bundle status
2561     if ( $item->in_bundle ) {
2562         my $host = $item->bundle_host;
2563         $messages->{InBundle} = $host;
2564     }
2565
2566     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2567     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2568
2569     if ( $doreturn and $issue ) {
2570         my $checkin = Koha::Old::Checkouts->find($issue->id);
2571
2572         Koha::Plugins->call('after_circ_action', {
2573             action  => 'checkin',
2574             payload => {
2575                 checkout=> $checkin
2576             }
2577         });
2578
2579         Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2580             {
2581                 biblio_ids => [ $item->biblionumber ]
2582             }
2583         ) if C4::Context->preference('RealTimeHoldsQueue');
2584     }
2585
2586     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2587 }
2588
2589 =head2 MarkIssueReturned
2590
2591   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2592
2593 Unconditionally marks an issue as being returned by
2594 moving the C<issues> row to C<old_issues> and
2595 setting C<returndate> to the current date.
2596
2597 if C<$returndate> is specified (in iso format), it is used as the date
2598 of the return.
2599
2600 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2601 the old_issue is immediately anonymised
2602
2603 Ideally, this function would be internal to C<C4::Circulation>,
2604 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2605 and offline_circ/process_koc.pl.
2606
2607 The last optional parameter allos passing skip_record_index to the item store call.
2608
2609 =cut
2610
2611 sub MarkIssueReturned {
2612     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2613
2614     # Retrieve the issue
2615     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2616     my $issue_branchcode = $issue->branchcode;
2617
2618     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2619
2620     my $issue_id = $issue->issue_id;
2621
2622     my $schema = Koha::Database->schema;
2623
2624     # FIXME Improve the return value and handle it from callers
2625     $schema->txn_do(sub {
2626
2627         my $patron = Koha::Patrons->find( $borrowernumber );
2628
2629         # Update the returndate value
2630         if ( $returndate ) {
2631             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2632         }
2633         else {
2634             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2635         }
2636
2637         # Create the old_issues entry
2638         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2639
2640         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2641         if ( $privacy && $privacy == 2) {
2642             $old_checkout->anonymize;
2643         }
2644
2645         # And finally delete the issue
2646         $issue->delete;
2647
2648         $issue->item->onloan(undef)->store(
2649             {   log_action        => 0,
2650                 skip_record_index => $params->{skip_record_index},
2651                 skip_holds_queue  => $params->{skip_holds_queue}
2652             }
2653         );
2654
2655         if ( C4::Context->preference('StoreLastBorrower') ) {
2656             my $item = Koha::Items->find( $itemnumber );
2657             $item->last_returned_by( $patron->borrowernumber )->store;
2658         }
2659
2660         # Possibly remove any OVERDUES related debarment
2661         my $overdue_restrictions = $patron->restrictions->search( { type => 'OVERDUES' } );
2662         if ( C4::Context->preference('AutoRemoveOverduesRestrictions') ne 'no' && $patron->is_debarred ) {
2663             my $remove_restrictions =
2664                 C4::Context->preference('AutoRemoveOverduesRestrictions') eq 'when_no_overdue_causing_debarment'
2665                 ? !$patron->has_restricting_overdues( { issue_branchcode => $issue_branchcode } )
2666                 : !$patron->has_overdues;
2667             if ( $remove_restrictions && $overdue_restrictions->count ) {
2668                 DelUniqueDebarment( { borrowernumber => $borrowernumber, type => 'OVERDUES' } );
2669             }
2670         }
2671
2672     });
2673
2674     return $issue_id;
2675 }
2676
2677 =head2 _debar_user_on_return
2678
2679     _debar_user_on_return($patron, $item, $datedue, $returndate);
2680
2681 C<$patron> patron object
2682
2683 C<$item> item object
2684
2685 C<$datedue> date due DateTime object
2686
2687 C<$returndate> DateTime object representing the return time
2688
2689 Internal function, called only by AddReturn that calculates and updates
2690  the user fine days, and debars them if necessary.
2691
2692 Should only be called for overdue returns
2693
2694 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2695 to ease testing.
2696
2697 =cut
2698
2699 sub _calculate_new_debar_dt {
2700     my ( $patron, $item, $dt_due, $return_date ) = @_;
2701
2702     my $branchcode = _GetCircControlBranch( $item, $patron );
2703     my $circcontrol = C4::Context->preference('CircControl');
2704     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2705         {   categorycode => $patron->categorycode,
2706             itemtype     => $item->effective_itemtype,
2707             branchcode   => $branchcode,
2708             rules => [
2709                 'finedays',
2710                 'lengthunit',
2711                 'firstremind',
2712                 'maxsuspensiondays',
2713                 'suspension_chargeperiod',
2714             ]
2715         }
2716     );
2717     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2718     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2719     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2720
2721     return unless $finedays;
2722
2723     # finedays is in days, so hourly loans must multiply by 24
2724     # thus 1 hour late equals 1 day suspension * finedays rate
2725     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2726
2727     # grace period is measured in the same units as the loan
2728     my $grace =
2729       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2730
2731     my $deltadays = DateTime::Duration->new(
2732         days => $chargeable_units
2733     );
2734
2735     if ( $deltadays->subtract($grace)->is_positive() ) {
2736         my $suspension_days = $deltadays * $finedays;
2737
2738         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2739             # No need to / 1 and do not consider / 0
2740             $suspension_days = DateTime::Duration->new(
2741                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2742             );
2743         }
2744
2745         # If the max suspension days is < than the suspension days
2746         # the suspension days is limited to this maximum period.
2747         my $max_sd = $issuing_rule->{maxsuspensiondays};
2748         if ( defined $max_sd && $max_sd ne '' ) {
2749             $max_sd = DateTime::Duration->new( days => $max_sd );
2750             $suspension_days = $max_sd
2751               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2752         }
2753
2754         my ( $has_been_extended );
2755         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $patron->is_debarred ) {
2756             my $debarment = $patron->restrictions->search({type => 'SUSPENSION' },{rows => 1})->single;
2757             if ( $debarment ) {
2758                 $return_date = dt_from_string( $debarment->expiration, 'sql' );
2759                 $has_been_extended = 1;
2760             }
2761         }
2762
2763         my $new_debar_dt;
2764         # Use the calendar or not to calculate the debarment date
2765         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2766             my $calendar = Koha::Calendar->new(
2767                 branchcode => $branchcode,
2768                 days_mode  => 'Calendar'
2769             );
2770             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2771         }
2772         else {
2773             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2774         }
2775         return $new_debar_dt;
2776     }
2777     return;
2778 }
2779
2780 sub _debar_user_on_return {
2781     my ( $patron, $item, $dt_due, $return_date ) = @_;
2782
2783     $return_date //= dt_from_string();
2784
2785     my $new_debar_dt = _calculate_new_debar_dt($patron, $item, $dt_due, $return_date);
2786
2787     return unless $new_debar_dt;
2788
2789     Koha::Patron::Debarments::AddUniqueDebarment({
2790         borrowernumber => $patron->borrowernumber,
2791         expiration     => $new_debar_dt->ymd(),
2792         type           => 'SUSPENSION',
2793     });
2794     # if borrower was already debarred but does not get an extra debarment
2795     my ($new_debarment_str, $is_a_reminder);
2796     if ( $patron->is_debarred ) {
2797         $is_a_reminder = 1;
2798         $new_debarment_str = $patron->debarred;
2799     } else {
2800         $new_debarment_str = $new_debar_dt->ymd();
2801     }
2802     # FIXME Should return a DateTime object
2803     return $new_debarment_str, $is_a_reminder;
2804 }
2805
2806 =head2 _FixOverduesOnReturn
2807
2808    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2809
2810 C<$borrowernumber> borrowernumber
2811
2812 C<$itemnumber> itemnumber
2813
2814 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2815
2816 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2817
2818 Internal function
2819
2820 =cut
2821
2822 sub _FixOverduesOnReturn {
2823     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2824     unless( $borrowernumber ) {
2825         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2826         return;
2827     }
2828     unless( $item ) {
2829         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2830         return;
2831     }
2832     unless( $status ) {
2833         warn "_FixOverduesOnReturn() not supplied valid status";
2834         return;
2835     }
2836
2837     my $schema = Koha::Database->schema;
2838
2839     my $result = $schema->txn_do(
2840         sub {
2841             # check for overdue fine
2842             my $accountlines = Koha::Account::Lines->search(
2843                 {
2844                     borrowernumber  => $borrowernumber,
2845                     itemnumber      => $item,
2846                     debit_type_code => 'OVERDUE',
2847                     status          => 'UNRETURNED'
2848                 }
2849             );
2850             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2851
2852             my $accountline = $accountlines->next;
2853             my $payments = $accountline->credits;
2854
2855             my $amountoutstanding = $accountline->amountoutstanding;
2856             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2857                 $accountline->delete;
2858                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2859             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2860                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2861                 my $credit = $account->add_credit(
2862                     {
2863                         amount     => $amountoutstanding,
2864                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2865                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2866                         interface  => C4::Context->interface,
2867                         type       => 'FORGIVEN',
2868                         item_id    => $item
2869                     }
2870                 );
2871
2872                 $credit->apply({ debits => [ $accountline ] });
2873
2874                 if (C4::Context->preference("FinesLog")) {
2875                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2876                 }
2877             }
2878
2879             $accountline->status($status);
2880             return $accountline->store();
2881         }
2882     );
2883
2884     return $result;
2885 }
2886
2887 =head2 _GetCircControlBranch
2888
2889    my $circ_control_branch = _GetCircControlBranch($item, $patron);
2890
2891 Internal function :
2892
2893 Return the library code to be used to determine which circulation
2894 policy applies to a transaction.  Looks up the CircControl and
2895 HomeOrHoldingBranch system preferences.
2896
2897 C<$item> is an item object.
2898
2899 C<$patron> is a patron object.
2900
2901 =cut
2902
2903 sub _GetCircControlBranch {
2904     my ($item, $patron) = @_;
2905     my $circcontrol = C4::Context->preference('CircControl');
2906     my $branch;
2907
2908     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2909         $branch = C4::Context->userenv->{'branch'};
2910     } elsif ($circcontrol eq 'PatronLibrary') {
2911         $branch = $patron->branchcode;
2912     } else {
2913         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2914         $branch = $item->get_column($branchfield);
2915         # default to item home branch if holdingbranch is used
2916         # and is not defined
2917         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2918             $branch = $item->homebranch;
2919         }
2920     }
2921     return $branch;
2922 }
2923
2924 =head2 GetUpcomingDueIssues
2925
2926   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2927
2928 =cut
2929
2930 sub GetUpcomingDueIssues {
2931     my $params = shift;
2932
2933     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2934     my $dbh = C4::Context->dbh;
2935     my $statement;
2936     $statement = q{
2937         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2938         FROM issues
2939         LEFT JOIN items USING (itemnumber)
2940         LEFT JOIN branches ON branches.branchcode =
2941     };
2942     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2943     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2944     my @bind_parameters = ( $params->{'days_in_advance'} );
2945
2946     my $sth = $dbh->prepare( $statement );
2947     $sth->execute( @bind_parameters );
2948     my $upcoming_dues = $sth->fetchall_arrayref({});
2949
2950     return $upcoming_dues;
2951 }
2952
2953 =head2 CanBookBeRenewed
2954
2955   ($ok,$error,$info) = &CanBookBeRenewed($patron, $issue, $override_limit, $cron);
2956
2957 Find out whether a borrowed item may be renewed.
2958
2959 C<$patron> is the patron who currently has the issue.
2960
2961 C<$issue> is the checkout to renew.
2962
2963 C<$cron> true or false, specifies if this check is being made
2964 by the automatic_renewals.pl cronscript
2965
2966 C<$override_limit>, if supplied with a true value, causes
2967 the limit on the number of times that the loan can be renewed
2968 (as controlled by the item type) to be ignored. Overriding also allows
2969 to renew sooner than "No renewal before" and to manually renew loans
2970 that are automatically renewed.
2971
2972 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2973 item must currently be on loan to the specified borrower; renewals
2974 must be allowed for the item's type; and the borrower must not have
2975 already renewed the loan.
2976     $error will contain the reason the renewal can not proceed
2977     $info will contain a hash of additional info
2978       currently 'soonest_renew_date' if error is 'too soon'
2979
2980 =cut
2981
2982 sub CanBookBeRenewed {
2983     my ( $patron, $issue, $override_limit, $cron ) = @_;
2984
2985     my $auto_renew = "no";
2986     my $soonest;
2987     my $item = $issue->item;
2988
2989     return ( 0, 'no_item' ) unless $item;
2990     return ( 0, 'no_checkout' ) unless $issue;
2991     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2992     return ( 0, 'item_issued_to_other_patron') if $issue->borrowernumber != $patron->borrowernumber;
2993     return ( 0, 'item_denied_renewal') if $item->is_denied_renewal;
2994
2995     my $final_renewal        = 0;
2996     my $final_unseen_renewal = 0;
2997
2998     # override_limit will override anything else except on_reserve
2999     unless ( $override_limit ){
3000         my $branchcode = _GetCircControlBranch( $item, $patron );
3001
3002         ( $auto_renew, $soonest ) = _CanBookBeAutoRenewed({
3003             patron     => $patron,
3004             item       => $item,
3005             branchcode => $branchcode,
3006             issue      => $issue
3007         });
3008         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'auto_too_soon' && $cron;
3009         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
3010         # extra notices being sent. Cron also implies no override
3011         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
3012         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
3013         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
3014
3015         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3016             {
3017                 categorycode => $patron->categorycode,
3018                 itemtype     => $item->effective_itemtype,
3019                 branchcode   => $branchcode,
3020                 rules => [
3021                     'renewalsallowed',
3022                     'lengthunit',
3023                     'unseen_renewals_allowed'
3024                 ]
3025             }
3026         );
3027
3028         return ( 0, "too_many" )
3029           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals_count;
3030
3031         return ( 0, "too_unseen" )
3032           if C4::Context->preference('UnseenRenewals') &&
3033             looks_like_number($issuing_rule->{unseen_renewals_allowed}) &&
3034             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
3035
3036         $final_renewal        = $issuing_rule->{renewalsallowed} == ( $issue->renewals_count + 1 ) ? 1 : 0;
3037         $final_unseen_renewal = ( C4::Context->preference('UnseenRenewals')
3038                 && $issuing_rule->{unseen_renewals_allowed} == ( $issue->unseen_renewals + 1 ) ) ? 1 : 0;
3039
3040         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
3041         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
3042         my $restricted  = $patron->is_debarred;
3043         my $hasoverdues = $patron->has_overdues;
3044
3045         if ( $restricted and $restrictionblockrenewing ) {
3046             return ( 0, 'restriction');
3047         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
3048             return ( 0, 'overdue');
3049         }
3050
3051     }
3052
3053     if ( C4::Context->preference('UseRecalls') ) {
3054         my $recall = undef;
3055         $recall = $item->check_recalls if $item->can_be_waiting_recall;
3056         if ( defined $recall ) {
3057             if ( $recall->item_level ) {
3058                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
3059                 return ( 0, 'recalled' ) if ( $recall->item_id == $item->itemnumber );
3060             } else {
3061                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
3062                 return ( 0, 'recalled' ) unless ( $recall->waiting );
3063             }
3064         }
3065     }
3066
3067     # There is an item level hold on this item, no other item can fill the hold
3068     return ( 0, "on_reserve" )
3069       if ( $item->current_holds->search( { non_priority => 0 } )->count );
3070
3071     my $fillable_holds = Koha::Holds->search(
3072         {
3073             biblionumber => $item->biblionumber,
3074             non_priority => 0,
3075             found        => undef,
3076             reservedate  => { '<=' => \'NOW()' },
3077             suspend      => 0
3078         }
3079     );
3080     if ( $fillable_holds->count ) {
3081         if ( C4::Context->preference('AllowRenewalIfOtherItemsAvailable') ) {
3082             my @possible_holds = $fillable_holds->as_list;
3083
3084             # Get all other items that could possibly fill reserves
3085             # FIXME We could join reserves (or more tables) here to eliminate some checks later
3086             my @other_items = Koha::Items->search({
3087                 biblionumber => $item->biblionumber,
3088                 onloan       => undef,
3089                 notforloan   => 0,
3090                 -not         => { itemnumber => $item->itemnumber } })->as_list;
3091
3092             return ( 0, "on_reserve" ) if @possible_holds && (scalar @other_items < scalar @possible_holds);
3093
3094             my %matched_items;
3095             foreach my $possible_hold (@possible_holds) {
3096                 my $fillable = 0;
3097                 my $patron_with_reserve = Koha::Patrons->find($possible_hold->borrowernumber);
3098
3099                 # FIXME: We are not checking whether the item we are renewing can fill the hold
3100
3101                 foreach my $other_item (@other_items) {
3102                   next if defined $matched_items{$other_item->itemnumber};
3103                   next if IsItemOnHoldAndFound( $other_item->itemnumber );
3104                   next unless IsAvailableForItemLevelRequest($other_item, $patron_with_reserve, undef);
3105                   next unless CanItemBeReserved($patron_with_reserve,$other_item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
3106                   # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
3107                   # CanItemBeReserved checks 'rules' and 'policies' which means
3108                   # items will fill holds at checkin that are rejected here
3109                   $fillable = 1;
3110                   $matched_items{$other_item->itemnumber} = 1;
3111                   last;
3112                 }
3113                 return ( 0, "on_reserve" ) unless $fillable;
3114             }
3115         }
3116         else {
3117             my ($status, $matched_reserve, $possible_reserves) = CheckReserves($item);
3118             return ( 0, "on_reserve" ) if $status;
3119         }
3120     }
3121
3122     if ( $auto_renew eq 'auto_too_soon' ) {
3123
3124         # If its cron, tell it it's too soon for a an auto renewal
3125         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $cron;
3126
3127         # Check if it's too soon for a manual renewal
3128         my $soonestManual = GetSoonestRenewDate( $patron, $issue );
3129         if ( $soonestManual > dt_from_string() ) {
3130             return ( 0, "too_soon", { soonest_renew_date => $soonestManual } ) unless $override_limit;
3131         }
3132     }
3133
3134     $soonest = GetSoonestRenewDate($patron, $issue);
3135     if ( $soonest > dt_from_string() ){
3136         return (0, "too_soon", { soonest_renew_date => $soonest } ) unless $override_limit;
3137     }
3138
3139     my $auto_renew_code = $final_renewal ? 'auto_renew_final' : $final_unseen_renewal ? 'auto_unseen_final' : 'auto_renew';
3140     return ( 1, $auto_renew_code ) if $auto_renew eq "ok" || $auto_renew eq "auto_too_soon" && !$override_limit;
3141
3142     return ( 1, undef );
3143 }
3144
3145 =head2 AddRenewal
3146
3147   $new_date_due = AddRenewal({
3148       borrowernumber   => $borrowernumber,
3149       itemnumber       => $itemnumber,
3150       branch           => $branch,
3151       [datedue         => $datedue],
3152       [lastreneweddate => $lastreneweddate],
3153       [skipfinecalc    => $skipfinecalc],
3154       [seen            => $seen],
3155       [automatic       => $automatic],
3156       [skip_record_index => $skip_record_index]
3157   });
3158
3159 Renews a loan, returns the updated due date upon success.
3160
3161 C<$borrowernumber> is the borrower number of the patron who currently
3162 has the item.
3163
3164 C<$itemnumber> is the number of the item to renew.
3165
3166 C<$branch> is the library where the renewal took place (if any).
3167            The library that controls the circ policies for the renewal is retrieved from the issues record.
3168
3169 C<$datedue> can be a DateTime object used to set the due date.
3170
3171 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3172 this parameter is not supplied, lastreneweddate is set to the current date.
3173
3174 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3175 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3176 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3177 syspref)
3178
3179 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3180 from the book's item type.
3181
3182 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3183 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3184 fallback to a true value
3185
3186 C<$automatic> is a boolean flag indicating the renewal was triggered automatically and not by a person ( librarian or patron )
3187
3188 C<$skip_record_index> is an optional boolean flag to indicate whether queuing the search indexing
3189 should be skipped for this renewal.
3190
3191 =cut
3192
3193 sub AddRenewal {
3194     my $params = shift;
3195
3196     my $borrowernumber  = $params->{borrowernumber};
3197     my $itemnumber      = $params->{itemnumber};
3198     return unless $itemnumber;
3199
3200     my $branch            = $params->{branch};
3201     my $datedue           = $params->{datedue};
3202     my $lastreneweddate   = $params->{lastreneweddate} // dt_from_string();
3203     my $skipfinecalc      = $params->{skipfinecalc};
3204     my $seen              = $params->{seen};
3205     my $automatic         = $params->{automatic};
3206     my $skip_record_index = $params->{skip_record_index};
3207
3208     # Fallback on a 'seen' renewal
3209     $seen = defined $seen && $seen == 0 ? 0 : 1;
3210
3211     my $item_object   = Koha::Items->find($itemnumber) or return;
3212     my $biblio = $item_object->biblio;
3213     my $issue  = $item_object->checkout;
3214     my $item_unblessed = $item_object->unblessed;
3215
3216     my $renewal_type = $automatic ? "Automatic" : "Manual";
3217
3218     my $dbh = C4::Context->dbh;
3219
3220     return unless $issue;
3221
3222     $borrowernumber ||= $issue->borrowernumber;
3223
3224     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3225         $datedue = dt_from_string($datedue, 'sql');
3226     }
3227
3228     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3229     my $patron_unblessed = $patron->unblessed;
3230
3231     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_object, $patron) );
3232
3233     my $schema = Koha::Database->schema;
3234     $schema->txn_do(sub{
3235
3236         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3237             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3238         }
3239         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3240
3241         # If the due date wasn't specified, calculate it by adding the
3242         # book's loan length to today's date or the current due date
3243         # based on the value of the RenewalPeriodBase syspref.
3244         my $itemtype = $item_object->effective_itemtype;
3245         unless ($datedue) {
3246
3247             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3248                                             dt_from_string( $issue->date_due, 'sql' ) :
3249                                             dt_from_string();
3250             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron, 'is a renewal');
3251         }
3252
3253         my $fees = Koha::Charges::Fees->new(
3254             {
3255                 patron    => $patron,
3256                 library   => $circ_library,
3257                 item      => $item_object,
3258                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3259                 to_date   => dt_from_string($datedue),
3260             }
3261         );
3262
3263         # Increment the unseen renewals, if appropriate
3264         # We only do so if the syspref is enabled and
3265         # a maximum value has been set in the circ rules
3266         my $unseen_renewals = $issue->unseen_renewals;
3267         if (C4::Context->preference('UnseenRenewals')) {
3268             my $rule = Koha::CirculationRules->get_effective_rule(
3269                 {   categorycode => $patron->categorycode,
3270                     itemtype     => $item_object->effective_itemtype,
3271                     branchcode   => $circ_library->branchcode,
3272                     rule_name    => 'unseen_renewals_allowed'
3273                 }
3274             );
3275             if (!$seen && $rule && looks_like_number($rule->rule_value)) {
3276                 $unseen_renewals++;
3277             } else {
3278                 # If the renewal is seen, unseen should revert to 0
3279                 $unseen_renewals = 0;
3280             }
3281         }
3282
3283         # Update the issues record to have the new due date, and a new count
3284         # of how many times it has been renewed.
3285         my $renews = ( $issue->renewals_count || 0 ) + 1;
3286         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals_count = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3287
3288         eval{
3289             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3290         };
3291         if( $sth->err ){
3292             Koha::Exceptions::Checkout::FailedRenewal->throw(
3293                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3294             );
3295         }
3296
3297         # Update the renewal count on the item, and tell zebra to reindex
3298         $renews = ( $item_object->renewals || 0 ) + 1;
3299         $item_object->renewals($renews);
3300         $item_object->onloan($datedue);
3301         # Don't index as we are in a transaction, skip hardcoded here
3302         $item_object->store({ log_action => 0, skip_record_index => 1 });
3303
3304         # Charge a new rental fee, if applicable
3305         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3306         if ( $charge > 0 ) {
3307             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3308         }
3309
3310         # Charge a new accumulate rental fee, if applicable
3311         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3312         if ( $itemtype_object ) {
3313             my $accumulate_charge = $fees->accumulate_rentalcharge();
3314             if ( $accumulate_charge > 0 ) {
3315                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3316             }
3317             $charge += $accumulate_charge;
3318         }
3319
3320         # Send a renewal slip according to checkout alert preferencei
3321         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3322             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3323             my %conditions        = (
3324                 branchcode   => $branch,
3325                 categorycode => $patron->categorycode,
3326                 item_type    => $itemtype,
3327                 notification => 'CHECKOUT',
3328             );
3329             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3330                 SendCirculationAlert(
3331                     {
3332                         type     => 'RENEWAL',
3333                         item     => $item_unblessed,
3334                         borrower => $patron->unblessed,
3335                         branch   => $branch,
3336                     }
3337                 );
3338             }
3339         }
3340
3341         # Remove any OVERDUES related debarment if the borrower has no overdues
3342         my $overdue_restrictions = $patron->restrictions->search({ type => 'OVERDUES' });
3343         if ( $patron
3344           && $patron->is_debarred
3345           && ! $patron->has_overdues
3346           && $overdue_restrictions->count
3347         ) {
3348             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3349         }
3350
3351         # Add renewal record
3352         my $renewal = Koha::Checkouts::Renewal->new(
3353             {
3354                 checkout_id  => $issue->issue_id,
3355                 interface    => C4::Context->interface,
3356                 renewal_type => $renewal_type,
3357                 renewer_id   => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3358                 seen         => $seen,
3359             }
3360         )->store();
3361
3362         # Add the renewal to stats
3363         C4::Stats::UpdateStats(
3364             {
3365                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3366                 type           => 'renew',
3367                 amount         => $charge,
3368                 itemnumber     => $itemnumber,
3369                 itemtype       => $itemtype,
3370                 location       => $item_object->location,
3371                 borrowernumber => $borrowernumber,
3372                 ccode          => $item_object->ccode,
3373                 categorycode   => $patron->categorycode,
3374                 interface      => C4::Context->interface,
3375             }
3376         );
3377         #Update borrowers.lastseen
3378         $patron->update_lastseen('renewal');
3379
3380         #Log the renewal
3381         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3382
3383         Koha::Plugins->call('after_circ_action', {
3384             action  => 'renewal',
3385             payload => {
3386                 checkout  => $issue->get_from_storage
3387             }
3388         });
3389     });
3390
3391     unless( $skip_record_index ){
3392         # We index now, after the transaction is committed
3393         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
3394         $indexer->index_records( $item_object->biblionumber, "specialUpdate", "biblioserver" );
3395     }
3396
3397     return $datedue;
3398 }
3399
3400 sub GetRenewCount {
3401     # check renewal status
3402     my ( $borrowernumber_or_patron, $itemnumber_or_item ) = @_;
3403
3404     my $dbh           = C4::Context->dbh;
3405     my $renewcount    = 0;
3406     my $unseencount    = 0;
3407     my $renewsallowed = 0;
3408     my $unseenallowed = 0;
3409     my $renewsleft    = 0;
3410     my $unseenleft    = 0;
3411     my $patron = blessed $borrowernumber_or_patron ?
3412         $borrowernumber_or_patron : Koha::Patrons->find($borrowernumber_or_patron);
3413     my $item = blessed $itemnumber_or_item ?
3414         $itemnumber_or_item : Koha::Items->find($itemnumber_or_item);
3415
3416     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3417
3418     # Look in the issues table for this item, lent to this borrower,
3419     # and not yet returned.
3420
3421     # FIXME - I think this function could be redone to use only one SQL call.
3422     my $sth = $dbh->prepare(q{
3423         SELECT * FROM issues
3424         WHERE  (borrowernumber = ?) AND (itemnumber = ?)
3425     });
3426     $sth->execute( $patron->borrowernumber, $item->itemnumber );
3427     my $data = $sth->fetchrow_hashref;
3428     $renewcount = $data->{'renewals_count'} if $data->{'renewals_count'};
3429     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3430     # $item and $borrower should be calculated
3431     my $branchcode = _GetCircControlBranch($item, $patron);
3432
3433     my $rules = Koha::CirculationRules->get_effective_rules(
3434         {
3435             categorycode => $patron->categorycode,
3436             itemtype     => $item->effective_itemtype,
3437             branchcode   => $branchcode,
3438             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3439         }
3440     );
3441     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3442     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3443         $rules->{unseen_renewals_allowed} :
3444         0;
3445     $renewsleft    = $renewsallowed - $renewcount;
3446     $unseenleft    = $unseenallowed - $unseencount;
3447     if($renewsleft < 0){ $renewsleft = 0; }
3448     if($unseenleft < 0){ $unseenleft = 0; }
3449     return (
3450         $renewcount,
3451         $renewsallowed,
3452         $renewsleft,
3453         $unseencount,
3454         $unseenallowed,
3455         $unseenleft
3456     );
3457 }
3458
3459 =head2 GetSoonestRenewDate
3460
3461   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($patron, $issue);
3462
3463 Find out the soonest possible renew date of a borrowed item.
3464
3465 C<$patron> is the patron who currently has the item on loan.
3466
3467 C<$issue> is the the item issue.
3468
3469 C<$is_auto> is this soonest renew date for an auto renewal?
3470
3471 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3472 renew date, based on the value "No renewal before" of the applicable
3473 issuing rule. Returns the current date if the item can already be
3474 renewed, and returns undefined if the patron, item, or checkout
3475 cannot be found.
3476
3477 =cut
3478
3479 sub GetSoonestRenewDate {
3480     my ( $patron, $issue, $is_auto ) = @_;
3481     return unless $issue;
3482     return unless $patron;
3483
3484     my $item = $issue->item;
3485     return unless $item;
3486
3487     my $circ_rule = $is_auto ? 'noautorenewalbefore' : 'norenewalbefore';
3488
3489     my $dbh = C4::Context->dbh;
3490
3491     my $branchcode = _GetCircControlBranch( $item, $patron );
3492     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3493         {   categorycode => $patron->categorycode,
3494             itemtype     => $item->effective_itemtype,
3495             branchcode   => $branchcode,
3496             rules => [
3497                 $circ_rule,
3498                 'lengthunit',
3499             ]
3500         }
3501     );
3502
3503     my $now = dt_from_string;
3504
3505     if ( defined $issuing_rule->{$circ_rule}
3506         and $issuing_rule->{$circ_rule} ne "" )
3507     {
3508         my $soonestrenewal =
3509           dt_from_string( $issue->date_due )->subtract(
3510             $issuing_rule->{lengthunit} => $issuing_rule->{$circ_rule} );
3511
3512         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3513             and $issuing_rule->{lengthunit} eq 'days' )
3514         {
3515             $soonestrenewal->truncate( to => 'day' );
3516         }
3517         return $soonestrenewal;
3518     } elsif ( $is_auto && $issue->auto_renew && $patron->autorenew_checkouts ) {
3519         # Checkouts with auto-renewing fall back to due date if noautorenewalbefore is undef
3520         my $soonestrenewal = dt_from_string( $issue->date_due );
3521         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3522             and $issuing_rule->{lengthunit} eq 'days' )
3523         {
3524             $soonestrenewal->truncate( to => 'day' );
3525         }
3526         return $soonestrenewal;
3527     }
3528     return $now;
3529 }
3530
3531 =head2 GetLatestAutoRenewDate
3532
3533   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($patron, $issue);
3534
3535 Find out the latest possible auto renew date of a borrowed item.
3536
3537 C<$patron> is the patron who currently has the item on loan.
3538
3539 C<$issue> is the item issue.
3540
3541 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3542 auto renew date, based on the value "No auto renewal after" and the "No auto
3543 renewal after (hard limit) of the applicable issuing rule.
3544 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3545 or item cannot be found.
3546
3547 =cut
3548
3549 sub GetLatestAutoRenewDate {
3550     my ( $patron, $issue ) = @_;
3551     return unless $issue;
3552     return unless $patron;
3553
3554     my $item = $issue->item;
3555     return unless $item;
3556
3557     my $dbh = C4::Context->dbh;
3558     my $branchcode = _GetCircControlBranch( $item, $patron );
3559
3560     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3561         {
3562             categorycode => $patron->categorycode,
3563             itemtype     => $item->effective_itemtype,
3564             branchcode   => $branchcode,
3565             rules => [
3566                 'no_auto_renewal_after',
3567                 'no_auto_renewal_after_hard_limit',
3568                 'lengthunit',
3569             ]
3570         }
3571     );
3572
3573     return unless $circulation_rules;
3574     return
3575       if ( not $circulation_rules->{no_auto_renewal_after}
3576             or $circulation_rules->{no_auto_renewal_after} eq '' )
3577       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3578              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3579
3580     my $maximum_renewal_date;
3581     if ( $circulation_rules->{no_auto_renewal_after} ) {
3582         $maximum_renewal_date = dt_from_string($issue->issuedate);
3583         $maximum_renewal_date->add(
3584             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3585         );
3586     }
3587
3588     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3589         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3590         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3591     }
3592     return $maximum_renewal_date;
3593 }
3594
3595
3596 =head2 GetIssuingCharges
3597
3598   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3599
3600 Calculate how much it would cost for a given patron to borrow a given
3601 item, including any applicable discounts.
3602
3603 C<$itemnumber> is the item number of item the patron wishes to borrow.
3604
3605 C<$borrowernumber> is the patron's borrower number.
3606
3607 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3608 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3609 if it's a video).
3610
3611 =cut
3612
3613 sub GetIssuingCharges {
3614
3615     # calculate charges due
3616     my ( $itemnumber, $borrowernumber ) = @_;
3617     my $charge = 0;
3618     my $dbh    = C4::Context->dbh;
3619     my $item_type;
3620
3621     # Get the book's item type and rental charge (via its biblioitem).
3622     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3623         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3624     $charge_query .= (C4::Context->preference('item-level_itypes'))
3625         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3626         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3627
3628     $charge_query .= ' WHERE items.itemnumber =?';
3629
3630     my $sth = $dbh->prepare($charge_query);
3631     $sth->execute($itemnumber);
3632     my $patron;
3633     if ( my $item_data = $sth->fetchrow_hashref ) {
3634         $item_type = $item_data->{itemtype};
3635         $charge    = $item_data->{rentalcharge};
3636         if ($charge) {
3637             # FIXME This should follow CircControl
3638             my $branch = C4::Context::mybranch();
3639             $patron //= Koha::Patrons->find( $borrowernumber );
3640             my $discount = Koha::CirculationRules->get_effective_rule({
3641                 categorycode => $patron->categorycode,
3642                 branchcode   => $branch,
3643                 itemtype     => $item_type,
3644                 rule_name    => 'rentaldiscount'
3645             });
3646             if ($discount) {
3647                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3648             }
3649             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3650         }
3651     }
3652
3653     return ( $charge, $item_type );
3654 }
3655
3656 =head2 AddIssuingCharge
3657
3658   &AddIssuingCharge( $checkout, $charge, $type )
3659
3660 =cut
3661
3662 sub AddIssuingCharge {
3663     my ( $checkout, $charge, $type ) = @_;
3664
3665     # FIXME What if checkout does not exist?
3666
3667     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3668     my $accountline = $account->add_debit(
3669         {
3670             amount      => $charge,
3671             note        => undef,
3672             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3673             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3674             interface   => C4::Context->interface,
3675             type        => $type,
3676             item_id     => $checkout->itemnumber,
3677             issue_id    => $checkout->issue_id,
3678         }
3679     );
3680 }
3681
3682 =head2 GetTransfersFromTo
3683
3684   @results = GetTransfersFromTo($frombranch,$tobranch);
3685
3686 Returns the list of pending transfers between $from and $to branch
3687
3688 =cut
3689
3690 sub GetTransfersFromTo {
3691     my ( $frombranch, $tobranch ) = @_;
3692     return unless ( $frombranch && $tobranch );
3693     my $dbh   = C4::Context->dbh;
3694     my $query = "
3695         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3696         FROM   branchtransfers
3697         WHERE  frombranch=?
3698           AND  tobranch=?
3699           AND datecancelled IS NULL
3700           AND datesent IS NOT NULL
3701           AND datearrived IS NULL
3702     ";
3703     my $sth = $dbh->prepare($query);
3704     $sth->execute( $frombranch, $tobranch );
3705     my @gettransfers;
3706
3707     while ( my $data = $sth->fetchrow_hashref ) {
3708         push @gettransfers, $data;
3709     }
3710     return (@gettransfers);
3711 }
3712
3713 =head2 SendCirculationAlert
3714
3715 Send out a C<check-in> or C<checkout> alert using the messaging system.
3716
3717 B<Parameters>:
3718
3719 =over 4
3720
3721 =item type
3722
3723 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3724
3725 =item item
3726
3727 Hashref of information about the item being checked in or out.
3728
3729 =item borrower
3730
3731 Hashref of information about the borrower of the item.
3732
3733 =item branch
3734
3735 The branchcode from where the checkout or check-in took place.
3736
3737 =back
3738
3739 B<Example>:
3740
3741     SendCirculationAlert({
3742         type     => 'CHECKOUT',
3743         item     => $item,
3744         borrower => $borrower,
3745         branch   => $branch,
3746     });
3747
3748 =cut
3749
3750 sub SendCirculationAlert {
3751     my ($opts) = @_;
3752     my ($type, $item, $borrower, $branch, $issue) =
3753         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3754     my %message_name = (
3755         CHECKIN  => 'Item_Check_in',
3756         CHECKOUT => 'Item_Checkout',
3757         RENEWAL  => 'Item_Checkout',
3758     );
3759     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3760         borrowernumber => $borrower->{borrowernumber},
3761         message_name   => $message_name{$type},
3762     });
3763
3764
3765     my $tables = {
3766         items => $item->{itemnumber},
3767         biblio      => $item->{biblionumber},
3768         biblioitems => $item->{biblionumber},
3769         borrowers   => $borrower,
3770         branches    => $branch,
3771     };
3772
3773     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3774     # See C4::Letters:: _parseletter_sth
3775     if( $type eq 'CHECKIN' ){
3776         $tables->{old_issues} = $issue->issue_id;
3777     } else {
3778         $tables->{issues} = $item->{itemnumber};
3779     }
3780
3781     my $schema = Koha::Database->new->schema;
3782     my @transports = keys %{ $borrower_preferences->{transports} };
3783
3784     # From the MySQL doc:
3785     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3786     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3787     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3788     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3789
3790     for my $mtt (@transports) {
3791         my $letter =  C4::Letters::GetPreparedLetter (
3792             module => 'circulation',
3793             letter_code => $type,
3794             branchcode => $branch,
3795             message_transport_type => $mtt,
3796             lang => $borrower->{lang},
3797             tables => $tables,
3798         ) or next;
3799
3800         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3801         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3802         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3803         unless ( $message ) {
3804             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3805             my $patron = Koha::Patrons->find($borrower->{borrowernumber});
3806             C4::Message->enqueue($letter, $patron, $mtt);
3807         } else {
3808             $message->append($letter);
3809             $message->update;
3810         }
3811         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3812     }
3813
3814     return;
3815 }
3816
3817 =head2 updateWrongTransfer
3818
3819   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3820
3821 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3822
3823 =cut
3824
3825 sub updateWrongTransfer {
3826         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3827
3828     # first step: cancel the original transfer
3829     my $item = Koha::Items->find($itemNumber);
3830     my $transfer = $item->get_transfer;
3831     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3832
3833     # second step: create a new transfer to the right location
3834     my $new_transfer = $item->request_transfer(
3835         {
3836             to            => $transfer->to_library,
3837             reason        => $transfer->reason,
3838             comment       => $transfer->comments,
3839             ignore_limits => 1,
3840             enqueue       => 1
3841         }
3842     );
3843
3844     return $new_transfer;
3845 }
3846
3847 =head2 CalcDateDue
3848
3849 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3850
3851 this function calculates the due date given the start date and configured circulation rules,
3852 checking against the holidays calendar as per the daysmode circulation rule.
3853 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3854 C<$itemtype>  = itemtype code of item in question
3855 C<$branch>  = location whose calendar to use
3856 C<$patron> = Patron object
3857 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3858
3859 =cut
3860
3861 sub CalcDateDue {
3862     my ( $startdate, $itemtype, $branch, $patron, $isrenewal ) = @_;
3863
3864     $isrenewal ||= 0;
3865
3866     # loanlength now a href
3867     my $loanlength =
3868             GetLoanLength( $patron->categorycode, $itemtype, $branch );
3869
3870     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} and $loanlength->{renewalperiod} ne q{} )
3871             ? qq{renewalperiod}
3872             : qq{issuelength};
3873
3874     my $datedue;
3875     if ( $startdate ) {
3876         if (ref $startdate ne 'DateTime' ) {
3877             $datedue = dt_from_string($datedue);
3878         } else {
3879             $datedue = $startdate->clone;
3880         }
3881     } else {
3882         $datedue = dt_from_string()->truncate( to => 'minute' );
3883     }
3884
3885
3886     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3887         {
3888             categorycode => $patron->categorycode,
3889             itemtype     => $itemtype,
3890             branchcode   => $branch,
3891         }
3892     );
3893
3894     # calculate the datedue as normal
3895     if ( $daysmode eq 'Days' )
3896     {    # ignoring calendar
3897         if ( $loanlength->{lengthunit} eq 'hours' ) {
3898             $datedue->add( hours => $loanlength->{$length_key} );
3899         } else {    # days
3900             $datedue->add( days => $loanlength->{$length_key} );
3901             $datedue->set_hour(23);
3902             $datedue->set_minute(59);
3903         }
3904     } else {
3905         my $dur;
3906         if ($loanlength->{lengthunit} eq 'hours') {
3907             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3908         }
3909         else { # days
3910             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3911         }
3912         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3913         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3914         if ($loanlength->{lengthunit} eq 'days') {
3915             $datedue->set_hour(23);
3916             $datedue->set_minute(59);
3917         }
3918     }
3919
3920     # if Hard Due Dates are used, retrieve them and apply as necessary
3921     my ( $hardduedate, $hardduedatecompare ) =
3922       GetHardDueDate( $patron->categorycode, $itemtype, $branch );
3923     if ($hardduedate) {    # hardduedates are currently dates
3924         $hardduedate->truncate( to => 'minute' );
3925         $hardduedate->set_hour(23);
3926         $hardduedate->set_minute(59);
3927         my $cmp = DateTime->compare( $hardduedate, $datedue );
3928
3929 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3930 # if the calculated date is before the 'after' Hard Due Date (floor), override
3931 # if the hard due date is set to 'exactly', overrride
3932         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3933             $datedue = $hardduedate->clone;
3934         }
3935
3936         # in all other cases, keep the date due as it is
3937
3938     }
3939
3940     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3941     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3942         my $expiry_dt = dt_from_string( $patron->dateexpiry, 'iso', 'floating');
3943         if( $expiry_dt ) { #skip empty expiry date..
3944             $expiry_dt->set( hour => 23, minute => 59);
3945             my $d1= $datedue->clone->set_time_zone('floating');
3946             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3947                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3948             }
3949         }
3950         if ( $daysmode ne 'Days' ) {
3951           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3952           if ( $calendar->is_holiday($datedue) ) {
3953               # Don't return on a closed day
3954               $datedue = $calendar->prev_open_days( $datedue, 1 );
3955           }
3956         }
3957     }
3958
3959     return $datedue;
3960 }
3961
3962
3963 sub CheckValidBarcode{
3964 my ($barcode) = @_;
3965 my $dbh = C4::Context->dbh;
3966 my $query=qq|SELECT count(*)
3967              FROM items
3968              WHERE barcode=?
3969             |;
3970 my $sth = $dbh->prepare($query);
3971 $sth->execute($barcode);
3972 my $exist=$sth->fetchrow ;
3973 return $exist;
3974 }
3975
3976 =head2 IsBranchTransferAllowed
3977
3978   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3979
3980 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3981
3982 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3983 Koha::Item->can_be_transferred.
3984
3985 =cut
3986
3987 sub IsBranchTransferAllowed {
3988         my ( $toBranch, $fromBranch, $code ) = @_;
3989
3990         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3991
3992         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3993         my $dbh = C4::Context->dbh;
3994
3995         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3996         $sth->execute( $toBranch, $fromBranch, $code );
3997         my $limit = $sth->fetchrow_hashref();
3998
3999         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
4000         if ( $limit->{'limitId'} ) {
4001                 return 0;
4002         } else {
4003                 return 1;
4004         }
4005 }
4006
4007 =head2 CreateBranchTransferLimit
4008
4009   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
4010
4011 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
4012
4013 Deprecated in favor of Koha::Item::Transfer::Limit->new.
4014
4015 =cut
4016
4017 sub CreateBranchTransferLimit {
4018    my ( $toBranch, $fromBranch, $code ) = @_;
4019    return unless defined($toBranch) && defined($fromBranch);
4020    my $limitType = C4::Context->preference("BranchTransferLimitsType");
4021
4022    my $dbh = C4::Context->dbh;
4023
4024    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
4025    return $sth->execute( $code, $toBranch, $fromBranch );
4026 }
4027
4028 =head2 DeleteBranchTransferLimits
4029
4030     my $result = DeleteBranchTransferLimits($frombranch);
4031
4032 Deletes all the library transfer limits for one library.  Returns the
4033 number of limits deleted, 0e0 if no limits were deleted, or undef if
4034 no arguments are supplied.
4035
4036 Deprecated in favor of Koha::Item::Transfer::Limits->search({
4037     fromBranch => $fromBranch
4038     })->delete.
4039
4040 =cut
4041
4042 sub DeleteBranchTransferLimits {
4043     my $branch = shift;
4044     return unless defined $branch;
4045     my $dbh    = C4::Context->dbh;
4046     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
4047     return $sth->execute($branch);
4048 }
4049
4050 sub ReturnLostItem{
4051     my ( $borrowernumber, $itemnum ) = @_;
4052     MarkIssueReturned( $borrowernumber, $itemnum );
4053 }
4054
4055 =head2 LostItem
4056
4057   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
4058
4059 The final optional parameter, C<$params>, expected to contain
4060 'skip_record_index' key, which relayed down to Koha::Item/store,
4061 there it prevents calling of ModZebra index_records,
4062 which takes most of the time in batch adds/deletes: index_records better
4063 to be called later in C<additem.pl> after the whole loop.
4064
4065 $params:
4066     skip_record_index => 1|0
4067
4068 =cut
4069
4070 sub LostItem{
4071     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
4072
4073     unless ( $mark_lost_from ) {
4074         # Temporary check to avoid regressions
4075         die q|LostItem called without $mark_lost_from, check the API.|;
4076     }
4077
4078     my $mark_returned;
4079     if ( $force_mark_returned ) {
4080         $mark_returned = 1;
4081     } else {
4082         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
4083         $mark_returned = ( $pref =~ m|$mark_lost_from| );
4084     }
4085
4086     my $dbh = C4::Context->dbh();
4087     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
4088                            FROM issues
4089                            JOIN items USING (itemnumber)
4090                            JOIN biblio USING (biblionumber)
4091                            WHERE issues.itemnumber=?");
4092     $sth->execute($itemnumber);
4093     my $issues=$sth->fetchrow_hashref();
4094
4095     # If a borrower lost the item, add a replacement cost to the their record
4096     if ( my $borrowernumber = $issues->{borrowernumber} ){
4097         my $patron = Koha::Patrons->find( $borrowernumber );
4098
4099         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
4100         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
4101
4102         if (C4::Context->preference('WhenLostChargeReplacementFee')){
4103             C4::Accounts::chargelostitem(
4104                 $borrowernumber,
4105                 $itemnumber,
4106                 $issues->{'replacementprice'},
4107                 sprintf( "%s %s %s",
4108                     $issues->{'title'}          || q{},
4109                     $issues->{'barcode'}        || q{},
4110                     $issues->{'itemcallnumber'} || q{},
4111                 ),
4112             );
4113             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
4114             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
4115         }
4116
4117         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
4118     }
4119
4120     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
4121     my $item = Koha::Items->find($itemnumber);
4122     my $transfers = $item->get_transfers;
4123     while (my $transfer = $transfers->next) {
4124         $transfer->cancel({ reason => 'ItemLost', force => 1 });
4125     }
4126 }
4127
4128 sub GetOfflineOperations {
4129     my $dbh = C4::Context->dbh;
4130     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
4131     $sth->execute(C4::Context->userenv->{'branch'});
4132     my $results = $sth->fetchall_arrayref({});
4133     return $results;
4134 }
4135
4136 sub GetOfflineOperation {
4137     my $operationid = shift;
4138     return unless $operationid;
4139     my $dbh = C4::Context->dbh;
4140     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
4141     $sth->execute( $operationid );
4142     return $sth->fetchrow_hashref;
4143 }
4144
4145 sub AddOfflineOperation {
4146     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
4147     my $dbh = C4::Context->dbh;
4148     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
4149     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
4150     return "Added.";
4151 }
4152
4153 sub DeleteOfflineOperation {
4154     my $dbh = C4::Context->dbh;
4155     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
4156     $sth->execute( shift );
4157     return "Deleted.";
4158 }
4159
4160 sub ProcessOfflineOperation {
4161     my $operation = shift;
4162
4163     my $report;
4164     if ( $operation->{action} eq 'return' ) {
4165         $report = ProcessOfflineReturn( $operation );
4166     } elsif ( $operation->{action} eq 'issue' ) {
4167         $report = ProcessOfflineIssue( $operation );
4168     } elsif ( $operation->{action} eq 'payment' ) {
4169         $report = ProcessOfflinePayment( $operation );
4170     }
4171
4172     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
4173
4174     return $report;
4175 }
4176
4177 sub ProcessOfflineReturn {
4178     my $operation = shift;
4179
4180     my $item = Koha::Items->find({barcode => $operation->{barcode}});
4181
4182     if ( $item ) {
4183         my $itemnumber = $item->itemnumber;
4184         my $issue = $item->checkout;
4185         if ( $issue ) {
4186             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4187             ModDateLastSeen( $itemnumber, $leave_item_lost );
4188             MarkIssueReturned(
4189                 $issue->borrowernumber,
4190                 $itemnumber,
4191                 $operation->{timestamp},
4192             );
4193             $item->onloan(undef);
4194             $item->store({ log_action => 0 });
4195             return "Success.";
4196         } else {
4197             return "Item not issued.";
4198         }
4199     } else {
4200         return "Item not found.";
4201     }
4202 }
4203
4204 sub ProcessOfflineIssue {
4205     my $operation = shift;
4206
4207     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4208     $patron ||= Koha::Patrons->find( { userid => $operation->{cardnumber} } );
4209
4210     if ( $patron ) {
4211         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4212         unless ($item) {
4213             return "Barcode not found.";
4214         }
4215         my $itemnumber = $item->itemnumber;
4216         my $issue = $item->checkout;
4217
4218         if ( $issue and ( $issue->borrowernumber ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4219             MarkIssueReturned(
4220                 $issue->borrowernumber,
4221                 $itemnumber,
4222                 $operation->{timestamp},
4223             );
4224         }
4225         AddIssue(
4226             $patron,
4227             $operation->{'barcode'},
4228             undef,
4229             undef,
4230             $operation->{timestamp},
4231             undef,
4232         );
4233         return "Success.";
4234     } else {
4235         return "Borrower not found.";
4236     }
4237 }
4238
4239 sub ProcessOfflinePayment {
4240     my $operation = shift;
4241
4242     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4243     $patron ||= Koha::Patrons->find( { userid => $operation->{cardnumber} } );
4244
4245     $patron->account->pay(
4246         {
4247             amount     => $operation->{amount},
4248             library_id => $operation->{branchcode},
4249             interface  => 'koc'
4250         }
4251     );
4252
4253     return "Success.";
4254 }
4255
4256 =head2 TransferSlip
4257
4258   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4259
4260   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4261
4262 =cut
4263
4264 sub TransferSlip {
4265     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4266
4267     my $item =
4268       $itemnumber
4269       ? Koha::Items->find($itemnumber)
4270       : Koha::Items->find( { barcode => $barcode } );
4271
4272     $item or return;
4273
4274     return C4::Letters::GetPreparedLetter (
4275         module => 'circulation',
4276         letter_code => 'TRANSFERSLIP',
4277         branchcode => $branch,
4278         tables => {
4279             'branches'    => $to_branch,
4280             'biblio'      => $item->biblionumber,
4281             'items'       => $item->unblessed,
4282         },
4283     );
4284 }
4285
4286 =head2 CheckIfIssuedToPatron
4287
4288   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4289
4290   Return 1 if any record item is issued to patron, otherwise return 0
4291
4292 =cut
4293
4294 sub CheckIfIssuedToPatron {
4295     my ($borrowernumber, $biblionumber) = @_;
4296
4297     my $dbh = C4::Context->dbh;
4298     my $query = q|
4299         SELECT COUNT(*) FROM issues
4300         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4301         WHERE items.biblionumber = ?
4302         AND issues.borrowernumber = ?
4303     |;
4304     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4305     return 1 if $is_issued;
4306     return;
4307 }
4308
4309 =head2 IsItemIssued
4310
4311   IsItemIssued( $itemnumber )
4312
4313   Return 1 if the item is on loan, otherwise return 0
4314
4315 =cut
4316
4317 sub IsItemIssued {
4318     my $itemnumber = shift;
4319     my $dbh = C4::Context->dbh;
4320     my $sth = $dbh->prepare(q{
4321         SELECT COUNT(*)
4322         FROM issues
4323         WHERE itemnumber = ?
4324     });
4325     $sth->execute($itemnumber);
4326     return $sth->fetchrow;
4327 }
4328
4329 =head2 GetAgeRestriction
4330
4331   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4332   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4333
4334   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4335   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4336
4337 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4338 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4339 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4340          Negative days mean the borrower has gone past the age restriction age.
4341
4342 =cut
4343
4344 sub GetAgeRestriction {
4345     my ($record_restrictions, $borrower) = @_;
4346     my $markers = C4::Context->preference('AgeRestrictionMarker');
4347
4348     return unless $record_restrictions;
4349     # Split $record_restrictions to something like FSK 16 or PEGI 6
4350     my @values = split ' ', uc($record_restrictions);
4351     return unless @values;
4352
4353     # Search first occurrence of one of the markers
4354     my @markers = split /\|/, uc($markers);
4355     return unless @markers;
4356
4357     my $index            = 0;
4358     my $restriction_year = 0;
4359     for my $value (@values) {
4360         $index++;
4361         for my $marker (@markers) {
4362             $marker =~ s/^\s+//;    #remove leading spaces
4363             $marker =~ s/\s+$//;    #remove trailing spaces
4364             if ( $marker eq $value ) {
4365                 if ( $index <= $#values ) {
4366                     $restriction_year += $values[$index];
4367                 }
4368                 last;
4369             }
4370             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4371
4372                 # Perhaps it is something like "K16" (as in Finland)
4373                 $restriction_year += $1;
4374                 last;
4375             }
4376         }
4377         last if ( $restriction_year > 0 );
4378     }
4379
4380     #Check if the borrower is age restricted for this material and for how long.
4381     if ($restriction_year && $borrower) {
4382         if ( $borrower->{'dateofbirth'} ) {
4383             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4384             $alloweddate[0] += $restriction_year;
4385
4386             #Prevent runime eror on leap year (invalid date)
4387             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4388                 $alloweddate[2] = 28;
4389             }
4390
4391             #Get how many days the borrower has to reach the age restriction
4392             my @Today = split /-/, dt_from_string()->ymd();
4393             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4394             #Negative days means the borrower went past the age restriction age
4395             return ($restriction_year, $daysToAgeRestriction);
4396         }
4397     }
4398
4399     return ($restriction_year);
4400 }
4401
4402
4403 =head2 GetPendingOnSiteCheckouts
4404
4405 =cut
4406
4407 sub GetPendingOnSiteCheckouts {
4408     my $dbh = C4::Context->dbh;
4409     return $dbh->selectall_arrayref(q|
4410         SELECT
4411           items.barcode,
4412           items.biblionumber,
4413           items.itemnumber,
4414           items.itemnotes,
4415           items.itemcallnumber,
4416           items.location,
4417           issues.date_due,
4418           issues.branchcode,
4419           issues.date_due < NOW() AS is_overdue,
4420           biblio.author,
4421           biblio.title,
4422           borrowers.firstname,
4423           borrowers.surname,
4424           borrowers.cardnumber,
4425           borrowers.borrowernumber
4426         FROM items
4427         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4428         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4429         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4430         WHERE issues.onsite_checkout = 1
4431     |, { Slice => {} } );
4432 }
4433
4434 sub GetTopIssues {
4435     my ($params) = @_;
4436
4437     my ($count, $branch, $itemtype, $ccode, $newness)
4438         = @$params{qw(count branch itemtype ccode newness)};
4439
4440     my $dbh = C4::Context->dbh;
4441     my $query = q{
4442         SELECT * FROM (
4443         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4444           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4445           i.ccode, SUM(i.issues) AS count
4446         FROM biblio b
4447         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4448         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4449     };
4450
4451     my (@where_strs, @where_args);
4452
4453     if ($branch) {
4454         push @where_strs, 'i.homebranch = ?';
4455         push @where_args, $branch;
4456     }
4457     if ($itemtype) {
4458         if (C4::Context->preference('item-level_itypes')){
4459             push @where_strs, 'i.itype = ?';
4460             push @where_args, $itemtype;
4461         } else {
4462             push @where_strs, 'bi.itemtype = ?';
4463             push @where_args, $itemtype;
4464         }
4465     }
4466     if ($ccode) {
4467         push @where_strs, 'i.ccode = ?';
4468         push @where_args, $ccode;
4469     }
4470     if ($newness) {
4471         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4472         push @where_args, $newness;
4473     }
4474
4475     if (@where_strs) {
4476         $query .= 'WHERE ' . join(' AND ', @where_strs);
4477     }
4478
4479     $query .= q{
4480         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4481           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4482           i.ccode
4483         ORDER BY count DESC
4484     };
4485
4486     $query .= q{ ) xxx WHERE count > 0 };
4487     $count = int($count);
4488     if ($count > 0) {
4489         $query .= "LIMIT $count";
4490     }
4491
4492     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4493
4494     return @$rows;
4495 }
4496
4497 =head2 Internal methods
4498
4499 =cut
4500
4501 sub _CalculateAndUpdateFine {
4502     my ($params) = @_;
4503
4504     my $borrower    = $params->{borrower};
4505     my $item        = $params->{item};
4506     my $issue       = $params->{issue};
4507     my $return_date = $params->{return_date};
4508
4509     unless ($borrower) { carp "No borrower passed in!" && return; }
4510     unless ($item)     { carp "No item passed in!"     && return; }
4511     unless ($issue)    { carp "No issue passed in!"    && return; }
4512
4513     my $datedue = dt_from_string( $issue->date_due );
4514
4515     # we only need to calculate and change the fines if we want to do that on return
4516     # Should be on for hourly loans
4517     my $control = C4::Context->preference('CircControl');
4518     my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
4519     my $control_branchcode =
4520         ( $control eq 'ItemHomeLibrary' ) ? $item->{$branch_type}
4521       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4522       :                                     $issue->branchcode;
4523
4524     my $date_returned = $return_date ? $return_date : dt_from_string();
4525
4526     my ( $amount, $unitcounttotal, $unitcount  ) =
4527       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4528
4529     if ( C4::Context->preference('finesMode') eq 'production' ) {
4530         if ( $amount > 0 ) {
4531             C4::Overdues::UpdateFine({
4532                 issue_id       => $issue->issue_id,
4533                 itemnumber     => $issue->itemnumber,
4534                 borrowernumber => $issue->borrowernumber,
4535                 amount         => $amount,
4536                 due            => $datedue,
4537             });
4538         }
4539         elsif ($return_date) {
4540
4541             # Backdated returns may have fines that shouldn't exist,
4542             # so in this case, we need to drop those fines to 0
4543
4544             C4::Overdues::UpdateFine({
4545                 issue_id       => $issue->issue_id,
4546                 itemnumber     => $issue->itemnumber,
4547                 borrowernumber => $issue->borrowernumber,
4548                 amount         => 0,
4549                 due            => $datedue,
4550             });
4551         }
4552     }
4553 }
4554
4555 sub _CanBookBeAutoRenewed {
4556     my ( $params ) = @_;
4557     my $patron = $params->{patron};
4558     my $item = $params->{item};
4559     my $branchcode = $params->{branchcode};
4560     my $issue = $params->{issue};
4561
4562     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4563
4564     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4565         {
4566             categorycode => $patron->categorycode,
4567             itemtype     => $item->effective_itemtype,
4568             branchcode   => $branchcode,
4569             rules => [
4570                 'no_auto_renewal_after',
4571                 'no_auto_renewal_after_hard_limit',
4572                 'lengthunit',
4573                 'noautorenewalbefore',
4574             ]
4575         }
4576     );
4577
4578     if ( $patron->is_expired && $patron->category->effective_BlockExpiredPatronOpacActions ) {
4579         return 'auto_account_expired';
4580     }
4581
4582     if ( defined $issuing_rule->{no_auto_renewal_after}
4583             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4584         # Get issue_date and add no_auto_renewal_after
4585         # If this is greater than today, it's too late for renewal.
4586         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4587         $maximum_renewal_date->add(
4588             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4589         );
4590         my $now = dt_from_string;
4591         if ( $now >= $maximum_renewal_date ) {
4592             return "auto_too_late";
4593         }
4594     }
4595     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4596                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4597         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4598         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4599             return "auto_too_late";
4600         }
4601     }
4602
4603     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4604         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4605         my $amountoutstanding =
4606           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4607           ? $patron->account->balance
4608           : $patron->account->outstanding_debits->total_outstanding;
4609         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4610             return "auto_too_much_oweing";
4611         }
4612     }
4613
4614     my $soonest = GetSoonestRenewDate( $patron, $issue, 1 );
4615     if ( $soonest > dt_from_string() )
4616     {
4617         return ( "auto_too_soon", $soonest );
4618     }
4619
4620     return "ok";
4621 }
4622
4623
4624 1;
4625
4626 __END__
4627
4628 =head1 AUTHOR
4629
4630 Koha Development Team <http://koha-community.org/>
4631
4632 =cut