Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use DateTime;
  21 use C4::Context;
  22 use Koha::Exceptions;
  23
  24 use vars qw(@ISA @EXPORT_OK);
  25 BEGIN {
  26     require Exporter;
  27     @ISA = qw(Exporter);
  28
  29     @EXPORT_OK = qw(
  30         dt_from_string
  31         output_pref
  32         format_sqldatetime
  33     );
  34 }
  35
  36 =head1 DateUtils
  37
  38 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  39
  40 =head1 DESCRIPTION
  41
  42 Koha has historically only used dates not datetimes and been content to
  43 handle these as strings. It also has confused formatting with actual dates
  44 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  45
  46 =cut
  47
  48 =head2 dt_ftom_string
  49
  50 $dt = dt_from_string($date_string, [$format, $timezone ]);
  51
  52 Passed a date string returns a DateTime object format and timezone default
  53 to the system preferences. If the date string is empty DateTime->now is returned
  54
  55 =cut
  56
  57 sub dt_from_string {
  58     my ( $date_string, $date_format, $tz ) = @_;
  59
  60     return if $date_string and $date_string =~ m|^0000-0|;
  61
  62     my $do_fallback = defined($date_format) ? 0 : 1;
  63     my $server_tz = C4::Context->tz;
  64     $tz = C4::Context->tz unless $tz;
  65
  66     return DateTime->now( time_zone => $tz ) unless $date_string;
  67
  68     $date_format = C4::Context->preference('dateformat') unless $date_format;
  69
  70     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  71         return $date_string;
  72     }
  73
  74     my $regex;
  75
  76     # The fallback format is sql/iso
  77     my $fallback_re = qr|
  78         (?<year>\d{4})
  79         -
  80         (?<month>\d{2})
  81         -
  82         (?<day>\d{2})
  83     |xms;
  84
  85     if ( $date_format eq 'metric' ) {
  86         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  87         $regex = qr|
  88             (?<day>\d{2})
  89             /
  90             (?<month>\d{2})
  91             /
  92             (?<year>\d{4})
  93         |xms;
  94     }
  95     elsif ( $date_format eq 'dmydot' ) {
  96         # dmydot format is "dd.mm.yyyy[ hh:mm:ss]"
  97         $regex = qr|
  98             (?<day>\d{2})
  99             .
 100             (?<month>\d{2})
 101             .
 102             (?<year>\d{4})
 103         |xms;
 104     }
 105     elsif ( $date_format eq 'us' ) {
 106         # us format is "mm/dd/yyyy[ hh:mm:ss]"
 107         $regex = qr|
 108             (?<month>\d{2})
 109             /
 110             (?<day>\d{2})
 111             /
 112             (?<year>\d{4})
 113         |xms;
 114     }
 115     elsif ( $date_format eq 'rfc3339' ) {
 116         $regex = qr/
 117             (?<year>\d{4})
 118             -
 119             (?<month>\d{2})
 120             -
 121             (?<day>\d{2})
 122             ([Tt\s])
 123             (?<hour>\d{2})
 124             :
 125             (?<minute>\d{2})
 126             :
 127             (?<second>\d{2})
 128             (\.\d{1,3})?(([Zz]$)|((?<offset>[\+|\-])(?<hours>[01][0-9]|2[0-3]):(?<minutes>[0-5][0-9])))
 129         /xms;
 130
 131         # Default to UTC (when 'Z' is passed) for inbound timezone.
 132         # The regex above succeeds for both 'z', 'Z' and '+/-' offset.
 133         # We set tz as though Z was passed by default and then correct it later if an offset is detected
 134         # by the presence fo the <offset> variable.
 135         $tz = DateTime::TimeZone->new( name => 'UTC' );
 136     }
 137     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
 138         # iso or sql format are yyyy-dd-mm[ hh:mm:ss]"
 139         $regex = $fallback_re;
 140     }
 141     else {
 142         die "Invalid dateformat parameter ($date_format)";
 143     }
 144
 145     # Add the faculative time part [hh:mm[:ss]]
 146     my $time_re .= qr|
 147             (
 148                 T?
 149                 \s*
 150                 (?<hour>\d{2})
 151                 :
 152                 (?<minute>\d{2})
 153                 (
 154                     :
 155                     (?<second>\d{2})
 156                 )?
 157                 (
 158                     \s
 159                     (?<ampm>\w{2})
 160                 )?
 161             )?
 162     |xms;
 163     $regex .= $time_re unless ( $date_format eq 'rfc3339' );
 164     $fallback_re .= $time_re;
 165
 166     my %dt_params;
 167     my $ampm;
 168     if ( $date_string =~ $regex ) {
 169         %dt_params = (
 170             year   => $+{year},
 171             month  => $+{month},
 172             day    => $+{day},
 173             hour   => $+{hour},
 174             minute => $+{minute},
 175             second => $+{second},
 176         );
 177         $ampm = $+{ampm};
 178         if ( $+{offset} ) {
 179             # If offset given, set inbound timezone using it.
 180             $tz = DateTime::TimeZone->new( name => $+{offset} . $+{hours} . $+{minutes} );
 181         }
 182     } elsif ( $do_fallback && $date_string =~ $fallback_re ) {
 183         %dt_params = (
 184             year   => $+{year},
 185             month  => $+{month},
 186             day    => $+{day},
 187             hour   => $+{hour},
 188             minute => $+{minute},
 189             second => $+{second},
 190         );
 191         $ampm = $+{ampm};
 192     }
 193     else {
 194         die "The given date ($date_string) does not match the date format ($date_format)";
 195     }
 196
 197     # system allows the 0th of the month
 198     $dt_params{day} = '01' if $dt_params{day} eq '00';
 199
 200     # Set default hh:mm:ss to 00:00:00
 201     my $date_only = ( !defined( $dt_params{hour} )
 202         && !defined( $dt_params{minute} )
 203         && !defined( $dt_params{second} ) );
 204     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 205     $dt_params{minute} = 00 unless defined $dt_params{minute};
 206     $dt_params{second} = 00 unless defined $dt_params{second};
 207
 208     if ( $ampm ) {
 209         if ( $ampm eq 'AM' ) {
 210             $dt_params{hour} = 00 if $dt_params{hour} == 12;
 211         } elsif ( $dt_params{hour} != 12 ) { # PM
 212             $dt_params{hour} += 12;
 213             $dt_params{hour} = 00 if $dt_params{hour} == 24;
 214         }
 215     }
 216
 217     my $floating = 0;
 218     my $dt = eval {
 219         DateTime->new(
 220             %dt_params,
 221             # No TZ for dates 'infinite' => see bug 13242
 222             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 223         );
 224     };
 225     if ($@) {
 226         $tz = DateTime::TimeZone->new( name => 'floating' );
 227         $floating = 1;
 228         $dt = DateTime->new(
 229             %dt_params,
 230             # No TZ for dates 'infinite' => see bug 13242
 231             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 232         );
 233     }
 234
 235     # Convert to configured timezone (unless we started with a dateonly string or had to drop to floating time)
 236     $dt->set_time_zone($server_tz) unless ( $date_only || $floating );
 237
 238     return $dt;
 239 }
 240
 241 =head2 output_pref
 242
 243 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 244 $date_string = output_pref( $dt );
 245
 246 Returns a string containing the time & date formatted as per the C4::Context setting,
 247 or C<undef> if C<undef> was provided.
 248
 249 This routine can either be passed a DateTime object or or a hashref.  If it is
 250 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 251 an optional 'dateformat' to override the dateformat system preference, an
 252 optional 'timeformat' to override the TimeFormat system preference value,
 253 and an optional 'dateonly' to specify that only the formatted date string
 254 should be returned without the time.
 255
 256 =cut
 257
 258 sub output_pref {
 259     my $params = shift;
 260     my ( $dt, $str, $force_pref, $force_time, $dateonly, $as_due_date );
 261     if ( ref $params eq 'HASH' ) {
 262         $dt         = $params->{dt};
 263         $str        = $params->{str};
 264         $force_pref = $params->{dateformat};         # if testing we want to override Context
 265         $force_time = $params->{timeformat};
 266         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 267         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 268     } else {
 269         $dt = $params;
 270     }
 271
 272     Koha::Exceptions::WrongParameter->throw( 'output_pref should not be called with both dt and str parameter' ) if $dt and $str;
 273
 274     if ( $str ) {
 275         local $@;
 276         $dt = eval { dt_from_string( $str ) };
 277         Koha::Exceptions::WrongParameter->throw("Invalid date '$str' passed to output_pref" ) if $@;
 278     }
 279
 280     return if !defined $dt; # NULL date
 281     Koha::Exceptions::WrongParameter->throw( "output_pref is called with '$dt' (ref ". ( ref($dt) ? ref($dt):'SCALAR')."), not a DateTime object")  if ref($dt) ne 'DateTime';
 282
 283     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 284     if ( $dt->ymd !~ /^9999/ ) {
 285         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 286         $dt->set_time_zone( $tz );
 287     }
 288
 289     my $pref =
 290       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 291
 292     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 293     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 294     my $date;
 295     if ( $pref =~ m/^iso/ ) {
 296         $date = $dateonly
 297           ? $dt->strftime("%Y-%m-%d")
 298           : $dt->strftime("%Y-%m-%d $time");
 299     }
 300     elsif ( $pref =~ m/^rfc3339/ ) {
 301         if (!$dateonly) {
 302             $date = $dt->strftime('%FT%T%z');
 303             substr($date, -2, 0, ':'); # timezone "HHmm" => "HH:mm"
 304         }
 305         else {
 306             $date = $dt->strftime("%Y-%m-%d");
 307         }
 308     }
 309     elsif ( $pref =~ m/^metric/ ) {
 310         $date = $dateonly
 311           ? $dt->strftime("%d/%m/%Y")
 312           : $dt->strftime("%d/%m/%Y $time");
 313     }
 314     elsif ( $pref =~ m/^dmydot/ ) {
 315         $date = $dateonly
 316           ? $dt->strftime("%d.%m.%Y")
 317           : $dt->strftime("%d.%m.%Y $time");
 318     }
 319
 320     elsif ( $pref =~ m/^us/ ) {
 321         $date = $dateonly
 322           ? $dt->strftime("%m/%d/%Y")
 323           : $dt->strftime("%m/%d/%Y $time");
 324     }
 325     else {
 326         $date = $dateonly
 327           ? $dt->strftime("%Y-%m-%d")
 328           : $dt->strftime("%Y-%m-%d $time");
 329     }
 330
 331     if ( $as_due_date ) {
 332         $time_format eq '12hr'
 333             ? $date =~ s| 11:59 PM$||
 334             : $date =~ s| 23:59$||;
 335     }
 336
 337     return $date;
 338 }
 339
 340 =head2 format_sqldatetime
 341
 342 $string = format_sqldatetime( $string_as_returned_from_db );
 343
 344 a convenience routine for calling dt_from_string and formatting the result
 345 with output_pref as it is a frequent activity in scripts
 346
 347 =cut
 348
 349 sub format_sqldatetime {
 350     my $str        = shift;
 351     my $force_pref = shift;    # if testing we want to override Context
 352     my $force_time = shift;
 353     my $dateonly   = shift;
 354
 355     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 356         my $dt = dt_from_string( $str, 'sql' );
 357         return q{} unless $dt;
 358         $dt->truncate( to => 'minute' );
 359         return output_pref({
 360             dt => $dt,
 361             dateformat => $force_pref,
 362             timeformat => $force_time,
 363             dateonly => $dateonly
 364         });
 365     }
 366     return q{};
 367 }
 368
 369 1;