C4/Reserves.pm

   1 package C4::Reserves;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN Ouest Provence
   5 #           2007-2010 BibLibre Paul POULAIN
   6 #           2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 use Modern::Perl;
  25
  26 use C4::Accounts;
  27 use C4::Biblio qw( GetMarcFromKohaField );
  28 use C4::Circulation qw( CheckIfIssuedToPatron GetAgeRestriction GetBranchItemRule );
  29 use C4::Context;
  30 use C4::Items qw( CartToShelf get_hostitemnumbers_of );
  31 use C4::Letters;
  32 use C4::Log qw( logaction );
  33 use C4::Members::Messaging;
  34 use C4::Members;
  35 use Koha::Account::Lines;
  36 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  37 use Koha::Biblios;
  38 use Koha::Calendar;
  39 use Koha::Cache::Memory::Lite;
  40 use Koha::CirculationRules;
  41 use Koha::Database;
  42 use Koha::DateUtils qw( dt_from_string output_pref );
  43 use Koha::Holds;
  44 use Koha::ItemTypes;
  45 use Koha::Items;
  46 use Koha::Libraries;
  47 use Koha::Old::Holds;
  48 use Koha::Patrons;
  49 use Koha::Plugins;
  50
  51 use List::MoreUtils qw( any );
  52
  53 =head1 NAME
  54
  55 C4::Reserves - Koha functions for dealing with reservation.
  56
  57 =head1 SYNOPSIS
  58
  59   use C4::Reserves;
  60
  61 =head1 DESCRIPTION
  62
  63 This modules provides somes functions to deal with reservations.
  64
  65   Reserves are stored in reserves table.
  66   The following columns contains important values :
  67   - priority >0      : then the reserve is at 1st stage, and not yet affected to any item.
  68              =0      : then the reserve is being dealed
  69   - found : NULL         : means the patron requested the 1st available, and we haven't chosen the item
  70             T(ransit)    : the reserve is linked to an item but is in transit to the pickup branch
  71             W(aiting)    : the reserve is linked to an item, is at the pickup branch, and is waiting on the hold shelf
  72             F(inished)   : the reserve has been completed, and is done
  73             P(rocessing) : reserved item has been returned using self-check machine and reserve needs to be confirmed
  74                            by librarian before notice is send and status changed to waiting.
  75                            Applicable only if HoldsNeedProcessingSIP system preference is set.
  76   - itemnumber : empty : the reserve is still unaffected to an item
  77                  filled: the reserve is attached to an item
  78   The complete workflow is :
  79   ==== 1st use case ====
  80   patron request a document, 1st available :                      P >0, F=NULL, I=NULL
  81   a library having it run "transfertodo", and clic on the list
  82          if there is no transfer to do, the reserve waiting
  83          patron can pick it up                                    P =0, F=W,    I=filled
  84          if there is a transfer to do, write in branchtransfer    P =0, F=T,    I=filled
  85            The pickup library receive the book, it check in       P =0, F=W,    I=filled
  86   The patron borrow the book                                      P =0, F=F,    I=filled
  87
  88   ==== 2nd use case ====
  89   patron requests a document, a given item,
  90     If pickup is holding branch                                   P =0, F=W,   I=filled
  91     If transfer needed, write in branchtransfer                   P =0, F=T,    I=filled
  92         The pickup library receive the book, it checks it in      P =0, F=W,    I=filled
  93   The patron borrow the book                                      P =0, F=F,    I=filled
  94
  95 =head1 FUNCTIONS
  96
  97 =cut
  98
  99 our (@ISA, @EXPORT_OK);
 100 BEGIN {
 101     require Exporter;
 102     @ISA = qw(Exporter);
 103     @EXPORT_OK = qw(
 104       AddReserve
 105
 106       GetReserveStatus
 107
 108       GetOtherReserves
 109       ChargeReserveFee
 110       GetReserveFee
 111
 112       ModReserveAffect
 113       ModReserve
 114       ModReserveStatus
 115       ModReserveCancelAll
 116       ModReserveMinusPriority
 117       MoveReserve
 118
 119       CheckReserves
 120       CanBookBeReserved
 121       CanItemBeReserved
 122       CanReserveBeCanceledFromOpac
 123       CancelExpiredReserves
 124
 125       AutoUnsuspendReserves
 126
 127       IsAvailableForItemLevelRequest
 128       ItemsAnyAvailableAndNotRestricted
 129
 130       AlterPriority
 131       ToggleLowestPriority
 132
 133       ReserveSlip
 134       ToggleSuspend
 135       SuspendAll
 136
 137       GetReservesControlBranch
 138
 139       CalculatePriority
 140
 141       IsItemOnHoldAndFound
 142
 143       GetMaxPatronHoldsForRecord
 144
 145       MergeHolds
 146
 147       RevertWaitingStatus
 148     );
 149 }
 150
 151 =head2 AddReserve
 152
 153     AddReserve(
 154         {
 155             branchcode       => $branchcode,
 156             borrowernumber   => $borrowernumber,
 157             biblionumber     => $biblionumber,
 158             priority         => $priority,
 159             reservation_date => $reservation_date,
 160             expiration_date  => $expiration_date,
 161             notes            => $notes,
 162             title            => $title,
 163             itemnumber       => $itemnumber,
 164             found            => $found,
 165             itemtype         => $itemtype,
 166             item_group_id    => $item_group_id
 167         }
 168     );
 169
 170 Adds reserve and generates HOLDPLACED message.
 171
 172 The following tables are available witin the HOLDPLACED message:
 173
 174     branches
 175     borrowers
 176     biblio
 177     biblioitems
 178     items
 179     reserves
 180
 181 =cut
 182
 183 sub AddReserve {
 184     my ($params)       = @_;
 185     my $branch         = $params->{branchcode};
 186     my $borrowernumber = $params->{borrowernumber};
 187     my $biblionumber   = $params->{biblionumber};
 188     my $priority       = $params->{priority};
 189     my $resdate        = $params->{reservation_date};
 190     my $patron_expiration_date = $params->{expiration_date};
 191     my $notes          = $params->{notes};
 192     my $title          = $params->{title};
 193     my $checkitem      = $params->{itemnumber};
 194     my $found          = $params->{found};
 195     my $itemtype       = $params->{itemtype};
 196     my $non_priority   = $params->{non_priority};
 197     my $item_group_id  = $params->{item_group_id};
 198
 199     $resdate ||= dt_from_string;
 200
 201     # if we have an item selectionned, and the pickup branch is the same as the holdingbranch
 202     # of the document, we force the value $priority and $found .
 203     if ( $checkitem and not C4::Context->preference('ReservesNeedReturns') ) {
 204         my $item = Koha::Items->find( $checkitem ); # FIXME Prevent bad calls
 205
 206         if (
 207             # If item is already checked out, it cannot be set waiting
 208             !$item->onloan
 209
 210             # The item can't be waiting if it needs a transfer
 211             && $item->holdingbranch eq $branch
 212
 213             # Similarly, if in transit it can't be waiting
 214             && !$item->get_transfer
 215
 216             # If we can't hold damaged items, and it is damaged, it can't be waiting
 217             && ( $item->damaged && C4::Context->preference('AllowHoldsOnDamagedItems') || !$item->damaged )
 218
 219             # Lastly, if this already has holds, we shouldn't make it waiting for the new hold
 220             && !$item->current_holds->count )
 221         {
 222             $priority = 0;
 223             $found = 'W';
 224         }
 225     }
 226     if ( C4::Context->preference( 'AllowHoldDateInFuture' ) ) {
 227     # Make room in reserves for this if passed a priority
 228     $priority = _ShiftPriority( $biblionumber, $priority );
 229     }
 230
 231     my $waitingdate;
 232
 233     # If the reserv had the waiting status, we had the value of the resdate
 234     if ( $found && $found eq 'W' ) {
 235         $waitingdate = $resdate;
 236     }
 237
 238     # Don't add itemtype limit if specific item is selected
 239     $itemtype = undef if $checkitem;
 240
 241     # updates take place here
 242     my $hold = Koha::Hold->new(
 243         {
 244             borrowernumber => $borrowernumber,
 245             biblionumber   => $biblionumber,
 246             item_group_id  => $item_group_id,
 247             reservedate    => $resdate,
 248             branchcode     => $branch,
 249             priority       => $priority,
 250             reservenotes   => $notes,
 251             itemnumber     => $checkitem,
 252             found          => $found,
 253             waitingdate    => $waitingdate,
 254             patron_expiration_date => $patron_expiration_date,
 255             itemtype       => $itemtype,
 256             item_level_hold => $checkitem ? 1 : 0,
 257             non_priority   => $non_priority ? 1 : 0,
 258         }
 259     )->store();
 260     $hold->set_waiting() if $found && $found eq 'W';
 261
 262     logaction( 'HOLDS', 'CREATE', $hold->id, $hold )
 263         if C4::Context->preference('HoldsLog');
 264
 265     my $reserve_id = $hold->id();
 266
 267     # add a reserve fee if needed
 268     if ( C4::Context->preference('HoldFeeMode') ne 'any_time_is_collected' ) {
 269         my $reserve_fee = GetReserveFee( $borrowernumber, $biblionumber );
 270         ChargeReserveFee( $borrowernumber, $reserve_fee, $title );
 271     }
 272
 273     _FixPriority({ biblionumber => $biblionumber});
 274
 275     # Send e-mail to librarian if syspref is active
 276     if(C4::Context->preference("emailLibrarianWhenHoldIsPlaced")){
 277         my $patron = Koha::Patrons->find( $borrowernumber );
 278         my $library = $patron->library;
 279         if ( my $letter =  C4::Letters::GetPreparedLetter (
 280             module => 'reserves',
 281             letter_code => 'HOLDPLACED',
 282             branchcode => $branch,
 283             lang => $patron->lang,
 284             tables => {
 285                 'branches'    => $library->unblessed,
 286                 'borrowers'   => $patron->unblessed,
 287                 'biblio'      => $biblionumber,
 288                 'biblioitems' => $biblionumber,
 289                 'items'       => $checkitem,
 290                 'reserves'    => $hold->unblessed,
 291             },
 292         ) ) {
 293
 294             my $branch_email_address = $library->inbound_email_address;
 295
 296             C4::Letters::EnqueueLetter(
 297                 {
 298                     letter                 => $letter,
 299                     borrowernumber         => $borrowernumber,
 300                     message_transport_type => 'email',
 301                     to_address             => $branch_email_address,
 302                 }
 303             );
 304         }
 305     }
 306
 307     Koha::Plugins->call('after_hold_create', $hold);
 308     Koha::Plugins->call(
 309         'after_hold_action',
 310         {
 311             action  => 'place',
 312             payload => { hold => $hold->get_from_storage }
 313         }
 314     );
 315
 316     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 317         {
 318             biblio_ids => [ $biblionumber ]
 319         }
 320     ) if C4::Context->preference('RealTimeHoldsQueue');
 321
 322     return $reserve_id;
 323 }
 324
 325 =head2 CanBookBeReserved
 326
 327   $canReserve = &CanBookBeReserved($borrowernumber, $biblionumber, $branchcode, $params)
 328   if ($canReserve eq 'OK') { #We can reserve this Item! }
 329
 330   $params are passed directly through to CanItemBeReserved
 331
 332 See CanItemBeReserved() for possible return values.
 333
 334 =cut
 335
 336 sub CanBookBeReserved{
 337     my ($borrowernumber, $biblionumber, $pickup_branchcode, $params) = @_;
 338
 339     # Check that patron have not checked out this biblio (if AllowHoldsOnPatronsPossessions set)
 340     if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 341         && C4::Circulation::CheckIfIssuedToPatron( $borrowernumber, $biblionumber ) ) {
 342         return { status =>'alreadypossession' };
 343     }
 344
 345     if ( $params->{itemtype} ) {
 346
 347         # biblio-level, item type-contrained
 348         my $patron          = Koha::Patrons->find($borrowernumber);
 349         my $reservesallowed = Koha::CirculationRules->get_effective_rule(
 350             {
 351                 itemtype     => $params->{itemtype},
 352                 categorycode => $patron->categorycode,
 353                 branchcode   => $pickup_branchcode,
 354                 rule_name    => 'reservesallowed',
 355             }
 356         )->rule_value;
 357
 358         $reservesallowed = ( $reservesallowed eq '' ) ? undef : $reservesallowed;
 359
 360         my $count = $patron->holds->search(
 361             {
 362                 '-or' => [
 363                     { 'me.itemtype' => $params->{itemtype} },
 364                     { 'item.itype'  => $params->{itemtype} }
 365                 ]
 366             },
 367             {
 368                 join => ['item']
 369             }
 370         )->count;
 371
 372         return { status => '' }
 373           if defined $reservesallowed and $reservesallowed < $count + 1;
 374     }
 375
 376     my $items;
 377     #get items linked via host records
 378     my @hostitemnumbers = get_hostitemnumbers_of($biblionumber);
 379     if (@hostitemnumbers){
 380         $items = Koha::Items->search({
 381             -or => [
 382                 biblionumber => $biblionumber,
 383                 itemnumber => { -in => @hostitemnumbers }
 384             ]
 385         });
 386     } else {
 387         $items = Koha::Items->search({ biblionumber => $biblionumber});
 388     }
 389
 390     my $canReserve = { status => '' };
 391     my $patron = Koha::Patrons->find( $borrowernumber );
 392     while ( my $item = $items->next ) {
 393         $canReserve = CanItemBeReserved( $patron, $item, $pickup_branchcode, $params );
 394         return { status => 'OK' } if $canReserve->{status} eq 'OK';
 395     }
 396     return $canReserve;
 397 }
 398
 399 =head2 CanItemBeReserved
 400
 401   $canReserve = &CanItemBeReserved($patron, $item, $branchcode, $params)
 402   if ($canReserve->{status} eq 'OK') { #We can reserve this Item! }
 403
 404   current params are:
 405   'ignore_hold_counts' - we use this routine to check if an item can fill a hold - on this case we
 406   should not check if there are too many holds as we only care about reservability
 407
 408 @RETURNS { status => OK },              if the Item can be reserved.
 409          { status => ageRestricted },   if the Item is age restricted for this borrower.
 410          { status => damaged },         if the Item is damaged.
 411          { status => cannotReserveFromOtherBranches }, if syspref 'canreservefromotherbranches' is OK.
 412          { status => branchNotInHoldGroup }, if borrower home library is not in hold group, and holds are only allowed from hold groups.
 413          { status => tooManyReserves, limit => $limit }, if the borrower has exceeded their maximum reserve amount.
 414          { status => notReservable },   if holds on this item are not allowed
 415          { status => libraryNotFound },   if given branchcode is not an existing library
 416          { status => libraryNotPickupLocation },   if given branchcode is not configured to be a pickup location
 417          { status => cannotBeTransferred }, if branch transfer limit applies on given item and branchcode
 418          { status => pickupNotInHoldGroup }, pickup location is not in hold group, and pickup locations are only allowed from hold groups.
 419          { status => recall }, if the borrower has already placed a recall on this item
 420
 421 =cut
 422
 423 our $CanItemBeReserved_cache_key;
 424 sub _cache {
 425     my ( $return )  = @_;
 426     my $memory_cache = Koha::Cache::Memory::Lite->get_instance();
 427     $memory_cache->set_in_cache( $CanItemBeReserved_cache_key, $return );
 428     return $return;
 429 }
 430
 431 sub CanItemBeReserved {
 432     my ( $patron, $item, $pickup_branchcode, $params ) = @_;
 433
 434     my $memory_cache = Koha::Cache::Memory::Lite->get_instance();
 435     $CanItemBeReserved_cache_key = sprintf "Hold_CanItemBeReserved:%s:%s:%s", $patron->borrowernumber, $item->itemnumber, $pickup_branchcode || "";
 436     if ( $params->{get_from_cache} ) {
 437         my $cached = $memory_cache->get_from_cache($CanItemBeReserved_cache_key);
 438         return $cached if $cached;
 439     }
 440
 441     my $dbh = C4::Context->dbh;
 442     my $ruleitemtype;    # itemtype of the matching issuing rule
 443     my $allowedreserves  = 0; # Total number of holds allowed across all records, default to none
 444
 445     # We check item branch if IndependentBranches is ON
 446     # and canreservefromotherbranches is OFF
 447     if ( C4::Context->preference('IndependentBranches')
 448         and !C4::Context->preference('canreservefromotherbranches') )
 449     {
 450         if ( $item->homebranch ne $patron->branchcode ) {
 451             return _cache { status => 'cannotReserveFromOtherBranches' };
 452         }
 453     }
 454
 455     # we retrieve borrowers and items informations #
 456     # item->{itype} will come for biblioitems if necessery
 457     my $borrower = $patron->unblessed;
 458
 459     # If an item is damaged and we don't allow holds on damaged items, we can stop right here
 460     return _cache { status =>'damaged' }
 461       if ( $item->damaged
 462         && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 463
 464     if( GetMarcFromKohaField('biblioitems.agerestriction') ){
 465         my $biblio = $item->biblio;
 466         # Check for the age restriction
 467         my ( $ageRestriction, $daysToAgeRestriction ) =
 468           C4::Circulation::GetAgeRestriction( $biblio->biblioitem->agerestriction, $borrower );
 469         return _cache { status => 'ageRestricted' } if $daysToAgeRestriction && $daysToAgeRestriction > 0;
 470     }
 471
 472     # Check that the patron doesn't have an item level hold on this item already
 473     return _cache { status =>'itemAlreadyOnHold' }
 474       if ( !$params->{ignore_hold_counts} && Koha::Holds->search( { borrowernumber => $patron->borrowernumber, itemnumber => $item->itemnumber } )->count() );
 475
 476     # Check that patron have not checked out this biblio (if AllowHoldsOnPatronsPossessions set)
 477     if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 478         && C4::Circulation::CheckIfIssuedToPatron( $patron->borrowernumber, $item->biblionumber ) ) {
 479         return _cache { status =>'alreadypossession' };
 480     }
 481
 482     # check if a recall exists on this item from this borrower
 483     return _cache { status => 'recall' }
 484       if $patron->recalls->filter_by_current->search({ item_id => $item->itemnumber })->count;
 485
 486     my $controlbranch = C4::Context->preference('ReservesControlBranch');
 487
 488     my $reserves_control_branch;
 489     my $branchfield = "reserves.branchcode";
 490
 491     if ( $controlbranch eq "ItemHomeLibrary" ) {
 492         $branchfield = "items.homebranch";
 493         $reserves_control_branch  = $item->homebranch;
 494     }
 495     elsif ( $controlbranch eq "PatronLibrary" ) {
 496         $branchfield = "borrowers.branchcode";
 497         $reserves_control_branch  = $borrower->{branchcode};
 498     }
 499
 500     # we retrieve rights
 501     if (
 502         my $reservesallowed = Koha::CirculationRules->get_effective_rule({
 503                 itemtype     => $item->effective_itemtype,
 504                 categorycode => $borrower->{categorycode},
 505                 branchcode   => $reserves_control_branch,
 506                 rule_name    => 'reservesallowed',
 507         })
 508     ) {
 509         $ruleitemtype     = $reservesallowed->itemtype;
 510         $allowedreserves  = $reservesallowed->rule_value // 0; #undefined is 0, blank is unlimited
 511     }
 512     else {
 513         $ruleitemtype = undef;
 514     }
 515
 516     my $rights = Koha::CirculationRules->get_effective_rules({
 517         categorycode => $borrower->{'categorycode'},
 518         itemtype     => $item->effective_itemtype,
 519         branchcode   => $reserves_control_branch,
 520         rules        => ['holds_per_record','holds_per_day']
 521     });
 522     my $holds_per_record = $rights->{holds_per_record} // 1;
 523     my $holds_per_day    = $rights->{holds_per_day};
 524
 525     if (   defined $holds_per_record && $holds_per_record ne '' ){
 526         if ( $holds_per_record == 0 ) {
 527             return _cache { status => "noReservesAllowed" };
 528         }
 529         if ( !$params->{ignore_hold_counts} ) {
 530             my $search_params = {
 531                 borrowernumber => $patron->borrowernumber,
 532                 biblionumber   => $item->biblionumber,
 533             };
 534             my $holds = Koha::Holds->search($search_params);
 535             return _cache { status => "tooManyHoldsForThisRecord", limit => $holds_per_record } if $holds->count() >= $holds_per_record;
 536         }
 537     }
 538
 539     if (!$params->{ignore_hold_counts} && defined $holds_per_day && $holds_per_day ne '')
 540     {
 541         my $today_holds = Koha::Holds->search({
 542             borrowernumber => $patron->borrowernumber,
 543             reservedate    => dt_from_string->date
 544         });
 545         return _cache { status => 'tooManyReservesToday', limit => $holds_per_day } if $today_holds->count() >= $holds_per_day;
 546     }
 547
 548     # we check if it's ok or not
 549     if ( defined $allowedreserves && $allowedreserves ne '' ){
 550         if( $allowedreserves == 0 ){
 551             return _cache { status => 'noReservesAllowed' };
 552         }
 553         if ( !$params->{ignore_hold_counts} ) {
 554             # we retrieve count
 555             my $querycount = q{
 556                 SELECT count(*) AS count
 557                   FROM reserves
 558              LEFT JOIN items USING (itemnumber)
 559              LEFT JOIN biblioitems ON (reserves.biblionumber=biblioitems.biblionumber)
 560              LEFT JOIN borrowers USING (borrowernumber)
 561                  WHERE borrowernumber = ?
 562             };
 563             $querycount .= "AND ( $branchfield = ? OR $branchfield IS NULL )";
 564
 565             # If using item-level itypes, fall back to the record
 566             # level itemtype if the hold has no associated item
 567             if ( defined $ruleitemtype ) {
 568                 if ( C4::Context->preference('item-level_itypes') ) {
 569                     $querycount .= q{
 570                         AND ( COALESCE( items.itype, biblioitems.itemtype ) = ?
 571                            OR reserves.itemtype = ? )
 572                     };
 573                 }
 574                 else {
 575                     $querycount .= q{
 576                         AND ( biblioitems.itemtype = ?
 577                            OR reserves.itemtype = ? )
 578                     };
 579                 }
 580             }
 581
 582             my $sthcount = $dbh->prepare($querycount);
 583
 584             if ( defined $ruleitemtype ) {
 585                 $sthcount->execute( $patron->borrowernumber, $reserves_control_branch, $ruleitemtype, $ruleitemtype );
 586             }
 587             else {
 588                 $sthcount->execute( $patron->borrowernumber, $reserves_control_branch );
 589             }
 590
 591             my $reservecount = "0";
 592             if ( my $rowcount = $sthcount->fetchrow_hashref() ) {
 593                 $reservecount = $rowcount->{count};
 594             }
 595
 596             return _cache { status => 'tooManyReserves', limit => $allowedreserves } if $reservecount >= $allowedreserves;
 597         }
 598     }
 599
 600     # Now we need to check hold limits by patron category
 601     my $rule = Koha::CirculationRules->get_effective_rule(
 602         {
 603             categorycode => $patron->categorycode,
 604             branchcode   => $reserves_control_branch,
 605             rule_name    => 'max_holds',
 606         }
 607     );
 608     if (!$params->{ignore_hold_counts} && $rule && defined( $rule->rule_value ) && $rule->rule_value ne '' ) {
 609         my $total_holds_count = Koha::Holds->search(
 610             {
 611                 borrowernumber => $patron->borrowernumber
 612             }
 613         )->count();
 614
 615         return _cache { status => 'tooManyReserves', limit => $rule->rule_value} if $total_holds_count >= $rule->rule_value;
 616     }
 617
 618     my $branchitemrule =
 619       C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->effective_itemtype );
 620
 621     if ( $branchitemrule->{holdallowed} eq 'not_allowed' ) {
 622         return _cache { status => 'notReservable' };
 623     }
 624
 625     if (   $branchitemrule->{holdallowed} eq 'from_home_library'
 626         && $borrower->{branchcode} ne $item->homebranch )
 627     {
 628         return _cache { status => 'cannotReserveFromOtherBranches' };
 629     }
 630
 631     my $item_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
 632     if ( $branchitemrule->{holdallowed} eq 'from_local_hold_group') {
 633         if($patron->branchcode ne $item->homebranch && !$item_library->validate_hold_sibling( {branchcode => $patron->branchcode} )) {
 634             return _cache { status => 'branchNotInHoldGroup' };
 635         }
 636     }
 637
 638     if ($pickup_branchcode) {
 639         my $destination = Koha::Libraries->find({
 640             branchcode => $pickup_branchcode,
 641         });
 642
 643         unless ($destination) {
 644             return _cache { status => 'libraryNotFound' };
 645         }
 646         unless ($destination->pickup_location) {
 647             return _cache { status => 'libraryNotPickupLocation' };
 648         }
 649         unless ($item->can_be_transferred({ to => $destination })) {
 650             return _cache { status => 'cannotBeTransferred' };
 651         }
 652         if ($branchitemrule->{hold_fulfillment_policy} eq 'holdgroup' && !$item_library->validate_hold_sibling( {branchcode => $pickup_branchcode} )) {
 653             return _cache { status => 'pickupNotInHoldGroup' };
 654         }
 655         if ($branchitemrule->{hold_fulfillment_policy} eq 'patrongroup' && !Koha::Libraries->find({branchcode => $borrower->{branchcode}})->validate_hold_sibling({branchcode => $pickup_branchcode})) {
 656             return _cache { status => 'pickupNotInHoldGroup' };
 657         }
 658     }
 659
 660     return _cache { status => 'OK' };
 661 }
 662
 663 =head2 CanReserveBeCanceledFromOpac
 664
 665     $number = CanReserveBeCanceledFromOpac($reserve_id, $borrowernumber);
 666
 667     returns 1 if reserve can be cancelled by user from OPAC.
 668     First check if reserve belongs to user, next checks if reserve is not in
 669     transfer or waiting status
 670
 671 =cut
 672
 673 sub CanReserveBeCanceledFromOpac {
 674     my ($reserve_id, $borrowernumber) = @_;
 675
 676     return unless $reserve_id and $borrowernumber;
 677     my $reserve = Koha::Holds->find($reserve_id) or return;
 678
 679     return 0 unless $reserve->borrowernumber == $borrowernumber;
 680     return $reserve->is_cancelable_from_opac;
 681 }
 682
 683 =head2 GetOtherReserves
 684
 685   ($messages,$nextreservinfo)=$GetOtherReserves(itemnumber);
 686
 687 Check queued list of this document and check if this document must be transferred
 688
 689 =cut
 690
 691 sub GetOtherReserves {
 692     my ($itemnumber) = @_;
 693     my $messages;
 694     my $nextreservinfo;
 695     my $item = Koha::Items->find($itemnumber);
 696     my ( undef, $checkreserves, undef ) = CheckReserves($item);
 697     if ($checkreserves) {
 698         if ( $item->holdingbranch ne $checkreserves->{'branchcode'} ) {
 699             $messages->{'transfert'} = $checkreserves->{'branchcode'};
 700             #minus priorities of others reservs
 701             ModReserveMinusPriority(
 702                 $itemnumber,
 703                 $checkreserves->{'reserve_id'},
 704             );
 705
 706             #launch the subroutine dotransfer
 707             C4::Items::ModItemTransfer(
 708                 $itemnumber,
 709                 $item->holdingbranch,
 710                 $checkreserves->{'branchcode'},
 711                 'Reserve'
 712               ),
 713               ;
 714         }
 715
 716      #step 2b : case of a reservation on the same branch, set the waiting status
 717         else {
 718             $messages->{'waiting'} = 1;
 719             ModReserveMinusPriority(
 720                 $itemnumber,
 721                 $checkreserves->{'reserve_id'},
 722             );
 723             ModReserveStatus($itemnumber,'W');
 724         }
 725
 726         $nextreservinfo = $checkreserves;
 727     }
 728
 729     return ( $messages, $nextreservinfo );
 730 }
 731
 732 =head2 ChargeReserveFee
 733
 734     $fee = ChargeReserveFee( $borrowernumber, $fee, $title );
 735
 736     Charge the fee for a reserve (if $fee > 0)
 737
 738 =cut
 739
 740 sub ChargeReserveFee {
 741     my ( $borrowernumber, $fee, $title ) = @_;
 742     return if !$fee || $fee == 0;    # the last test is needed to include 0.00
 743     Koha::Account->new( { patron_id => $borrowernumber } )->add_debit(
 744         {
 745             amount       => $fee,
 746             description  => $title,
 747             note         => undef,
 748             user_id      => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 749             library_id   => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 750             interface    => C4::Context->interface,
 751             invoice_type => undef,
 752             type         => 'RESERVE',
 753             item_id      => undef
 754         }
 755     );
 756 }
 757
 758 =head2 GetReserveFee
 759
 760     $fee = GetReserveFee( $borrowernumber, $biblionumber );
 761
 762     Calculate the fee for a reserve (if applicable).
 763
 764 =cut
 765
 766 sub GetReserveFee {
 767     my ( $borrowernumber, $biblionumber ) = @_;
 768     my $borquery = qq{
 769 SELECT reservefee FROM borrowers LEFT JOIN categories ON borrowers.categorycode = categories.categorycode WHERE borrowernumber = ?
 770     };
 771     my $issue_qry = qq{
 772 SELECT COUNT(*) FROM items
 773 LEFT JOIN issues USING (itemnumber)
 774 WHERE items.biblionumber=? AND issues.issue_id IS NULL
 775     };
 776     my $holds_qry = qq{
 777 SELECT COUNT(*) FROM reserves WHERE biblionumber=? AND borrowernumber<>?
 778     };
 779
 780     my $dbh = C4::Context->dbh;
 781     my ( $fee ) = $dbh->selectrow_array( $borquery, undef, ($borrowernumber) );
 782     $fee += 0;
 783     my $hold_fee_mode = C4::Context->preference('HoldFeeMode') || 'not_always';
 784     if( $fee and $fee > 0 and $hold_fee_mode eq 'not_always' ) {
 785         # This is a reconstruction of the old code:
 786         # Compare number of items with items issued, and optionally check holds
 787         # If not all items are issued and there are no holds: charge no fee
 788         # NOTE: Lost, damaged, not-for-loan, etc. are just ignored here
 789         my ( $notissued, $reserved );
 790         ( $notissued ) = $dbh->selectrow_array( $issue_qry, undef,
 791             ( $biblionumber ) );
 792         if( $notissued == 0 ) {
 793             # all items are issued
 794             ( $reserved ) = $dbh->selectrow_array( $holds_qry, undef,
 795                 ( $biblionumber, $borrowernumber ) );
 796             $fee = 0 if $reserved == 0;
 797         } else {
 798             $fee = 0;
 799         }
 800     }
 801     return $fee;
 802 }
 803
 804 =head2 GetReserveStatus
 805
 806   $reservestatus = GetReserveStatus($itemnumber);
 807
 808 Takes an itemnumber and returns the status of the reserve placed on it.
 809 If several reserves exist, the reserve with the lower priority is given.
 810
 811 =cut
 812
 813 ## FIXME: I don't think this does what it thinks it does.
 814 ## It only ever checks the first reserve result, even though
 815 ## multiple reserves for that bib can have the itemnumber set
 816 ## the sub is only used once in the codebase.
 817 sub GetReserveStatus {
 818     my ($itemnumber) = @_;
 819
 820     my $dbh = C4::Context->dbh;
 821
 822     my ($sth, $found, $priority);
 823     if ( $itemnumber ) {
 824         $sth = $dbh->prepare("SELECT found, priority FROM reserves WHERE itemnumber = ? order by priority LIMIT 1");
 825         $sth->execute($itemnumber);
 826         ($found, $priority) = $sth->fetchrow_array;
 827     }
 828
 829     if(defined $found) {
 830         return 'Waiting'  if $found eq 'W' and $priority == 0;
 831         return 'Processing'  if $found eq 'P';
 832         return 'Finished' if $found eq 'F';
 833     }
 834
 835     return 'Reserved' if defined $priority && $priority > 0;
 836
 837     return ''; # empty string here will remove need for checking undef, or less log lines
 838 }
 839
 840 =head2 CheckReserves
 841
 842   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($item);
 843   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($item, $lookahead);
 844
 845 Find a book in the reserves.
 846
 847 C<$item> is the book's item.
 848 C<$lookahead> is the number of days to look in advance for future reserves.
 849
 850 As I understand it, C<&CheckReserves> looks for the given item in the
 851 reserves. If it is found, that's a match, and C<$status> is set to
 852 C<Waiting>.
 853
 854 Otherwise, it finds the most important item in the reserves with the
 855 same biblio number as this book (I'm not clear on this) and returns it
 856 with C<$status> set to C<Reserved>.
 857
 858 C<&CheckReserves> returns a two-element list:
 859
 860 C<$status> is either C<Waiting>, C<Reserved> (see above), or 0.
 861
 862 C<$reserve> is the reserve item that matched. It is a
 863 reference-to-hash whose keys are mostly the fields of the reserves
 864 table in the Koha database.
 865
 866 =cut
 867
 868 sub CheckReserves {
 869     my ( $item, $lookahead_days, $ignore_borrowers ) = @_;
 870     # note: we get the itemnumber because we might have started w/ just the barcode.  Now we know for sure we have it.
 871
 872     return unless $item; # bail if we got nothing.
 873
 874     return if ( $item->damaged && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 875
 876     # if item is not for loan it cannot be reserved either.....
 877     # except where items.notforloan < 0 :  This indicates the item is holdable.
 878
 879     my @SkipHoldTrapOnNotForLoanValue = split( '\|', C4::Context->preference('SkipHoldTrapOnNotForLoanValue') );
 880     return if grep { $_ eq $item->notforloan } @SkipHoldTrapOnNotForLoanValue;
 881
 882     my $dont_trap = C4::Context->preference('TrapHoldsOnOrder') ? $item->notforloan > 0 : $item->notforloan;
 883     if ( !$dont_trap ) {
 884         my $item_type = $item->effective_itemtype;
 885         if ( $item_type ) {
 886             return if Koha::ItemTypes->find( $item_type )->notforloan;
 887         }
 888     }
 889     else {
 890         return;
 891     }
 892
 893     # Find this item in the reserves
 894     my @reserves = _Findgroupreserve( $item->biblionumber, $item->itemnumber, $lookahead_days, $ignore_borrowers);
 895
 896     # $priority and $highest are used to find the most important item
 897     # in the list returned by &_Findgroupreserve. (The lower $priority,
 898     # the more important the item.)
 899     # $highest is the most important item we've seen so far.
 900     my $highest;
 901
 902     if (scalar @reserves) {
 903         my $LocalHoldsPriority = C4::Context->preference('LocalHoldsPriority');
 904         my $LocalHoldsPriorityPatronControl = C4::Context->preference('LocalHoldsPriorityPatronControl');
 905         my $LocalHoldsPriorityItemControl = C4::Context->preference('LocalHoldsPriorityItemControl');
 906         my $priority = 10000000;
 907
 908         foreach my $res (@reserves) {
 909             if ($res->{'found'} && $res->{'found'} eq 'W') {
 910                 return ( "Waiting", $res, \@reserves ); # Found it, it is waiting
 911             } elsif ($res->{'found'} && $res->{'found'} eq 'P') {
 912                 return ( "Processing", $res, \@reserves ); # Found determinated hold, e. g. the transferred one
 913             } elsif ($res->{'found'} && $res->{'found'} eq 'T') {
 914                 return ( "Transferred", $res, \@reserves ); # Found determinated hold, e. g. the transferred one
 915             } else {
 916                 my $patron;
 917                 my $local_hold_match;
 918
 919                 if ($LocalHoldsPriority) {
 920                     $patron = Koha::Patrons->find( $res->{borrowernumber} );
 921
 922                     unless ($item->exclude_from_local_holds_priority || $patron->category->exclude_from_local_holds_priority) {
 923                         my $local_holds_priority_item_branchcode =
 924                             $item->$LocalHoldsPriorityItemControl;
 925                         my $local_holds_priority_patron_branchcode =
 926                             ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 927                             ? $res->{branchcode}
 928                             : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 929                             ? $patron->branchcode
 930                             : undef;
 931                         $local_hold_match =
 932                             $local_holds_priority_item_branchcode eq
 933                             $local_holds_priority_patron_branchcode;
 934                     }
 935                 }
 936
 937                 # See if this item is more important than what we've got so far
 938                 if ( ( $res->{'priority'} && $res->{'priority'} < $priority ) || $local_hold_match ) {
 939                     next if $res->{item_group_id} && ( !$item->item_group || $item->item_group->id != $res->{item_group_id} );
 940                     next if $res->{itemtype} && $res->{itemtype} ne $item->effective_itemtype;
 941                     $patron //= Koha::Patrons->find( $res->{borrowernumber} );
 942                     my $branch = GetReservesControlBranch( $item->unblessed, $patron->unblessed );
 943                     my $branchitemrule = C4::Circulation::GetBranchItemRule($branch,$item->effective_itemtype);
 944                     next if ($branchitemrule->{'holdallowed'} eq 'not_allowed');
 945                     next if (($branchitemrule->{'holdallowed'} eq 'from_home_library') && ($item->homebranch ne $patron->branchcode));
 946                     my $library = Koha::Libraries->find({branchcode=>$item->homebranch});
 947                     next if (($branchitemrule->{'holdallowed'} eq 'from_local_hold_group') && (!$library->validate_hold_sibling({branchcode => $patron->branchcode}) ));
 948                     my $hold_fulfillment_policy = $branchitemrule->{hold_fulfillment_policy};
 949                     next if ( ($hold_fulfillment_policy eq 'holdgroup') && (!$library->validate_hold_sibling({branchcode => $res->{branchcode}})) );
 950                     next if ( ($hold_fulfillment_policy eq 'homebranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 951                     next if ( ($hold_fulfillment_policy eq 'holdingbranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 952                     next unless $item->can_be_transferred( { to => Koha::Libraries->find( $res->{branchcode} ) } );
 953                     $priority = $res->{'priority'};
 954                     $highest  = $res;
 955                     last if $local_hold_match;
 956                 }
 957             }
 958         }
 959     }
 960
 961     # If we get this far, then no exact match was found.
 962     # We return the most important (i.e. next) reservation.
 963     if ($highest) {
 964         $highest->{'itemnumber'} = $item->itemnumber;
 965         return ( "Reserved", $highest, \@reserves );
 966     }
 967
 968     return ( '' );
 969 }
 970
 971 =head2 CancelExpiredReserves
 972
 973   CancelExpiredReserves();
 974
 975 Cancels all reserves with an expiration date from before today.
 976
 977 =cut
 978
 979 sub CancelExpiredReserves {
 980     my $cancellation_reason = shift;
 981     my $today = dt_from_string();
 982     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 983     my $expireWaiting = C4::Context->preference('ExpireReservesMaxPickUpDelay');
 984
 985     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 986     my $params = {
 987         -or => [
 988             { expirationdate => { '<', $dtf->format_date($today) } },
 989             { patron_expiration_date => { '<' => $dtf->format_date($today) } }
 990         ]
 991     };
 992
 993     $params->{found} = [ { '!=', 'W' }, undef ]  unless $expireWaiting;
 994
 995     # FIXME To move to Koha::Holds->search_expired (?)
 996     my $holds = Koha::Holds->search( $params );
 997
 998     while ( my $hold = $holds->next ) {
 999         my $calendar = Koha::Calendar->new( branchcode => $hold->branchcode );
1000
1001         next if !$cancel_on_holidays && $calendar->is_holiday( $today );
1002
1003         my $cancel_params = {};
1004         $cancel_params->{cancellation_reason} = $cancellation_reason if defined($cancellation_reason);
1005         if ( defined($hold->found) && $hold->found eq 'W' ) {
1006             $cancel_params->{charge_cancel_fee} = 1;
1007         }
1008         $cancel_params->{autofill} = C4::Context->preference('ExpireReservesAutoFill');
1009         $hold->cancel( $cancel_params );
1010     }
1011 }
1012
1013 =head2 AutoUnsuspendReserves
1014
1015   AutoUnsuspendReserves();
1016
1017 Unsuspends all suspended reserves with a suspend_until date from before today.
1018
1019 =cut
1020
1021 sub AutoUnsuspendReserves {
1022     my $today = dt_from_string();
1023
1024     my @holds = Koha::Holds->search( { suspend_until => { '<=' => $today->ymd() } } )->as_list;
1025
1026     map { $_->resume() } @holds;
1027 }
1028
1029 =head2 ModReserve
1030
1031   ModReserve({ rank => $rank,
1032                reserve_id => $reserve_id,
1033                branchcode => $branchcode
1034                [, itemnumber => $itemnumber ]
1035                [, biblionumber => $biblionumber, $borrowernumber => $borrowernumber ]
1036               });
1037
1038 Change a hold request's priority or cancel it.
1039
1040 C<$rank> specifies the effect of the change.  If C<$rank>
1041 is 'n', nothing happens.  This corresponds to leaving a
1042 request alone when changing its priority in the holds queue
1043 for a bib.
1044
1045 If C<$rank> is 'del', the hold request is cancelled.
1046
1047 If C<$rank> is an integer greater than zero, the priority of
1048 the request is set to that value.  Since priority != 0 means
1049 that the item is not waiting on the hold shelf, setting the
1050 priority to a non-zero value also sets the request's found
1051 status and waiting date to NULL.
1052
1053 If the hold is 'found' (waiting, in-transit, processing) the
1054 only field that can be updated is the expiration date.
1055
1056 The optional C<$itemnumber> parameter is used only when
1057 C<$rank> is a non-zero integer; if supplied, the itemnumber
1058 of the hold request is set accordingly; if omitted, the itemnumber
1059 is cleared.
1060
1061 B<FIXME:> Note that the forgoing can have the effect of causing
1062 item-level hold requests to turn into title-level requests.  This
1063 will be fixed once reserves has separate columns for requested
1064 itemnumber and supplying itemnumber.
1065
1066 =cut
1067
1068 sub ModReserve {
1069     my ( $params ) = @_;
1070
1071     my $rank = $params->{'rank'};
1072     my $reserve_id = $params->{'reserve_id'};
1073     my $branchcode = $params->{'branchcode'};
1074     my $itemnumber = $params->{'itemnumber'};
1075     my $suspend_until = $params->{'suspend_until'};
1076     my $borrowernumber = $params->{'borrowernumber'};
1077     my $biblionumber = $params->{'biblionumber'};
1078     my $cancellation_reason = $params->{'cancellation_reason'};
1079     my $date = $params->{expirationdate};
1080
1081     return if defined $rank && $rank eq "n";
1082
1083     return unless ( $reserve_id || ( $borrowernumber && ( $biblionumber || $itemnumber ) ) );
1084
1085     my $hold;
1086     unless ( $reserve_id ) {
1087         my $holds = Koha::Holds->search({ biblionumber => $biblionumber, borrowernumber => $borrowernumber, itemnumber => $itemnumber });
1088         return unless $holds->count; # FIXME Should raise an exception
1089         $hold = $holds->next;
1090         $reserve_id = $hold->reserve_id;
1091     }
1092
1093     $hold ||= Koha::Holds->find($reserve_id);
1094
1095     # FIXME Other calls may fail
1096     Koha::Exceptions::ObjectNotFound->throw( 'No hold with id ' . $reserve_id ) unless $hold;
1097
1098     if ( $rank eq "del" ) {
1099         $hold->cancel({ cancellation_reason => $cancellation_reason });
1100     }
1101     elsif ($hold->found && $hold->priority eq '0' && $date) {
1102         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, $hold )
1103             if C4::Context->preference('HoldsLog');
1104
1105         # The only column that can be updated for a found hold is the expiration date
1106         $hold->expirationdate($date)->store();
1107     }
1108     elsif ($rank =~ /^\d+/ and $rank > 0) {
1109         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, $hold )
1110             if C4::Context->preference('HoldsLog');
1111
1112         my $properties = {
1113             priority    => $rank,
1114             branchcode  => $branchcode,
1115             itemnumber  => $itemnumber,
1116             found       => undef,
1117             waitingdate => undef
1118         };
1119         if (exists $params->{reservedate}) {
1120             $properties->{reservedate} = $params->{reservedate} || undef;
1121         }
1122         if (exists $params->{expirationdate}) {
1123             $properties->{expirationdate} = $params->{expirationdate} || undef;
1124         }
1125
1126         $hold->set($properties)->store();
1127
1128         if ( defined( $suspend_until ) ) {
1129             if ( $suspend_until ) {
1130                 $hold->suspend_hold( $suspend_until );
1131             } else {
1132                 # If the hold is suspended leave the hold suspended, but convert it to an indefinite hold.
1133                 # If the hold is not suspended, this does nothing.
1134                 $hold->set( { suspend_until => undef } )->store();
1135             }
1136         }
1137
1138         _FixPriority({ reserve_id => $reserve_id, rank =>$rank });
1139     }
1140 }
1141
1142 =head2 ModReserveStatus
1143
1144   &ModReserveStatus($itemnumber, $newstatus);
1145
1146 Update the reserve status for the active (priority=0) reserve.
1147
1148 $itemnumber is the itemnumber the reserve is on
1149
1150 $newstatus is the new status.
1151
1152 =cut
1153
1154 sub ModReserveStatus {
1155
1156     #first : check if we have a reservation for this item .
1157     my ($itemnumber, $newstatus) = @_;
1158     my $dbh = C4::Context->dbh;
1159
1160     my $query = "UPDATE reserves SET found = ?, waitingdate = NOW() WHERE itemnumber = ? AND found IS NULL AND priority = 0";
1161     my $sth_set = $dbh->prepare($query);
1162     $sth_set->execute( $newstatus, $itemnumber );
1163
1164     my $item = Koha::Items->find($itemnumber);
1165     if ( $item->location && $item->location eq 'CART'
1166         && ( !$item->permanent_location || $item->permanent_location ne 'CART' )
1167         && $newstatus ) {
1168       CartToShelf( $itemnumber );
1169     }
1170 }
1171
1172 =head2 ModReserveAffect
1173
1174   &ModReserveAffect($itemnumber,$borrowernumber,$diffBranchSend,$reserve_id, $desk_id, $notify_library);
1175
1176 This function affect an item and a status for a given reserve, either fetched directly
1177 by record_id, or by borrowernumber and itemnumber or biblionumber. If only biblionumber
1178 is given, only first reserve returned is affected, which is ok for anything but
1179 multi-item holds.
1180
1181 if $transferToDo is not set, then the status is set to "Waiting" as well.
1182 otherwise, a transfer is on the way, and the end of the transfer will
1183 take care of the waiting status
1184
1185 This function also removes any entry of the hold in holds queue table.
1186
1187 =cut
1188
1189 sub ModReserveAffect {
1190     my ( $itemnumber, $borrowernumber, $transferToDo, $reserve_id, $desk_id, $notify_library ) = @_;
1191     my $dbh = C4::Context->dbh;
1192
1193     # we want to attach $itemnumber to $borrowernumber, find the biblionumber
1194     # attached to $itemnumber
1195     my $sth = $dbh->prepare("SELECT biblionumber FROM items WHERE itemnumber=?");
1196     $sth->execute($itemnumber);
1197     my ($biblionumber) = $sth->fetchrow;
1198
1199     # get request - need to find out if item is already
1200     # waiting in order to not send duplicate hold filled notifications
1201
1202     my $hold;
1203     # Find hold by id if we have it
1204     $hold = Koha::Holds->find( $reserve_id ) if $reserve_id;
1205     # Find item level hold for this item if there is one
1206     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->next();
1207     # Find record level hold if there is no item level hold
1208     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, biblionumber => $biblionumber } )->next();
1209
1210     return unless $hold;
1211
1212     my $already_on_shelf = $hold->found && $hold->found eq 'W';
1213
1214     $hold->itemnumber($itemnumber);
1215
1216     if ($transferToDo) {
1217         $hold->set_transfer();
1218     } elsif (C4::Context->preference('HoldsNeedProcessingSIP')
1219              && C4::Context->interface eq 'sip'
1220              && !$already_on_shelf) {
1221         $hold->set_processing();
1222     } else {
1223         $hold->set_waiting($desk_id);
1224         _koha_notify_reserve( $hold->reserve_id ) unless $already_on_shelf;
1225         # Complete transfer if one exists
1226         my $transfer = $hold->item->get_transfer;
1227         $transfer->receive if $transfer;
1228     }
1229
1230     _koha_notify_hold_changed( $hold ) if $notify_library;
1231
1232     _FixPriority( { biblionumber => $biblionumber } );
1233     my $item = Koha::Items->find($itemnumber);
1234     if ( $item->location && $item->location eq 'CART'
1235         && ( !$item->permanent_location || $item->permanent_location ne 'CART' ) ) {
1236       CartToShelf( $itemnumber );
1237     }
1238
1239     my $std = $dbh->prepare(q{
1240         DELETE  q, t
1241         FROM    tmp_holdsqueue q
1242         INNER JOIN hold_fill_targets t
1243         ON  q.borrowernumber = t.borrowernumber
1244             AND q.biblionumber = t.biblionumber
1245             AND q.itemnumber = t.itemnumber
1246             AND q.item_level_request = t.item_level_request
1247             AND q.holdingbranch = t.source_branchcode
1248         WHERE t.reserve_id = ?
1249     });
1250     $std->execute($hold->reserve_id);
1251
1252     logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, $hold )
1253         if C4::Context->preference('HoldsLog');
1254
1255     return;
1256 }
1257
1258 =head2 ModReserveCancelAll
1259
1260   ($messages,$nextreservinfo) = &ModReserveCancelAll($itemnumber,$borrowernumber,$reason);
1261
1262 function to cancel reserv,check other reserves, and transfer document if it's necessary
1263
1264 =cut
1265
1266 sub ModReserveCancelAll {
1267     my $messages;
1268     my $nextreservinfo;
1269     my ( $itemnumber, $borrowernumber, $cancellation_reason ) = @_;
1270
1271     #step 1 : cancel the reservation
1272     my $holds = Koha::Holds->search({ itemnumber => $itemnumber, borrowernumber => $borrowernumber });
1273     return unless $holds->count;
1274     $holds->next->cancel({ cancellation_reason => $cancellation_reason });
1275
1276     #step 2 launch the subroutine of the others reserves
1277     ( $messages, $nextreservinfo ) = GetOtherReserves($itemnumber);
1278
1279     return ( $messages, $nextreservinfo->{borrowernumber} );
1280 }
1281
1282 =head2 ModReserveMinusPriority
1283
1284   &ModReserveMinusPriority($itemnumber,$borrowernumber,$biblionumber)
1285
1286 Reduce the values of queued list
1287
1288 =cut
1289
1290 sub ModReserveMinusPriority {
1291     my ( $itemnumber, $reserve_id ) = @_;
1292
1293     #first step update the value of the first person on reserv
1294     my $dbh   = C4::Context->dbh;
1295     my $query = "
1296         UPDATE reserves
1297         SET    priority = 0 , itemnumber = ?
1298         WHERE  reserve_id = ?
1299     ";
1300     my $sth_upd = $dbh->prepare($query);
1301     $sth_upd->execute( $itemnumber, $reserve_id );
1302     # second step update all others reserves
1303     _FixPriority({ reserve_id => $reserve_id, rank => '0' });
1304 }
1305
1306 =head2 IsAvailableForItemLevelRequest
1307
1308   my $is_available = IsAvailableForItemLevelRequest( $item_record, $borrower_record, $pickup_branchcode );
1309
1310 Checks whether a given item record is available for an
1311 item-level hold request.  An item is available if
1312
1313 * it is not lost AND
1314 * it is not damaged AND
1315 * it is not withdrawn AND
1316 * a waiting or in transit reserve is placed on
1317 * does not have a not for loan value > 0
1318
1319 Need to check the issuingrules onshelfholds column,
1320 if this is set items on the shelf can be placed on hold
1321
1322 Note that IsAvailableForItemLevelRequest() does not
1323 check if the staff operator is authorized to place
1324 a request on the item - in particular,
1325 this routine does not check IndependentBranches
1326 and canreservefromotherbranches.
1327
1328 Note also that this subroutine does not checks smart
1329 rules limits for item by reservesallowed/holds_per_record
1330 values, this complemented in calling code with calls and
1331 checks with CanItemBeReserved or CanBookBeReserved.
1332
1333 =cut
1334
1335 sub IsAvailableForItemLevelRequest {
1336     my $item                = shift;
1337     my $patron              = shift;
1338     my $pickup_branchcode   = shift;
1339     # items_any_available is precalculated status passed from request.pl when set of items
1340     # looped outside of IsAvailableForItemLevelRequest to avoid nested loops:
1341     my $items_any_available = shift;
1342
1343     my $dbh = C4::Context->dbh;
1344     # must check the notforloan setting of the itemtype
1345     # FIXME - a lot of places in the code do this
1346     #         or something similar - need to be
1347     #         consolidated
1348     my $itemtype = $item->effective_itemtype;
1349     return 0
1350       unless defined $itemtype;
1351     my $notforloan_per_itemtype = Koha::ItemTypes->find($itemtype)->notforloan;
1352
1353     return 0 if
1354         $notforloan_per_itemtype ||
1355         $item->itemlost        ||
1356         $item->notforloan > 0  || # item with negative or zero notforloan value is holdable
1357         $item->withdrawn        ||
1358         ($item->damaged && !C4::Context->preference('AllowHoldsOnDamagedItems'));
1359
1360     if ($pickup_branchcode) {
1361         my $destination = Koha::Libraries->find($pickup_branchcode);
1362         return 0 unless $destination;
1363         return 0 unless $destination->pickup_location;
1364         return 0 unless $item->can_be_transferred( { to => $destination } );
1365         my $reserves_control_branch =
1366             GetReservesControlBranch( $item->unblessed(), $patron->unblessed() );
1367         my $branchitemrule =
1368             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype );
1369         my $home_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
1370         return 0 unless $branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $home_library->validate_hold_sibling( {branchcode => $pickup_branchcode} );
1371     }
1372
1373     my $on_shelf_holds = Koha::CirculationRules->get_onshelfholds_policy( { item => $item, patron => $patron } );
1374
1375     if ( $on_shelf_holds == 1 ) {
1376         return 1;
1377     } elsif ( $on_shelf_holds == 2 ) {
1378
1379         # if we have this param predefined from outer caller sub, we just need
1380         # to return it, so we saving from having loop inside other loop:
1381         return  $items_any_available ? 0 : 1
1382             if defined $items_any_available;
1383
1384         my $any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron });
1385         return $any_available ? 0 : 1;
1386     } else { # on_shelf_holds == 0 "If any unavailable" (the description is rather cryptic and could still be improved)
1387         return $item->onloan || IsItemOnHoldAndFound( $item->itemnumber );
1388     }
1389 }
1390
1391 =head2 ItemsAnyAvailableAndNotRestricted
1392
1393   ItemsAnyAvailableAndNotRestricted( { biblionumber => $biblionumber, patron => $patron });
1394
1395 This function checks all items for specified biblionumber (numeric) against patron (object)
1396 and returns true (1) if at least one item available for loan/check out/present/not held
1397 and also checks other parameters logic which not restricts item for hold at all (for ex.
1398 AllowHoldsOnDamagedItems or 'holdallowed' own/sibling library)
1399
1400 =cut
1401
1402 sub ItemsAnyAvailableAndNotRestricted {
1403     my $param = shift;
1404
1405     my @items = Koha::Items->search( { biblionumber => $param->{biblionumber} } )->as_list;
1406
1407     foreach my $i (@items) {
1408         my $reserves_control_branch =
1409             GetReservesControlBranch( $i->unblessed(), $param->{patron}->unblessed );
1410         my $branchitemrule =
1411             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $i->itype );
1412         my $item_library = Koha::Libraries->find( { branchcode => $i->homebranch } );
1413
1414         # we can return (end the loop) when first one found:
1415         return 1
1416             unless $i->itemlost
1417             || $i->notforloan # items with non-zero notforloan cannot be checked out
1418             || $i->withdrawn
1419             || $i->onloan
1420             || IsItemOnHoldAndFound( $i->id )
1421             || ( $i->damaged
1422                  && ! C4::Context->preference('AllowHoldsOnDamagedItems') )
1423             || Koha::ItemTypes->find( $i->effective_itemtype() )->notforloan
1424             || $branchitemrule->{holdallowed} eq 'from_home_library' && $param->{patron}->branchcode ne $i->homebranch
1425             || $branchitemrule->{holdallowed} eq 'from_local_hold_group' && ! $item_library->validate_hold_sibling( { branchcode => $param->{patron}->branchcode } )
1426             || CanItemBeReserved( $param->{patron}, $i )->{status} ne 'OK';
1427     }
1428
1429     return 0;
1430 }
1431
1432 =head2 AlterPriority
1433
1434   AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
1435
1436 This function changes a reserve's priority up, down, to the top, or to the bottom.
1437 Input: $where is 'up', 'down', 'top' or 'bottom'. Biblionumber, Date reserve was placed
1438
1439 =cut
1440
1441 sub AlterPriority {
1442     my ( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority ) = @_;
1443
1444     my $hold = Koha::Holds->find( $reserve_id );
1445     return unless $hold;
1446
1447     if ( $hold->cancellationdate ) {
1448         warn "I cannot alter the priority for reserve_id $reserve_id, the reserve has been cancelled (" . $hold->cancellationdate . ')';
1449         return;
1450     }
1451
1452     if ( $where eq 'up' ) {
1453       return unless $prev_priority;
1454       _FixPriority({ reserve_id => $reserve_id, rank => $prev_priority })
1455     } elsif ( $where eq 'down' ) {
1456       return unless $next_priority;
1457       _FixPriority({ reserve_id => $reserve_id, rank => $next_priority })
1458     } elsif ( $where eq 'top' ) {
1459       _FixPriority({ reserve_id => $reserve_id, rank => $first_priority })
1460     } elsif ( $where eq 'bottom' ) {
1461       _FixPriority({ reserve_id => $reserve_id, rank => $last_priority });
1462     }
1463
1464     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1465         {
1466             biblio_ids => [ $hold->biblionumber ]
1467         }
1468     ) if C4::Context->preference('RealTimeHoldsQueue');
1469     # FIXME Should return the new priority
1470 }
1471
1472 =head2 ToggleLowestPriority
1473
1474   ToggleLowestPriority( $borrowernumber, $biblionumber );
1475
1476 This function sets the lowestPriority field to true if is false, and false if it is true.
1477
1478 =cut
1479
1480 sub ToggleLowestPriority {
1481     my ( $reserve_id ) = @_;
1482
1483     my $dbh = C4::Context->dbh;
1484
1485     my $sth = $dbh->prepare( "UPDATE reserves SET lowestPriority = NOT lowestPriority WHERE reserve_id = ?");
1486     $sth->execute( $reserve_id );
1487
1488     _FixPriority({ reserve_id => $reserve_id, rank => '999999' });
1489 }
1490
1491 =head2 ToggleSuspend
1492
1493   ToggleSuspend( $reserve_id );
1494
1495 This function sets the suspend field to true if is false, and false if it is true.
1496 If the reserve is currently suspended with a suspend_until date, that date will
1497 be cleared when it is unsuspended.
1498
1499 =cut
1500
1501 sub ToggleSuspend {
1502     my ( $reserve_id, $suspend_until ) = @_;
1503
1504     my $hold = Koha::Holds->find( $reserve_id );
1505
1506     if ( $hold->is_suspended ) {
1507         $hold->resume()
1508     } else {
1509         $hold->suspend_hold( $suspend_until );
1510     }
1511 }
1512
1513 =head2 SuspendAll
1514
1515   SuspendAll(
1516       borrowernumber   => $borrowernumber,
1517       [ biblionumber   => $biblionumber, ]
1518       [ suspend_until  => $suspend_until, ]
1519       [ suspend        => $suspend ]
1520   );
1521
1522   This function accepts a set of hash keys as its parameters.
1523   It requires either borrowernumber or biblionumber, or both.
1524
1525   suspend_until is wholly optional.
1526
1527 =cut
1528
1529 sub SuspendAll {
1530     my %params = @_;
1531
1532     my $borrowernumber = $params{'borrowernumber'} || undef;
1533     my $biblionumber   = $params{'biblionumber'}   || undef;
1534     my $suspend_until  = $params{'suspend_until'}  || undef;
1535     my $suspend = defined( $params{'suspend'} ) ? $params{'suspend'} : 1;
1536
1537     return unless ( $borrowernumber || $biblionumber );
1538
1539     my $params;
1540     $params->{found}          = undef;
1541     $params->{borrowernumber} = $borrowernumber if $borrowernumber;
1542     $params->{biblionumber}   = $biblionumber if $biblionumber;
1543
1544     my @holds = Koha::Holds->search($params)->as_list;
1545
1546     if ($suspend) {
1547         map { $_->suspend_hold($suspend_until) } @holds;
1548     }
1549     else {
1550         map { $_->resume() } @holds;
1551     }
1552 }
1553
1554
1555 =head2 _FixPriority
1556
1557   _FixPriority({
1558     reserve_id => $reserve_id,
1559     [rank => $rank,]
1560     [ignoreSetLowestRank => $ignoreSetLowestRank]
1561   });
1562
1563   or
1564
1565   _FixPriority({ biblionumber => $biblionumber});
1566
1567 This routine adjusts the priority of a hold request and holds
1568 on the same bib.
1569
1570 In the first form, where a reserve_id is passed, the priority of the
1571 hold is set to supplied rank, and other holds for that bib are adjusted
1572 accordingly.  If the rank is "del", the hold is cancelled.  If no rank
1573 is supplied, all of the holds on that bib have their priority adjusted
1574 as if the second form had been used.
1575
1576 In the second form, where a biblionumber is passed, the holds on that
1577 bib (that are not captured) are sorted in order of increasing priority,
1578 then have reserves.priority set so that the first non-captured hold
1579 has its priority set to 1, the second non-captured hold has its priority
1580 set to 2, and so forth.
1581
1582 In both cases, holds that have the lowestPriority flag on are have their
1583 priority adjusted to ensure that they remain at the end of the line.
1584
1585 Note that the ignoreSetLowestRank parameter is meant to be used only
1586 when _FixPriority calls itself.
1587
1588 =cut
1589
1590 sub _FixPriority {
1591     my ( $params ) = @_;
1592     my $reserve_id = $params->{reserve_id};
1593     my $rank = $params->{rank} // '';
1594     my $ignoreSetLowestRank = $params->{ignoreSetLowestRank};
1595     my $biblionumber = $params->{biblionumber};
1596
1597     my $dbh = C4::Context->dbh;
1598
1599     my $hold;
1600     if ( $reserve_id ) {
1601         $hold = Koha::Holds->find( $reserve_id );
1602         if (!defined $hold){
1603             # may have already been checked out and hold fulfilled
1604             $hold = Koha::Old::Holds->find( $reserve_id );
1605         }
1606         return unless $hold;
1607     }
1608
1609     unless ( $biblionumber ) { # FIXME This is a very weird API
1610         $biblionumber = $hold->biblionumber;
1611     }
1612
1613     if ( $rank eq "del" ) { # FIXME will crash if called without $hold
1614         $hold->cancel;
1615     }
1616     elsif ( $reserve_id && ( $rank eq "W" || $rank eq "0" ) ) {
1617
1618         # make sure priority for waiting or in-transit items is 0
1619         my $query = "
1620             UPDATE reserves
1621             SET    priority = 0
1622             WHERE reserve_id = ?
1623             AND found IN ('W', 'T', 'P')
1624         ";
1625         my $sth = $dbh->prepare($query);
1626         $sth->execute( $reserve_id );
1627     }
1628     my @priority;
1629
1630     # get whats left
1631     my $query = "
1632         SELECT reserve_id, borrowernumber, reservedate
1633         FROM   reserves
1634         WHERE  biblionumber   = ?
1635           AND  ((found <> 'W' AND found <> 'T' AND found <> 'P') OR found IS NULL)
1636         ORDER BY priority ASC
1637     ";
1638     my $sth = $dbh->prepare($query);
1639     $sth->execute( $biblionumber );
1640     while ( my $line = $sth->fetchrow_hashref ) {
1641         push( @priority,     $line );
1642     }
1643
1644     # FIXME This whole sub must be rewritten, especially to highlight what is done when reserve_id is not given
1645     # To find the matching index
1646     my $i;
1647     my $key = -1;    # to allow for 0 to be a valid result
1648     for ( $i = 0 ; $i < @priority ; $i++ ) {
1649         if ( $reserve_id && $reserve_id == $priority[$i]->{'reserve_id'} ) {
1650             $key = $i;    # save the index
1651             last;
1652         }
1653     }
1654
1655     # if index exists in array then move it to new position
1656     if ( $key > -1 && $rank ne 'del' && $rank > 0 ) {
1657         my $new_rank = $rank - 1; # $new_rank is what you want the new index to be in the array
1658         my $moving_item = splice( @priority, $key, 1 );
1659         $new_rank = scalar @priority if $new_rank > scalar @priority;
1660         splice( @priority, $new_rank, 0, $moving_item );
1661     }
1662
1663     # now fix the priority on those that are left....
1664     $query = "
1665         UPDATE reserves
1666         SET    priority = ?
1667         WHERE  reserve_id = ?
1668     ";
1669     $sth = $dbh->prepare($query);
1670     for ( my $j = 0 ; $j < @priority ; $j++ ) {
1671         $sth->execute(
1672             $j + 1,
1673             $priority[$j]->{'reserve_id'}
1674         );
1675     }
1676
1677     unless ( $ignoreSetLowestRank ) {
1678         $sth = $dbh->prepare( "SELECT reserve_id FROM reserves WHERE lowestPriority = 1 AND biblionumber = ? ORDER BY priority" );
1679         $sth->execute($biblionumber);
1680       while ( my $res = $sth->fetchrow_hashref() ) {
1681         _FixPriority({
1682             reserve_id => $res->{'reserve_id'},
1683             rank => '999999',
1684             ignoreSetLowestRank => 1
1685         });
1686       }
1687     }
1688 }
1689
1690 =head2 _Findgroupreserve
1691
1692   @results = &_Findgroupreserve($biblionumber, $itemnumber, $lookahead, $ignore_borrowers);
1693
1694 Looks for a holds-queue based item-specific match first, then for a holds-queue title-level match, returning the
1695 first match found.  If neither, then we look for non-holds-queue based holds.
1696 Lookahead is the number of days to look in advance.
1697
1698 C<&_Findgroupreserve> returns :
1699 C<@results> is an array of references-to-hash whose keys are mostly
1700 fields from the reserves table of the Koha database, plus
1701 C<biblioitemnumber>.
1702
1703 This routine with either return:
1704 1 - Item specific holds from the holds queue
1705 2 - Title level holds from the holds queue
1706 3 - All holds for this biblionumber
1707
1708 All return values will respect any borrowernumbers passed as arrayref in $ignore_borrowers
1709
1710 =cut
1711
1712 sub _Findgroupreserve {
1713     my ( $biblionumber, $itemnumber, $lookahead, $ignore_borrowers) = @_;
1714     my $dbh   = C4::Context->dbh;
1715
1716     # TODO: consolidate at least the SELECT portion of the first 2 queries to a common $select var.
1717     # check for exact targeted match
1718     my $item_level_target_query = qq{
1719         SELECT reserves.biblionumber        AS biblionumber,
1720                reserves.borrowernumber      AS borrowernumber,
1721                reserves.reservedate         AS reservedate,
1722                reserves.branchcode          AS branchcode,
1723                reserves.cancellationdate    AS cancellationdate,
1724                reserves.found               AS found,
1725                reserves.reservenotes        AS reservenotes,
1726                reserves.priority            AS priority,
1727                reserves.timestamp           AS timestamp,
1728                biblioitems.biblioitemnumber AS biblioitemnumber,
1729                reserves.itemnumber          AS itemnumber,
1730                reserves.reserve_id          AS reserve_id,
1731                reserves.itemtype            AS itemtype,
1732                reserves.non_priority        AS non_priority,
1733                reserves.item_group_id           AS item_group_id
1734         FROM reserves
1735         JOIN biblioitems USING (biblionumber)
1736         JOIN hold_fill_targets USING (reserve_id)
1737         WHERE found IS NULL
1738         AND priority > 0
1739         AND item_level_request = 1
1740         AND hold_fill_targets.itemnumber = ?
1741         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1742         AND suspend = 0
1743         ORDER BY priority
1744     };
1745     my $sth = $dbh->prepare($item_level_target_query);
1746     $sth->execute($itemnumber, $lookahead||0);
1747     my @results;
1748     if ( my $data = $sth->fetchrow_hashref ) {
1749         push( @results, $data )
1750           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1751     }
1752     return @results if @results;
1753
1754     # check for title-level targeted match
1755     my $title_level_target_query = qq{
1756         SELECT reserves.biblionumber        AS biblionumber,
1757                reserves.borrowernumber      AS borrowernumber,
1758                reserves.reservedate         AS reservedate,
1759                reserves.branchcode          AS branchcode,
1760                reserves.cancellationdate    AS cancellationdate,
1761                reserves.found               AS found,
1762                reserves.reservenotes        AS reservenotes,
1763                reserves.priority            AS priority,
1764                reserves.timestamp           AS timestamp,
1765                biblioitems.biblioitemnumber AS biblioitemnumber,
1766                reserves.itemnumber          AS itemnumber,
1767                reserves.reserve_id          AS reserve_id,
1768                reserves.itemtype            AS itemtype,
1769                reserves.non_priority        AS non_priority,
1770                reserves.item_group_id           AS item_group_id
1771         FROM reserves
1772         JOIN biblioitems USING (biblionumber)
1773         JOIN hold_fill_targets USING (reserve_id)
1774         LEFT JOIN item_group_items ON ( item_group_items.item_id = hold_fill_targets.itemnumber )
1775         WHERE found IS NULL
1776         AND priority > 0
1777         AND item_level_request = 0
1778         AND hold_fill_targets.itemnumber = ?
1779         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1780         AND suspend = 0
1781         AND reserves.item_group_id = item_group_items.item_group_id
1782         ORDER BY priority
1783     };
1784     $sth = $dbh->prepare($title_level_target_query);
1785     $sth->execute($itemnumber, $lookahead||0);
1786     @results = ();
1787     if ( my $data = $sth->fetchrow_hashref ) {
1788         push( @results, $data )
1789           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1790     }
1791     return @results if @results;
1792
1793     my $query = qq{
1794         SELECT reserves.biblionumber               AS biblionumber,
1795                reserves.borrowernumber             AS borrowernumber,
1796                reserves.reservedate                AS reservedate,
1797                reserves.waitingdate                AS waitingdate,
1798                reserves.branchcode                 AS branchcode,
1799                reserves.cancellationdate           AS cancellationdate,
1800                reserves.found                      AS found,
1801                reserves.reservenotes               AS reservenotes,
1802                reserves.priority                   AS priority,
1803                reserves.timestamp                  AS timestamp,
1804                reserves.itemnumber                 AS itemnumber,
1805                reserves.reserve_id                 AS reserve_id,
1806                reserves.itemtype                   AS itemtype,
1807                reserves.non_priority               AS non_priority,
1808                reserves.item_group_id              AS item_group_id
1809         FROM reserves
1810         WHERE reserves.biblionumber = ?
1811           AND (reserves.itemnumber IS NULL OR reserves.itemnumber = ?)
1812           AND reserves.reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1813           AND suspend = 0
1814           ORDER BY priority
1815     };
1816     $sth = $dbh->prepare($query);
1817     $sth->execute( $biblionumber, $itemnumber, $lookahead||0);
1818     @results = ();
1819     while ( my $data = $sth->fetchrow_hashref ) {
1820         push( @results, $data )
1821           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1822     }
1823     return @results;
1824 }
1825
1826 =head2 _koha_notify_reserve
1827
1828   _koha_notify_reserve( $hold->reserve_id );
1829
1830 Sends a notification to the patron that their hold has been filled (through
1831 ModReserveAffect)
1832
1833 The letter code for this notice may be found using the following query:
1834
1835     select distinct letter_code
1836     from message_transports
1837     inner join message_attributes using (message_attribute_id)
1838     where message_name = 'Hold_Filled'
1839
1840 This will probably sipmly be 'HOLD', but because it is defined in the database,
1841 it is subject to addition or change.
1842
1843 The following tables are availalbe witin the notice:
1844
1845     branches
1846     borrowers
1847     biblio
1848     biblioitems
1849     reserves
1850     items
1851
1852 =cut
1853
1854 sub _koha_notify_reserve {
1855     my $reserve_id = shift;
1856
1857     my $hold = Koha::Holds->find($reserve_id);
1858     my $borrowernumber = $hold->borrowernumber;
1859
1860     my $patron = Koha::Patrons->find( $borrowernumber );
1861
1862     # Try to get the borrower's email address
1863     my $to_address = $patron->notice_email_address;
1864
1865     my $messagingprefs = C4::Members::Messaging::GetMessagingPreferences( {
1866             borrowernumber => $borrowernumber,
1867             message_name => 'Hold_Filled'
1868     } );
1869
1870     my $library = Koha::Libraries->find( $hold->branchcode );
1871     my $from_email_address = $library->from_email_address;
1872
1873     my %letter_params = (
1874         module => 'reserves',
1875         branchcode => $hold->branchcode,
1876         lang => $patron->lang,
1877         tables => {
1878             'branches'       => $library->unblessed,
1879             'borrowers'      => $patron->unblessed,
1880             'biblio'         => $hold->biblionumber,
1881             'biblioitems'    => $hold->biblionumber,
1882             'reserves'       => $hold->unblessed,
1883             'items'          => $hold->itemnumber,
1884         },
1885     );
1886
1887     my $notification_sent = 0; #Keeping track if a Hold_filled message is sent. If no message can be sent, then default to a print message.
1888     my $send_notification = sub {
1889         my ( $mtt, $letter_code ) = (@_);
1890         return unless defined $letter_code;
1891         $letter_params{letter_code} = $letter_code;
1892         $letter_params{message_transport_type} = $mtt;
1893         my $letter =  C4::Letters::GetPreparedLetter ( %letter_params );
1894         unless ($letter) {
1895             warn "Could not find a letter called '$letter_params{'letter_code'}' for $mtt in the 'reserves' module";
1896             return;
1897         }
1898
1899         C4::Letters::EnqueueLetter( {
1900             letter => $letter,
1901             borrowernumber => $borrowernumber,
1902             from_address => $from_email_address,
1903             message_transport_type => $mtt,
1904         } );
1905     };
1906
1907     while ( my ( $mtt, $letter_code ) = each %{ $messagingprefs->{transports} } ) {
1908         next if (
1909                ( $mtt eq 'email' and not $to_address ) # No email address
1910             or ( $mtt eq 'sms'   and not $patron->smsalertnumber ) # No SMS number
1911             or ( $mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') ) # Notice is handled by TalkingTech_itiva_outbound.pl
1912             or ( $mtt eq 'phone' and not $patron->phone ) # No phone number to call
1913         );
1914
1915         &$send_notification($mtt, $letter_code);
1916         $notification_sent++;
1917     }
1918     #Making sure that a print notification is sent if no other transport types can be utilized.
1919     if (! $notification_sent) {
1920         &$send_notification('print', 'HOLD');
1921     }
1922
1923 }
1924
1925 =head2 _koha_notify_hold_changed
1926
1927   _koha_notify_hold_changed( $hold_object );
1928
1929 =cut
1930
1931 sub _koha_notify_hold_changed {
1932     my $hold = shift;
1933
1934     my $patron = $hold->patron;
1935     my $library = $hold->branch;
1936
1937     my $letter = C4::Letters::GetPreparedLetter(
1938         module      => 'reserves',
1939         letter_code => 'HOLD_CHANGED',
1940         branchcode  => $hold->branchcode,
1941         substitute  => { today => output_pref( dt_from_string ) },
1942         tables      => {
1943             'branches'    => $library->unblessed,
1944             'borrowers'   => $patron->unblessed,
1945             'biblio'      => $hold->biblionumber,
1946             'biblioitems' => $hold->biblionumber,
1947             'reserves'    => $hold->unblessed,
1948             'items'       => $hold->itemnumber,
1949         },
1950     );
1951
1952     return unless $letter;
1953
1954     my $email =
1955          C4::Context->preference('ExpireReservesAutoFillEmail')
1956       || $library->inbound_email_address;
1957
1958     C4::Letters::EnqueueLetter(
1959         {
1960             letter                 => $letter,
1961             borrowernumber         => $patron->id,
1962             message_transport_type => 'email',
1963             from_address           => $library->from_email_address,
1964             to_address             => $email,
1965         }
1966     );
1967 }
1968
1969 =head2 _ShiftPriority
1970
1971   $new_priority = _ShiftPriority( $biblionumber, $priority );
1972
1973 This increments the priority of all reserves after the one
1974 with either the lowest date after C<$reservedate>
1975 or the lowest priority after C<$priority>.
1976
1977 It effectively makes room for a new reserve to be inserted with a certain
1978 priority, which is returned.
1979
1980 This is most useful when the reservedate can be set by the user.  It allows
1981 the new reserve to be placed before other reserves that have a later
1982 reservedate.  Since priority also is set by the form in reserves/request.pl
1983 the sub accounts for that too.
1984
1985 =cut
1986
1987 sub _ShiftPriority {
1988     my ( $biblio, $new_priority ) = @_;
1989
1990     my $dbh = C4::Context->dbh;
1991     my $query = "SELECT priority FROM reserves WHERE biblionumber = ? AND priority > ? ORDER BY priority ASC LIMIT 1";
1992     my $sth = $dbh->prepare( $query );
1993     $sth->execute( $biblio, $new_priority );
1994     my $min_priority = $sth->fetchrow;
1995     # if no such matches are found, $new_priority remains as original value
1996     $new_priority = $min_priority if ( $min_priority );
1997
1998     # Shift the priority up by one; works in conjunction with the next SQL statement
1999     $query = "UPDATE reserves
2000               SET priority = priority+1
2001               WHERE biblionumber = ?
2002               AND borrowernumber = ?
2003               AND reservedate = ?
2004               AND found IS NULL";
2005     my $sth_update = $dbh->prepare( $query );
2006
2007     # Select all reserves for the biblio with priority greater than $new_priority, and order greatest to least
2008     $query = "SELECT borrowernumber, reservedate FROM reserves WHERE priority >= ? AND biblionumber = ? ORDER BY priority DESC";
2009     $sth = $dbh->prepare( $query );
2010     $sth->execute( $new_priority, $biblio );
2011     while ( my $row = $sth->fetchrow_hashref ) {
2012         $sth_update->execute( $biblio, $row->{borrowernumber}, $row->{reservedate} );
2013     }
2014
2015     return $new_priority;  # so the caller knows what priority they wind up receiving
2016 }
2017
2018 =head2 MoveReserve
2019
2020   MoveReserve( $itemnumber, $borrowernumber, $cancelreserve )
2021
2022 Use when checking out an item to handle reserves
2023 If $cancelreserve boolean is set to true, it will remove existing reserve
2024
2025 =cut
2026
2027 sub MoveReserve {
2028     my ( $itemnumber, $borrowernumber, $cancelreserve ) = @_;
2029
2030     $cancelreserve //= 0;
2031
2032     my $lookahead = C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2033     my $item = Koha::Items->find($itemnumber);
2034     my ( $restype, $res, undef ) = CheckReserves( $item, $lookahead );
2035     return unless $res;
2036
2037     my $biblionumber = $res->{biblionumber};
2038
2039     if ($res->{borrowernumber} == $borrowernumber) {
2040         my $hold = Koha::Holds->find( $res->{reserve_id} );
2041         $hold->fill({ item_id => $itemnumber });
2042     }
2043     else {
2044         # warn "Reserved";
2045         # The item is reserved by someone else.
2046         # Find this item in the reserves
2047
2048         my $borr_res  = Koha::Holds->search({
2049             borrowernumber => $borrowernumber,
2050             biblionumber   => $biblionumber,
2051         },{
2052             order_by       => 'priority'
2053         })->next();
2054
2055         if ( $borr_res ) {
2056             # The item is reserved by the current patron
2057             $borr_res->fill({ item_id => $itemnumber });
2058         }
2059
2060         if ( $cancelreserve eq 'revert' ) { ## Revert waiting reserve to priority 1
2061             RevertWaitingStatus({ itemnumber => $itemnumber });
2062         }
2063         elsif ( $cancelreserve eq 'cancel' || $cancelreserve ) { # cancel reserves on this item
2064             my $hold = Koha::Holds->find( $res->{reserve_id} );
2065             $hold->cancel;
2066         }
2067     }
2068 }
2069
2070 =head2 MergeHolds
2071
2072   MergeHolds($dbh,$to_biblio, $from_biblio);
2073
2074 This shifts the holds from C<$from_biblio> to C<$to_biblio> and reorders them by the date they were placed
2075
2076 =cut
2077
2078 sub MergeHolds {
2079     my ( $dbh, $to_biblio, $from_biblio ) = @_;
2080     my $sth = $dbh->prepare(
2081         "SELECT count(*) as reserve_count FROM reserves WHERE biblionumber = ?"
2082     );
2083     $sth->execute($from_biblio);
2084     if ( my $data = $sth->fetchrow_hashref() ) {
2085
2086         # holds exist on old record, if not we don't need to do anything
2087         $sth = $dbh->prepare(
2088             "UPDATE reserves SET biblionumber = ? WHERE biblionumber = ?");
2089         $sth->execute( $to_biblio, $from_biblio );
2090
2091         # Reorder by date
2092         # don't reorder those already waiting
2093
2094         $sth = $dbh->prepare(
2095 "SELECT * FROM reserves WHERE biblionumber = ? AND (found NOT IN ('W', 'T', 'P') OR found is NULL) ORDER BY reservedate ASC"
2096         );
2097         my $upd_sth = $dbh->prepare(
2098 "UPDATE reserves SET priority = ? WHERE biblionumber = ? AND borrowernumber = ?
2099         AND reservedate = ? AND (itemnumber = ? or itemnumber is NULL) "
2100         );
2101         $sth->execute( $to_biblio );
2102         my $priority = 1;
2103         while ( my $reserve = $sth->fetchrow_hashref() ) {
2104             $upd_sth->execute(
2105                 $priority,                    $to_biblio,
2106                 $reserve->{'borrowernumber'}, $reserve->{'reservedate'},
2107                 $reserve->{'itemnumber'}
2108             );
2109             $priority++;
2110         }
2111     }
2112 }
2113
2114 =head2 RevertWaitingStatus
2115
2116   RevertWaitingStatus({ itemnumber => $itemnumber });
2117
2118   Reverts a 'waiting' hold back to a regular hold with a priority of 1.
2119
2120   Caveat: Any waiting hold fixed with RevertWaitingStatus will be an
2121           item level hold, even if it was only a bibliolevel hold to
2122           begin with. This is because we can no longer know if a hold
2123           was item-level or bib-level after a hold has been set to
2124           waiting status.
2125
2126 =cut
2127
2128 sub RevertWaitingStatus {
2129     my ( $params ) = @_;
2130     my $itemnumber = $params->{'itemnumber'};
2131
2132     return unless ( $itemnumber );
2133
2134     my $dbh = C4::Context->dbh;
2135
2136     ## Get the waiting reserve we want to revert
2137     my $hold = Koha::Holds->search(
2138         {
2139             itemnumber => $itemnumber,
2140             found => { not => undef },
2141         }
2142     )->next;
2143
2144     ## Increment the priority of all other non-waiting
2145     ## reserves for this bib record
2146     my $holds = Koha::Holds->search({ biblionumber => $hold->biblionumber, priority => { '>' => 0 } })
2147                            ->update({ priority => \'priority + 1' }, { no_triggers => 1 });
2148
2149     ## Fix up the currently waiting reserve
2150     $hold->set(
2151         {
2152             priority    => 1,
2153             found       => undef,
2154             waitingdate => undef,
2155             expirationdate => $hold->patron_expiration_date,
2156             itemnumber  => $hold->item_level_hold ? $hold->itemnumber : undef,
2157         }
2158     )->store();
2159
2160     _FixPriority( { biblionumber => $hold->biblionumber } );
2161
2162     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2163         {
2164             biblio_ids => [ $hold->biblionumber ]
2165         }
2166     ) if C4::Context->preference('RealTimeHoldsQueue');
2167
2168
2169     return $hold;
2170 }
2171
2172 =head2 ReserveSlip
2173
2174 ReserveSlip(
2175     {
2176         branchcode     => $branchcode,
2177         borrowernumber => $borrowernumber,
2178         biblionumber   => $biblionumber,
2179         [ itemnumber   => $itemnumber, ]
2180         [ barcode      => $barcode, ]
2181     }
2182   )
2183
2184 Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
2185
2186 The letter code will be HOLD_SLIP, and the following tables are
2187 available within the slip:
2188
2189     reserves
2190     branches
2191     borrowers
2192     biblio
2193     biblioitems
2194     items
2195
2196 =cut
2197
2198 sub ReserveSlip {
2199     my ($args) = @_;
2200     my $branchcode     = $args->{branchcode};
2201     my $reserve_id = $args->{reserve_id};
2202
2203     my $hold = Koha::Holds->find($reserve_id);
2204     return unless $hold;
2205
2206     my $patron = $hold->borrower;
2207     my $reserve = $hold->unblessed;
2208
2209     return  C4::Letters::GetPreparedLetter (
2210         module => 'circulation',
2211         letter_code => 'HOLD_SLIP',
2212         branchcode => $branchcode,
2213         lang => $patron->lang,
2214         tables => {
2215             'reserves'    => $reserve,
2216             'branches'    => $reserve->{branchcode},
2217             'borrowers'   => $reserve->{borrowernumber},
2218             'biblio'      => $reserve->{biblionumber},
2219             'biblioitems' => $reserve->{biblionumber},
2220             'items'       => $reserve->{itemnumber},
2221         },
2222     );
2223 }
2224
2225 =head2 GetReservesControlBranch
2226
2227   my $reserves_control_branch = GetReservesControlBranch($item, $borrower);
2228
2229   Return the branchcode to be used to determine which reserves
2230   policy applies to a transaction.
2231
2232   C<$item> is a hashref for an item. Only 'homebranch' is used.
2233
2234   C<$borrower> is a hashref to borrower. Only 'branchcode' is used.
2235
2236 =cut
2237
2238 sub GetReservesControlBranch {
2239     my ( $item, $borrower ) = @_;
2240
2241     my $reserves_control = C4::Context->preference('ReservesControlBranch');
2242
2243     my $branchcode =
2244         ( $reserves_control eq 'ItemHomeLibrary' ) ? $item->{'homebranch'}
2245       : ( $reserves_control eq 'PatronLibrary' )   ? $borrower->{'branchcode'}
2246       :                                              undef;
2247
2248     return $branchcode;
2249 }
2250
2251 =head2 CalculatePriority
2252
2253     my $p = CalculatePriority($biblionumber, $resdate);
2254
2255 Calculate priority for a new reserve on biblionumber, placing it at
2256 the end of the line of all holds whose start date falls before
2257 the current system time and that are neither on the hold shelf
2258 or in transit.
2259
2260 The reserve date parameter is optional; if it is supplied, the
2261 priority is based on the set of holds whose start date falls before
2262 the parameter value.
2263
2264 After calculation of this priority, it is recommended to call
2265 _ShiftPriority. Note that this is currently done in
2266 AddReserves.
2267
2268 =cut
2269
2270 sub CalculatePriority {
2271     my ( $biblionumber, $resdate ) = @_;
2272
2273     my $sql = q{
2274         SELECT COUNT(*) FROM reserves
2275         WHERE biblionumber = ?
2276         AND   priority > 0
2277         AND   (found IS NULL OR found = '')
2278     };
2279     #skip found==W or found==T or found==P (waiting, transit or processing holds)
2280     if( $resdate ) {
2281         $sql.= ' AND ( reservedate <= ? )';
2282     }
2283     else {
2284         $sql.= ' AND ( reservedate < NOW() )';
2285     }
2286     my $dbh = C4::Context->dbh();
2287     my @row = $dbh->selectrow_array(
2288         $sql,
2289         undef,
2290         $resdate ? ($biblionumber, $resdate) : ($biblionumber)
2291     );
2292
2293     return @row ? $row[0]+1 : 1;
2294 }
2295
2296 =head2 IsItemOnHoldAndFound
2297
2298     my $bool = IsItemFoundHold( $itemnumber );
2299
2300     Returns true if the item is currently on hold
2301     and that hold has a non-null found status ( W, T, etc. )
2302
2303 =cut
2304
2305 sub IsItemOnHoldAndFound {
2306     my ($itemnumber) = @_;
2307
2308     my $rs = Koha::Database->new()->schema()->resultset('Reserve');
2309
2310     my $found = $rs->count(
2311         {
2312             itemnumber => $itemnumber,
2313             found      => { '!=' => undef }
2314         }
2315     );
2316
2317     return $found;
2318 }
2319
2320 =head2 GetMaxPatronHoldsForRecord
2321
2322 my $holds_per_record = ReservesControlBranch( $borrowernumber, $biblionumber );
2323
2324 For multiple holds on a given record for a given patron, the max
2325 number of record level holds that a patron can be placed is the highest
2326 value of the holds_per_record rule for each item if the record for that
2327 patron. This subroutine finds and returns the highest holds_per_record
2328 rule value for a given patron id and record id.
2329
2330 =cut
2331
2332 sub GetMaxPatronHoldsForRecord {
2333     my ( $borrowernumber, $biblionumber ) = @_;
2334
2335     my $patron = Koha::Patrons->find($borrowernumber);
2336     my @items = Koha::Items->search( { biblionumber => $biblionumber } )->as_list;
2337
2338     my $controlbranch = C4::Context->preference('ReservesControlBranch');
2339
2340     my $categorycode = $patron->categorycode;
2341     my $branchcode;
2342     $branchcode = $patron->branchcode if ( $controlbranch eq "PatronLibrary" );
2343
2344     my $max = 0;
2345     foreach my $item (@items) {
2346         my $itemtype = $item->effective_itemtype();
2347
2348         $branchcode = $item->homebranch if ( $controlbranch eq "ItemHomeLibrary" );
2349
2350         my $rule = Koha::CirculationRules->get_effective_rule({
2351             categorycode => $categorycode,
2352             itemtype     => $itemtype,
2353             branchcode   => $branchcode,
2354             rule_name    => 'holds_per_record'
2355         });
2356         my $holds_per_record = $rule ? $rule->rule_value : 0;
2357         $max = $holds_per_record if $holds_per_record > $max;
2358     }
2359
2360     return $max;
2361 }
2362
2363 =head1 AUTHOR
2364
2365 Koha Development Team <http://koha-community.org/>
2366
2367 =cut
2368
2369 1;