Koha/REST/V1/BackgroundJobs.pm

   1 package Koha::REST::V1::BackgroundJobs;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious::Controller';
  21
  22 use Koha::BackgroundJobs;
  23
  24 use Try::Tiny;
  25
  26 =head1 API
  27
  28 =head2 Methods
  29
  30 =head3 list
  31
  32 Controller function that handles listing Koha::BackgroundJob objects
  33
  34 =cut
  35
  36 sub list {
  37     my $c = shift->openapi->valid_input or return;
  38
  39     return try {
  40
  41         my $only_current = $c->param('only_current');
  42         $c->req->params->remove('only_current');
  43
  44         my $bj_rs = Koha::BackgroundJobs->new;
  45
  46         if ($only_current) {
  47             $bj_rs = $bj_rs->filter_by_current;
  48         }
  49
  50         return $c->render(
  51             status  => 200,
  52             openapi => $c->objects->search($bj_rs)
  53         );
  54     } catch {
  55         $c->unhandled_exception($_);
  56     };
  57 }
  58
  59 =head3 get
  60
  61 Controller function that handles retrieving a single Koha::BackgroundJob object
  62
  63 =cut
  64
  65 sub get {
  66     my $c = shift->openapi->valid_input or return;
  67
  68     return try {
  69
  70         my $job_id = $c->param('job_id');
  71         my $patron = $c->stash('koha.user');
  72
  73         my $can_manage_background_jobs =
  74           $patron->has_permission( { parameters => 'manage_background_jobs' } );
  75
  76         my $job = Koha::BackgroundJobs->find($job_id);
  77
  78         return $c->render(
  79             status  => 404,
  80             openapi => { error => "Object not found" }
  81         ) unless $job;
  82
  83         return $c->render(
  84             status  => 403,
  85             openapi => { error => "Cannot see background job info" }
  86           )
  87           if !$can_manage_background_jobs
  88           && $job->borrowernumber != $patron->borrowernumber;
  89
  90         return $c->render(
  91             status  => 200,
  92             openapi => $job->to_api
  93         );
  94     }
  95     catch {
  96         $c->unhandled_exception($_);
  97     };
  98 }
  99
 100 1;