C4/Reserves.pm

   1 package C4::Reserves;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN Ouest Provence
   5 #           2007-2010 BibLibre Paul POULAIN
   6 #           2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 use Modern::Perl;
  25
  26 use C4::Accounts;
  27 use C4::Biblio qw( GetMarcFromKohaField );
  28 use C4::Circulation qw( CheckIfIssuedToPatron GetAgeRestriction GetBranchItemRule );
  29 use C4::Context;
  30 use C4::Items qw( CartToShelf get_hostitemnumbers_of );
  31 use C4::Letters;
  32 use C4::Log qw( logaction );
  33 use C4::Members::Messaging;
  34 use C4::Members;
  35 use Koha::Account::Lines;
  36 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  37 use Koha::Biblios;
  38 use Koha::Calendar;
  39 use Koha::Cache::Memory::Lite;
  40 use Koha::CirculationRules;
  41 use Koha::Database;
  42 use Koha::DateUtils qw( dt_from_string output_pref );
  43 use Koha::Holds;
  44 use Koha::ItemTypes;
  45 use Koha::Items;
  46 use Koha::Libraries;
  47 use Koha::Old::Holds;
  48 use Koha::Patrons;
  49 use Koha::Plugins;
  50 use Koha::Policy::Holds;
  51
  52 use List::MoreUtils qw( any );
  53
  54 =head1 NAME
  55
  56 C4::Reserves - Koha functions for dealing with reservation.
  57
  58 =head1 SYNOPSIS
  59
  60   use C4::Reserves;
  61
  62 =head1 DESCRIPTION
  63
  64 This modules provides somes functions to deal with reservations.
  65
  66   Reserves are stored in reserves table.
  67   The following columns contains important values :
  68   - priority >0      : then the reserve is at 1st stage, and not yet affected to any item.
  69              =0      : then the reserve is being dealed
  70   - found : NULL         : means the patron requested the 1st available, and we haven't chosen the item
  71             T(ransit)    : the reserve is linked to an item but is in transit to the pickup branch
  72             W(aiting)    : the reserve is linked to an item, is at the pickup branch, and is waiting on the hold shelf
  73             F(inished)   : the reserve has been completed, and is done
  74             P(rocessing) : reserved item has been returned using self-check machine and reserve needs to be confirmed
  75                            by librarian before notice is send and status changed to waiting.
  76                            Applicable only if HoldsNeedProcessingSIP system preference is set.
  77   - itemnumber : empty : the reserve is still unaffected to an item
  78                  filled: the reserve is attached to an item
  79   The complete workflow is :
  80   ==== 1st use case ====
  81   patron request a document, 1st available :                      P >0, F=NULL, I=NULL
  82   a library having it run "transfertodo", and clic on the list
  83          if there is no transfer to do, the reserve waiting
  84          patron can pick it up                                    P =0, F=W,    I=filled
  85          if there is a transfer to do, write in branchtransfer    P =0, F=T,    I=filled
  86            The pickup library receive the book, it check in       P =0, F=W,    I=filled
  87   The patron borrow the book                                      P =0, F=F,    I=filled
  88
  89   ==== 2nd use case ====
  90   patron requests a document, a given item,
  91     If pickup is holding branch                                   P =0, F=W,   I=filled
  92     If transfer needed, write in branchtransfer                   P =0, F=T,    I=filled
  93         The pickup library receive the book, it checks it in      P =0, F=W,    I=filled
  94   The patron borrow the book                                      P =0, F=F,    I=filled
  95
  96 =head1 FUNCTIONS
  97
  98 =cut
  99
 100 our (@ISA, @EXPORT_OK);
 101 BEGIN {
 102     require Exporter;
 103     @ISA = qw(Exporter);
 104     @EXPORT_OK = qw(
 105       AddReserve
 106
 107       GetReserveStatus
 108
 109       ChargeReserveFee
 110       GetReserveFee
 111
 112       ModReserveAffect
 113       ModReserve
 114       ModReserveStatus
 115       ModReserveCancelAll
 116       ModReserveMinusPriority
 117       MoveReserve
 118
 119       CheckReserves
 120       CanBookBeReserved
 121       CanItemBeReserved
 122       CanReserveBeCanceledFromOpac
 123       CancelExpiredReserves
 124
 125       AutoUnsuspendReserves
 126
 127       IsAvailableForItemLevelRequest
 128       ItemsAnyAvailableAndNotRestricted
 129
 130       AlterPriority
 131       ToggleLowestPriority
 132
 133       ReserveSlip
 134       ToggleSuspend
 135       SuspendAll
 136
 137       CalculatePriority
 138
 139       IsItemOnHoldAndFound
 140
 141       GetMaxPatronHoldsForRecord
 142
 143       MergeHolds
 144
 145       RevertWaitingStatus
 146     );
 147 }
 148
 149 =head2 AddReserve
 150
 151     AddReserve(
 152         {
 153             branchcode       => $branchcode,
 154             borrowernumber   => $borrowernumber,
 155             biblionumber     => $biblionumber,
 156             priority         => $priority,
 157             reservation_date => $reservation_date,
 158             expiration_date  => $expiration_date,
 159             notes            => $notes,
 160             title            => $title,
 161             itemnumber       => $itemnumber,
 162             found            => $found,
 163             itemtype         => $itemtype,
 164             item_group_id    => $item_group_id
 165         }
 166     );
 167
 168 Adds reserve and generates HOLDPLACED message and HOLDPLACED_PATRON message.
 169
 170 The following tables are available witin the HOLDPLACED message:
 171
 172     branches
 173     borrowers
 174     biblio
 175     biblioitems
 176     items
 177     reserves
 178
 179 The following tables are available within the HOLDPLACED_PATRON message:
 180
 181     borrowers
 182     reserves
 183
 184 =cut
 185
 186 sub AddReserve {
 187     my ($params)       = @_;
 188     my $branch         = $params->{branchcode};
 189     my $borrowernumber = $params->{borrowernumber};
 190     my $biblionumber   = $params->{biblionumber};
 191     my $priority       = $params->{priority};
 192     my $resdate        = $params->{reservation_date};
 193     my $patron_expiration_date = $params->{expiration_date};
 194     my $notes          = $params->{notes};
 195     my $title          = $params->{title};
 196     my $checkitem      = $params->{itemnumber};
 197     my $found          = $params->{found};
 198     my $itemtype       = $params->{itemtype};
 199     my $non_priority   = $params->{non_priority};
 200     my $item_group_id  = $params->{item_group_id};
 201
 202     $resdate ||= dt_from_string;
 203
 204     # if we have an item selectionned, and the pickup branch is the same as the holdingbranch
 205     # of the document, we force the value $priority and $found .
 206     if ( $checkitem and not C4::Context->preference('ReservesNeedReturns') ) {
 207         my $item = Koha::Items->find( $checkitem ); # FIXME Prevent bad calls
 208
 209         if (
 210             # If item is already checked out, it cannot be set waiting
 211             !$item->onloan
 212
 213             # The item can't be waiting if it needs a transfer
 214             && $item->holdingbranch eq $branch
 215
 216             # Similarly, if in transit it can't be waiting
 217             && !$item->get_transfer
 218
 219             # If we can't hold damaged items, and it is damaged, it can't be waiting
 220             && ( $item->damaged && C4::Context->preference('AllowHoldsOnDamagedItems') || !$item->damaged )
 221
 222             # Lastly, if this already has holds, we shouldn't make it waiting for the new hold
 223             && !$item->current_holds->count )
 224         {
 225             $priority = 0;
 226             $found = 'W';
 227         }
 228     }
 229     if ( C4::Context->preference( 'AllowHoldDateInFuture' ) ) {
 230     # Make room in reserves for this if passed a priority
 231     $priority = _ShiftPriority( $biblionumber, $priority );
 232     }
 233
 234     my $waitingdate;
 235
 236     # If the reserv had the waiting status, we had the value of the resdate
 237     if ( $found && $found eq 'W' ) {
 238         $waitingdate = $resdate;
 239     }
 240
 241     # Don't add itemtype limit if specific item is selected
 242     $itemtype = undef if $checkitem;
 243
 244     # updates take place here
 245     my $hold = Koha::Hold->new(
 246         {
 247             borrowernumber => $borrowernumber,
 248             biblionumber   => $biblionumber,
 249             item_group_id  => $item_group_id,
 250             reservedate    => $resdate,
 251             branchcode     => $branch,
 252             priority       => $priority,
 253             reservenotes   => $notes,
 254             itemnumber     => $checkitem,
 255             found          => $found,
 256             waitingdate    => $waitingdate,
 257             patron_expiration_date => $patron_expiration_date,
 258             itemtype       => $itemtype,
 259             item_level_hold => $checkitem ? 1 : 0,
 260             non_priority   => $non_priority ? 1 : 0,
 261         }
 262     )->store();
 263     $hold->set_waiting() if $found && $found eq 'W';
 264
 265     # record patron activity
 266     $hold->patron->update_lastseen('hold');
 267
 268     logaction( 'HOLDS', 'CREATE', $hold->id, $hold )
 269         if C4::Context->preference('HoldsLog');
 270
 271     my $reserve_id = $hold->id();
 272
 273     # add a reserve fee if needed
 274     if ( C4::Context->preference('HoldFeeMode') ne 'any_time_is_collected' ) {
 275         my $reserve_fee = GetReserveFee( $borrowernumber, $biblionumber );
 276         ChargeReserveFee( $borrowernumber, $reserve_fee, $title );
 277     }
 278
 279     _FixPriority({ biblionumber => $biblionumber});
 280
 281     # Send e-mail to librarian if syspref is active
 282     if(C4::Context->preference("emailLibrarianWhenHoldIsPlaced")){
 283         my $patron = $hold->patron;
 284         my $library = $patron->library;
 285         if ( my $letter =  C4::Letters::GetPreparedLetter (
 286             module => 'reserves',
 287             letter_code => 'HOLDPLACED',
 288             branchcode => $branch,
 289             lang => $patron->lang,
 290             tables => {
 291                 'branches'    => $library->unblessed,
 292                 'borrowers'   => $patron->unblessed,
 293                 'biblio'      => $biblionumber,
 294                 'biblioitems' => $biblionumber,
 295                 'items'       => $checkitem,
 296                 'reserves'    => $hold->unblessed,
 297             },
 298         ) ) {
 299
 300             my $branch_email_address = $library->inbound_email_address;
 301
 302             C4::Letters::EnqueueLetter(
 303                 {
 304                     letter                 => $letter,
 305                     borrowernumber         => $borrowernumber,
 306                     message_transport_type => 'email',
 307                     to_address             => $branch_email_address,
 308                 }
 309             );
 310         }
 311     }
 312
 313     # Send email to patron if syspref is active
 314     if ( C4::Context->preference("EmailPatronWhenHoldIsPlaced") ) {
 315         my $patron = $hold->patron;
 316         if (
 317             my $letter = C4::Letters::GetPreparedLetter(
 318                 module      => 'reserves',
 319                 letter_code => 'HOLDPLACED_PATRON',
 320                 branchcode  => $branch,
 321                 lang        => $patron->lang,
 322                 tables      => {
 323                     borrowers => $patron->unblessed,
 324                     reserves  => $hold->unblessed,
 325                 },
 326             )
 327             )
 328         {
 329             C4::Letters::EnqueueLetter(
 330                 {
 331                     letter                 => $letter,
 332                     borrowernumber         => $borrowernumber,
 333                     message_transport_type => 'email',
 334                     to_address             => $patron->notice_email_address,
 335                 }
 336             );
 337         }
 338     }
 339
 340     Koha::Plugins->call('after_hold_create', $hold);
 341     Koha::Plugins->call(
 342         'after_hold_action',
 343         {
 344             action  => 'place',
 345             payload => { hold => $hold->get_from_storage }
 346         }
 347     );
 348
 349     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 350         {
 351             biblio_ids => [ $biblionumber ]
 352         }
 353     ) if C4::Context->preference('RealTimeHoldsQueue');
 354
 355     return $reserve_id;
 356 }
 357
 358 =head2 CanBookBeReserved
 359
 360   $canReserve = &CanBookBeReserved($borrowernumber, $biblionumber, $branchcode, $params)
 361   if ($canReserve eq 'OK') { #We can reserve this Item! }
 362
 363   $params are passed directly through to CanItemBeReserved
 364
 365 See CanItemBeReserved() for possible return values.
 366
 367 =cut
 368
 369 sub CanBookBeReserved{
 370     my ($borrowernumber, $biblionumber, $pickup_branchcode, $params) = @_;
 371
 372     # Check that patron have not checked out this biblio (if AllowHoldsOnPatronsPossessions set)
 373     if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 374         && C4::Circulation::CheckIfIssuedToPatron( $borrowernumber, $biblionumber ) ) {
 375         return { status =>'alreadypossession' };
 376     }
 377
 378     if ( $params->{itemtype} ) {
 379
 380         # biblio-level, item type-contrained
 381         my $patron          = Koha::Patrons->find($borrowernumber);
 382         my $reservesallowed = Koha::CirculationRules->get_effective_rule(
 383             {
 384                 itemtype     => $params->{itemtype},
 385                 categorycode => $patron->categorycode,
 386                 branchcode   => $pickup_branchcode,
 387                 rule_name    => 'reservesallowed',
 388             }
 389         )->rule_value;
 390
 391         $reservesallowed = ( $reservesallowed eq '' ) ? undef : $reservesallowed;
 392
 393         my $count = $patron->holds->search(
 394             {
 395                 '-or' => [
 396                     { 'me.itemtype' => $params->{itemtype} },
 397                     { 'item.itype'  => $params->{itemtype} }
 398                 ]
 399             },
 400             {
 401                 join => ['item']
 402             }
 403         )->count;
 404
 405         return { status => '' }
 406           if defined $reservesallowed and $reservesallowed < $count + 1;
 407     }
 408
 409     my $items;
 410     #get items linked via host records
 411     my @hostitemnumbers = get_hostitemnumbers_of($biblionumber);
 412     if (@hostitemnumbers){
 413         $items = Koha::Items->search({
 414             -or => [
 415                 biblionumber => $biblionumber,
 416                 itemnumber => { -in => @hostitemnumbers }
 417             ]
 418         });
 419     } else {
 420         $items = Koha::Items->search({ biblionumber => $biblionumber});
 421     }
 422
 423     my $canReserve = { status => '' };
 424     my $patron = Koha::Patrons->find( $borrowernumber );
 425     while ( my $item = $items->next ) {
 426         $canReserve = CanItemBeReserved( $patron, $item, $pickup_branchcode, $params );
 427         return { status => 'OK' } if $canReserve->{status} eq 'OK';
 428     }
 429     return $canReserve;
 430 }
 431
 432 =head2 CanItemBeReserved
 433
 434   $canReserve = &CanItemBeReserved($patron, $item, $branchcode, $params)
 435   if ($canReserve->{status} eq 'OK') { #We can reserve this Item! }
 436
 437   current params are:
 438   'ignore_hold_counts' - we use this routine to check if an item can fill a hold - on this case we
 439   should not check if there are too many holds as we only care about reservability
 440
 441 @RETURNS { status => OK },              if the Item can be reserved.
 442          { status => ageRestricted },   if the Item is age restricted for this borrower.
 443          { status => damaged },         if the Item is damaged.
 444          { status => cannotReserveFromOtherBranches }, if syspref 'canreservefromotherbranches' is OK.
 445          { status => branchNotInHoldGroup }, if borrower home library is not in hold group, and holds are only allowed from hold groups.
 446          { status => tooManyReserves, limit => $limit }, if the borrower has exceeded their maximum reserve amount.
 447          { status => notReservable },   if holds on this item are not allowed
 448          { status => libraryNotFound },   if given branchcode is not an existing library
 449          { status => libraryNotPickupLocation },   if given branchcode is not configured to be a pickup location
 450          { status => cannotBeTransferred }, if branch transfer limit applies on given item and branchcode
 451          { status => pickupNotInHoldGroup }, pickup location is not in hold group, and pickup locations are only allowed from hold groups.
 452          { status => recall }, if the borrower has already placed a recall on this item
 453
 454 =cut
 455
 456 our $CanItemBeReserved_cache_key;
 457 sub _cache {
 458     my ( $return )  = @_;
 459     my $memory_cache = Koha::Cache::Memory::Lite->get_instance();
 460     $memory_cache->set_in_cache( $CanItemBeReserved_cache_key, $return );
 461     return $return;
 462 }
 463
 464 sub CanItemBeReserved {
 465     my ( $patron, $item, $pickup_branchcode, $params ) = @_;
 466
 467     my $memory_cache = Koha::Cache::Memory::Lite->get_instance();
 468     $CanItemBeReserved_cache_key = sprintf "Hold_CanItemBeReserved:%s:%s:%s", $patron->borrowernumber, $item->itemnumber, $pickup_branchcode || "";
 469     if ( $params->{get_from_cache} ) {
 470         my $cached = $memory_cache->get_from_cache($CanItemBeReserved_cache_key);
 471         return $cached if $cached;
 472     }
 473
 474     my $dbh = C4::Context->dbh;
 475     my $ruleitemtype;    # itemtype of the matching issuing rule
 476     my $allowedreserves  = 0; # Total number of holds allowed across all records, default to none
 477
 478     # We check item branch if IndependentBranches is ON
 479     # and canreservefromotherbranches is OFF
 480     if ( C4::Context->preference('IndependentBranches')
 481         and !C4::Context->preference('canreservefromotherbranches') )
 482     {
 483         if ( $item->homebranch ne $patron->branchcode ) {
 484             return _cache { status => 'cannotReserveFromOtherBranches' };
 485         }
 486     }
 487
 488     # we retrieve borrowers and items informations #
 489     # item->{itype} will come for biblioitems if necessery
 490     my $borrower = $patron->unblessed;
 491
 492     # If an item is damaged and we don't allow holds on damaged items, we can stop right here
 493     return _cache { status =>'damaged' }
 494       if ( $item->damaged
 495         && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 496
 497     if( GetMarcFromKohaField('biblioitems.agerestriction') ){
 498         my $biblio = $item->biblio;
 499         # Check for the age restriction
 500         my ( $ageRestriction, $daysToAgeRestriction ) =
 501           C4::Circulation::GetAgeRestriction( $biblio->biblioitem->agerestriction, $borrower );
 502         return _cache { status => 'ageRestricted' } if $daysToAgeRestriction && $daysToAgeRestriction > 0;
 503     }
 504
 505     # Check that the patron doesn't have an item level hold on this item already
 506     return _cache { status =>'itemAlreadyOnHold' }
 507       if ( !$params->{ignore_hold_counts} && Koha::Holds->search( { borrowernumber => $patron->borrowernumber, itemnumber => $item->itemnumber } )->count() );
 508
 509     # Check that patron have not checked out this biblio (if AllowHoldsOnPatronsPossessions set)
 510     if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 511         && C4::Circulation::CheckIfIssuedToPatron( $patron->borrowernumber, $item->biblionumber ) ) {
 512         return _cache { status =>'alreadypossession' };
 513     }
 514
 515     # check if a recall exists on this item from this borrower
 516     return _cache { status => 'recall' }
 517       if $patron->recalls->filter_by_current->search({ item_id => $item->itemnumber })->count;
 518
 519     my $controlbranch = C4::Context->preference('ReservesControlBranch');
 520
 521     my $reserves_control_branch;
 522     my $branchfield = "reserves.branchcode";
 523
 524     if ( $controlbranch eq "ItemHomeLibrary" ) {
 525         $branchfield = "items.homebranch";
 526         $reserves_control_branch  = $item->homebranch;
 527     }
 528     elsif ( $controlbranch eq "PatronLibrary" ) {
 529         $branchfield = "borrowers.branchcode";
 530         $reserves_control_branch  = $borrower->{branchcode};
 531     }
 532
 533     # we retrieve rights
 534     if (
 535         my $reservesallowed = Koha::CirculationRules->get_effective_rule({
 536                 itemtype     => $item->effective_itemtype,
 537                 categorycode => $borrower->{categorycode},
 538                 branchcode   => $reserves_control_branch,
 539                 rule_name    => 'reservesallowed',
 540         })
 541     ) {
 542         $ruleitemtype     = $reservesallowed->itemtype;
 543         $allowedreserves  = $reservesallowed->rule_value // 0; #undefined is 0, blank is unlimited
 544     }
 545     else {
 546         $ruleitemtype = undef;
 547     }
 548
 549     my $rights = Koha::CirculationRules->get_effective_rules({
 550         categorycode => $borrower->{'categorycode'},
 551         itemtype     => $item->effective_itemtype,
 552         branchcode   => $reserves_control_branch,
 553         rules        => ['holds_per_record','holds_per_day']
 554     });
 555     my $holds_per_record = $rights->{holds_per_record} // 1;
 556     my $holds_per_day    = $rights->{holds_per_day};
 557
 558     if (   defined $holds_per_record && $holds_per_record ne '' ){
 559         if ( $holds_per_record == 0 ) {
 560             return _cache { status => "noReservesAllowed" };
 561         }
 562         if ( !$params->{ignore_hold_counts} ) {
 563             my $search_params = {
 564                 borrowernumber => $patron->borrowernumber,
 565                 biblionumber   => $item->biblionumber,
 566             };
 567             my $holds = Koha::Holds->search($search_params);
 568             return _cache { status => "tooManyHoldsForThisRecord", limit => $holds_per_record } if $holds->count() >= $holds_per_record;
 569         }
 570     }
 571
 572     if (!$params->{ignore_hold_counts} && defined $holds_per_day && $holds_per_day ne '')
 573     {
 574         my $today_holds = Koha::Holds->search({
 575             borrowernumber => $patron->borrowernumber,
 576             reservedate    => dt_from_string->date
 577         });
 578         return _cache { status => 'tooManyReservesToday', limit => $holds_per_day } if $today_holds->count() >= $holds_per_day;
 579     }
 580
 581     # we check if it's ok or not
 582     if ( defined $allowedreserves && $allowedreserves ne '' ){
 583         if( $allowedreserves == 0 ){
 584             return _cache { status => 'noReservesAllowed' };
 585         }
 586         if ( !$params->{ignore_hold_counts} ) {
 587             # we retrieve count
 588             my $querycount = q{
 589                 SELECT count(*) AS count
 590                   FROM reserves
 591              LEFT JOIN items USING (itemnumber)
 592              LEFT JOIN biblioitems ON (reserves.biblionumber=biblioitems.biblionumber)
 593              LEFT JOIN borrowers USING (borrowernumber)
 594                  WHERE borrowernumber = ?
 595             };
 596             $querycount .= "AND ( $branchfield = ? OR $branchfield IS NULL )";
 597
 598             # If using item-level itypes, fall back to the record
 599             # level itemtype if the hold has no associated item
 600             if ( defined $ruleitemtype ) {
 601                 if ( C4::Context->preference('item-level_itypes') ) {
 602                     $querycount .= q{
 603                         AND ( COALESCE( items.itype, biblioitems.itemtype ) = ?
 604                            OR reserves.itemtype = ? )
 605                     };
 606                 }
 607                 else {
 608                     $querycount .= q{
 609                         AND ( biblioitems.itemtype = ?
 610                            OR reserves.itemtype = ? )
 611                     };
 612                 }
 613             }
 614
 615             my $sthcount = $dbh->prepare($querycount);
 616
 617             if ( defined $ruleitemtype ) {
 618                 $sthcount->execute( $patron->borrowernumber, $reserves_control_branch, $ruleitemtype, $ruleitemtype );
 619             }
 620             else {
 621                 $sthcount->execute( $patron->borrowernumber, $reserves_control_branch );
 622             }
 623
 624             my $reservecount = "0";
 625             if ( my $rowcount = $sthcount->fetchrow_hashref() ) {
 626                 $reservecount = $rowcount->{count};
 627             }
 628
 629             return _cache { status => 'tooManyReserves', limit => $allowedreserves } if $reservecount >= $allowedreserves;
 630         }
 631     }
 632
 633     # Now we need to check hold limits by patron category
 634     my $rule = Koha::CirculationRules->get_effective_rule(
 635         {
 636             categorycode => $patron->categorycode,
 637             branchcode   => $reserves_control_branch,
 638             rule_name    => 'max_holds',
 639         }
 640     );
 641     if (!$params->{ignore_hold_counts} && $rule && defined( $rule->rule_value ) && $rule->rule_value ne '' ) {
 642         my $total_holds_count = Koha::Holds->search(
 643             {
 644                 borrowernumber => $patron->borrowernumber
 645             }
 646         )->count();
 647
 648         return _cache { status => 'tooManyReserves', limit => $rule->rule_value} if $total_holds_count >= $rule->rule_value;
 649     }
 650
 651     my $branchitemrule =
 652       C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->effective_itemtype );
 653
 654     if ( $branchitemrule->{holdallowed} eq 'not_allowed' ) {
 655         return _cache { status => 'notReservable' };
 656     }
 657
 658     if (   $branchitemrule->{holdallowed} eq 'from_home_library'
 659         && $borrower->{branchcode} ne $item->homebranch )
 660     {
 661         return _cache { status => 'cannotReserveFromOtherBranches' };
 662     }
 663
 664     my $item_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
 665     if ( $branchitemrule->{holdallowed} eq 'from_local_hold_group') {
 666         if($patron->branchcode ne $item->homebranch && !$item_library->validate_hold_sibling( {branchcode => $patron->branchcode} )) {
 667             return _cache { status => 'branchNotInHoldGroup' };
 668         }
 669     }
 670
 671     if ($pickup_branchcode) {
 672         my $destination = Koha::Libraries->find({
 673             branchcode => $pickup_branchcode,
 674         });
 675
 676         unless ($destination) {
 677             return _cache { status => 'libraryNotFound' };
 678         }
 679         unless ($destination->pickup_location) {
 680             return _cache { status => 'libraryNotPickupLocation' };
 681         }
 682         unless ($item->can_be_transferred({ to => $destination })) {
 683             return _cache { status => 'cannotBeTransferred' };
 684         }
 685         if ($branchitemrule->{hold_fulfillment_policy} eq 'holdgroup' && !$item_library->validate_hold_sibling( {branchcode => $pickup_branchcode} )) {
 686             return _cache { status => 'pickupNotInHoldGroup' };
 687         }
 688         if ($branchitemrule->{hold_fulfillment_policy} eq 'patrongroup' && !Koha::Libraries->find({branchcode => $borrower->{branchcode}})->validate_hold_sibling({branchcode => $pickup_branchcode})) {
 689             return _cache { status => 'pickupNotInHoldGroup' };
 690         }
 691     }
 692
 693     return _cache { status => 'OK' };
 694 }
 695
 696 =head2 CanReserveBeCanceledFromOpac
 697
 698     $number = CanReserveBeCanceledFromOpac($reserve_id, $borrowernumber);
 699
 700     returns 1 if reserve can be cancelled by user from OPAC.
 701     First check if reserve belongs to user, next checks if reserve is not in
 702     transfer or waiting status
 703
 704 =cut
 705
 706 sub CanReserveBeCanceledFromOpac {
 707     my ($reserve_id, $borrowernumber) = @_;
 708
 709     return unless $reserve_id and $borrowernumber;
 710     my $reserve = Koha::Holds->find($reserve_id) or return;
 711
 712     return 0 unless $reserve->borrowernumber == $borrowernumber;
 713     return $reserve->is_cancelable_from_opac;
 714 }
 715
 716 =head2 ChargeReserveFee
 717
 718     $fee = ChargeReserveFee( $borrowernumber, $fee, $title );
 719
 720     Charge the fee for a reserve (if $fee > 0)
 721
 722 =cut
 723
 724 sub ChargeReserveFee {
 725     my ( $borrowernumber, $fee, $title ) = @_;
 726     return if !$fee || $fee == 0;    # the last test is needed to include 0.00
 727     Koha::Account->new( { patron_id => $borrowernumber } )->add_debit(
 728         {
 729             amount       => $fee,
 730             description  => $title,
 731             note         => undef,
 732             user_id      => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 733             library_id   => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 734             interface    => C4::Context->interface,
 735             invoice_type => undef,
 736             type         => 'RESERVE',
 737             item_id      => undef
 738         }
 739     );
 740 }
 741
 742 =head2 GetReserveFee
 743
 744     $fee = GetReserveFee( $borrowernumber, $biblionumber );
 745
 746     Calculate the fee for a reserve (if applicable).
 747
 748 =cut
 749
 750 sub GetReserveFee {
 751     my ( $borrowernumber, $biblionumber ) = @_;
 752     my $borquery = qq{
 753 SELECT reservefee FROM borrowers LEFT JOIN categories ON borrowers.categorycode = categories.categorycode WHERE borrowernumber = ?
 754     };
 755     my $issue_qry = qq{
 756 SELECT COUNT(*) FROM items
 757 LEFT JOIN issues USING (itemnumber)
 758 WHERE items.biblionumber=? AND issues.issue_id IS NULL
 759     };
 760     my $holds_qry = qq{
 761 SELECT COUNT(*) FROM reserves WHERE biblionumber=? AND borrowernumber<>?
 762     };
 763
 764     my $dbh = C4::Context->dbh;
 765     my ( $fee ) = $dbh->selectrow_array( $borquery, undef, ($borrowernumber) );
 766     $fee += 0;
 767     my $hold_fee_mode = C4::Context->preference('HoldFeeMode') || 'not_always';
 768     if( $fee and $fee > 0 and $hold_fee_mode eq 'not_always' ) {
 769         # This is a reconstruction of the old code:
 770         # Compare number of items with items issued, and optionally check holds
 771         # If not all items are issued and there are no holds: charge no fee
 772         # NOTE: Lost, damaged, not-for-loan, etc. are just ignored here
 773         my ( $notissued, $reserved );
 774         ( $notissued ) = $dbh->selectrow_array( $issue_qry, undef,
 775             ( $biblionumber ) );
 776         if( $notissued == 0 ) {
 777             # all items are issued
 778             ( $reserved ) = $dbh->selectrow_array( $holds_qry, undef,
 779                 ( $biblionumber, $borrowernumber ) );
 780             $fee = 0 if $reserved == 0;
 781         } else {
 782             $fee = 0;
 783         }
 784     }
 785     return $fee;
 786 }
 787
 788 =head2 GetReserveStatus
 789
 790   $reservestatus = GetReserveStatus($itemnumber);
 791
 792 Takes an itemnumber and returns the status of the reserve placed on it.
 793 If several reserves exist, the reserve with the lower priority is given.
 794
 795 =cut
 796
 797 ## FIXME: I don't think this does what it thinks it does.
 798 ## It only ever checks the first reserve result, even though
 799 ## multiple reserves for that bib can have the itemnumber set
 800 ## the sub is only used once in the codebase.
 801 sub GetReserveStatus {
 802     my ($itemnumber) = @_;
 803
 804     my $dbh = C4::Context->dbh;
 805
 806     my ($sth, $found, $priority);
 807     if ( $itemnumber ) {
 808         $sth = $dbh->prepare("SELECT found, priority FROM reserves WHERE itemnumber = ? order by priority LIMIT 1");
 809         $sth->execute($itemnumber);
 810         ($found, $priority) = $sth->fetchrow_array;
 811     }
 812
 813     if(defined $found) {
 814         return 'Waiting'  if $found eq 'W' and $priority == 0;
 815         return 'Processing'  if $found eq 'P';
 816         return 'Finished' if $found eq 'F';
 817     }
 818
 819     return 'Reserved' if defined $priority && $priority > 0;
 820
 821     return ''; # empty string here will remove need for checking undef, or less log lines
 822 }
 823
 824 =head2 CheckReserves
 825
 826   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($item);
 827   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($item, $lookahead);
 828
 829 Find a book in the reserves.
 830
 831 C<$item> is the book's item.
 832 C<$lookahead> is the number of days to look in advance for future reserves.
 833
 834 As I understand it, C<&CheckReserves> looks for the given item in the
 835 reserves. If it is found, that's a match, and C<$status> is set to
 836 C<Waiting>.
 837
 838 Otherwise, it finds the most important item in the reserves with the
 839 same biblio number as this book (I'm not clear on this) and returns it
 840 with C<$status> set to C<Reserved>.
 841
 842 C<&CheckReserves> returns a two-element list:
 843
 844 C<$status> is either C<Waiting>, C<Reserved> (see above), or 0.
 845
 846 C<$reserve> is the reserve item that matched. It is a
 847 reference-to-hash whose keys are mostly the fields of the reserves
 848 table in the Koha database.
 849
 850 =cut
 851
 852 sub CheckReserves {
 853     my ( $item, $lookahead_days, $ignore_borrowers ) = @_;
 854     # note: we get the itemnumber because we might have started w/ just the barcode.  Now we know for sure we have it.
 855
 856     return unless $item; # bail if we got nothing.
 857
 858     return if ( $item->damaged && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 859
 860     # if item is not for loan it cannot be reserved either.....
 861     # except where items.notforloan < 0 :  This indicates the item is holdable.
 862
 863     my @SkipHoldTrapOnNotForLoanValue = split( '\|', C4::Context->preference('SkipHoldTrapOnNotForLoanValue') );
 864     return if grep { $_ eq $item->notforloan } @SkipHoldTrapOnNotForLoanValue;
 865
 866     my $dont_trap = C4::Context->preference('TrapHoldsOnOrder') ? $item->notforloan > 0 : $item->notforloan;
 867     if ( !$dont_trap ) {
 868         my $item_type = $item->effective_itemtype;
 869         if ( $item_type ) {
 870             return if Koha::ItemTypes->find( $item_type )->notforloan;
 871         }
 872     }
 873     else {
 874         return;
 875     }
 876
 877     # Find this item in the reserves
 878     my @reserves = _Findgroupreserve( $item->biblionumber, $item->itemnumber, $lookahead_days, $ignore_borrowers);
 879
 880     # $priority and $highest are used to find the most important item
 881     # in the list returned by &_Findgroupreserve. (The lower $priority,
 882     # the more important the item.)
 883     # $highest is the most important item we've seen so far.
 884     my $highest;
 885
 886     if (scalar @reserves) {
 887         my $LocalHoldsPriority = C4::Context->preference('LocalHoldsPriority');
 888         my $LocalHoldsPriorityPatronControl = C4::Context->preference('LocalHoldsPriorityPatronControl');
 889         my $LocalHoldsPriorityItemControl = C4::Context->preference('LocalHoldsPriorityItemControl');
 890         my $priority = 10000000;
 891
 892         foreach my $res (@reserves) {
 893             if ($res->{'found'} && $res->{'found'} eq 'W') {
 894                 return ( "Waiting", $res, \@reserves ); # Found it, it is waiting
 895             } elsif ($res->{'found'} && $res->{'found'} eq 'P') {
 896                 return ( "Processing", $res, \@reserves ); # Found determinated hold, e. g. the transferred one
 897             } elsif ($res->{'found'} && $res->{'found'} eq 'T') {
 898                 return ( "Transferred", $res, \@reserves ); # Found determinated hold, e. g. the transferred one
 899             } else {
 900                 my $patron;
 901                 my $local_hold_match;
 902
 903                 if ($LocalHoldsPriority) {
 904                     $patron = Koha::Patrons->find( $res->{borrowernumber} );
 905
 906                     unless ($item->exclude_from_local_holds_priority || $patron->category->exclude_from_local_holds_priority) {
 907                         my $local_holds_priority_item_branchcode =
 908                             $item->$LocalHoldsPriorityItemControl;
 909                         my $local_holds_priority_patron_branchcode =
 910                             ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 911                             ? $res->{branchcode}
 912                             : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 913                             ? $patron->branchcode
 914                             : undef;
 915                         $local_hold_match =
 916                             $local_holds_priority_item_branchcode eq
 917                             $local_holds_priority_patron_branchcode;
 918                     }
 919                 }
 920
 921                 # See if this item is more important than what we've got so far
 922                 if ( ( $res->{'priority'} && $res->{'priority'} < $priority ) || $local_hold_match ) {
 923                     next if $res->{item_group_id} && ( !$item->item_group || $item->item_group->id != $res->{item_group_id} );
 924                     next if $res->{itemtype} && $res->{itemtype} ne $item->effective_itemtype;
 925                     $patron //= Koha::Patrons->find( $res->{borrowernumber} );
 926                     my $branch = Koha::Policy::Holds->holds_control_library( $item, $patron );
 927                     my $branchitemrule = C4::Circulation::GetBranchItemRule($branch,$item->effective_itemtype);
 928                     next if ($branchitemrule->{'holdallowed'} eq 'not_allowed');
 929                     next if (($branchitemrule->{'holdallowed'} eq 'from_home_library') && ($item->homebranch ne $patron->branchcode));
 930                     my $library = Koha::Libraries->find({branchcode=>$item->homebranch});
 931                     next if (($branchitemrule->{'holdallowed'} eq 'from_local_hold_group') && (!$library->validate_hold_sibling({branchcode => $patron->branchcode}) ));
 932                     my $hold_fulfillment_policy = $branchitemrule->{hold_fulfillment_policy};
 933                     next if ( ($hold_fulfillment_policy eq 'holdgroup') && (!$library->validate_hold_sibling({branchcode => $res->{branchcode}})) );
 934                     next if ( ($hold_fulfillment_policy eq 'homebranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 935                     next if ( ($hold_fulfillment_policy eq 'holdingbranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 936                     next unless $item->can_be_transferred( { to => Koha::Libraries->find( $res->{branchcode} ) } );
 937                     $priority = $res->{'priority'};
 938                     $highest  = $res;
 939                     last if $local_hold_match;
 940                 }
 941             }
 942         }
 943     }
 944
 945     # If we get this far, then no exact match was found.
 946     # We return the most important (i.e. next) reservation.
 947     if ($highest) {
 948         $highest->{'itemnumber'} = $item->itemnumber;
 949         return ( "Reserved", $highest, \@reserves );
 950     }
 951
 952     return ( '' );
 953 }
 954
 955 =head2 CancelExpiredReserves
 956
 957   CancelExpiredReserves();
 958
 959 Cancels all reserves with an expiration date from before today.
 960
 961 =cut
 962
 963 sub CancelExpiredReserves {
 964     my $cancellation_reason = shift;
 965     my $today = dt_from_string();
 966     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 967     my $expireWaiting = C4::Context->preference('ExpireReservesMaxPickUpDelay');
 968
 969     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 970     my $params = {
 971         -or => [
 972             { expirationdate => { '<', $dtf->format_date($today) } },
 973             { patron_expiration_date => { '<' => $dtf->format_date($today) } }
 974         ]
 975     };
 976
 977     $params->{found} = [ { '!=', 'W' }, undef ]  unless $expireWaiting;
 978
 979     # FIXME To move to Koha::Holds->search_expired (?)
 980     my $holds = Koha::Holds->search( $params );
 981
 982     while ( my $hold = $holds->next ) {
 983         my $calendar = Koha::Calendar->new( branchcode => $hold->branchcode );
 984
 985         next if !$cancel_on_holidays && $calendar->is_holiday( $today );
 986
 987         my $cancel_params = {};
 988         $cancel_params->{cancellation_reason} = $cancellation_reason if defined($cancellation_reason);
 989         if ( defined($hold->found) && $hold->found eq 'W' ) {
 990             $cancel_params->{charge_cancel_fee} = 1;
 991         }
 992         $cancel_params->{autofill} = C4::Context->preference('ExpireReservesAutoFill');
 993         $hold->cancel( $cancel_params );
 994     }
 995 }
 996
 997 =head2 AutoUnsuspendReserves
 998
 999   AutoUnsuspendReserves();
1000
1001 Unsuspends all suspended reserves with a suspend_until date from before today.
1002
1003 =cut
1004
1005 sub AutoUnsuspendReserves {
1006     my $today = dt_from_string();
1007
1008     my @holds = Koha::Holds->search( { suspend_until => { '<=' => $today->ymd() } } )->as_list;
1009
1010     map { $_->resume() } @holds;
1011 }
1012
1013 =head2 ModReserve
1014
1015   ModReserve({ rank => $rank,
1016                reserve_id => $reserve_id,
1017                branchcode => $branchcode
1018                [, itemnumber => $itemnumber ]
1019                [, biblionumber => $biblionumber, $borrowernumber => $borrowernumber ]
1020               });
1021
1022 Change a hold request's priority or cancel it.
1023
1024 C<$rank> specifies the effect of the change.  If C<$rank>
1025 is 'n', nothing happens.  This corresponds to leaving a
1026 request alone when changing its priority in the holds queue
1027 for a bib.
1028
1029 If C<$rank> is 'del', the hold request is cancelled.
1030
1031 If C<$rank> is an integer greater than zero, the priority of
1032 the request is set to that value.  Since priority != 0 means
1033 that the item is not waiting on the hold shelf, setting the
1034 priority to a non-zero value also sets the request's found
1035 status and waiting date to NULL.
1036
1037 If the hold is 'found' (waiting, in-transit, processing) the
1038 only field that can be updated is the expiration date.
1039
1040 The optional C<$itemnumber> parameter is used only when
1041 C<$rank> is a non-zero integer; if supplied, the itemnumber
1042 of the hold request is set accordingly; if omitted, the itemnumber
1043 is cleared.
1044
1045 B<FIXME:> Note that the forgoing can have the effect of causing
1046 item-level hold requests to turn into title-level requests.  This
1047 will be fixed once reserves has separate columns for requested
1048 itemnumber and supplying itemnumber.
1049
1050 =cut
1051
1052 sub ModReserve {
1053     my ( $params ) = @_;
1054
1055     my $rank = $params->{'rank'};
1056     my $reserve_id = $params->{'reserve_id'};
1057     my $branchcode = $params->{'branchcode'};
1058     my $itemnumber = $params->{'itemnumber'};
1059     my $suspend_until = $params->{'suspend_until'};
1060     my $borrowernumber = $params->{'borrowernumber'};
1061     my $biblionumber = $params->{'biblionumber'};
1062     my $cancellation_reason = $params->{'cancellation_reason'};
1063     my $date = $params->{expirationdate};
1064
1065     return if defined $rank && $rank eq "n";
1066
1067     return unless ( $reserve_id || ( $borrowernumber && ( $biblionumber || $itemnumber ) ) );
1068
1069     my $hold;
1070     unless ( $reserve_id ) {
1071         my $holds = Koha::Holds->search({ biblionumber => $biblionumber, borrowernumber => $borrowernumber, itemnumber => $itemnumber });
1072         return unless $holds->count; # FIXME Should raise an exception
1073         $hold = $holds->next;
1074         $reserve_id = $hold->reserve_id;
1075     }
1076
1077     $hold ||= Koha::Holds->find($reserve_id);
1078
1079     # FIXME Other calls may fail
1080     Koha::Exceptions::ObjectNotFound->throw( 'No hold with id ' . $reserve_id ) unless $hold;
1081
1082     my $original = C4::Context->preference('HoldsLog') ? $hold->unblessed : undef;
1083
1084     if ( $rank eq "del" ) {
1085         $hold->cancel({ cancellation_reason => $cancellation_reason });
1086     }
1087     elsif ($hold->found && $hold->priority eq '0' && $date) {
1088
1089         # The only column that can be updated for a found hold is the expiration date
1090         $hold->expirationdate($date)->store();
1091
1092         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, $hold, undef, $original )
1093             if C4::Context->preference('HoldsLog');
1094     }
1095     elsif ($rank =~ /^\d+/ and $rank > 0) {
1096         my $properties = {
1097             priority    => $rank,
1098             branchcode  => $branchcode,
1099             itemnumber  => $itemnumber,
1100             found       => undef,
1101             waitingdate => undef
1102         };
1103         if (exists $params->{reservedate}) {
1104             $properties->{reservedate} = $params->{reservedate} || undef;
1105         }
1106         if (exists $params->{expirationdate}) {
1107             $properties->{expirationdate} = $params->{expirationdate} || undef;
1108         }
1109
1110         $hold->set($properties)->store();
1111
1112         if ( defined( $suspend_until ) ) {
1113             if ( $suspend_until ) {
1114                 $hold->suspend_hold( $suspend_until );
1115             } else {
1116                 # If the hold is suspended leave the hold suspended, but convert it to an indefinite hold.
1117                 # If the hold is not suspended, this does nothing.
1118                 $hold->set( { suspend_until => undef } )->store();
1119             }
1120         }
1121
1122         _FixPriority( { reserve_id => $reserve_id, rank => $rank } );
1123
1124         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, $hold, undef, $original )
1125             if C4::Context->preference('HoldsLog');
1126     }
1127 }
1128
1129 =head2 ModReserveStatus
1130
1131   &ModReserveStatus($itemnumber, $newstatus);
1132
1133 Update the reserve status for the active (priority=0) reserve.
1134
1135 $itemnumber is the itemnumber the reserve is on
1136
1137 $newstatus is the new status.
1138
1139 =cut
1140
1141 sub ModReserveStatus {
1142
1143     #first : check if we have a reservation for this item .
1144     my ($itemnumber, $newstatus) = @_;
1145     my $dbh = C4::Context->dbh;
1146
1147     my $query = "UPDATE reserves SET found = ?, waitingdate = NOW() WHERE itemnumber = ? AND found IS NULL AND priority = 0";
1148     my $sth_set = $dbh->prepare($query);
1149     $sth_set->execute( $newstatus, $itemnumber );
1150
1151     my $item = Koha::Items->find($itemnumber);
1152     if ( $item->location && $item->location eq 'CART'
1153         && ( !$item->permanent_location || $item->permanent_location ne 'CART' )
1154         && $newstatus ) {
1155       CartToShelf( $itemnumber );
1156     }
1157 }
1158
1159 =head2 ModReserveAffect
1160
1161   &ModReserveAffect($itemnumber,$borrowernumber,$diffBranchSend,$reserve_id, $desk_id, $notify_library);
1162
1163 This function affect an item and a status for a given reserve, either fetched directly
1164 by record_id, or by borrowernumber and itemnumber or biblionumber. If only biblionumber
1165 is given, only first reserve returned is affected, which is ok for anything but
1166 multi-item holds.
1167
1168 if $transferToDo is not set, then the status is set to "Waiting" as well.
1169 otherwise, a transfer is on the way, and the end of the transfer will
1170 take care of the waiting status
1171
1172 This function also removes any entry of the hold in holds queue table.
1173
1174 =cut
1175
1176 sub ModReserveAffect {
1177     my ( $itemnumber, $borrowernumber, $transferToDo, $reserve_id, $desk_id, $notify_library ) = @_;
1178     my $dbh = C4::Context->dbh;
1179
1180     # we want to attach $itemnumber to $borrowernumber, find the biblionumber
1181     # attached to $itemnumber
1182     my $sth = $dbh->prepare("SELECT biblionumber FROM items WHERE itemnumber=?");
1183     $sth->execute($itemnumber);
1184     my ($biblionumber) = $sth->fetchrow;
1185
1186     # get request - need to find out if item is already
1187     # waiting in order to not send duplicate hold filled notifications
1188
1189     my $hold;
1190     # Find hold by id if we have it
1191     $hold = Koha::Holds->find( $reserve_id ) if $reserve_id;
1192     # Find item level hold for this item if there is one
1193     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->next();
1194     # Find record level hold if there is no item level hold
1195     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, biblionumber => $biblionumber } )->next();
1196
1197     return unless $hold;
1198
1199     my $original = $hold->unblessed;
1200
1201     my $already_on_shelf = $hold->found && $hold->found eq 'W';
1202
1203     $hold->itemnumber($itemnumber);
1204
1205     if ($transferToDo) {
1206         $hold->set_transfer();
1207     } elsif (C4::Context->preference('HoldsNeedProcessingSIP')
1208              && C4::Context->interface eq 'sip'
1209              && !$already_on_shelf) {
1210         $hold->set_processing();
1211     } else {
1212         $hold->set_waiting($desk_id);
1213         _koha_notify_reserve( $hold->reserve_id ) unless $already_on_shelf;
1214         # Complete transfer if one exists
1215         my $transfer = $hold->item->get_transfer;
1216         $transfer->receive if $transfer;
1217     }
1218
1219     _koha_notify_hold_changed( $hold ) if $notify_library;
1220
1221     _FixPriority( { biblionumber => $biblionumber } );
1222     my $item = Koha::Items->find($itemnumber);
1223     if ( $item->location && $item->location eq 'CART'
1224         && ( !$item->permanent_location || $item->permanent_location ne 'CART' ) ) {
1225       CartToShelf( $itemnumber );
1226     }
1227
1228     my $std = $dbh->prepare(q{
1229         DELETE  q, t
1230         FROM    tmp_holdsqueue q
1231         INNER JOIN hold_fill_targets t
1232         ON  q.borrowernumber = t.borrowernumber
1233             AND q.biblionumber = t.biblionumber
1234             AND q.itemnumber = t.itemnumber
1235             AND q.item_level_request = t.item_level_request
1236             AND q.holdingbranch = t.source_branchcode
1237         WHERE t.reserve_id = ?
1238     });
1239     $std->execute($hold->reserve_id);
1240
1241     logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, $hold, undef, $original )
1242         if C4::Context->preference('HoldsLog');
1243
1244     return;
1245 }
1246
1247 =head2 ModReserveCancelAll
1248
1249   ($messages,$nextreservinfo) = &ModReserveCancelAll($itemnumber,$borrowernumber,$reason);
1250
1251 function to cancel reserve and check other reserves
1252
1253 =cut
1254
1255 sub ModReserveCancelAll {
1256     my $messages;
1257     my $nextreservinfo;
1258     my ( $itemnumber, $borrowernumber, $cancellation_reason ) = @_;
1259     my $item = Koha::Items->find($itemnumber);
1260
1261     #step 1 : cancel the reservation
1262     my $holds = Koha::Holds->search({ itemnumber => $itemnumber, borrowernumber => $borrowernumber });
1263     return unless $holds->count;
1264     $holds->next->cancel({ cancellation_reason => $cancellation_reason });
1265
1266     #step 2 check for other reserves on this item
1267     ( undef, $nextreservinfo, undef ) = CheckReserves($item);
1268
1269     if ($nextreservinfo) {
1270         if( $item->holdingbranch ne $nextreservinfo->{'branchcode'} ) {
1271             $messages->{'transfert'} = $nextreservinfo->{'branchcode'};
1272         }
1273         else {
1274             $messages->{'waiting'} = 1;
1275         }
1276     }
1277
1278     return ( $messages, $nextreservinfo->{borrowernumber} );
1279 }
1280
1281 =head2 ModReserveMinusPriority
1282
1283   &ModReserveMinusPriority($itemnumber,$borrowernumber,$biblionumber)
1284
1285 Reduce the values of queued list
1286
1287 =cut
1288
1289 sub ModReserveMinusPriority {
1290     my ( $itemnumber, $reserve_id ) = @_;
1291
1292     #first step update the value of the first person on reserv
1293     my $dbh   = C4::Context->dbh;
1294     my $query = "
1295         UPDATE reserves
1296         SET    priority = 0 , itemnumber = ?
1297         WHERE  reserve_id = ?
1298     ";
1299     my $sth_upd = $dbh->prepare($query);
1300     $sth_upd->execute( $itemnumber, $reserve_id );
1301     # second step update all others reserves
1302     _FixPriority({ reserve_id => $reserve_id, rank => '0' });
1303 }
1304
1305 =head2 IsAvailableForItemLevelRequest
1306
1307   my $is_available = IsAvailableForItemLevelRequest( $item_record, $borrower_record, $pickup_branchcode );
1308
1309 Checks whether a given item record is available for an
1310 item-level hold request.  An item is available if
1311
1312 * it is not lost AND
1313 * it is not damaged AND
1314 * it is not withdrawn AND
1315 * a waiting or in transit reserve is placed on
1316 * does not have a not for loan value > 0
1317
1318 Need to check the issuingrules onshelfholds column,
1319 if this is set items on the shelf can be placed on hold
1320
1321 Note that IsAvailableForItemLevelRequest() does not
1322 check if the staff operator is authorized to place
1323 a request on the item - in particular,
1324 this routine does not check IndependentBranches
1325 and canreservefromotherbranches.
1326
1327 Note also that this subroutine does not checks smart
1328 rules limits for item by reservesallowed/holds_per_record
1329 values, this complemented in calling code with calls and
1330 checks with CanItemBeReserved or CanBookBeReserved.
1331
1332 =cut
1333
1334 sub IsAvailableForItemLevelRequest {
1335     my $item                = shift;
1336     my $patron              = shift;
1337     my $pickup_branchcode   = shift;
1338
1339     my $dbh = C4::Context->dbh;
1340     # must check the notforloan setting of the itemtype
1341     # FIXME - a lot of places in the code do this
1342     #         or something similar - need to be
1343     #         consolidated
1344     my $itemtype = $item->effective_itemtype;
1345     return 0
1346       unless defined $itemtype;
1347     my $notforloan_per_itemtype = Koha::ItemTypes->find($itemtype)->notforloan;
1348
1349     return 0 if
1350         $notforloan_per_itemtype ||
1351         $item->itemlost        ||
1352         $item->notforloan > 0  || # item with negative or zero notforloan value is holdable
1353         $item->withdrawn        ||
1354         ($item->damaged && !C4::Context->preference('AllowHoldsOnDamagedItems'));
1355
1356     if ($pickup_branchcode) {
1357         my $destination = Koha::Libraries->find($pickup_branchcode);
1358         return 0 unless $destination;
1359         return 0 unless $destination->pickup_location;
1360         return 0 unless $item->can_be_transferred( { to => $destination } );
1361         my $reserves_control_branch = Koha::Policy::Holds->holds_control_library( $item, $patron );
1362         my $branchitemrule =
1363             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype );
1364         my $home_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
1365         return 0 unless $branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $home_library->validate_hold_sibling( {branchcode => $pickup_branchcode} );
1366     }
1367
1368     my $on_shelf_holds = Koha::CirculationRules->get_onshelfholds_policy( { item => $item, patron => $patron } );
1369
1370     if ( $on_shelf_holds == 1 ) {
1371         return 1;
1372     } elsif ( $on_shelf_holds == 2 ) {
1373
1374         # These calculations work at the biblio level, and can be expensive
1375         # we use the in-memory cache to avoid calling once per item when looping items on a biblio
1376
1377         my $memory_cache = Koha::Cache::Memory::Lite->get_instance();
1378         my $cache_key    = sprintf "ItemsAnyAvailableAndNotRestricted:%s:%s", $patron->id, $item->biblionumber;
1379
1380         my $any_available = $memory_cache->get_from_cache($cache_key);
1381         return $any_available ? 0 : 1 if defined($any_available);
1382
1383         $any_available =
1384             ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron } );
1385         $memory_cache->set_in_cache( $cache_key, $any_available );
1386         return $any_available ? 0 : 1;
1387
1388     } else {  # on_shelf_holds == 0 "If any unavailable" (the description is rather cryptic and could still be improved)
1389         return $item->notforloan < 0 || $item->onloan || IsItemOnHoldAndFound( $item->itemnumber );
1390     }
1391 }
1392
1393 =head2 ItemsAnyAvailableAndNotRestricted
1394
1395   ItemsAnyAvailableAndNotRestricted( { biblionumber => $biblionumber, patron => $patron });
1396
1397 This function checks all items for specified biblionumber (numeric) against patron (object)
1398 and returns true (1) if at least one item available for loan/check out/present/not held
1399 and also checks other parameters logic which not restricts item for hold at all (for ex.
1400 AllowHoldsOnDamagedItems or 'holdallowed' own/sibling library)
1401
1402 =cut
1403
1404 sub ItemsAnyAvailableAndNotRestricted {
1405     my $param = shift;
1406
1407     my @items = Koha::Items->search( { biblionumber => $param->{biblionumber} } )->as_list;
1408
1409     foreach my $i (@items) {
1410         my $reserves_control_branch = Koha::Policy::Holds->holds_control_library( $i, $param->{patron} );
1411         my $branchitemrule =
1412             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $i->itype );
1413         my $item_library = Koha::Libraries->find( { branchcode => $i->homebranch } );
1414
1415         # we can return (end the loop) when first one found:
1416         return 1
1417             unless $i->itemlost
1418             || $i->notforloan # items with non-zero notforloan cannot be checked out
1419             || $i->withdrawn
1420             || $i->onloan
1421             || IsItemOnHoldAndFound( $i->id )
1422             || ( $i->damaged
1423                  && ! C4::Context->preference('AllowHoldsOnDamagedItems') )
1424             || Koha::ItemTypes->find( $i->effective_itemtype() )->notforloan
1425             || $branchitemrule->{holdallowed} eq 'from_home_library' && $param->{patron}->branchcode ne $i->homebranch
1426             || $branchitemrule->{holdallowed} eq 'from_local_hold_group' && ! $item_library->validate_hold_sibling( { branchcode => $param->{patron}->branchcode } )
1427             || CanItemBeReserved( $param->{patron}, $i )->{status} ne 'OK';
1428     }
1429
1430     return 0;
1431 }
1432
1433 =head2 AlterPriority
1434
1435   AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
1436
1437 This function changes a reserve's priority up, down, to the top, or to the bottom.
1438 Input: $where is 'up', 'down', 'top' or 'bottom'. Biblionumber, Date reserve was placed
1439
1440 =cut
1441
1442 sub AlterPriority {
1443     my ( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority ) = @_;
1444
1445     my $hold = Koha::Holds->find( $reserve_id );
1446     return unless $hold;
1447
1448     if ( $hold->cancellationdate ) {
1449         warn "I cannot alter the priority for reserve_id $reserve_id, the reserve has been cancelled (" . $hold->cancellationdate . ')';
1450         return;
1451     }
1452
1453     if ( $where eq 'up' ) {
1454       return unless $prev_priority;
1455       _FixPriority({ reserve_id => $reserve_id, rank => $prev_priority })
1456     } elsif ( $where eq 'down' ) {
1457       return unless $next_priority;
1458       _FixPriority({ reserve_id => $reserve_id, rank => $next_priority })
1459     } elsif ( $where eq 'top' ) {
1460       _FixPriority({ reserve_id => $reserve_id, rank => $first_priority })
1461     } elsif ( $where eq 'bottom' ) {
1462       _FixPriority({ reserve_id => $reserve_id, rank => $last_priority });
1463     }
1464
1465     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1466         {
1467             biblio_ids => [ $hold->biblionumber ]
1468         }
1469     ) if C4::Context->preference('RealTimeHoldsQueue');
1470     # FIXME Should return the new priority
1471 }
1472
1473 =head2 ToggleLowestPriority
1474
1475   ToggleLowestPriority( $borrowernumber, $biblionumber );
1476
1477 This function sets the lowestPriority field to true if is false, and false if it is true.
1478
1479 =cut
1480
1481 sub ToggleLowestPriority {
1482     my ( $reserve_id ) = @_;
1483
1484     my $dbh = C4::Context->dbh;
1485
1486     my $sth = $dbh->prepare( "UPDATE reserves SET lowestPriority = NOT lowestPriority WHERE reserve_id = ?");
1487     $sth->execute( $reserve_id );
1488
1489     _FixPriority({ reserve_id => $reserve_id, rank => '999999' });
1490 }
1491
1492 =head2 ToggleSuspend
1493
1494   ToggleSuspend( $reserve_id );
1495
1496 This function sets the suspend field to true if is false, and false if it is true.
1497 If the reserve is currently suspended with a suspend_until date, that date will
1498 be cleared when it is unsuspended.
1499
1500 =cut
1501
1502 sub ToggleSuspend {
1503     my ( $reserve_id, $suspend_until ) = @_;
1504
1505     my $hold = Koha::Holds->find( $reserve_id );
1506
1507     if ( $hold->is_suspended ) {
1508         $hold->resume()
1509     } else {
1510         $hold->suspend_hold( $suspend_until );
1511     }
1512 }
1513
1514 =head2 SuspendAll
1515
1516   SuspendAll(
1517       borrowernumber   => $borrowernumber,
1518       [ biblionumber   => $biblionumber, ]
1519       [ suspend_until  => $suspend_until, ]
1520       [ suspend        => $suspend ]
1521   );
1522
1523   This function accepts a set of hash keys as its parameters.
1524   It requires either borrowernumber or biblionumber, or both.
1525
1526   suspend_until is wholly optional.
1527
1528 =cut
1529
1530 sub SuspendAll {
1531     my %params = @_;
1532
1533     my $borrowernumber = $params{'borrowernumber'} || undef;
1534     my $biblionumber   = $params{'biblionumber'}   || undef;
1535     my $suspend_until  = $params{'suspend_until'}  || undef;
1536     my $suspend = defined( $params{'suspend'} ) ? $params{'suspend'} : 1;
1537
1538     return unless ( $borrowernumber || $biblionumber );
1539
1540     my $params;
1541     $params->{found}          = undef;
1542     $params->{borrowernumber} = $borrowernumber if $borrowernumber;
1543     $params->{biblionumber}   = $biblionumber if $biblionumber;
1544
1545     my @holds = Koha::Holds->search($params)->as_list;
1546
1547     if ($suspend) {
1548         map { $_->suspend_hold($suspend_until) } @holds;
1549     }
1550     else {
1551         map { $_->resume() } @holds;
1552     }
1553 }
1554
1555
1556 =head2 _FixPriority
1557
1558   _FixPriority({
1559     reserve_id => $reserve_id,
1560     [rank => $rank,]
1561     [ignoreSetLowestRank => $ignoreSetLowestRank]
1562   });
1563
1564   or
1565
1566   _FixPriority({ biblionumber => $biblionumber});
1567
1568 This routine adjusts the priority of a hold request and holds
1569 on the same bib.
1570
1571 In the first form, where a reserve_id is passed, the priority of the
1572 hold is set to supplied rank, and other holds for that bib are adjusted
1573 accordingly.  If the rank is "del", the hold is cancelled.  If no rank
1574 is supplied, all of the holds on that bib have their priority adjusted
1575 as if the second form had been used.
1576
1577 In the second form, where a biblionumber is passed, the holds on that
1578 bib (that are not captured) are sorted in order of increasing priority,
1579 then have reserves.priority set so that the first non-captured hold
1580 has its priority set to 1, the second non-captured hold has its priority
1581 set to 2, and so forth.
1582
1583 In both cases, holds that have the lowestPriority flag on are have their
1584 priority adjusted to ensure that they remain at the end of the line.
1585
1586 Note that the ignoreSetLowestRank parameter is meant to be used only
1587 when _FixPriority calls itself.
1588
1589 =cut
1590
1591 sub _FixPriority {
1592     my ( $params ) = @_;
1593     my $reserve_id = $params->{reserve_id};
1594     my $rank = $params->{rank} // '';
1595     my $ignoreSetLowestRank = $params->{ignoreSetLowestRank};
1596     my $biblionumber = $params->{biblionumber};
1597
1598     my $dbh = C4::Context->dbh;
1599
1600     my $hold;
1601     if ( $reserve_id ) {
1602         $hold = Koha::Holds->find( $reserve_id );
1603         if (!defined $hold){
1604             # may have already been checked out and hold fulfilled
1605             $hold = Koha::Old::Holds->find( $reserve_id );
1606         }
1607         return unless $hold;
1608     }
1609
1610     unless ( $biblionumber ) { # FIXME This is a very weird API
1611         $biblionumber = $hold->biblionumber;
1612     }
1613
1614     if ( $rank eq "del" ) { # FIXME will crash if called without $hold
1615         $hold->cancel;
1616     }
1617     elsif ( $reserve_id && ( $rank eq "W" || $rank eq "0" ) ) {
1618
1619         # make sure priority for waiting or in-transit items is 0
1620         my $query = "
1621             UPDATE reserves
1622             SET    priority = 0
1623             WHERE reserve_id = ?
1624             AND found IN ('W', 'T', 'P')
1625         ";
1626         my $sth = $dbh->prepare($query);
1627         $sth->execute( $reserve_id );
1628     }
1629     my @priority;
1630
1631     # get whats left
1632     my $query = "
1633         SELECT reserve_id, borrowernumber, reservedate
1634         FROM   reserves
1635         WHERE  biblionumber   = ?
1636           AND  ((found <> 'W' AND found <> 'T' AND found <> 'P') OR found IS NULL)
1637         ORDER BY priority ASC
1638     ";
1639     my $sth = $dbh->prepare($query);
1640     $sth->execute( $biblionumber );
1641     while ( my $line = $sth->fetchrow_hashref ) {
1642         push( @priority,     $line );
1643     }
1644
1645     # FIXME This whole sub must be rewritten, especially to highlight what is done when reserve_id is not given
1646     # To find the matching index
1647     my $i;
1648     my $key = -1;    # to allow for 0 to be a valid result
1649     for ( $i = 0 ; $i < @priority ; $i++ ) {
1650         if ( $reserve_id && $reserve_id == $priority[$i]->{'reserve_id'} ) {
1651             $key = $i;    # save the index
1652             last;
1653         }
1654     }
1655
1656     # if index exists in array then move it to new position
1657     if ( $key > -1 && $rank ne 'del' && $rank > 0 ) {
1658         my $new_rank = $rank - 1; # $new_rank is what you want the new index to be in the array
1659         my $moving_item = splice( @priority, $key, 1 );
1660         $new_rank = scalar @priority if $new_rank > scalar @priority;
1661         splice( @priority, $new_rank, 0, $moving_item );
1662     }
1663
1664     # now fix the priority on those that are left....
1665     $query = "
1666         UPDATE reserves
1667         SET    priority = ?
1668         WHERE  reserve_id = ?
1669     ";
1670     $sth = $dbh->prepare($query);
1671     for ( my $j = 0 ; $j < @priority ; $j++ ) {
1672         $sth->execute(
1673             $j + 1,
1674             $priority[$j]->{'reserve_id'}
1675         );
1676     }
1677
1678     unless ( $ignoreSetLowestRank ) {
1679         $sth = $dbh->prepare( "SELECT reserve_id FROM reserves WHERE lowestPriority = 1 AND biblionumber = ? ORDER BY priority" );
1680         $sth->execute($biblionumber);
1681       while ( my $res = $sth->fetchrow_hashref() ) {
1682         _FixPriority({
1683             reserve_id => $res->{'reserve_id'},
1684             rank => '999999',
1685             ignoreSetLowestRank => 1
1686         });
1687       }
1688     }
1689 }
1690
1691 =head2 _Findgroupreserve
1692
1693   @results = &_Findgroupreserve($biblionumber, $itemnumber, $lookahead, $ignore_borrowers);
1694
1695 Looks for a holds-queue based item-specific match first, then for a holds-queue title-level match, returning the
1696 first match found.  If neither, then we look for non-holds-queue based holds.
1697 Lookahead is the number of days to look in advance.
1698
1699 C<&_Findgroupreserve> returns :
1700 C<@results> is an array of references-to-hash whose keys are mostly
1701 fields from the reserves table of the Koha database, plus
1702 C<biblioitemnumber>.
1703
1704 This routine with either return:
1705 1 - Item specific holds from the holds queue
1706 2 - Title level holds from the holds queue
1707 3 - All holds for this biblionumber
1708
1709 All return values will respect any borrowernumbers passed as arrayref in $ignore_borrowers
1710
1711 =cut
1712
1713 sub _Findgroupreserve {
1714     my ( $biblionumber, $itemnumber, $lookahead, $ignore_borrowers) = @_;
1715     my $dbh   = C4::Context->dbh;
1716
1717     # check for targeted match form the holds queue
1718     my $hold_target_query = qq{
1719         SELECT reserves.biblionumber        AS biblionumber,
1720                reserves.borrowernumber      AS borrowernumber,
1721                reserves.reservedate         AS reservedate,
1722                reserves.branchcode          AS branchcode,
1723                reserves.cancellationdate    AS cancellationdate,
1724                reserves.found               AS found,
1725                reserves.reservenotes        AS reservenotes,
1726                reserves.priority            AS priority,
1727                reserves.timestamp           AS timestamp,
1728                biblioitems.biblioitemnumber AS biblioitemnumber,
1729                reserves.itemnumber          AS itemnumber,
1730                reserves.reserve_id          AS reserve_id,
1731                reserves.itemtype            AS itemtype,
1732                reserves.non_priority        AS non_priority,
1733                reserves.item_group_id           AS item_group_id
1734         FROM reserves
1735         JOIN biblioitems USING (biblionumber)
1736         JOIN hold_fill_targets USING (reserve_id)
1737         WHERE found IS NULL
1738         AND priority > 0
1739         AND hold_fill_targets.itemnumber = ?
1740         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1741         AND suspend = 0
1742         ORDER BY priority
1743     };
1744     my $sth = $dbh->prepare($hold_target_query);
1745     $sth->execute($itemnumber, $lookahead||0);
1746     my @results;
1747     if ( my $data = $sth->fetchrow_hashref ) {
1748         push( @results, $data )
1749           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1750     }
1751     return @results if @results;
1752
1753     my $query = qq{
1754         SELECT reserves.biblionumber               AS biblionumber,
1755                reserves.borrowernumber             AS borrowernumber,
1756                reserves.reservedate                AS reservedate,
1757                reserves.waitingdate                AS waitingdate,
1758                reserves.branchcode                 AS branchcode,
1759                reserves.cancellationdate           AS cancellationdate,
1760                reserves.found                      AS found,
1761                reserves.reservenotes               AS reservenotes,
1762                reserves.priority                   AS priority,
1763                reserves.timestamp                  AS timestamp,
1764                reserves.itemnumber                 AS itemnumber,
1765                reserves.reserve_id                 AS reserve_id,
1766                reserves.itemtype                   AS itemtype,
1767                reserves.non_priority               AS non_priority,
1768                reserves.item_group_id              AS item_group_id
1769         FROM reserves
1770         WHERE reserves.biblionumber = ?
1771           AND (reserves.itemnumber IS NULL OR reserves.itemnumber = ?)
1772           AND reserves.reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1773           AND suspend = 0
1774           ORDER BY priority
1775     };
1776     $sth = $dbh->prepare($query);
1777     $sth->execute( $biblionumber, $itemnumber, $lookahead||0);
1778     @results = ();
1779     while ( my $data = $sth->fetchrow_hashref ) {
1780         push( @results, $data )
1781           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1782     }
1783     return @results;
1784 }
1785
1786 =head2 _koha_notify_reserve
1787
1788   _koha_notify_reserve( $hold->reserve_id );
1789
1790 Sends a notification to the patron that their hold has been filled (through
1791 ModReserveAffect)
1792
1793 The letter code for this notice may be found using the following query:
1794
1795     select distinct letter_code
1796     from message_transports
1797     inner join message_attributes using (message_attribute_id)
1798     where message_name = 'Hold_Filled'
1799
1800 This will probably sipmly be 'HOLD', but because it is defined in the database,
1801 it is subject to addition or change.
1802
1803 The following tables are availalbe witin the notice:
1804
1805     branches
1806     borrowers
1807     biblio
1808     biblioitems
1809     reserves
1810     items
1811
1812 =cut
1813
1814 sub _koha_notify_reserve {
1815     my $reserve_id = shift;
1816
1817     my $hold = Koha::Holds->find($reserve_id);
1818     my $borrowernumber = $hold->borrowernumber;
1819
1820     my $patron = Koha::Patrons->find( $borrowernumber );
1821
1822     # Try to get the borrower's email address
1823     my $to_address = $patron->notice_email_address;
1824
1825     my $messagingprefs = C4::Members::Messaging::GetMessagingPreferences( {
1826             borrowernumber => $borrowernumber,
1827             message_name => 'Hold_Filled'
1828     } );
1829
1830     my $library = Koha::Libraries->find( $hold->branchcode );
1831     my $from_email_address = $library->from_email_address;
1832
1833     my %letter_params = (
1834         module => 'reserves',
1835         branchcode => $hold->branchcode,
1836         lang => $patron->lang,
1837         tables => {
1838             'branches'       => $library->unblessed,
1839             'borrowers'      => $patron->unblessed,
1840             'biblio'         => $hold->biblionumber,
1841             'biblioitems'    => $hold->biblionumber,
1842             'reserves'       => $hold->unblessed,
1843             'items'          => $hold->itemnumber,
1844         },
1845     );
1846
1847     my $notification_sent = 0; #Keeping track if a Hold_filled message is sent. If no message can be sent, then default to a print message.
1848     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
1849     my $send_notification = sub {
1850         my ( $mtt, $letter_code, $wants_digest ) = (@_);
1851         return unless defined $letter_code;
1852         $letter_params{letter_code}            = $letter_code;
1853         $letter_params{message_transport_type} = $mtt;
1854         my $letter = C4::Letters::GetPreparedLetter(%letter_params);
1855         unless ($letter) {
1856             warn "Could not find a letter called '$letter_params{'letter_code'}' for $mtt in the 'reserves' module";
1857             return;
1858         }
1859
1860         unless ($wants_digest) {
1861             C4::Letters::EnqueueLetter(
1862                 {
1863                     letter                 => $letter,
1864                     borrowernumber         => $borrowernumber,
1865                     from_address           => $from_email_address,
1866                     message_transport_type => $mtt,
1867                 }
1868             );
1869         } else {
1870             C4::Context->dbh->do(q|LOCK TABLE message_queue READ|)  unless $do_not_lock;
1871             C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
1872             my $message = C4::Message->find_last_message( $patron->unblessed, $letter_code, $mtt );
1873             unless ($message) {
1874                 C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
1875                 C4::Message->enqueue( $letter, $patron, $mtt );
1876             } else {
1877                 $message->append($letter);
1878                 $message->update;
1879             }
1880             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
1881         }
1882     };
1883
1884     while ( my ( $mtt, $letter_code ) = each %{ $messagingprefs->{transports} } ) {
1885         next if (
1886                ( $mtt eq 'email' and not $to_address ) # No email address
1887             or ( $mtt eq 'sms'   and not $patron->smsalertnumber ) # No SMS number
1888             or ( $mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') ) # Notice is handled by TalkingTech_itiva_outbound.pl
1889             or ( $mtt eq 'phone' and not $patron->phone ) # No phone number to call
1890         );
1891
1892         &$send_notification($mtt, $letter_code, $messagingprefs->{wants_digest});
1893         $notification_sent++;
1894     }
1895     #Making sure that a print notification is sent if no other transport types can be utilized.
1896     if (! $notification_sent) {
1897         &$send_notification('print', 'HOLD');
1898     }
1899
1900 }
1901
1902 =head2 _koha_notify_hold_changed
1903
1904   _koha_notify_hold_changed( $hold_object );
1905
1906 =cut
1907
1908 sub _koha_notify_hold_changed {
1909     my $hold = shift;
1910
1911     my $patron = $hold->patron;
1912     my $library = $hold->branch;
1913
1914     my $letter = C4::Letters::GetPreparedLetter(
1915         module      => 'reserves',
1916         letter_code => 'HOLD_CHANGED',
1917         branchcode  => $hold->branchcode,
1918         substitute  => { today => output_pref( dt_from_string ) },
1919         tables      => {
1920             'branches'    => $library->unblessed,
1921             'borrowers'   => $patron->unblessed,
1922             'biblio'      => $hold->biblionumber,
1923             'biblioitems' => $hold->biblionumber,
1924             'reserves'    => $hold->unblessed,
1925             'items'       => $hold->itemnumber,
1926         },
1927     );
1928
1929     return unless $letter;
1930
1931     my $email =
1932          C4::Context->preference('ExpireReservesAutoFillEmail')
1933       || $library->inbound_email_address;
1934
1935     C4::Letters::EnqueueLetter(
1936         {
1937             letter                 => $letter,
1938             borrowernumber         => $patron->id,
1939             message_transport_type => 'email',
1940             from_address           => $library->from_email_address,
1941             to_address             => $email,
1942         }
1943     );
1944 }
1945
1946 =head2 _ShiftPriority
1947
1948   $new_priority = _ShiftPriority( $biblionumber, $priority );
1949
1950 This increments the priority of all reserves after the one
1951 with either the lowest date after C<$reservedate>
1952 or the lowest priority after C<$priority>.
1953
1954 It effectively makes room for a new reserve to be inserted with a certain
1955 priority, which is returned.
1956
1957 This is most useful when the reservedate can be set by the user.  It allows
1958 the new reserve to be placed before other reserves that have a later
1959 reservedate.  Since priority also is set by the form in reserves/request.pl
1960 the sub accounts for that too.
1961
1962 =cut
1963
1964 sub _ShiftPriority {
1965     my ( $biblio, $new_priority ) = @_;
1966
1967     my $dbh = C4::Context->dbh;
1968     my $query = "SELECT priority FROM reserves WHERE biblionumber = ? AND priority > ? ORDER BY priority ASC LIMIT 1";
1969     my $sth = $dbh->prepare( $query );
1970     $sth->execute( $biblio, $new_priority );
1971     my $min_priority = $sth->fetchrow;
1972     # if no such matches are found, $new_priority remains as original value
1973     $new_priority = $min_priority if ( $min_priority );
1974
1975     # Shift the priority up by one; works in conjunction with the next SQL statement
1976     $query = "UPDATE reserves
1977               SET priority = priority+1
1978               WHERE biblionumber = ?
1979               AND borrowernumber = ?
1980               AND reservedate = ?
1981               AND found IS NULL";
1982     my $sth_update = $dbh->prepare( $query );
1983
1984     # Select all reserves for the biblio with priority greater than $new_priority, and order greatest to least
1985     $query = "SELECT borrowernumber, reservedate FROM reserves WHERE priority >= ? AND biblionumber = ? ORDER BY priority DESC";
1986     $sth = $dbh->prepare( $query );
1987     $sth->execute( $new_priority, $biblio );
1988     while ( my $row = $sth->fetchrow_hashref ) {
1989         $sth_update->execute( $biblio, $row->{borrowernumber}, $row->{reservedate} );
1990     }
1991
1992     return $new_priority;  # so the caller knows what priority they wind up receiving
1993 }
1994
1995 =head2 MoveReserve
1996
1997   MoveReserve( $itemnumber, $borrowernumber, $cancelreserve )
1998
1999 Use when checking out an item to handle reserves
2000 If $cancelreserve boolean is set to true, it will remove existing reserve
2001
2002 =cut
2003
2004 sub MoveReserve {
2005     my ( $itemnumber, $borrowernumber, $cancelreserve ) = @_;
2006
2007     $cancelreserve //= 0;
2008
2009     my $lookahead = C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2010     my $item = Koha::Items->find($itemnumber);
2011     my ( $restype, $res, undef ) = CheckReserves( $item, $lookahead );
2012     return unless $res;
2013
2014     my $biblionumber = $res->{biblionumber};
2015
2016     if ($res->{borrowernumber} == $borrowernumber) {
2017         my $hold = Koha::Holds->find( $res->{reserve_id} );
2018         $hold->fill({ item_id => $itemnumber });
2019     }
2020     else {
2021         # warn "Reserved";
2022         # The item is reserved by someone else.
2023         # Find this item in the reserves
2024
2025         my $borr_res  = Koha::Holds->search({
2026             borrowernumber => $borrowernumber,
2027             biblionumber   => $biblionumber,
2028         },{
2029             order_by       => 'priority'
2030         })->next();
2031
2032         if ( $borr_res ) {
2033             # The item is reserved by the current patron
2034             $borr_res->fill({ item_id => $itemnumber });
2035         }
2036
2037         if ( $cancelreserve eq 'revert' ) { ## Revert waiting reserve to priority 1
2038             RevertWaitingStatus({ itemnumber => $itemnumber });
2039         }
2040         elsif ( $cancelreserve eq 'cancel' || $cancelreserve ) { # cancel reserves on this item
2041             my $hold = Koha::Holds->find( $res->{reserve_id} );
2042             $hold->cancel;
2043         }
2044     }
2045 }
2046
2047 =head2 MergeHolds
2048
2049   MergeHolds($dbh,$to_biblio, $from_biblio);
2050
2051 This shifts the holds from C<$from_biblio> to C<$to_biblio> and reorders them by the date they were placed
2052
2053 =cut
2054
2055 sub MergeHolds {
2056     my ( $dbh, $to_biblio, $from_biblio ) = @_;
2057     my $sth = $dbh->prepare(
2058         "SELECT count(*) as reserve_count FROM reserves WHERE biblionumber = ?"
2059     );
2060     $sth->execute($from_biblio);
2061     if ( my $data = $sth->fetchrow_hashref() ) {
2062
2063         # holds exist on old record, if not we don't need to do anything
2064         $sth = $dbh->prepare(
2065             "UPDATE reserves SET biblionumber = ? WHERE biblionumber = ?");
2066         $sth->execute( $to_biblio, $from_biblio );
2067
2068         # Reorder by date
2069         # don't reorder those already waiting
2070
2071         $sth = $dbh->prepare(
2072 "SELECT * FROM reserves WHERE biblionumber = ? AND (found NOT IN ('W', 'T', 'P') OR found is NULL) ORDER BY reservedate ASC"
2073         );
2074         my $upd_sth = $dbh->prepare(
2075 "UPDATE reserves SET priority = ? WHERE biblionumber = ? AND borrowernumber = ?
2076         AND reservedate = ? AND (itemnumber = ? or itemnumber is NULL) "
2077         );
2078         $sth->execute( $to_biblio );
2079         my $priority = 1;
2080         while ( my $reserve = $sth->fetchrow_hashref() ) {
2081             $upd_sth->execute(
2082                 $priority,                    $to_biblio,
2083                 $reserve->{'borrowernumber'}, $reserve->{'reservedate'},
2084                 $reserve->{'itemnumber'}
2085             );
2086             $priority++;
2087         }
2088     }
2089 }
2090
2091 =head2 RevertWaitingStatus
2092
2093   RevertWaitingStatus({ itemnumber => $itemnumber });
2094
2095   Reverts a 'waiting' hold back to a regular hold with a priority of 1.
2096
2097   Caveat: Any waiting hold fixed with RevertWaitingStatus will be an
2098           item level hold, even if it was only a bibliolevel hold to
2099           begin with. This is because we can no longer know if a hold
2100           was item-level or bib-level after a hold has been set to
2101           waiting status.
2102
2103 =cut
2104
2105 sub RevertWaitingStatus {
2106     my ( $params ) = @_;
2107     my $itemnumber = $params->{'itemnumber'};
2108
2109     return unless ( $itemnumber );
2110
2111     my $dbh = C4::Context->dbh;
2112
2113     ## Get the waiting reserve we want to revert
2114     my $hold = Koha::Holds->search(
2115         {
2116             itemnumber => $itemnumber,
2117             found => { not => undef },
2118         }
2119     )->next;
2120
2121     ## Increment the priority of all other non-waiting
2122     ## reserves for this bib record
2123     my $holds = Koha::Holds->search({ biblionumber => $hold->biblionumber, priority => { '>' => 0 } })
2124                            ->update({ priority => \'priority + 1' }, { no_triggers => 1 });
2125
2126     ## Fix up the currently waiting reserve
2127     $hold->set(
2128         {
2129             priority       => 1,
2130             found          => undef,
2131             waitingdate    => undef,
2132             expirationdate => $hold->patron_expiration_date,
2133             itemnumber     => $hold->item_level_hold ? $hold->itemnumber : undef,
2134         }
2135     )->store( { hold_reverted => 1 } );
2136
2137     logaction( 'HOLDS', 'MODIFY', $hold->id, $hold )
2138         if C4::Context->preference('HoldsLog');
2139
2140     _FixPriority( { biblionumber => $hold->biblionumber } );
2141
2142     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2143         {
2144             biblio_ids => [ $hold->biblionumber ]
2145         }
2146     ) if C4::Context->preference('RealTimeHoldsQueue');
2147
2148
2149     return $hold;
2150 }
2151
2152 =head2 ReserveSlip
2153
2154 ReserveSlip(
2155     {
2156         branchcode     => $branchcode,
2157         borrowernumber => $borrowernumber,
2158         biblionumber   => $biblionumber,
2159         [ itemnumber   => $itemnumber, ]
2160         [ barcode      => $barcode, ]
2161     }
2162   )
2163
2164 Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
2165
2166 The letter code will be HOLD_SLIP, and the following tables are
2167 available within the slip:
2168
2169     reserves
2170     branches
2171     borrowers
2172     biblio
2173     biblioitems
2174     items
2175
2176 =cut
2177
2178 sub ReserveSlip {
2179     my ($args) = @_;
2180     my $branchcode     = $args->{branchcode};
2181     my $reserve_id = $args->{reserve_id};
2182     my $itemnumber = $args->{itemnumber};
2183
2184     my $hold = Koha::Holds->find($reserve_id);
2185     return unless $hold;
2186
2187     my $patron = $hold->borrower;
2188     my $reserve = $hold->unblessed;
2189
2190     return  C4::Letters::GetPreparedLetter (
2191         module => 'circulation',
2192         letter_code => 'HOLD_SLIP',
2193         branchcode => $branchcode,
2194         lang => $patron->lang,
2195         tables => {
2196             'reserves'    => $reserve,
2197             'branches'    => $reserve->{branchcode},
2198             'borrowers'   => $reserve->{borrowernumber},
2199             'biblio'      => $reserve->{biblionumber},
2200             'biblioitems' => $reserve->{biblionumber},
2201             'items'       => $reserve->{itemnumber} || $itemnumber,
2202         },
2203     );
2204 }
2205
2206 =head2 CalculatePriority
2207
2208     my $p = CalculatePriority($biblionumber, $resdate);
2209
2210 Calculate priority for a new reserve on biblionumber, placing it at
2211 the end of the line of all holds whose start date falls before
2212 the current system time and that are neither on the hold shelf
2213 or in transit.
2214
2215 The reserve date parameter is optional; if it is supplied, the
2216 priority is based on the set of holds whose start date falls before
2217 the parameter value.
2218
2219 After calculation of this priority, it is recommended to call
2220 _ShiftPriority. Note that this is currently done in
2221 AddReserves.
2222
2223 =cut
2224
2225 sub CalculatePriority {
2226     my ( $biblionumber, $resdate ) = @_;
2227
2228     my $sql = q{
2229         SELECT COUNT(*) FROM reserves
2230         WHERE biblionumber = ?
2231         AND   priority > 0
2232         AND   (found IS NULL OR found = '')
2233     };
2234     #skip found==W or found==T or found==P (waiting, transit or processing holds)
2235     if( $resdate ) {
2236         $sql.= ' AND ( reservedate <= ? )';
2237     }
2238     else {
2239         $sql.= ' AND ( reservedate < NOW() )';
2240     }
2241     my $dbh = C4::Context->dbh();
2242     my @row = $dbh->selectrow_array(
2243         $sql,
2244         undef,
2245         $resdate ? ($biblionumber, $resdate) : ($biblionumber)
2246     );
2247
2248     return @row ? $row[0]+1 : 1;
2249 }
2250
2251 =head2 IsItemOnHoldAndFound
2252
2253     my $bool = IsItemFoundHold( $itemnumber );
2254
2255     Returns true if the item is currently on hold
2256     and that hold has a non-null found status ( W, T, etc. )
2257
2258 =cut
2259
2260 sub IsItemOnHoldAndFound {
2261     my ($itemnumber) = @_;
2262
2263     my $rs = Koha::Database->new()->schema()->resultset('Reserve');
2264
2265     my $found = $rs->count(
2266         {
2267             itemnumber => $itemnumber,
2268             found      => { '!=' => undef }
2269         }
2270     );
2271
2272     return $found;
2273 }
2274
2275 =head2 GetMaxPatronHoldsForRecord
2276
2277 my $holds_per_record = ReservesControlBranch( $borrowernumber, $biblionumber );
2278
2279 For multiple holds on a given record for a given patron, the max
2280 number of record level holds that a patron can be placed is the highest
2281 value of the holds_per_record rule for each item if the record for that
2282 patron. This subroutine finds and returns the highest holds_per_record
2283 rule value for a given patron id and record id.
2284
2285 =cut
2286
2287 sub GetMaxPatronHoldsForRecord {
2288     my ( $borrowernumber, $biblionumber ) = @_;
2289
2290     my $patron = Koha::Patrons->find($borrowernumber);
2291     my @items = Koha::Items->search( { biblionumber => $biblionumber } )->as_list;
2292
2293     my $controlbranch = C4::Context->preference('ReservesControlBranch');
2294
2295     my $categorycode = $patron->categorycode;
2296     my $branchcode;
2297     $branchcode = $patron->branchcode if ( $controlbranch eq "PatronLibrary" );
2298
2299     my $max = 0;
2300     foreach my $item (@items) {
2301         my $itemtype = $item->effective_itemtype();
2302
2303         $branchcode = $item->homebranch if ( $controlbranch eq "ItemHomeLibrary" );
2304
2305         my $rule = Koha::CirculationRules->get_effective_rule({
2306             categorycode => $categorycode,
2307             itemtype     => $itemtype,
2308             branchcode   => $branchcode,
2309             rule_name    => 'holds_per_record'
2310         });
2311         my $holds_per_record = $rule ? $rule->rule_value : 0;
2312         $max = $holds_per_record if $holds_per_record > $max;
2313     }
2314
2315     return $max;
2316 }
2317
2318 =head1 AUTHOR
2319
2320 Koha Development Team <http://koha-community.org/>
2321
2322 =cut
2323
2324 1;