Koha/Item.pm

   1 package Koha::Item;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use List::MoreUtils qw( any );
  23 use Try::Tiny qw( catch try );
  24
  25 use Koha::Database;
  26 use Koha::DateUtils qw( dt_from_string output_pref );
  27
  28 use C4::Context;
  29 use C4::Circulation qw( barcodedecode GetBranchItemRule );
  30 use C4::Reserves;
  31 use C4::ClassSource qw( GetClassSort );
  32 use C4::Log qw( logaction );
  33
  34 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  35 use Koha::Biblio::ItemGroups;
  36 use Koha::Checkouts;
  37 use Koha::CirculationRules;
  38 use Koha::CoverImages;
  39 use Koha::Exceptions::Item::Transfer;
  40 use Koha::Item::Attributes;
  41 use Koha::Item::Transfer::Limits;
  42 use Koha::Item::Transfers;
  43 use Koha::ItemTypes;
  44 use Koha::Libraries;
  45 use Koha::Patrons;
  46 use Koha::Plugins;
  47 use Koha::Recalls;
  48 use Koha::Result::Boolean;
  49 use Koha::SearchEngine::Indexer;
  50 use Koha::StockRotationItem;
  51 use Koha::StockRotationRotas;
  52 use Koha::TrackedLinks;
  53
  54 use base qw(Koha::Object);
  55
  56 =head1 NAME
  57
  58 Koha::Item - Koha Item object class
  59
  60 =head1 API
  61
  62 =head2 Class methods
  63
  64 =cut
  65
  66 =head3 store
  67
  68     $item->store;
  69
  70 $params can take an optional 'skip_record_index' parameter.
  71 If set, the reindexation process will not happen (index_records not called)
  72
  73 NOTE: This is a temporary fix to answer a performance issue when lot of items
  74 are added (or modified) at the same time.
  75 The correct way to fix this is to make the ES reindexation process async.
  76 You should not turn it on if you do not understand what it is doing exactly.
  77
  78 =cut
  79
  80 sub store {
  81     my $self = shift;
  82     my $params = @_ ? shift : {};
  83
  84     my $log_action = $params->{log_action} // 1;
  85
  86     # We do not want to oblige callers to pass this value
  87     # Dev conveniences vs performance?
  88     unless ( $self->biblioitemnumber ) {
  89         $self->biblioitemnumber( $self->biblio->biblioitem->biblioitemnumber );
  90     }
  91
  92     # See related changes from C4::Items::AddItem
  93     unless ( $self->itype ) {
  94         $self->itype($self->biblio->biblioitem->itemtype);
  95     }
  96
  97     $self->barcode( C4::Circulation::barcodedecode( $self->barcode ) );
  98
  99     my $today  = dt_from_string;
 100     my $action = 'create';
 101
 102     unless ( $self->in_storage ) { #AddItem
 103
 104         unless ( $self->permanent_location ) {
 105             $self->permanent_location($self->location);
 106         }
 107
 108         my $default_location = C4::Context->preference('NewItemsDefaultLocation');
 109         unless ( $self->location || !$default_location ) {
 110             $self->permanent_location( $self->location || $default_location )
 111               unless $self->permanent_location;
 112             $self->location($default_location);
 113         }
 114
 115         unless ( $self->replacementpricedate ) {
 116             $self->replacementpricedate($today);
 117         }
 118         unless ( $self->datelastseen ) {
 119             $self->datelastseen($today);
 120         }
 121
 122         unless ( $self->dateaccessioned ) {
 123             $self->dateaccessioned($today);
 124         }
 125
 126         if (   $self->itemcallnumber
 127             or $self->cn_source )
 128         {
 129             my $cn_sort = GetClassSort( $self->cn_source, $self->itemcallnumber, "" );
 130             $self->cn_sort($cn_sort);
 131         }
 132
 133     } else { # ModItem
 134
 135         $action = 'modify';
 136
 137         my %updated_columns = $self->_result->get_dirty_columns;
 138         return $self->SUPER::store unless %updated_columns;
 139
 140         # Retrieve the item for comparison if we need to
 141         my $pre_mod_item = (
 142                  exists $updated_columns{itemlost}
 143               or exists $updated_columns{withdrawn}
 144               or exists $updated_columns{damaged}
 145         ) ? $self->get_from_storage : undef;
 146
 147         # Update *_on  fields if needed
 148         # FIXME: Why not for AddItem as well?
 149         my @fields = qw( itemlost withdrawn damaged );
 150         for my $field (@fields) {
 151
 152             # If the field is defined but empty or 0, we are
 153             # removing/unsetting and thus need to clear out
 154             # the 'on' field
 155             if (   exists $updated_columns{$field}
 156                 && defined( $self->$field )
 157                 && !$self->$field )
 158             {
 159                 my $field_on = "${field}_on";
 160                 $self->$field_on(undef);
 161             }
 162             # If the field has changed otherwise, we much update
 163             # the 'on' field
 164             elsif (exists $updated_columns{$field}
 165                 && $updated_columns{$field}
 166                 && !$pre_mod_item->$field )
 167             {
 168                 my $field_on = "${field}_on";
 169                 $self->$field_on(dt_from_string);
 170             }
 171         }
 172
 173         if (   exists $updated_columns{itemcallnumber}
 174             or exists $updated_columns{cn_source} )
 175         {
 176             my $cn_sort = GetClassSort( $self->cn_source, $self->itemcallnumber, "" );
 177             $self->cn_sort($cn_sort);
 178         }
 179
 180
 181         if (    exists $updated_columns{location}
 182             and $self->location ne 'CART'
 183             and $self->location ne 'PROC'
 184             and not exists $updated_columns{permanent_location} )
 185         {
 186             $self->permanent_location( $self->location );
 187         }
 188
 189         # If item was lost and has now been found,
 190         # reverse any list item charges if necessary.
 191         if (    exists $updated_columns{itemlost}
 192             and $updated_columns{itemlost} <= 0
 193             and $pre_mod_item->itemlost > 0 )
 194         {
 195             $self->_set_found_trigger($pre_mod_item);
 196         }
 197
 198     }
 199
 200     my $result = $self->SUPER::store;
 201     if ( $log_action && C4::Context->preference("CataloguingLog") ) {
 202         $action eq 'create'
 203           ? logaction( "CATALOGUING", "ADD", $self->itemnumber, "item" )
 204           : logaction( "CATALOGUING", "MODIFY", $self->itemnumber, $self );
 205     }
 206     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 207     $indexer->index_records( $self->biblionumber, "specialUpdate", "biblioserver" )
 208         unless $params->{skip_record_index};
 209     $self->get_from_storage->_after_item_action_hooks({ action => $action });
 210
 211     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 212         {
 213             biblio_ids => [ $self->biblionumber ]
 214         }
 215     ) unless $params->{skip_holds_queue} or !C4::Context->preference('RealTimeHoldsQueue');
 216
 217     return $result;
 218 }
 219
 220 =head3 delete
 221
 222 =cut
 223
 224 sub delete {
 225     my $self = shift;
 226     my $params = @_ ? shift : {};
 227
 228     # FIXME check the item has no current issues
 229     # i.e. raise the appropriate exception
 230
 231     # Get the item group so we can delete it later if it has no items left
 232     my $item_group = C4::Context->preference('EnableItemGroups') ? $self->item_group : undef;
 233
 234     my $result = $self->SUPER::delete;
 235
 236     # Delete the item gorup if it has no items left
 237     $item_group->delete if ( $item_group && $item_group->items->count == 0 );
 238
 239     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 240     $indexer->index_records( $self->biblionumber, "specialUpdate", "biblioserver" )
 241         unless $params->{skip_record_index};
 242
 243     $self->_after_item_action_hooks({ action => 'delete' });
 244
 245     logaction( "CATALOGUING", "DELETE", $self->itemnumber, "item" )
 246       if C4::Context->preference("CataloguingLog");
 247
 248     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 249         {
 250             biblio_ids => [ $self->biblionumber ]
 251         }
 252     ) unless $params->{skip_holds_queue} or !C4::Context->preference('RealTimeHoldsQueue');
 253
 254     return $result;
 255 }
 256
 257 =head3 safe_delete
 258
 259 =cut
 260
 261 sub safe_delete {
 262     my $self = shift;
 263     my $params = @_ ? shift : {};
 264
 265     my $safe_to_delete = $self->safe_to_delete;
 266     return $safe_to_delete unless $safe_to_delete;
 267
 268     $self->move_to_deleted;
 269
 270     return $self->delete($params);
 271 }
 272
 273 =head3 safe_to_delete
 274
 275 returns 1 if the item is safe to delete,
 276
 277 "book_on_loan" if the item is checked out,
 278
 279 "not_same_branch" if the item is blocked by independent branches,
 280
 281 "book_reserved" if the there are holds aganst the item, or
 282
 283 "linked_analytics" if the item has linked analytic records.
 284
 285 "last_item_for_hold" if the item is the last one on a record on which a biblio-level hold is placed
 286
 287 =cut
 288
 289 sub safe_to_delete {
 290     my ($self) = @_;
 291
 292     my $error;
 293
 294     $error = "book_on_loan" if $self->checkout;
 295
 296     $error = "not_same_branch"
 297       if defined C4::Context->userenv
 298       and !C4::Context->IsSuperLibrarian()
 299       and C4::Context->preference("IndependentBranches")
 300       and ( C4::Context->userenv->{branch} ne $self->homebranch );
 301
 302     # check it doesn't have a waiting reserve
 303     $error = "book_reserved"
 304       if $self->holds->search( { found => [ 'W', 'T' ] } )->count;
 305
 306     $error = "linked_analytics"
 307       if C4::Items::GetAnalyticsCount( $self->itemnumber ) > 0;
 308
 309     $error = "last_item_for_hold"
 310       if $self->biblio->items->count == 1
 311       && $self->biblio->holds->search(
 312           {
 313               itemnumber => undef,
 314           }
 315         )->count;
 316
 317     if ( $error ) {
 318         return Koha::Result::Boolean->new(0)->add_message({ message => $error });
 319     }
 320
 321     return Koha::Result::Boolean->new(1);
 322 }
 323
 324 =head3 move_to_deleted
 325
 326 my $is_moved = $item->move_to_deleted;
 327
 328 Move an item to the deleteditems table.
 329 This can be done before deleting an item, to make sure the data are not completely deleted.
 330
 331 =cut
 332
 333 sub move_to_deleted {
 334     my ($self) = @_;
 335     my $item_infos = $self->unblessed;
 336     delete $item_infos->{timestamp}; #This ensures the timestamp date in deleteditems will be set to the current timestamp
 337     $item_infos->{deleted_on} = dt_from_string;
 338     return Koha::Database->new->schema->resultset('Deleteditem')->create($item_infos);
 339 }
 340
 341
 342 =head3 effective_itemtype
 343
 344 Returns the itemtype for the item based on whether item level itemtypes are set or not.
 345
 346 =cut
 347
 348 sub effective_itemtype {
 349     my ( $self ) = @_;
 350
 351     return $self->_result()->effective_itemtype();
 352 }
 353
 354 =head3 home_branch
 355
 356 =cut
 357
 358 sub home_branch {
 359     my ($self) = @_;
 360
 361     my $hb_rs = $self->_result->homebranch;
 362
 363     return Koha::Library->_new_from_dbic( $hb_rs );
 364 }
 365
 366 =head3 holding_branch
 367
 368 =cut
 369
 370 sub holding_branch {
 371     my ($self) = @_;
 372
 373     my $hb_rs = $self->_result->holdingbranch;
 374
 375     return Koha::Library->_new_from_dbic( $hb_rs );
 376 }
 377
 378 =head3 biblio
 379
 380 my $biblio = $item->biblio;
 381
 382 Return the bibliographic record of this item
 383
 384 =cut
 385
 386 sub biblio {
 387     my ( $self ) = @_;
 388     my $biblio_rs = $self->_result->biblio;
 389     return Koha::Biblio->_new_from_dbic( $biblio_rs );
 390 }
 391
 392 =head3 biblioitem
 393
 394 my $biblioitem = $item->biblioitem;
 395
 396 Return the biblioitem record of this item
 397
 398 =cut
 399
 400 sub biblioitem {
 401     my ( $self ) = @_;
 402     my $biblioitem_rs = $self->_result->biblioitem;
 403     return Koha::Biblioitem->_new_from_dbic( $biblioitem_rs );
 404 }
 405
 406 =head3 checkout
 407
 408 my $checkout = $item->checkout;
 409
 410 Return the checkout for this item
 411
 412 =cut
 413
 414 sub checkout {
 415     my ( $self ) = @_;
 416     my $checkout_rs = $self->_result->issue;
 417     return unless $checkout_rs;
 418     return Koha::Checkout->_new_from_dbic( $checkout_rs );
 419 }
 420
 421 =head3 item_group
 422
 423 my $item_group = $item->item_group;
 424
 425 Return the item group for this item
 426
 427 =cut
 428
 429 sub item_group {
 430     my ( $self ) = @_;
 431
 432     my $item_group_item = $self->_result->item_group_item;
 433     return unless $item_group_item;
 434
 435     my $item_group_rs = $item_group_item->item_group;
 436     return unless $item_group_rs;
 437
 438     my $item_group = Koha::Biblio::ItemGroup->_new_from_dbic( $item_group_rs );
 439     return $item_group;
 440 }
 441
 442 =head3 return_claims
 443
 444   my $return_claims = $item->return_claims;
 445
 446 Return any return_claims associated with this item
 447
 448 =cut
 449
 450 sub return_claims {
 451     my ( $self, $params, $attrs ) = @_;
 452     my $claims_rs = $self->_result->return_claims->search($params, $attrs);
 453     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $claims_rs );
 454 }
 455
 456 =head3 return_claim
 457
 458   my $return_claim = $item->return_claim;
 459
 460 Returns the most recent unresolved return_claims associated with this item
 461
 462 =cut
 463
 464 sub return_claim {
 465     my ($self) = @_;
 466     my $claims_rs =
 467       $self->_result->return_claims->search( { resolution => undef },
 468         { order_by => { '-desc' => 'created_on' }, rows => 1 } )->single;
 469     return unless $claims_rs;
 470     return Koha::Checkouts::ReturnClaim->_new_from_dbic($claims_rs);
 471 }
 472
 473 =head3 holds
 474
 475 my $holds = $item->holds();
 476 my $holds = $item->holds($params);
 477 my $holds = $item->holds({ found => 'W'});
 478
 479 Return holds attached to an item, optionally accept a hashref of params to pass to search
 480
 481 =cut
 482
 483 sub holds {
 484     my ( $self,$params ) = @_;
 485     my $holds_rs = $self->_result->reserves->search($params);
 486     return Koha::Holds->_new_from_dbic( $holds_rs );
 487 }
 488
 489 =head3 request_transfer
 490
 491   my $transfer = $item->request_transfer(
 492     {
 493         to     => $to_library,
 494         reason => $reason,
 495         [ ignore_limits => 0, enqueue => 1, replace => 1 ]
 496     }
 497   );
 498
 499 Add a transfer request for this item to the given branch for the given reason.
 500
 501 An exception will be thrown if the BranchTransferLimits would prevent the requested
 502 transfer, unless 'ignore_limits' is passed to override the limits.
 503
 504 An exception will be thrown if an active transfer (i.e pending arrival date) is found;
 505 The caller should catch such cases and retry the transfer request as appropriate passing
 506 an appropriate override.
 507
 508 Overrides
 509 * enqueue - Used to queue up the transfer when the existing transfer is found to be in transit.
 510 * replace - Used to replace the existing transfer request with your own.
 511
 512 =cut
 513
 514 sub request_transfer {
 515     my ( $self, $params ) = @_;
 516
 517     # check for mandatory params
 518     my @mandatory = ( 'to', 'reason' );
 519     for my $param (@mandatory) {
 520         unless ( defined( $params->{$param} ) ) {
 521             Koha::Exceptions::MissingParameter->throw(
 522                 error => "The $param parameter is mandatory" );
 523         }
 524     }
 525
 526     Koha::Exceptions::Item::Transfer::Limit->throw()
 527       unless ( $params->{ignore_limits}
 528         || $self->can_be_transferred( { to => $params->{to} } ) );
 529
 530     my $request = $self->get_transfer;
 531     Koha::Exceptions::Item::Transfer::InQueue->throw( transfer => $request )
 532       if ( $request && !$params->{enqueue} && !$params->{replace} );
 533
 534     $request->cancel( { reason => $params->{reason}, force => 1 } )
 535       if ( defined($request) && $params->{replace} );
 536
 537     my $transfer = Koha::Item::Transfer->new(
 538         {
 539             itemnumber    => $self->itemnumber,
 540             daterequested => dt_from_string,
 541             frombranch    => $self->holdingbranch,
 542             tobranch      => $params->{to}->branchcode,
 543             reason        => $params->{reason},
 544             comments      => $params->{comment}
 545         }
 546     )->store();
 547
 548     return $transfer;
 549 }
 550
 551 =head3 get_transfer
 552
 553   my $transfer = $item->get_transfer;
 554
 555 Return the active transfer request or undef
 556
 557 Note: Transfers are retrieved in a Modified FIFO (First In First Out) order
 558 whereby the most recently sent, but not received, transfer will be returned
 559 if it exists, otherwise the oldest unsatisfied transfer will be returned.
 560
 561 This allows for transfers to queue, which is the case for stock rotation and
 562 rotating collections where a manual transfer may need to take precedence but
 563 we still expect the item to end up at a final location eventually.
 564
 565 =cut
 566
 567 sub get_transfer {
 568     my ($self) = @_;
 569
 570     return $self->get_transfers->search( {}, { rows => 1 } )->next;
 571 }
 572
 573 =head3 get_transfers
 574
 575   my $transfer = $item->get_transfers;
 576
 577 Return the list of outstanding transfers (i.e requested but not yet cancelled
 578 or received).
 579
 580 Note: Transfers are retrieved in a Modified FIFO (First In First Out) order
 581 whereby the most recently sent, but not received, transfer will be returned
 582 first if it exists, otherwise requests are in oldest to newest request order.
 583
 584 This allows for transfers to queue, which is the case for stock rotation and
 585 rotating collections where a manual transfer may need to take precedence but
 586 we still expect the item to end up at a final location eventually.
 587
 588 =cut
 589
 590 sub get_transfers {
 591     my ($self) = @_;
 592
 593     my $transfer_rs = $self->_result->branchtransfers;
 594
 595     return Koha::Item::Transfers
 596                 ->_new_from_dbic($transfer_rs)
 597                 ->filter_by_current
 598                 ->search( {}, { order_by => [ { -desc => 'datesent' }, { -asc => 'daterequested' } ], } );
 599 }
 600
 601 =head3 last_returned_by
 602
 603 Gets and sets the last borrower to return an item.
 604
 605 Accepts and returns Koha::Patron objects
 606
 607 $item->last_returned_by( $borrowernumber );
 608
 609 $last_returned_by = $item->last_returned_by();
 610
 611 =cut
 612
 613 sub last_returned_by {
 614     my ( $self, $borrower ) = @_;
 615
 616     my $items_last_returned_by_rs = Koha::Database->new()->schema()->resultset('ItemsLastBorrower');
 617
 618     if ($borrower) {
 619         return $items_last_returned_by_rs->update_or_create(
 620             { borrowernumber => $borrower->borrowernumber, itemnumber => $self->id } );
 621     }
 622     else {
 623         unless ( $self->{_last_returned_by} ) {
 624             my $result = $items_last_returned_by_rs->single( { itemnumber => $self->id } );
 625             if ($result) {
 626                 $self->{_last_returned_by} = Koha::Patrons->find( $result->get_column('borrowernumber') );
 627             }
 628         }
 629
 630         return $self->{_last_returned_by};
 631     }
 632 }
 633
 634 =head3 can_article_request
 635
 636 my $bool = $item->can_article_request( $borrower )
 637
 638 Returns true if item can be specifically requested
 639
 640 $borrower must be a Koha::Patron object
 641
 642 =cut
 643
 644 sub can_article_request {
 645     my ( $self, $borrower ) = @_;
 646
 647     my $rule = $self->article_request_type($borrower);
 648
 649     return 1 if $rule && $rule ne 'no' && $rule ne 'bib_only';
 650     return q{};
 651 }
 652
 653 =head3 hidden_in_opac
 654
 655 my $bool = $item->hidden_in_opac({ [ rules => $rules ] })
 656
 657 Returns true if item fields match the hidding criteria defined in $rules.
 658 Returns false otherwise.
 659
 660 Takes HASHref that can have the following parameters:
 661     OPTIONAL PARAMETERS:
 662     $rules : { <field> => [ value_1, ... ], ... }
 663
 664 Note: $rules inherits its structure from the parsed YAML from reading
 665 the I<OpacHiddenItems> system preference.
 666
 667 =cut
 668
 669 sub hidden_in_opac {
 670     my ( $self, $params ) = @_;
 671
 672     my $rules = $params->{rules} // {};
 673
 674     return 1
 675         if C4::Context->preference('hidelostitems') and
 676            $self->itemlost > 0;
 677
 678     my $hidden_in_opac = 0;
 679
 680     foreach my $field ( keys %{$rules} ) {
 681
 682         if ( any { $self->$field eq $_ } @{ $rules->{$field} } ) {
 683             $hidden_in_opac = 1;
 684             last;
 685         }
 686     }
 687
 688     return $hidden_in_opac;
 689 }
 690
 691 =head3 can_be_transferred
 692
 693 $item->can_be_transferred({ to => $to_library, from => $from_library })
 694 Checks if an item can be transferred to given library.
 695
 696 This feature is controlled by two system preferences:
 697 UseBranchTransferLimits to enable / disable the feature
 698 BranchTransferLimitsType to use either an itemnumber or ccode as an identifier
 699                          for setting the limitations
 700
 701 Takes HASHref that can have the following parameters:
 702     MANDATORY PARAMETERS:
 703     $to   : Koha::Library
 704     OPTIONAL PARAMETERS:
 705     $from : Koha::Library  # if not given, item holdingbranch
 706                            # will be used instead
 707
 708 Returns 1 if item can be transferred to $to_library, otherwise 0.
 709
 710 To find out whether at least one item of a Koha::Biblio can be transferred, please
 711 see Koha::Biblio->can_be_transferred() instead of using this method for
 712 multiple items of the same biblio.
 713
 714 =cut
 715
 716 sub can_be_transferred {
 717     my ($self, $params) = @_;
 718
 719     my $to   = $params->{to};
 720     my $from = $params->{from};
 721
 722     $to   = $to->branchcode;
 723     $from = defined $from ? $from->branchcode : $self->holdingbranch;
 724
 725     return 1 if $from eq $to; # Transfer to current branch is allowed
 726     return 1 unless C4::Context->preference('UseBranchTransferLimits');
 727
 728     my $limittype = C4::Context->preference('BranchTransferLimitsType');
 729     return Koha::Item::Transfer::Limits->search({
 730         toBranch => $to,
 731         fromBranch => $from,
 732         $limittype => $limittype eq 'itemtype'
 733                         ? $self->effective_itemtype : $self->ccode
 734     })->count ? 0 : 1;
 735
 736 }
 737
 738 =head3 pickup_locations
 739
 740 $pickup_locations = $item->pickup_locations( {patron => $patron } )
 741
 742 Returns possible pickup locations for this item, according to patron's home library (if patron is defined and holds are allowed only from hold groups)
 743 and if item can be transferred to each pickup location.
 744
 745 =cut
 746
 747 sub pickup_locations {
 748     my ($self, $params) = @_;
 749
 750     my $patron = $params->{patron};
 751
 752     my $circ_control_branch =
 753       C4::Reserves::GetReservesControlBranch( $self->unblessed(), $patron->unblessed );
 754     my $branchitemrule =
 755       C4::Circulation::GetBranchItemRule( $circ_control_branch, $self->itype );
 756
 757     if(defined $patron) {
 758         return Koha::Libraries->new()->empty if $branchitemrule->{holdallowed} eq 'from_local_hold_group' && !$self->home_branch->validate_hold_sibling( {branchcode => $patron->branchcode} );
 759         return Koha::Libraries->new()->empty if $branchitemrule->{holdallowed} eq 'from_home_library' && $self->home_branch->branchcode ne $patron->branchcode;
 760     }
 761
 762     my $pickup_libraries = Koha::Libraries->search();
 763     if ($branchitemrule->{hold_fulfillment_policy} eq 'holdgroup') {
 764         $pickup_libraries = $self->home_branch->get_hold_libraries;
 765     } elsif ($branchitemrule->{hold_fulfillment_policy} eq 'patrongroup') {
 766         my $plib = Koha::Libraries->find({ branchcode => $patron->branchcode});
 767         $pickup_libraries = $plib->get_hold_libraries;
 768     } elsif ($branchitemrule->{hold_fulfillment_policy} eq 'homebranch') {
 769         $pickup_libraries = Koha::Libraries->search({ branchcode => $self->homebranch });
 770     } elsif ($branchitemrule->{hold_fulfillment_policy} eq 'holdingbranch') {
 771         $pickup_libraries = Koha::Libraries->search({ branchcode => $self->holdingbranch });
 772     };
 773
 774     return $pickup_libraries->search(
 775         {
 776             pickup_location => 1
 777         },
 778         {
 779             order_by => ['branchname']
 780         }
 781     ) unless C4::Context->preference('UseBranchTransferLimits');
 782
 783     my $limittype = C4::Context->preference('BranchTransferLimitsType');
 784     my ($ccode, $itype) = (undef, undef);
 785     if( $limittype eq 'ccode' ){
 786         $ccode = $self->ccode;
 787     } else {
 788         $itype = $self->itype;
 789     }
 790     my $limits = Koha::Item::Transfer::Limits->search(
 791         {
 792             fromBranch => $self->holdingbranch,
 793             ccode      => $ccode,
 794             itemtype   => $itype,
 795         },
 796         { columns => ['toBranch'] }
 797     );
 798
 799     return $pickup_libraries->search(
 800         {
 801             pickup_location => 1,
 802             branchcode      => {
 803                 '-not_in' => $limits->_resultset->as_query
 804             }
 805         },
 806         {
 807             order_by => ['branchname']
 808         }
 809     );
 810 }
 811
 812 =head3 article_request_type
 813
 814 my $type = $item->article_request_type( $borrower )
 815
 816 returns 'yes', 'no', 'bib_only', or 'item_only'
 817
 818 $borrower must be a Koha::Patron object
 819
 820 =cut
 821
 822 sub article_request_type {
 823     my ( $self, $borrower ) = @_;
 824
 825     my $branch_control = C4::Context->preference('HomeOrHoldingBranch');
 826     my $branchcode =
 827         $branch_control eq 'homebranch'    ? $self->homebranch
 828       : $branch_control eq 'holdingbranch' ? $self->holdingbranch
 829       :                                      undef;
 830     my $borrowertype = $borrower->categorycode;
 831     my $itemtype = $self->effective_itemtype();
 832     my $rule = Koha::CirculationRules->get_effective_rule(
 833         {
 834             rule_name    => 'article_requests',
 835             categorycode => $borrowertype,
 836             itemtype     => $itemtype,
 837             branchcode   => $branchcode
 838         }
 839     );
 840
 841     return q{} unless $rule;
 842     return $rule->rule_value || q{}
 843 }
 844
 845 =head3 current_holds
 846
 847 =cut
 848
 849 sub current_holds {
 850     my ( $self ) = @_;
 851     my $attributes = { order_by => 'priority' };
 852     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 853     my $params = {
 854         itemnumber => $self->itemnumber,
 855         suspend => 0,
 856         -or => [
 857             reservedate => { '<=' => $dtf->format_date(dt_from_string) },
 858             waitingdate => { '!=' => undef },
 859         ],
 860     };
 861     my $hold_rs = $self->_result->reserves->search( $params, $attributes );
 862     return Koha::Holds->_new_from_dbic($hold_rs);
 863 }
 864
 865 =head3 stockrotationitem
 866
 867   my $sritem = Koha::Item->stockrotationitem;
 868
 869 Returns the stock rotation item associated with the current item.
 870
 871 =cut
 872
 873 sub stockrotationitem {
 874     my ( $self ) = @_;
 875     my $rs = $self->_result->stockrotationitem;
 876     return 0 if !$rs;
 877     return Koha::StockRotationItem->_new_from_dbic( $rs );
 878 }
 879
 880 =head3 add_to_rota
 881
 882   my $item = $item->add_to_rota($rota_id);
 883
 884 Add this item to the rota identified by $ROTA_ID, which means associating it
 885 with the first stage of that rota.  Should this item already be associated
 886 with a rota, then we will move it to the new rota.
 887
 888 =cut
 889
 890 sub add_to_rota {
 891     my ( $self, $rota_id ) = @_;
 892     Koha::StockRotationRotas->find($rota_id)->add_item($self->itemnumber);
 893     return $self;
 894 }
 895
 896 =head3 has_pending_hold
 897
 898   my $is_pending_hold = $item->has_pending_hold();
 899
 900 This method checks the tmp_holdsqueue to see if this item has been selected for a hold, but not filled yet and returns true or false
 901
 902 =cut
 903
 904 sub has_pending_hold {
 905     my ( $self ) = @_;
 906     my $pending_hold = $self->_result->tmp_holdsqueues;
 907     return $pending_hold->count ? 1: 0;
 908 }
 909
 910 =head3 has_pending_recall {
 911
 912   my $has_pending_recall
 913
 914 Return if whether has pending recall of not.
 915
 916 =cut
 917
 918 sub has_pending_recall {
 919     my ( $self ) = @_;
 920
 921     # FIXME Must be moved to $self->recalls
 922     return Koha::Recalls->search(
 923         {
 924             item_id   => $self->itemnumber,
 925             status    => 'waiting',
 926         }
 927     )->count;
 928 }
 929
 930 =head3 as_marc_field
 931
 932     my $field = $item->as_marc_field;
 933
 934 This method returns a MARC::Field object representing the Koha::Item object
 935 with the current mappings configuration.
 936
 937 =cut
 938
 939 sub as_marc_field {
 940     my ( $self ) = @_;
 941
 942     my ( $itemtag, $itemtagsubfield) = C4::Biblio::GetMarcFromKohaField( "items.itemnumber" );
 943
 944     my $tagslib = C4::Biblio::GetMarcStructure( 1, $self->biblio->frameworkcode, { unsafe => 1 });
 945
 946     my @subfields;
 947
 948     my $item_field = $tagslib->{$itemtag};
 949
 950     my $more_subfields = $self->additional_attributes->to_hashref;
 951     foreach my $subfield (
 952         sort {
 953                $a->{display_order} <=> $b->{display_order}
 954             || $a->{subfield} cmp $b->{subfield}
 955         } grep { ref($_) && %$_ } values %$item_field
 956     ){
 957
 958         my $kohafield = $subfield->{kohafield};
 959         my $tagsubfield = $subfield->{tagsubfield};
 960         my $value;
 961         if ( defined $kohafield ) {
 962             next if $kohafield !~ m{^items\.}; # That would be weird!
 963             ( my $attribute = $kohafield ) =~ s|^items\.||;
 964             $value = $self->$attribute # This call may fail if a kohafield is not a DB column but we don't want to add extra work for that there
 965                 if defined $self->$attribute and $self->$attribute ne '';
 966         } else {
 967             $value = $more_subfields->{$tagsubfield}
 968         }
 969
 970         next unless defined $value
 971             and $value ne q{};
 972
 973         if ( $subfield->{repeatable} ) {
 974             my @values = split '\|', $value;
 975             push @subfields, ( $tagsubfield => $_ ) for @values;
 976         }
 977         else {
 978             push @subfields, ( $tagsubfield => $value );
 979         }
 980
 981     }
 982
 983     return unless @subfields;
 984
 985     return MARC::Field->new(
 986         "$itemtag", ' ', ' ', @subfields
 987     );
 988 }
 989
 990 =head3 renewal_branchcode
 991
 992 Returns the branchcode to be recorded in statistics renewal of the item
 993
 994 =cut
 995
 996 sub renewal_branchcode {
 997
 998     my ($self, $params ) = @_;
 999
1000     my $interface = C4::Context->interface;
1001     my $branchcode;
1002     if ( $interface eq 'opac' ){
1003         my $renewal_branchcode = C4::Context->preference('OpacRenewalBranch');
1004         if( !defined $renewal_branchcode || $renewal_branchcode eq 'opacrenew' ){
1005             $branchcode = 'OPACRenew';
1006         }
1007         elsif ( $renewal_branchcode eq 'itemhomebranch' ) {
1008             $branchcode = $self->homebranch;
1009         }
1010         elsif ( $renewal_branchcode eq 'patronhomebranch' ) {
1011             $branchcode = $self->checkout->patron->branchcode;
1012         }
1013         elsif ( $renewal_branchcode eq 'checkoutbranch' ) {
1014             $branchcode = $self->checkout->branchcode;
1015         }
1016         else {
1017             $branchcode = "";
1018         }
1019     } else {
1020         $branchcode = ( C4::Context->userenv && defined C4::Context->userenv->{branch} )
1021             ? C4::Context->userenv->{branch} : $params->{branch};
1022     }
1023     return $branchcode;
1024 }
1025
1026 =head3 cover_images
1027
1028 Return the cover images associated with this item.
1029
1030 =cut
1031
1032 sub cover_images {
1033     my ( $self ) = @_;
1034
1035     my $cover_image_rs = $self->_result->cover_images;
1036     return unless $cover_image_rs;
1037     return Koha::CoverImages->_new_from_dbic($cover_image_rs);
1038 }
1039
1040 =head3 columns_to_str
1041
1042     my $values = $items->columns_to_str;
1043
1044 Return a hashref with the string representation of the different attribute of the item.
1045
1046 This is meant to be used for display purpose only.
1047
1048 =cut
1049
1050 sub columns_to_str {
1051     my ( $self ) = @_;
1052
1053     my $frameworkcode = $self->biblio->frameworkcode;
1054     my $tagslib = C4::Biblio::GetMarcStructure(1, $frameworkcode);
1055     my ( $itemtagfield, $itemtagsubfield) = C4::Biblio::GetMarcFromKohaField( "items.itemnumber" );
1056
1057     my $columns_info = $self->_result->result_source->columns_info;
1058
1059     my $mss = C4::Biblio::GetMarcSubfieldStructure( $frameworkcode, { unsafe => 1 } );
1060     my $values = {};
1061     for my $column ( keys %$columns_info ) {
1062
1063         next if $column eq 'more_subfields_xml';
1064
1065         my $value = $self->$column;
1066         # Maybe we need to deal with datetime columns here, but so far we have damaged_on, itemlost_on and withdrawn_on, and they are not linked with kohafield
1067
1068         if ( not defined $value or $value eq "" ) {
1069             $values->{$column} = $value;
1070             next;
1071         }
1072
1073         my $subfield =
1074           exists $mss->{"items.$column"}
1075           ? @{ $mss->{"items.$column"} }[0] # Should we deal with several subfields??
1076           : undef;
1077
1078         $values->{$column} =
1079             $subfield
1080           ? $subfield->{authorised_value}
1081               ? C4::Biblio::GetAuthorisedValueDesc( $itemtagfield,
1082                   $subfield->{tagsubfield}, $value, '', $tagslib )
1083               : $value
1084           : $value;
1085     }
1086
1087     my $marc_more=
1088       $self->more_subfields_xml
1089       ? MARC::Record->new_from_xml( $self->more_subfields_xml, 'UTF-8' )
1090       : undef;
1091
1092     my $more_values;
1093     if ( $marc_more ) {
1094         my ( $field ) = $marc_more->fields;
1095         for my $sf ( $field->subfields ) {
1096             my $subfield_code = $sf->[0];
1097             my $value = $sf->[1];
1098             my $subfield = $tagslib->{$itemtagfield}->{$subfield_code};
1099             next unless $subfield; # We have the value but it's not mapped, data lose! No regression however.
1100             $value =
1101               $subfield->{authorised_value}
1102               ? C4::Biblio::GetAuthorisedValueDesc( $itemtagfield,
1103                 $subfield->{tagsubfield}, $value, '', $tagslib )
1104               : $value;
1105
1106             push @{$more_values->{$subfield_code}}, $value;
1107         }
1108
1109         while ( my ( $k, $v ) = each %$more_values ) {
1110             $values->{$k} = join ' | ', @$v;
1111         }
1112     }
1113
1114     return $values;
1115 }
1116
1117 =head3 additional_attributes
1118
1119     my $attributes = $item->additional_attributes;
1120     $attributes->{k} = 'new k';
1121     $item->update({ more_subfields => $attributes->to_marcxml });
1122
1123 Returns a Koha::Item::Attributes object that represents the non-mapped
1124 attributes for this item.
1125
1126 =cut
1127
1128 sub additional_attributes {
1129     my ($self) = @_;
1130
1131     return Koha::Item::Attributes->new_from_marcxml(
1132         $self->more_subfields_xml,
1133     );
1134 }
1135
1136 =head3 _set_found_trigger
1137
1138     $self->_set_found_trigger
1139
1140 Finds the most recent lost item charge for this item and refunds the patron
1141 appropriately, taking into account any payments or writeoffs already applied
1142 against the charge.
1143
1144 Internal function, not exported, called only by Koha::Item->store.
1145
1146 =cut
1147
1148 sub _set_found_trigger {
1149     my ( $self, $pre_mod_item ) = @_;
1150
1151     # Reverse any lost item charges if necessary.
1152     my $no_refund_after_days =
1153       C4::Context->preference('NoRefundOnLostReturnedItemsAge');
1154     if ($no_refund_after_days) {
1155         my $today = dt_from_string();
1156         my $lost_age_in_days =
1157           dt_from_string( $pre_mod_item->itemlost_on )->delta_days($today)
1158           ->in_units('days');
1159
1160         return $self unless $lost_age_in_days < $no_refund_after_days;
1161     }
1162
1163     my $lostreturn_policy = Koha::CirculationRules->get_lostreturn_policy(
1164         {
1165             item          => $self,
1166             return_branch => C4::Context->userenv
1167             ? C4::Context->userenv->{'branch'}
1168             : undef,
1169         }
1170       );
1171
1172     if ( $lostreturn_policy ) {
1173
1174         # refund charge made for lost book
1175         my $lost_charge = Koha::Account::Lines->search(
1176             {
1177                 itemnumber      => $self->itemnumber,
1178                 debit_type_code => 'LOST',
1179                 status          => [ undef, { '<>' => 'FOUND' } ]
1180             },
1181             {
1182                 order_by => { -desc => [ 'date', 'accountlines_id' ] },
1183                 rows     => 1
1184             }
1185         )->single;
1186
1187         if ( $lost_charge ) {
1188
1189             my $patron = $lost_charge->patron;
1190             if ( $patron ) {
1191
1192                 my $account = $patron->account;
1193                 my $total_to_refund = 0;
1194
1195                 # Use cases
1196                 if ( $lost_charge->amount > $lost_charge->amountoutstanding ) {
1197
1198                     # some amount has been cancelled. collect the offsets that are not writeoffs
1199                     # this works because the only way to subtract from this kind of a debt is
1200                     # using the UI buttons 'Pay' and 'Write off'
1201                     my $credit_offsets = $lost_charge->debit_offsets(
1202                         {
1203                             'credit_id'               => { '!=' => undef },
1204                             'credit.credit_type_code' => { '!=' => 'Writeoff' }
1205                         },
1206                         { join => 'credit' }
1207                     );
1208
1209                     $total_to_refund = ( $credit_offsets->count > 0 )
1210                       ? $credit_offsets->total * -1    # credits are negative on the DB
1211                       : 0;
1212                 }
1213
1214                 my $credit_total = $lost_charge->amountoutstanding + $total_to_refund;
1215
1216                 my $credit;
1217                 if ( $credit_total > 0 ) {
1218                     my $branchcode =
1219                       C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1220                     $credit = $account->add_credit(
1221                         {
1222                             amount      => $credit_total,
1223                             description => 'Item found ' . $self->itemnumber,
1224                             type        => 'LOST_FOUND',
1225                             interface   => C4::Context->interface,
1226                             library_id  => $branchcode,
1227                             item_id     => $self->itemnumber,
1228                             issue_id    => $lost_charge->issue_id
1229                         }
1230                     );
1231
1232                     $credit->apply( { debits => [$lost_charge] } );
1233                     $self->add_message(
1234                         {
1235                             type    => 'info',
1236                             message => 'lost_refunded',
1237                             payload => { credit_id => $credit->id }
1238                         }
1239                     );
1240                 }
1241
1242                 # Update the account status
1243                 $lost_charge->status('FOUND');
1244                 $lost_charge->store();
1245
1246                 # Reconcile balances if required
1247                 if ( C4::Context->preference('AccountAutoReconcile') ) {
1248                     $account->reconcile_balance;
1249                 }
1250             }
1251         }
1252
1253         # restore fine for lost book
1254         if ( $lostreturn_policy eq 'restore' ) {
1255             my $lost_overdue = Koha::Account::Lines->search(
1256                 {
1257                     itemnumber      => $self->itemnumber,
1258                     debit_type_code => 'OVERDUE',
1259                     status          => 'LOST'
1260                 },
1261                 {
1262                     order_by => { '-desc' => 'date' },
1263                     rows     => 1
1264                 }
1265             )->single;
1266
1267             if ( $lost_overdue ) {
1268
1269                 my $patron = $lost_overdue->patron;
1270                 if ($patron) {
1271                     my $account = $patron->account;
1272
1273                     # Update status of fine
1274                     $lost_overdue->status('FOUND')->store();
1275
1276                     # Find related forgive credit
1277                     my $refund = $lost_overdue->credits(
1278                         {
1279                             credit_type_code => 'FORGIVEN',
1280                             itemnumber       => $self->itemnumber,
1281                             status           => [ { '!=' => 'VOID' }, undef ]
1282                         },
1283                         { order_by => { '-desc' => 'date' }, rows => 1 }
1284                     )->single;
1285
1286                     if ( $refund ) {
1287                         # Revert the forgive credit
1288                         $refund->void({ interface => 'trigger' });
1289                         $self->add_message(
1290                             {
1291                                 type    => 'info',
1292                                 message => 'lost_restored',
1293                                 payload => { refund_id => $refund->id }
1294                             }
1295                         );
1296                     }
1297
1298                     # Reconcile balances if required
1299                     if ( C4::Context->preference('AccountAutoReconcile') ) {
1300                         $account->reconcile_balance;
1301                     }
1302                 }
1303             }
1304         } elsif ( $lostreturn_policy eq 'charge' ) {
1305             $self->add_message(
1306                 {
1307                     type    => 'info',
1308                     message => 'lost_charge',
1309                 }
1310             );
1311         }
1312     }
1313
1314     return $self;
1315 }
1316
1317 =head3 public_read_list
1318
1319 This method returns the list of publicly readable database fields for both API and UI output purposes
1320
1321 =cut
1322
1323 sub public_read_list {
1324     return [
1325         'itemnumber',     'biblionumber',    'homebranch',
1326         'holdingbranch',  'location',        'collectioncode',
1327         'itemcallnumber', 'copynumber',      'enumchron',
1328         'barcode',        'dateaccessioned', 'itemnotes',
1329         'onloan',         'uri',             'itype',
1330         'notforloan',     'damaged',         'itemlost',
1331         'withdrawn',      'restricted'
1332     ];
1333 }
1334
1335 =head3 to_api
1336
1337 Overloaded to_api method to ensure item-level itypes is adhered to.
1338
1339 =cut
1340
1341 sub to_api {
1342     my ($self, $params) = @_;
1343
1344     my $response = $self->SUPER::to_api($params);
1345     my $overrides = {};
1346
1347     $overrides->{effective_item_type_id} = $self->effective_itemtype;
1348     $overrides->{effective_not_for_loan_status} = $self->notforloan ? $self->notforloan : $self->itemtype->notforloan;
1349
1350     return { %$response, %$overrides };
1351 }
1352
1353 =head3 to_api_mapping
1354
1355 This method returns the mapping for representing a Koha::Item object
1356 on the API.
1357
1358 =cut
1359
1360 sub to_api_mapping {
1361     return {
1362         itemnumber               => 'item_id',
1363         biblionumber             => 'biblio_id',
1364         biblioitemnumber         => undef,
1365         barcode                  => 'external_id',
1366         dateaccessioned          => 'acquisition_date',
1367         booksellerid             => 'acquisition_source',
1368         homebranch               => 'home_library_id',
1369         price                    => 'purchase_price',
1370         replacementprice         => 'replacement_price',
1371         replacementpricedate     => 'replacement_price_date',
1372         datelastborrowed         => 'last_checkout_date',
1373         datelastseen             => 'last_seen_date',
1374         stack                    => undef,
1375         notforloan               => 'not_for_loan_status',
1376         damaged                  => 'damaged_status',
1377         damaged_on               => 'damaged_date',
1378         itemlost                 => 'lost_status',
1379         itemlost_on              => 'lost_date',
1380         withdrawn                => 'withdrawn',
1381         withdrawn_on             => 'withdrawn_date',
1382         itemcallnumber           => 'callnumber',
1383         coded_location_qualifier => 'coded_location_qualifier',
1384         issues                   => 'checkouts_count',
1385         renewals                 => 'renewals_count',
1386         reserves                 => 'holds_count',
1387         restricted               => 'restricted_status',
1388         itemnotes                => 'public_notes',
1389         itemnotes_nonpublic      => 'internal_notes',
1390         holdingbranch            => 'holding_library_id',
1391         timestamp                => 'timestamp',
1392         location                 => 'location',
1393         permanent_location       => 'permanent_location',
1394         onloan                   => 'checked_out_date',
1395         cn_source                => 'call_number_source',
1396         cn_sort                  => 'call_number_sort',
1397         ccode                    => 'collection_code',
1398         materials                => 'materials_notes',
1399         uri                      => 'uri',
1400         itype                    => 'item_type_id',
1401         more_subfields_xml       => 'extended_subfields',
1402         enumchron                => 'serial_issue_number',
1403         copynumber               => 'copy_number',
1404         stocknumber              => 'inventory_number',
1405         new_status               => 'new_status',
1406         deleted_on               => undef,
1407     };
1408 }
1409
1410 =head3 itemtype
1411
1412     my $itemtype = $item->itemtype;
1413
1414     Returns Koha object for effective itemtype
1415
1416 =cut
1417
1418 sub itemtype {
1419     my ( $self ) = @_;
1420
1421     return Koha::ItemTypes->find( $self->effective_itemtype );
1422 }
1423
1424 =head3 orders
1425
1426   my $orders = $item->orders();
1427
1428 Returns a Koha::Acquisition::Orders object
1429
1430 =cut
1431
1432 sub orders {
1433     my ( $self ) = @_;
1434
1435     my $orders = $self->_result->item_orders;
1436     return Koha::Acquisition::Orders->_new_from_dbic($orders);
1437 }
1438
1439 =head3 tracked_links
1440
1441   my $tracked_links = $item->tracked_links();
1442
1443 Returns a Koha::TrackedLinks object
1444
1445 =cut
1446
1447 sub tracked_links {
1448     my ( $self ) = @_;
1449
1450     my $tracked_links = $self->_result->linktrackers;
1451     return Koha::TrackedLinks->_new_from_dbic($tracked_links);
1452 }
1453
1454 =head3 move_to_biblio
1455
1456   $item->move_to_biblio($to_biblio[, $params]);
1457
1458 Move the item to another biblio and update any references in other tables.
1459
1460 The final optional parameter, C<$params>, is expected to contain the
1461 'skip_record_index' key, which is relayed down to Koha::Item->store.
1462 There it prevents calling index_records, which takes most of the
1463 time in batch adds/deletes. The caller must take care of calling
1464 index_records separately.
1465
1466 $params:
1467     skip_record_index => 1|0
1468
1469 Returns undef if the move failed or the biblionumber of the destination record otherwise
1470
1471 =cut
1472
1473 sub move_to_biblio {
1474     my ( $self, $to_biblio, $params ) = @_;
1475
1476     $params //= {};
1477
1478     return if $self->biblionumber == $to_biblio->biblionumber;
1479
1480     my $from_biblionumber = $self->biblionumber;
1481     my $to_biblionumber = $to_biblio->biblionumber;
1482
1483     # Own biblionumber and biblioitemnumber
1484     $self->set({
1485         biblionumber => $to_biblionumber,
1486         biblioitemnumber => $to_biblio->biblioitem->biblioitemnumber
1487     })->store({ skip_record_index => $params->{skip_record_index} });
1488
1489     unless ($params->{skip_record_index}) {
1490         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
1491         $indexer->index_records( $from_biblionumber, "specialUpdate", "biblioserver" );
1492     }
1493
1494     # Acquisition orders
1495     $self->orders->update({ biblionumber => $to_biblionumber }, { no_triggers => 1 });
1496
1497     # Holds
1498     $self->holds->update({ biblionumber => $to_biblionumber }, { no_triggers => 1 });
1499
1500     # hold_fill_target (there's no Koha object available yet)
1501     my $hold_fill_target = $self->_result->hold_fill_target;
1502     if ($hold_fill_target) {
1503         $hold_fill_target->update({ biblionumber => $to_biblionumber });
1504     }
1505
1506     # tmp_holdsqueues - Can't update with DBIx since the table is missing a primary key
1507     # and can't even fake one since the significant columns are nullable.
1508     my $storage = $self->_result->result_source->storage;
1509     $storage->dbh_do(
1510         sub {
1511             my ($storage, $dbh, @cols) = @_;
1512
1513             $dbh->do("UPDATE tmp_holdsqueue SET biblionumber=? WHERE itemnumber=?", undef, $to_biblionumber, $self->itemnumber);
1514         }
1515     );
1516
1517     # tracked_links
1518     $self->tracked_links->update({ biblionumber => $to_biblionumber }, { no_triggers => 1 });
1519
1520     return $to_biblionumber;
1521 }
1522
1523 =head3 bundle_items
1524
1525   my $bundle_items = $item->bundle_items;
1526
1527 Returns the items associated with this bundle
1528
1529 =cut
1530
1531 sub bundle_items {
1532     my ($self) = @_;
1533
1534     if ( !$self->{_bundle_items_cached} ) {
1535         my $bundle_items = Koha::Items->search(
1536             { 'item_bundles_item.host' => $self->itemnumber },
1537             { join                     => 'item_bundles_item' } );
1538         $self->{_bundle_items}        = $bundle_items;
1539         $self->{_bundle_items_cached} = 1;
1540     }
1541
1542     return $self->{_bundle_items};
1543 }
1544
1545 =head3 is_bundle
1546
1547   my $is_bundle = $item->is_bundle;
1548
1549 Returns whether the item is a bundle or not
1550
1551 =cut
1552
1553 sub is_bundle {
1554     my ($self) = @_;
1555     return $self->bundle_items->count ? 1 : 0;
1556 }
1557
1558 =head3 bundle_host
1559
1560   my $bundle = $item->bundle_host;
1561
1562 Returns the bundle item this item is attached to
1563
1564 =cut
1565
1566 sub bundle_host {
1567     my ($self) = @_;
1568
1569     my $bundle_items_rs = $self->_result->item_bundles_item;
1570     return unless $bundle_items_rs;
1571     return Koha::Item->_new_from_dbic($bundle_items_rs->host);
1572 }
1573
1574 =head3 in_bundle
1575
1576   my $in_bundle = $item->in_bundle;
1577
1578 Returns whether this item is currently in a bundle
1579
1580 =cut
1581
1582 sub in_bundle {
1583     my ($self) = @_;
1584     return $self->bundle_host ? 1 : 0;
1585 }
1586
1587 =head3 add_to_bundle
1588
1589   my $link = $item->add_to_bundle($bundle_item);
1590
1591 Adds the bundle_item passed to this item
1592
1593 =cut
1594
1595 sub add_to_bundle {
1596     my ( $self, $bundle_item ) = @_;
1597
1598     my $schema = Koha::Database->new->schema;
1599
1600     my $BundleNotLoanValue = C4::Context->preference('BundleNotLoanValue');
1601
1602     try {
1603         $schema->txn_do(
1604             sub {
1605                 $self->_result->add_to_item_bundles_hosts(
1606                     { item => $bundle_item->itemnumber } );
1607
1608                 $bundle_item->notforloan($BundleNotLoanValue)->store();
1609             }
1610         );
1611     }
1612     catch {
1613
1614         # FIXME: See if we can move the below copy/paste from Koha::Object::store into it's own class and catch at a lower level in the Schema instantiation, take inspiration from DBIx::Error
1615         if ( ref($_) eq 'DBIx::Class::Exception' ) {
1616             if ( $_->{msg} =~ /Cannot add or update a child row: a foreign key constraint fails/ ) {
1617                 # FK constraints
1618                 # FIXME: MySQL error, if we support more DB engines we should implement this for each
1619                 if ( $_->{msg} =~ /FOREIGN KEY \(`(?<column>.*?)`\)/ ) {
1620                     Koha::Exceptions::Object::FKConstraint->throw(
1621                         error     => 'Broken FK constraint',
1622                         broken_fk => $+{column}
1623                     );
1624                 }
1625             }
1626             elsif (
1627                 $_->{msg} =~ /Duplicate entry '(.*?)' for key '(?<key>.*?)'/ )
1628             {
1629                 Koha::Exceptions::Object::DuplicateID->throw(
1630                     error        => 'Duplicate ID',
1631                     duplicate_id => $+{key}
1632                 );
1633             }
1634             elsif ( $_->{msg} =~
1635 /Incorrect (?<type>\w+) value: '(?<value>.*)' for column \W?(?<property>\S+)/
1636               )
1637             {    # The optional \W in the regex might be a quote or backtick
1638                 my $type     = $+{type};
1639                 my $value    = $+{value};
1640                 my $property = $+{property};
1641                 $property =~ s/['`]//g;
1642                 Koha::Exceptions::Object::BadValue->throw(
1643                     type     => $type,
1644                     value    => $value,
1645                     property => $property =~ /(\w+\.\w+)$/
1646                     ? $1
1647                     : $property
1648                     ,    # results in table.column without quotes or backtics
1649                 );
1650             }
1651
1652             # Catch-all for foreign key breakages. It will help find other use cases
1653             $_->rethrow();
1654         }
1655         else {
1656             $_;
1657         }
1658     };
1659 }
1660
1661 =head3 remove_from_bundle
1662
1663 Remove this item from any bundle it may have been attached to.
1664
1665 =cut
1666
1667 sub remove_from_bundle {
1668     my ($self) = @_;
1669
1670     my $bundle_item_rs = $self->_result->item_bundles_item;
1671     if ( $bundle_item_rs ) {
1672         $bundle_item_rs->delete;
1673         $self->notforloan(0)->store();
1674         return 1;
1675     }
1676     return 0;
1677 }
1678
1679 =head2 Internal methods
1680
1681 =head3 _after_item_action_hooks
1682
1683 Helper method that takes care of calling all plugin hooks
1684
1685 =cut
1686
1687 sub _after_item_action_hooks {
1688     my ( $self, $params ) = @_;
1689
1690     my $action = $params->{action};
1691
1692     Koha::Plugins->call(
1693         'after_item_action',
1694         {
1695             action  => $action,
1696             item    => $self,
1697             item_id => $self->itemnumber,
1698         }
1699     );
1700 }
1701
1702 =head3 recall
1703
1704     my $recall = $item->recall;
1705
1706 Return the relevant recall for this item
1707
1708 =cut
1709
1710 sub recall {
1711     my ( $self ) = @_;
1712     my @recalls = Koha::Recalls->search(
1713         {
1714             biblio_id => $self->biblionumber,
1715             completed => 0,
1716         },
1717         { order_by => { -asc => 'created_date' } }
1718     )->as_list;
1719     foreach my $recall (@recalls) {
1720         if ( $recall->item_level and $recall->item_id == $self->itemnumber ){
1721             return $recall;
1722         }
1723     }
1724     # no item-level recall to return, so return earliest biblio-level
1725     # FIXME: eventually this will be based on priority
1726     return $recalls[0];
1727 }
1728
1729 =head3 can_be_recalled
1730
1731     if ( $item->can_be_recalled({ patron => $patron_object }) ) # do recall
1732
1733 Does item-level checks and returns if items can be recalled by this borrower
1734
1735 =cut
1736
1737 sub can_be_recalled {
1738     my ( $self, $params ) = @_;
1739
1740     return 0 if !( C4::Context->preference('UseRecalls') );
1741
1742     # check if this item is not for loan, withdrawn or lost
1743     return 0 if ( $self->notforloan != 0 );
1744     return 0 if ( $self->itemlost != 0 );
1745     return 0 if ( $self->withdrawn != 0 );
1746
1747     # check if this item is not checked out - if not checked out, can't be recalled
1748     return 0 if ( !defined( $self->checkout ) );
1749
1750     my $patron = $params->{patron};
1751
1752     my $branchcode = C4::Context->userenv->{'branch'};
1753     if ( $patron ) {
1754         $branchcode = C4::Circulation::_GetCircControlBranch( $self->unblessed, $patron->unblessed );
1755     }
1756
1757     # Check the circulation rule for each relevant itemtype for this item
1758     my $rule = Koha::CirculationRules->get_effective_rules({
1759         branchcode => $branchcode,
1760         categorycode => $patron ? $patron->categorycode : undef,
1761         itemtype => $self->effective_itemtype,
1762         rules => [
1763             'recalls_allowed',
1764             'recalls_per_record',
1765             'on_shelf_recalls',
1766         ],
1767     });
1768
1769     # check recalls allowed has been set and is not zero
1770     return 0 if ( !defined($rule->{recalls_allowed}) || $rule->{recalls_allowed} == 0 );
1771
1772     if ( $patron ) {
1773         # check borrower has not reached open recalls allowed limit
1774         return 0 if ( $patron->recalls->filter_by_current->count >= $rule->{recalls_allowed} );
1775
1776         # check borrower has not reach open recalls allowed per record limit
1777         return 0 if ( $patron->recalls->filter_by_current->search({ biblio_id => $self->biblionumber })->count >= $rule->{recalls_per_record} );
1778
1779         # check if this patron has already recalled this item
1780         return 0 if ( Koha::Recalls->search({ item_id => $self->itemnumber, patron_id => $patron->borrowernumber })->filter_by_current->count > 0 );
1781
1782         # check if this patron has already checked out this item
1783         return 0 if ( Koha::Checkouts->search({ itemnumber => $self->itemnumber, borrowernumber => $patron->borrowernumber })->count > 0 );
1784
1785         # check if this patron has already reserved this item
1786         return 0 if ( Koha::Holds->search({ itemnumber => $self->itemnumber, borrowernumber => $patron->borrowernumber })->count > 0 );
1787     }
1788
1789     # check item availability
1790     # items are unavailable for recall if they are lost, withdrawn or notforloan
1791     my @items = Koha::Items->search({ biblionumber => $self->biblionumber, itemlost => 0, withdrawn => 0, notforloan => 0 })->as_list;
1792
1793     # if there are no available items at all, no recall can be placed
1794     return 0 if ( scalar @items == 0 );
1795
1796     my $checked_out_count = 0;
1797     foreach (@items) {
1798         if ( Koha::Checkouts->search({ itemnumber => $_->itemnumber })->count > 0 ){ $checked_out_count++; }
1799     }
1800
1801     # can't recall if on shelf recalls only allowed when all unavailable, but items are still available for checkout
1802     return 0 if ( $rule->{on_shelf_recalls} eq 'all' && $checked_out_count < scalar @items );
1803
1804     # can't recall if no items have been checked out
1805     return 0 if ( $checked_out_count == 0 );
1806
1807     # can recall
1808     return 1;
1809 }
1810
1811 =head3 can_be_waiting_recall
1812
1813     if ( $item->can_be_waiting_recall ) { # allocate item as waiting for recall
1814
1815 Checks item type and branch of circ rules to return whether this item can be used to fill a recall.
1816 At this point the item has already been recalled. We are now at the checkin and set waiting stage.
1817
1818 =cut
1819
1820 sub can_be_waiting_recall {
1821     my ( $self ) = @_;
1822
1823     return 0 if !( C4::Context->preference('UseRecalls') );
1824
1825     # check if this item is not for loan, withdrawn or lost
1826     return 0 if ( $self->notforloan != 0 );
1827     return 0 if ( $self->itemlost != 0 );
1828     return 0 if ( $self->withdrawn != 0 );
1829
1830     my $branchcode = $self->holdingbranch;
1831     if ( C4::Context->preference('CircControl') eq 'PickupLibrary' and C4::Context->userenv and C4::Context->userenv->{'branch'} ) {
1832         $branchcode = C4::Context->userenv->{'branch'};
1833     } else {
1834         $branchcode = ( C4::Context->preference('HomeOrHoldingBranch') eq 'homebranch' ) ? $self->homebranch : $self->holdingbranch;
1835     }
1836
1837     # Check the circulation rule for each relevant itemtype for this item
1838     my $rule = Koha::CirculationRules->get_effective_rules({
1839         branchcode => $branchcode,
1840         categorycode => undef,
1841         itemtype => $self->effective_itemtype,
1842         rules => [
1843             'recalls_allowed',
1844         ],
1845     });
1846
1847     # check recalls allowed has been set and is not zero
1848     return 0 if ( !defined($rule->{recalls_allowed}) || $rule->{recalls_allowed} == 0 );
1849
1850     # can recall
1851     return 1;
1852 }
1853
1854 =head3 check_recalls
1855
1856     my $recall = $item->check_recalls;
1857
1858 Get the most relevant recall for this item.
1859
1860 =cut
1861
1862 sub check_recalls {
1863     my ( $self ) = @_;
1864
1865     my @recalls = Koha::Recalls->search(
1866         {   biblio_id => $self->biblionumber,
1867             item_id   => [ $self->itemnumber, undef ]
1868         },
1869         { order_by => { -asc => 'created_date' } }
1870     )->filter_by_current->as_list;
1871
1872     my $recall;
1873     # iterate through relevant recalls to find the best one.
1874     # if we come across a waiting recall, use this one.
1875     # if we have iterated through all recalls and not found a waiting recall, use the first recall in the array, which should be the oldest recall.
1876     foreach my $r ( @recalls ) {
1877         if ( $r->waiting ) {
1878             $recall = $r;
1879             last;
1880         }
1881     }
1882     unless ( defined $recall ) {
1883         $recall = $recalls[0];
1884     }
1885
1886     return $recall;
1887 }
1888
1889 =head3 is_notforloan
1890
1891     my $is_notforloan = $item->is_notforloan;
1892
1893 Determine whether or not this item is "notforloan" based on
1894 the item's notforloan status or its item type
1895
1896 =cut
1897
1898 sub is_notforloan {
1899     my ( $self ) = @_;
1900     my $is_notforloan = 0;
1901
1902     if ( $self->notforloan ){
1903         $is_notforloan = 1;
1904     }
1905     else {
1906         my $itemtype = $self->itemtype;
1907         if ($itemtype){
1908             if ( $itemtype->notforloan ){
1909                 $is_notforloan = 1;
1910             }
1911         }
1912     }
1913
1914     return $is_notforloan;
1915 }
1916
1917 =head3 _type
1918
1919 =cut
1920
1921 sub _type {
1922     return 'Item';
1923 }
1924
1925 =head1 AUTHOR
1926
1927 Kyle M Hall <kyle@bywatersolutions.com>
1928
1929 =cut
1930
1931 1;