acqui/duplicate_orders.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2018 Koha Development Team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Auth qw( get_template_and_user );
  25 use C4::Output qw( output_and_exit output_html_with_http_headers );
  26 use C4::Acquisition qw( GetHistory );
  27 use C4::Budgets qw( GetBudgetHierarchy GetBudget CanUserUseBudget GetBudgetPeriods GetBudgetPeriod );
  28 use Koha::Acquisition::Baskets;
  29 use Koha::Acquisition::Currencies;
  30 use Koha::Acquisition::Orders;
  31 use Koha::DateUtils qw( dt_from_string );
  32
  33 my $input    = CGI->new;
  34 my $basketno = $input->param('basketno');
  35 my $op       = $input->param('op') || 'search';    # search, select, batch_edit
  36
  37 my ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
  38     {
  39         template_name   => "acqui/duplicate_orders.tt",
  40         query           => $input,
  41         type            => "intranet",
  42         flagsrequired   => { acquisition => 'order_manage' },
  43     }
  44 );
  45
  46 my $basket = Koha::Acquisition::Baskets->find($basketno);
  47
  48 output_and_exit( $input, $cookie, $template, 'unknown_basket' )
  49   unless $basket;
  50
  51 my $vendor = $basket->bookseller;
  52 my $patron = Koha::Patrons->find($loggedinuser)->unblessed;
  53
  54 my $filters = {
  55     basket                  => scalar $input->param('basket'),
  56     title                   => scalar $input->param('title'),
  57     author                  => scalar $input->param('author'),
  58     isbn                    => scalar $input->param('isbn'),
  59     name                    => scalar $input->param('name'),
  60     ean                     => scalar $input->param('ean'),
  61     basketgroupname         => scalar $input->param('basketgroupname'),
  62     booksellerinvoicenumber => scalar $input->param('booksellerinvoicenumber'),
  63     budget                  => scalar $input->param('budget'),
  64     orderstatus             => scalar $input->param('orderstatus'),
  65     ordernumber             => scalar $input->param('ordernumber'),
  66     search_children_too     => scalar $input->param('search_children_too'),
  67     created_by              => [$input->multi_param('created_by')]
  68 };
  69
  70 my $from_placed_on =
  71   eval { dt_from_string( scalar $input->param('from') ) } || dt_from_string;
  72 my $to_placed_on =
  73   eval { dt_from_string( scalar $input->param('to') )   } || dt_from_string;
  74
  75 unless ( $input->param('from') ) {
  76     # Fill the form with year-1
  77     $from_placed_on->set_time_zone('floating')->subtract( years => 1 );
  78 }
  79 $filters->{from_placed_on} = $from_placed_on;
  80 $filters->{to_placed_on}   = $to_placed_on;
  81
  82   my ( @result_order_loop, @selected_order_loop );
  83 my @ordernumbers = split ',', scalar $input->param('ordernumbers') || '';
  84 if ( $op eq 'select' ) {
  85
  86     # Set filter for 'all status'
  87     if ( $filters->{orderstatus} eq "any" ) {
  88         $filters->{get_canceled_order} = 1;
  89     }
  90
  91     @result_order_loop = map {
  92         my $order = $_;
  93         ( grep {$_ eq $order->{ordernumber}} @ordernumbers ) ? () : $order
  94     } @{ C4::Acquisition::GetHistory(%$filters) };
  95
  96     @selected_order_loop =
  97       scalar @ordernumbers
  98       ? @{ C4::Acquisition::GetHistory( ordernumbers => \@ordernumbers ) }
  99       : ();
 100 }
 101 elsif ( $op eq 'cud-batch_edit' ) {
 102     @ordernumbers = $input->multi_param('ordernumber');
 103
 104     # build budget list
 105     my $budget_loop       = [];
 106     my $budgets_hierarchy = GetBudgetHierarchy;
 107     foreach my $r ( @{$budgets_hierarchy} ) {
 108         next
 109           unless ( C4::Budgets::CanUserUseBudget( $patron, $r, $userflags ) );
 110
 111         push @{$budget_loop},
 112           {
 113             b_id            => $r->{budget_id},
 114             b_txt           => $r->{budget_name},
 115             b_code          => $r->{budget_code},
 116             b_sort1_authcat => $r->{'sort1_authcat'},
 117             b_sort2_authcat => $r->{'sort2_authcat'},
 118             b_active        => $r->{budget_period_active},
 119           };
 120     }
 121     @{$budget_loop} =
 122       sort { uc( $a->{b_txt} ) cmp uc( $b->{b_txt} ) } @{$budget_loop};
 123
 124     $template->param(
 125         currencies  => Koha::Acquisition::Currencies->search,
 126         budget_loop => $budget_loop,
 127     );
 128 }
 129 elsif ( $op eq 'cud-do_duplicate' ) {
 130     my @fields_to_copy = $input->multi_param('copy_existing_value');
 131
 132     my $default_values;
 133     for my $field (
 134         qw(currency budget_id order_internalnote order_vendornote sort1 sort2 ))
 135     {
 136         next if grep { $_ eq $field } @fields_to_copy;
 137         $default_values->{$field} = $input->param("all_$field");
 138     }
 139
 140     @ordernumbers = $input->multi_param('ordernumber');
 141     my @new_ordernumbers;
 142     for my $ordernumber (@ordernumbers) {
 143         my $original_order = Koha::Acquisition::Orders->find($ordernumber);
 144         next unless $original_order;
 145         my $new_order =
 146           $original_order->duplicate_to( $basket, $default_values );
 147         push @new_ordernumbers, $new_order->ordernumber;
 148     }
 149
 150     my $new_orders =
 151       C4::Acquisition::GetHistory( ordernumbers => \@new_ordernumbers );
 152     $template->param( new_orders => $new_orders );
 153     $op = 'duplication_done';
 154 }
 155
 156 my $budgetperiods = C4::Budgets::GetBudgetPeriods;
 157 my $bp_loop       = $budgetperiods;
 158 for my $bp ( @{$budgetperiods} ) {
 159     my $hierarchy = C4::Budgets::GetBudgetHierarchy( $$bp{budget_period_id} );
 160     for my $budget ( @{$hierarchy} ) {
 161         $$budget{budget_display_name} =
 162           sprintf( "%s", ">" x $$budget{depth} . $$budget{budget_name} );
 163     }
 164     $$bp{hierarchy} = $hierarchy;
 165 }
 166
 167 $template->param(
 168     basket              => $basket,
 169     vendor              => $vendor,
 170     filters             => $filters,
 171     result_order_loop   => \@result_order_loop,
 172     selected_order_loop => \@selected_order_loop,
 173     bp_loop             => $bp_loop,
 174     ordernumbers        => \@ordernumbers,
 175     op                  => $op,
 176 );
 177
 178 output_html_with_http_headers $input, $cookie, $template->output;