Koha/Library.pm

   1 package Koha::Library;
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use C4::Context;
  25
  26 use Koha::Database;
  27 use Koha::StockRotationStages;
  28 use Koha::SMTP::Servers;
  29
  30 use base qw(Koha::Object);
  31
  32 =head1 NAME
  33
  34 Koha::Library - Koha Library Object class
  35
  36 =head1 API
  37
  38 =head2 Class methods
  39
  40 =head3 stockrotationstages
  41
  42   my $stages = Koha::Library->stockrotationstages;
  43
  44 Returns the stockrotation stages associated with this Library.
  45
  46 =cut
  47
  48 sub stockrotationstages {
  49     my ( $self ) = @_;
  50     my $rs = $self->_result->stockrotationstages;
  51     return Koha::StockRotationStages->_new_from_dbic( $rs );
  52 }
  53
  54 =head3 get_effective_marcorgcode
  55
  56     my $marcorgcode = Koha::Libraries->find( $library_id )->get_effective_marcorgcode();
  57
  58 Returns the effective MARC organization code of the library. It falls back to the value
  59 from the I<MARCOrgCode> syspref if undefined for the library.
  60
  61 =cut
  62
  63 sub get_effective_marcorgcode {
  64     my ( $self )  = @_;
  65
  66     return $self->marcorgcode || C4::Context->preference("MARCOrgCode");
  67 }
  68
  69 =head3 smtp_server
  70
  71     my $smtp_server = $library->smtp_server;
  72     $library->smtp_server({ smtp_server => $smtp_server });
  73     $library->smtp_server({ smtp_server => undef });
  74
  75 Accessor for getting and setting the library's SMTP server.
  76
  77 Returns the effective SMTP server configuration to be used on the library. The returned
  78 value is always a I<Koha::SMTP::Server> object.
  79
  80 Setting it to undef will remove the link to a specific SMTP server and effectively
  81 make the library use the default setting
  82
  83 =cut
  84
  85 sub smtp_server {
  86     my ( $self, $params ) = @_;
  87
  88     my $library_smtp_server_rs = $self->_result->library_smtp_server;
  89
  90     if ( exists $params->{smtp_server} ) {
  91
  92         $self->_result->result_source->schema->txn_do( sub {
  93             $library_smtp_server_rs->delete
  94                 if $library_smtp_server_rs;
  95
  96             if ( defined $params->{smtp_server} ) {
  97                 # Set the new server
  98                 # Remove any already set SMTP server
  99
 100                 my $smtp_server = $params->{smtp_server};
 101                 $smtp_server->_result->add_to_library_smtp_servers({ library_id => $self->id });
 102             }
 103         });
 104     } # else => reset to default
 105     else {
 106         # Getter
 107         if ( $library_smtp_server_rs ) {
 108             return Koha::SMTP::Servers->find(
 109                 $library_smtp_server_rs->smtp_server_id );
 110         }
 111
 112         return Koha::SMTP::Servers->get_default;
 113     }
 114
 115     return $self;
 116 }
 117
 118 =head3 smtp_server_info
 119
 120 Returns the SMTP server info for the library, or 'system_default' if it is the system default.
 121
 122 =cut
 123
 124 sub smtp_server_info {
 125     my ($self) = @_;
 126
 127     my $smtp_server = $self->smtp_server;
 128
 129     return { name => 'system_default' }
 130         if $smtp_server->is_system_default;
 131
 132     return { name => $smtp_server->name, smtp_server_id => $smtp_server->id };
 133 }
 134
 135 =head3 inbound_email_address
 136
 137   my $to_email = Koha::Library->inbound_email_address;
 138
 139 Returns an effective email address which should be accessible to librarians at the branch.
 140
 141 =cut
 142
 143 sub inbound_email_address {
 144     my ($self) = @_;
 145
 146     return
 147          $self->branchreplyto
 148       || $self->branchemail
 149       || C4::Context->preference('ReplytoDefault')
 150       || C4::Context->preference('KohaAdminEmailAddress')
 151       || undef;
 152 }
 153
 154 =head3 library_groups
 155
 156 Return the Library groups of this library
 157
 158 =cut
 159
 160 sub library_groups {
 161     my ( $self ) = @_;
 162     my $rs = $self->_result->library_groups;
 163     return Koha::Library::Groups->_new_from_dbic( $rs );
 164 }
 165
 166 =head3 cash_registers
 167
 168 Return Cash::Registers associated with this Library
 169
 170 =cut
 171
 172 sub cash_registers {
 173     my ( $self ) = @_;
 174     my $rs = $self->_result->cash_registers;
 175     return Koha::Cash::Registers->_new_from_dbic( $rs );
 176 }
 177
 178 =head3 to_api_mapping
 179
 180 This method returns the mapping for representing a Koha::Library object
 181 on the API.
 182
 183 =cut
 184
 185 sub to_api_mapping {
 186     return {
 187         branchcode       => 'library_id',
 188         branchname       => 'name',
 189         branchaddress1   => 'address1',
 190         branchaddress2   => 'address2',
 191         branchaddress3   => 'address3',
 192         branchzip        => 'postal_code',
 193         branchcity       => 'city',
 194         branchstate      => 'state',
 195         branchcountry    => 'country',
 196         branchphone      => 'phone',
 197         branchfax        => 'fax',
 198         branchemail      => 'email',
 199         branchreplyto    => 'reply_to_email',
 200         branchreturnpath => 'return_path_email',
 201         branchurl        => 'url',
 202         issuing          => undef,
 203         branchip         => 'ip',
 204         branchnotes      => 'notes',
 205         marcorgcode      => 'marc_org_code',
 206     };
 207 }
 208
 209 =head3 get_hold_libraries
 210
 211 Return all libraries (including self) that belong to the same hold groups
 212
 213 =cut
 214
 215 sub get_hold_libraries {
 216     my ( $self ) = @_;
 217     my $library_groups = $self->library_groups;
 218     my @hold_libraries;
 219     while ( my $library_group = $library_groups->next ) {
 220         my $root = Koha::Library::Groups->get_root_ancestor({id => $library_group->id});
 221         if($root->ft_local_hold_group) {
 222             push @hold_libraries, $root->all_libraries;
 223         }
 224     }
 225
 226     my %seen;
 227     @hold_libraries =
 228       grep { !$seen{ $_->id }++ } @hold_libraries;
 229
 230     return @hold_libraries;
 231 }
 232
 233 =head3 validate_hold_sibling
 234
 235 Return if given library is a valid hold group member
 236
 237 =cut
 238
 239 sub validate_hold_sibling {
 240     my ( $self, $params ) = @_;
 241     my @hold_libraries = $self->get_hold_libraries;
 242
 243     foreach (@hold_libraries) {
 244         my $hold_library = $_;
 245         my $is_valid = 1;
 246         foreach my $key (keys %$params) {
 247             unless($hold_library->$key eq $params->{$key}) {
 248                 $is_valid=0;
 249                 last;
 250             }
 251         }
 252         if($is_valid) {
 253             #Found one library that meets all search parameters
 254             return 1;
 255         }
 256     }
 257     return 0;
 258 }
 259
 260 =head2 Internal methods
 261
 262 =head3 _type
 263
 264 =cut
 265
 266 sub _type {
 267     return 'Branch';
 268 }
 269
 270 1;