C4/Languages.pm

   1 package C4::Languages;
   2
   3 # Copyright 2006 (C) LibLime
   4 # Joshua Ferraro <jmf@liblime.com>
   5 # Portions Copyright 2009 Chris Cormack and the Koha Dev Team
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp qw( carp );
  26 use CGI;
  27 use List::MoreUtils qw( any );
  28 use C4::Context;
  29 use Koha::Caches;
  30 use Koha::Cache::Memory::Lite;
  31
  32 our (@ISA, @EXPORT_OK);
  33 BEGIN {
  34     require Exporter;
  35     @ISA    = qw(Exporter);
  36     @EXPORT_OK = qw(
  37         getFrameworkLanguages
  38         getTranslatedLanguages
  39         getLanguages
  40         getAllLanguages
  41     );
  42     push @EXPORT_OK, qw(getFrameworkLanguages getTranslatedLanguages getAllLanguages getLanguages get_bidi regex_lang_subtags language_get_description accept_language getlanguage get_rfc4646_from_iso639);
  43 }
  44
  45 =head1 NAME
  46
  47 C4::Languages - Perl Module containing language list functions for Koha
  48
  49 =head1 SYNOPSIS
  50
  51 use C4::Languages;
  52
  53 =head1 DESCRIPTION
  54
  55 =cut
  56
  57 =head1 FUNCTIONS
  58
  59 =head2 getFrameworkLanguages
  60
  61 Returns a reference to an array of hashes:
  62
  63  my $languages = getFrameworkLanguages();
  64  for my $language(@$languages) {
  65     print "$language->{language_code}\n"; # language code in iso 639-2
  66     print "$language->{language_name}\n"; # language name in native script
  67     print "$language->{language_locale_name}\n"; # language name in current locale
  68  }
  69
  70 =cut
  71
  72 sub getFrameworkLanguages {
  73     # get a hash with all language codes, names, and locale names
  74     my $all_languages = getAllLanguages();
  75     my @languages;
  76
  77     # find the available directory names
  78     my $dir=C4::Context->config('intranetdir')."/installer/data/";
  79     my $dir_h;
  80     opendir ($dir_h,$dir);
  81     my @listdir= grep { !/^\.|CVS/ && -d "$dir/$_"} readdir($dir_h);
  82     closedir $dir_h;
  83
  84     # pull out all data for the dir names that exist
  85     for my $dirname (@listdir) {
  86         for my $language_set (@$all_languages) {
  87
  88             if ($dirname eq $language_set->{language_code}) {
  89                 push @languages, {
  90                     'language_code'=>$dirname,
  91                     'language_description'=>$language_set->{language_description},
  92                     'native_descrition'=>$language_set->{language_native_description} }
  93             }
  94         }
  95     }
  96     return \@languages;
  97 }
  98
  99 =head2 getTranslatedLanguages
 100
 101 Returns a reference to an array of hashes:
 102
 103  my $languages = getTranslatedLanguages();
 104  print "Available translated languages:\n";
 105  for my $language(@$trlanguages) {
 106     print "$language->{language_code}\n"; # language code in iso 639-2
 107     print "$language->{language_name}\n"; # language name in native script
 108     print "$language->{language_locale_name}\n"; # language name in current locale
 109  }
 110
 111 =cut
 112
 113 sub getTranslatedLanguages {
 114     my ($interface, $theme, $current_language, $which) = @_;
 115     my @languages;
 116     my @enabled_languages =
 117       ( $interface && $interface eq 'intranet' )
 118       ? split ",", C4::Context->preference('language')
 119       : split ",", C4::Context->preference('OPACLanguages');
 120
 121     my $cache = Koha::Caches->get_instance;
 122     my $cache_key = "languages_${interface}_${theme}";
 123     if ($interface && $interface eq 'opac' ) {
 124         my $htdocs = C4::Context->config('opachtdocs');
 125         my $cached = $cache->get_from_cache($cache_key);
 126         if ( $cached ) {
 127             @languages = @{$cached};
 128         } else {
 129             @languages = _get_opac_language_dirs( $htdocs, $theme );
 130             $cache->set_in_cache($cache_key, \@languages );
 131         }
 132     }
 133     elsif ($interface && $interface eq 'intranet' ) {
 134         my $htdocs = C4::Context->config('intrahtdocs');
 135         my $cached = $cache->get_from_cache($cache_key);
 136         if ( $cached ) {
 137             @languages = @{$cached};
 138         } else {
 139             @languages = _get_intranet_language_dirs( $htdocs, $theme );
 140             $cache->set_in_cache($cache_key, \@languages );
 141         }
 142     }
 143     else {
 144         my $htdocs = C4::Context->config('intrahtdocs');
 145         push @languages, _get_intranet_language_dirs( $htdocs );
 146
 147         $htdocs = C4::Context->config('opachtdocs');
 148         push @languages, _get_opac_language_dirs( $htdocs );
 149
 150         my %seen;
 151         $seen{$_}++ for @languages;
 152         @languages = keys %seen;
 153     }
 154     return _build_languages_arrayref(\@languages,$current_language,\@enabled_languages);
 155 }
 156
 157 =head2 getAllLanguages
 158
 159 Returns a reference to an array of hashes:
 160
 161  my $alllanguages = getAllLanguages();
 162  print "Available translated languages:\n";
 163  for my $language(@$alllanguages) {
 164     print "$language->{language_code}\n";
 165     print "$language->{language_name}\n";
 166     print "$language->{language_locale_name}\n";
 167  }
 168
 169 This routine is a wrapper for getLanguages().
 170
 171 =cut
 172
 173 sub getAllLanguages {
 174     return getLanguages(shift);
 175 }
 176
 177 =head2 getLanguages
 178
 179     my $lang_arrayref = getLanguages([$lang[, $isFiltered]]);
 180
 181 Returns a reference to an array of hashes of languages.
 182
 183 - If no parameter is passed to the function, it returns english languages names
 184 - If a $lang parameter conforming to RFC4646 syntax is passed, the function returns languages names translated in $lang
 185   If a language name is not translated in $lang in database, the function returns english language name
 186 - If $isFiltered is set to true, only the detail of the languages selected in system preferences AdvanceSearchLanguages is returned.
 187
 188 =cut
 189
 190 sub getLanguages {
 191     my $lang = shift;
 192     my $isFiltered = shift;
 193
 194     my @languages_loop;
 195     my $dbh=C4::Context->dbh;
 196     my $default_language = 'en';
 197     my $current_language = $default_language;
 198     my $language_list = $isFiltered ? C4::Context->preference("AdvancedSearchLanguages") : undef;
 199     if ($lang) {
 200         $current_language = regex_lang_subtags($lang)->{'language'};
 201     }
 202     my $sth = $dbh->prepare('SELECT * FROM language_subtag_registry WHERE type=\'language\' ORDER BY description');
 203     $sth->execute();
 204     while (my $language_subtag_registry = $sth->fetchrow_hashref) {
 205         my $desc;
 206         # check if language name is stored in current language
 207         my $sth4= $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag =? AND lang = ?");
 208         $sth4->execute($language_subtag_registry->{subtag},$current_language);
 209         while (my $language_desc = $sth4->fetchrow_hashref) {
 210              $desc=$language_desc->{description};
 211         }
 212         my $sth2= $dbh->prepare("SELECT * FROM language_descriptions LEFT JOIN language_rfc4646_to_iso639 on language_rfc4646_to_iso639.rfc4646_subtag = language_descriptions.subtag WHERE type='language' AND subtag =? AND language_descriptions.lang = ?");
 213         if ($desc) {
 214             $sth2->execute($language_subtag_registry->{subtag},$current_language);
 215         }
 216         else {
 217             $sth2->execute($language_subtag_registry->{subtag},$default_language);
 218         }
 219         my $sth3 = $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag=? AND lang=?");
 220         # add the correct description info
 221         while (my $language_descriptions = $sth2->fetchrow_hashref) {
 222             $sth3->execute($language_subtag_registry->{subtag},$language_subtag_registry->{subtag});
 223             my $native_description;
 224             while (my $description = $sth3->fetchrow_hashref) {
 225                 $native_description = $description->{description};
 226             }
 227
 228             # fill in the ISO6329 code
 229             $language_subtag_registry->{iso639_2_code} = $language_descriptions->{iso639_2_code};
 230             # fill in the native description of the language, as well as the current language's translation of that if it exists
 231             if ($native_description) {
 232                 $language_subtag_registry->{language_description} = $native_description;
 233                 $language_subtag_registry->{language_description}.=" ($language_descriptions->{description})" if $language_descriptions->{description};
 234             }
 235             else {
 236                 $language_subtag_registry->{language_description} = $language_descriptions->{description};
 237             }
 238         }
 239         # Do not push unless valid iso639-2 code
 240         if ( $language_subtag_registry->{ iso639_2_code } and ( !$language_list || index (  $language_list, $language_subtag_registry->{ iso639_2_code } ) >= 0) ) {
 241             push @languages_loop, $language_subtag_registry;
 242         }
 243     }
 244     return \@languages_loop;
 245 }
 246
 247 sub _get_opac_language_dirs {
 248     my ( $htdocs, $theme ) = @_;
 249
 250     my @languages;
 251     if ( $theme and -d "$htdocs/$theme" ) {
 252         (@languages) = _get_language_dirs($htdocs,$theme);
 253     }
 254     else {
 255         for my $theme ( _get_themes('opac') ) {
 256             push @languages, _get_language_dirs($htdocs,$theme);
 257         }
 258     }
 259     return @languages;
 260 }
 261
 262
 263 sub _get_intranet_language_dirs {
 264     my ( $htdocs, $theme ) = @_;
 265
 266     my @languages;
 267     if ( $theme and -d "$htdocs/$theme" ) {
 268         @languages = _get_language_dirs($htdocs,$theme);
 269     }
 270     else {
 271         foreach my $theme ( _get_themes('intranet') ) {
 272             push @languages, _get_language_dirs($htdocs,$theme);
 273         }
 274     }
 275     return @languages;
 276 }
 277
 278 =head2 _get_themes
 279
 280 Internal function, returns an array of all available themes.
 281
 282   (@themes) = &_get_themes('opac');
 283   (@themes) = &_get_themes('intranet');
 284
 285 =cut
 286
 287 sub _get_themes {
 288     my $interface = shift;
 289     my $htdocs;
 290     my @themes;
 291     if ( $interface && $interface eq 'intranet' ) {
 292         $htdocs = C4::Context->config('intrahtdocs');
 293     }
 294     else {
 295         $htdocs = C4::Context->config('opachtdocs');
 296     }
 297     my $dir_h;
 298     opendir $dir_h, "$htdocs";
 299     my @dirlist = readdir $dir_h;
 300     foreach my $directory (@dirlist) {
 301         # if there's an en dir, it's a valid theme
 302         -d "$htdocs/$directory/en" and push @themes, $directory;
 303     }
 304     close $dir_h;
 305     return @themes;
 306 }
 307
 308 =head2 _get_language_dirs
 309
 310 Internal function, returns an array of directory names, excluding non-language directories
 311
 312 =cut
 313
 314 sub _get_language_dirs {
 315     my ($htdocs,$theme) = @_;
 316     $htdocs //= '';
 317     $theme //= '';
 318     my @lang_strings;
 319     my $dir_h;
 320     opendir $dir_h, "$htdocs/$theme";
 321     for my $lang_string ( sort readdir $dir_h ) {
 322         next if $lang_string =~/^\./;
 323         next if $lang_string eq 'all';
 324         next if $lang_string =~/png$/;
 325         next if $lang_string =~/js$/;
 326         next if $lang_string =~/css$/;
 327         next if $lang_string =~/CVS$/;
 328         next if $lang_string =~/\.txt$/i;     #Don't read the readme.txt !
 329         next if $lang_string =~/img|images|famfam|js|less|lib|sound|pdf/;
 330         push @lang_strings, $lang_string;
 331     }
 332     close $dir_h;
 333     return (@lang_strings);
 334 }
 335
 336 =head2 _build_languages_arrayref
 337
 338 Internal function for building the ref to array of hashes
 339
 340 FIXME: this could be rewritten and simplified using map
 341
 342 =cut
 343
 344 sub _build_languages_arrayref {
 345         my ($translated_languages,$current_language,$enabled_languages) = @_;
 346         $current_language //= '';
 347         my @translated_languages = @$translated_languages;
 348         my @languages_loop; # the final reference to an array of hashrefs
 349         my @enabled_languages = @$enabled_languages;
 350         # how many languages are enabled, if one, take note, some contexts won't need to display it
 351         my $language_groups;
 352         my $track_language_groups;
 353         my $current_language_regex = regex_lang_subtags($current_language);
 354         # Loop through the translated languages
 355         for my $translated_language (@translated_languages) {
 356             # separate the language string into its subtag types
 357             my $language_subtags_hashref = regex_lang_subtags($translated_language);
 358
 359             # is this language string 'enabled'?
 360             for my $enabled_language (@enabled_languages) {
 361                 #warn "Checking out if $translated_language eq $enabled_language";
 362                 $language_subtags_hashref->{'enabled'} = 1 if $translated_language eq $enabled_language;
 363             }
 364
 365             # group this language, key by langtag
 366             $language_subtags_hashref->{'sublanguage_current'} = 1 if $translated_language eq $current_language;
 367             $language_subtags_hashref->{'rfc4646_subtag'} = $translated_language;
 368             $language_subtags_hashref->{'native_description'} = language_get_description($language_subtags_hashref->{language},$language_subtags_hashref->{language},'language');
 369             $language_subtags_hashref->{'script_description'} = language_get_description($language_subtags_hashref->{script},$language_subtags_hashref->{'language'},'script');
 370             $language_subtags_hashref->{'region_description'} = language_get_description($language_subtags_hashref->{region},$language_subtags_hashref->{'language'},'region');
 371             $language_subtags_hashref->{'variant_description'} = language_get_description($language_subtags_hashref->{variant},$language_subtags_hashref->{'language'},'variant');
 372             $track_language_groups->{$language_subtags_hashref->{'language'}}++;
 373             push ( @{ $language_groups->{$language_subtags_hashref->{language}} }, $language_subtags_hashref );
 374         }
 375         # $key is a language subtag like 'en'
 376
 377         my %idx = map { $enabled_languages->[$_] => $_ } reverse 0 .. @$enabled_languages-1;
 378         my @ordered_keys = sort {
 379             my $aa     = '';
 380             my $bb     = '';
 381             my $acount = @{ $language_groups->{$a} };
 382             my $bcount = @{ $language_groups->{$b} };
 383             if ( $language_groups->{$a}->[0]->{enabled} ) {
 384                 $aa = $language_groups->{$a}->[0]->{rfc4646_subtag};
 385             }
 386             elsif ( $acount > 1 ) {
 387                 for ( my $i = 1 ; $i < $acount ; $i++ ) {
 388                     if ( $language_groups->{$a}->[$i]->{enabled} ) {
 389                         $aa = $language_groups->{$a}->[$i]->{rfc4646_subtag};
 390                         last;
 391                     }
 392                 }
 393             }
 394             if ( $language_groups->{$b}->[0]->{enabled} ) {
 395                 $bb = $language_groups->{$b}->[0]->{rfc4646_subtag};
 396             }
 397             elsif ( $bcount > 1 ) {
 398                 for ( my $i = 1 ; $i < $bcount ; $i++ ) {
 399                     if ( $language_groups->{$b}->[$i]->{enabled} ) {
 400                         $bb = $language_groups->{$b}->[$i]->{rfc4646_subtag};
 401                         last;
 402                     }
 403                 }
 404             }
 405             (         exists $idx{$aa}
 406                   and exists $idx{$bb}
 407                   and ( $idx{$aa} cmp $idx{$bb} ) )
 408               || ( exists $idx{$aa} and exists $idx{$bb} )
 409               || exists $idx{$bb}
 410         } keys %$language_groups;
 411
 412         for my $key ( @ordered_keys ) {
 413             my $value = $language_groups->{$key};
 414             # is this language group enabled? are any of the languages within it enabled?
 415             my $enabled;
 416             for my $enabled_language (@enabled_languages) {
 417                 my $regex_enabled_language = regex_lang_subtags($enabled_language);
 418                 $enabled = 1 if $key eq ($regex_enabled_language->{language} // '');
 419             }
 420             push @languages_loop,  {
 421                             # this is only use if there is one
 422                             rfc4646_subtag => @$value[0]->{rfc4646_subtag},
 423                             native_description => language_get_description($key,$key,'language'),
 424                             language => $key,
 425                             sublanguages_loop => $value,
 426                             plural => $track_language_groups->{$key} >1 ? 1 : 0,
 427                             current => ($current_language_regex->{language} // '') eq $key ? 1 : 0,
 428                             group_enabled => $enabled,
 429                            };
 430         }
 431         return \@languages_loop;
 432 }
 433
 434 sub language_get_description {
 435     my ($script,$lang,$type) = @_;
 436     my $dbh = C4::Context->dbh;
 437     my $desc;
 438     my $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 439     #warn "QUERY: SELECT description FROM language_descriptions WHERE subtag=$script AND lang=$lang AND type=$type";
 440     $sth->execute($script,$lang,$type);
 441     while (my $descriptions = $sth->fetchrow_hashref) {
 442         $desc = $descriptions->{'description'};
 443     }
 444     unless ($desc) {
 445         $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 446         $sth->execute($script,'en',$type);
 447         while (my $descriptions = $sth->fetchrow_hashref) {
 448             $desc = $descriptions->{'description'};
 449         }
 450     }
 451     return $desc;
 452 }
 453 =head2 regex_lang_subtags
 454
 455 This internal sub takes a string composed according to RFC 4646 as
 456 an input and returns a reference to a hash containing keys and values
 457 for ( language, script, region, variant, extension, privateuse )
 458
 459 =cut
 460
 461 sub regex_lang_subtags {
 462     my $string = shift;
 463
 464     # Regex for recognizing RFC 4646 well-formed tags
 465     # http://www.rfc-editor.org/rfc/rfc4646.txt
 466
 467     # regexes based on : http://unicode.org/cldr/data/tools/java/org/unicode/cldr/util/data/langtagRegex.txt
 468     # The structure requires no forward references, so it reverses the order.
 469     # The uppercase comments are fragments copied from RFC 4646
 470     #
 471     # Note: the tool requires that any real "=" or "#" or ";" in the regex be escaped.
 472
 473     my $alpha   = qr/[a-zA-Z]/ ;    # ALPHA
 474     my $digit   = qr/[0-9]/ ;   # DIGIT
 475     my $alphanum    = qr/[a-zA-Z0-9]/ ; # ALPHA / DIGIT
 476     my $x   = qr/[xX]/ ;    # private use singleton
 477     my $singleton = qr/[a-w y-z A-W Y-Z]/ ; # other singleton
 478     my $s   = qr/[-]/ ; # separator -- lenient parsers will use [-_]
 479
 480     # Now do the components. The structure is slightly different to allow for capturing the right components.
 481     # The notation (?:....) is a non-capturing version of (...): so the "?:" can be deleted if someone doesn't care about capturing.
 482
 483     my $extlang = qr{(?: $s $alpha{3} )}x ; # *3("-" 3ALPHA)
 484     my $language    = qr{(?: $alpha{2,3} | $alpha{4,8} )}x ;
 485     #my $language   = qr{(?: $alpha{2,3}$extlang{0,3} | $alpha{4,8} )}x ;   # (2*3ALPHA [ extlang ]) / 4ALPHA / 5*8ALPHA
 486
 487     my $script  = qr{(?: $alpha{4} )}x ;    # 4ALPHA
 488
 489     my $region  = qr{(?: $alpha{2} | $digit{3} )}x ;     # 2ALPHA / 3DIGIT
 490
 491     my $variantSub  = qr{(?: $digit$alphanum{3} | $alphanum{5,8} )}x ;  # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 492     my $variant = qr{(?: $variantSub (?: $s$variantSub )* )}x ; # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 493
 494     my $extensionSub    = qr{(?: $singleton (?: $s$alphanum{2,8} )+ )}x ;   # singleton 1*("-" (2*8alphanum))
 495     my $extension   = qr{(?: $extensionSub (?: $s$extensionSub )* )}x ; # singleton 1*("-" (2*8alphanum))
 496
 497     my $privateuse  = qr{(?: $x (?: $s$alphanum{1,8} )+ )}x ;   # ("x"/"X") 1*("-" (1*8alphanum))
 498
 499     # Define certain grandfathered codes, since otherwise the regex is pretty useless.
 500     # Since these are limited, this is safe even later changes to the registry --
 501     # the only oddity is that it might change the type of the tag, and thus
 502     # the results from the capturing groups.
 503     # http://www.iana.org/assignments/language-subtag-registry
 504     # Note that these have to be compared case insensitively, requiring (?i) below.
 505
 506     my $grandfathered   = qr{(?: (?i)
 507         en $s GB $s oed
 508     |   i $s (?: ami | bnn | default | enochian | hak | klingon | lux | mingo | navajo | pwn | tao | tay | tsu )
 509     |   sgn $s (?: BE $s fr | BE $s nl | CH $s de)
 510 )}x;
 511
 512     # For well-formedness, we don't need the ones that would otherwise pass, so they are commented out here
 513
 514     #   |   art $s lojban
 515     #   |   cel $s gaulish
 516     #   |   en $s (?: boont | GB $s oed | scouse )
 517     #   |   no $s (?: bok | nyn)
 518     #   |   zh $s (?: cmn | cmn $s Hans | cmn $s Hant | gan | guoyu | hakka | min | min $s nan | wuu | xiang | yue)
 519
 520     # Here is the final breakdown, with capturing groups for each of these components
 521     # The language, variants, extensions, grandfathered, and private-use may have interior '-'
 522
 523     #my $root = qr{(?: ($language) (?: $s ($script) )? 40% (?: $s ($region) )? 40% (?: $s ($variant) )? 10% (?: $s ($extension) )? 5% (?: $s ($privateuse) )? 5% ) 90% | ($grandfathered) 5% | ($privateuse) 5% };
 524
 525     $string =~  qr{^ (?:($language)) (?:$s($script))? (?:$s($region))?  (?:$s($variant))?  (?:$s($extension))?  (?:$s($privateuse))? $}xi;  # |($grandfathered) | ($privateuse) $}xi;
 526     my %subtag = (
 527         'rfc4646_subtag' => $string,
 528         'language' => $1,
 529         'script' => $2,
 530         'region' => $3,
 531         'variant' => $4,
 532         'extension' => $5,
 533         'privateuse' => $6,
 534     );
 535     return \%subtag;
 536 }
 537
 538 # Script Direction Resources:
 539 # http://www.w3.org/International/questions/qa-scripts
 540 sub get_bidi {
 541     my ($language_script)= @_;
 542     my $dbh = C4::Context->dbh;
 543     my $bidi;
 544     my $sth = $dbh->prepare('SELECT bidi FROM language_script_bidi WHERE rfc4646_subtag=?');
 545     $sth->execute($language_script);
 546     while (my $result = $sth->fetchrow_hashref) {
 547         $bidi = $result->{'bidi'};
 548     }
 549     return $bidi;
 550 };
 551
 552 sub accept_language {
 553     # referenced http://search.cpan.org/src/CGILMORE/I18N-AcceptLanguage-1.04/lib/I18N/AcceptLanguage.pm
 554     my ($clientPreferences,$supportedLanguages) = @_;
 555     my @languages = ();
 556     if ($clientPreferences) {
 557         # There should be no whitespace anways, but a cleanliness/sanity check
 558         $clientPreferences =~ s/\s//g;
 559         # Prepare the list of client-acceptable languages
 560         foreach my $tag (split(/,/, $clientPreferences)) {
 561             my ($language, $quality) = split(/\;/, $tag);
 562             $quality =~ s/^q=//i if $quality;
 563             $quality = 1 unless $quality;
 564             next if $quality <= 0;
 565             # We want to force the wildcard to be last
 566             $quality = 0 if ($language eq '*');
 567             # Pushing lowercase language here saves processing later
 568             push(@languages, { quality => $quality,
 569                language => $language,
 570                lclanguage => lc($language) });
 571         }
 572     } else {
 573         carp "accept_language(x,y) called with no clientPreferences (x).";
 574     }
 575     # Prepare the list of server-supported languages
 576     my %supportedLanguages = ();
 577     my %secondaryLanguages = ();
 578     foreach my $language (@$supportedLanguages) {
 579         # warn "Language supported: " . $language->{language};
 580         my $subtag = $language->{rfc4646_subtag};
 581         $supportedLanguages{lc($subtag)} = $subtag;
 582         if ( $subtag =~ /^([^-]+)-?/ ) {
 583             $secondaryLanguages{lc($1)} = $subtag;
 584         }
 585     }
 586
 587     # Reverse sort the list, making best quality at the front of the array
 588     @languages = sort { $b->{quality} <=> $a->{quality} } @languages;
 589     my $secondaryMatch = '';
 590     foreach my $tag (@languages) {
 591         if (exists($supportedLanguages{$tag->{lclanguage}})) {
 592             # Client en-us eq server en-us
 593             return $supportedLanguages{$tag->{language}} if exists($supportedLanguages{$tag->{language}});
 594             return $supportedLanguages{$tag->{lclanguage}};
 595         } elsif (exists($secondaryLanguages{$tag->{lclanguage}})) {
 596             # Client en eq server en-us
 597             return $secondaryLanguages{$tag->{language}} if exists($secondaryLanguages{$tag->{language}});
 598             return $supportedLanguages{$tag->{lclanguage}};
 599         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 600             # Client en-gb eq server en-us
 601             $secondaryMatch = $secondaryLanguages{$1};
 602         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 603             # FIXME: We just checked the exact same conditional!
 604             # Client en-us eq server en
 605             $secondaryMatch = $supportedLanguages{$1};
 606         } elsif ($tag->{lclanguage} eq '*') {
 607         # * matches every language not already specified.
 608         # It doesn't care which we pick, so let's pick the default,
 609         # if available, then the first in the array.
 610         #return $acceptor->defaultLanguage() if $acceptor->defaultLanguage();
 611         return $supportedLanguages->[0];
 612         }
 613     }
 614     # No primary matches. Secondary? (ie, en-us requested and en supported)
 615     return $secondaryMatch if $secondaryMatch;
 616     return;   # else, we got nothing.
 617 }
 618
 619 =head2 getlanguage
 620
 621     Select a language based on the URL parameter 'language', a cookie,
 622     syspref available languages & browser
 623
 624 =cut
 625
 626 sub getlanguage {
 627     my ($cgi) = @_;
 628
 629     my $memory_cache = Koha::Cache::Memory::Lite->get_instance();
 630     my $cache_key = "getlanguage";
 631     unless ( $cgi and $cgi->param('language') ) {
 632         my $cached = $memory_cache->get_from_cache($cache_key);
 633         return $cached if $cached;
 634     }
 635
 636     $cgi //= CGI->new;
 637     my $interface = C4::Context->interface;
 638     my $theme = C4::Context->preference( ( $interface eq 'opac' ) ? 'opacthemes' : 'template' );
 639     my $language;
 640
 641     my $preference_to_check =
 642       $interface eq 'intranet' ? 'language' : 'OPACLanguages';
 643     # Get the available/valid languages list
 644     my @languages;
 645     my $preference_value = C4::Context->preference($preference_to_check);
 646     if ($preference_value) {
 647         @languages = split /,/, $preference_value;
 648     }
 649
 650     # Chose language from the URL
 651     my $cgi_param_language = $cgi->param( 'language' );
 652     if ( defined $cgi_param_language && any { $_ eq $cgi_param_language } @languages) {
 653         $language = $cgi_param_language;
 654     }
 655
 656     # cookie
 657     if (not $language and my $cgi_cookie_language = $cgi->cookie('KohaOpacLanguage') ) {
 658         ( $language = $cgi_cookie_language ) =~ s/[^a-zA-Z_-]*//; # sanitize cookie
 659     }
 660
 661     # HTTP_ACCEPT_LANGUAGE
 662     if ( !$language && $ENV{HTTP_ACCEPT_LANGUAGE} ) {
 663         $language = accept_language( $ENV{HTTP_ACCEPT_LANGUAGE},
 664             getTranslatedLanguages( $interface, $theme ) );
 665     }
 666
 667     # Ignore a lang not selected in sysprefs
 668     if ( $language && not any { $_ eq $language } @languages ) {
 669         $language = undef;
 670     }
 671
 672     # Pick the first selected syspref language
 673     $language = shift @languages unless $language;
 674
 675     # Fall back to English if necessary
 676     $language ||= 'en';
 677
 678     $memory_cache->set_in_cache( $cache_key, $language );
 679     return $language;
 680 }
 681
 682 =head2 get_rfc4646_from_iso639
 683
 684     Select a language rfc4646 code given an iso639 code
 685
 686 =cut
 687
 688 sub get_rfc4646_from_iso639 {
 689
 690     my $iso_code = shift;
 691     my $rfc_subtag = Koha::Database->new()->schema->resultset('LanguageRfc4646ToIso639')->find({iso639_2_code=>$iso_code});
 692     if ( $rfc_subtag ) {
 693         return $rfc_subtag->rfc4646_subtag;
 694     } else {
 695         return;
 696     }
 697
 698 }
 699
 700 1;
 701
 702 __END__
 703
 704 =head1 AUTHOR
 705
 706 Joshua Ferraro
 707
 708 =cut