Koha/ApiKey.pm

   1 package Koha::ApiKey;
   2
   3 # Copyright BibLibre 2015
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22
  23 use Koha::AuthUtils qw(hash_password);
  24 use Koha::Exceptions::Object;
  25
  26 use List::MoreUtils qw(any);
  27 use UUID;
  28
  29 use base qw(Koha::Object);
  30
  31 =head1 NAME
  32
  33 Koha::ApiKey - Koha API Key Object class
  34
  35 =head1 API
  36
  37 =head2 Class methods
  38
  39 =head3 store
  40
  41     my $api_key = Koha::ApiKey->new({ patron_id => $patron_id })->store;
  42
  43 Overloaded I<store> method.
  44
  45 =cut
  46
  47 sub store {
  48     my ($self) = @_;
  49
  50     if ( $self->in_storage ) {
  51         my %dirty_columns = $self->_result->get_dirty_columns;
  52
  53         # only allow 'description' and 'active' to be updated
  54         for my $property ( keys %dirty_columns ) {
  55             Koha::Exceptions::Object::ReadOnlyProperty->throw( property => $property )
  56               if $property ne 'description' and $property ne 'active';
  57         }
  58     } else {
  59         $self->{_plain_text_secret} = $self->_generate_unused_uuid('secret');
  60         $self->set(
  61             {   secret    => Koha::AuthUtils::hash_password( $self->{_plain_text_secret} ),
  62                 client_id => $self->_generate_unused_uuid('client_id'),
  63             }
  64         );
  65     }
  66
  67     return $self->SUPER::store();
  68 }
  69
  70 =head3 validate_secret
  71
  72     if ( $api_key->validate_secret( $secret ) ) { ... }
  73
  74 Returns a boolean that tells if the passed secret matches the one on the DB.
  75
  76 =cut
  77
  78 sub validate_secret {
  79     my ( $self, $secret ) = @_;
  80
  81     my $digest = Koha::AuthUtils::hash_password( $secret, $self->secret );
  82
  83     return ( $self->secret eq $digest ) ? 1 : 0;
  84 }
  85
  86 =head3 plain_text_secret
  87
  88     my $generated_secret = $api_key->store->plain_text_secret;
  89
  90 Returns the generated I<secret> so it can be displayed to  the end user.
  91 This is only accessible when the object is new and has just been stored.
  92
  93 Returns I<undef> if the object was retrieved from the database.
  94
  95 =cut
  96
  97 sub plain_text_secret {
  98     my ($self) = @_;
  99
 100     return $self->{_plain_text_secret}
 101         if $self->{_plain_text_secret};
 102
 103     return;
 104 }
 105
 106 =head2 Internal methods
 107
 108 =cut
 109
 110 =head3 _type
 111
 112 =cut
 113
 114 sub _type {
 115     return 'ApiKey';
 116 }
 117
 118 =head3 _generate_unused_uuid
 119
 120     my $string = $self->_generate_unused_uuid($column);
 121
 122 $column can be 'client_id' or 'secret'.
 123
 124 =cut
 125
 126 sub _generate_unused_uuid {
 127     my ($self, $column) = @_;
 128
 129     my ( $uuid, $uuidstring );
 130
 131     UUID::generate($uuid);
 132     UUID::unparse( $uuid, $uuidstring );
 133
 134     while ( Koha::ApiKeys->search({ $column => $uuidstring })->count > 0 ) {
 135         # Make sure $secret is unique
 136         UUID::generate($uuid);
 137         UUID::unparse( $uuid, $uuidstring );
 138     }
 139
 140     return $uuidstring;
 141 }
 142
 143 1;