acqui/orderreceive.pl

   1 #!/usr/bin/perl
   2
   3
   4 #script to receive orders
   5 #written by chris@katipo.co.nz 24/2/2000
   6
   7 # Copyright 2000-2002 Katipo Communications
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 3 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24 =head1 NAME
  25
  26 orderreceive.pl
  27
  28 =head1 DESCRIPTION
  29
  30 This script shows all order already receive and all pendings orders.
  31 It permit to write a new order as 'received'.
  32
  33 =head1 CGI PARAMETERS
  34
  35 =over 4
  36
  37 =item booksellerid
  38
  39 to know on what supplier this script has to display receive order.
  40
  41 =item invoiceid
  42
  43 the id of this invoice.
  44
  45 =item freight
  46
  47 =item biblio
  48
  49 The biblionumber of this order.
  50
  51 =item datereceived
  52
  53 =item catview
  54
  55 =item gst
  56
  57 =back
  58
  59 =cut
  60
  61 use Modern::Perl;
  62
  63 use CGI qw ( -utf8 );
  64 use C4::Context;
  65 use C4::Acquisition qw( GetInvoice );
  66 use C4::Auth qw( get_template_and_user );
  67 use C4::Output qw( output_html_with_http_headers );
  68 use C4::Budgets qw( GetBudget GetBudgetPeriods GetBudgetPeriod GetBudgetHierarchy CanUserUseBudget );
  69 use C4::Members;
  70 use C4::Biblio qw( GetMarcStructure );
  71 use C4::Suggestions qw( GetSuggestion GetSuggestionInfoFromBiblionumber GetSuggestionInfo );
  72
  73 use Koha::Acquisition::Booksellers;
  74 use Koha::Acquisition::Currencies qw( get_active );
  75 use Koha::Acquisition::Orders;
  76 use Koha::DateUtils qw( dt_from_string );
  77 use Koha::ItemTypes;
  78 use Koha::Patrons;
  79
  80 my $input      = CGI->new;
  81
  82 my $dbh          = C4::Context->dbh;
  83 my $invoiceid    = $input->param('invoiceid');
  84 my $invoice      = GetInvoice($invoiceid);
  85 my $booksellerid   = $invoice->{booksellerid};
  86 my $freight      = $invoice->{shipmentcost};
  87 my $ordernumber  = $input->param('ordernumber');
  88 my $multiple_orders = $input->param('multiple_orders');
  89
  90 my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
  91 my $order = Koha::Acquisition::Orders->find( $ordernumber );
  92
  93 my ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
  94     {
  95         template_name   => "acqui/orderreceive.tt",
  96         query           => $input,
  97         type            => "intranet",
  98         flagsrequired   => {acquisition => 'order_receive'},
  99     }
 100 );
 101
 102 unless ( $order || $multiple_orders ) {
 103     output_html_with_http_headers $input, $cookie, $template->output;
 104     exit;
 105 }
 106
 107 my $budget;
 108 if ($order) {
 109
 110     # prepare the form for receiving
 111     my $creator = Koha::Patrons->find( $order->created_by );
 112
 113     $budget = GetBudget( $order->budget_id );
 114
 115     my $datereceived = $order->datereceived || dt_from_string;
 116
 117     my $order_internalnote = $order->order_internalnote;
 118     my $order_vendornote   = $order->order_vendornote;
 119     if ( $order->subscriptionid ) {
 120
 121         # Order from a subscription, we will display an history of what has been received
 122         my $orders = Koha::Acquisition::Orders->search(
 123             {
 124                 subscriptionid     => $order->subscriptionid,
 125                 parent_ordernumber => $order->ordernumber,
 126                 ordernumber        => { '!=' => $order->ordernumber }
 127             }
 128         );
 129         if ( $order->parent_ordernumber != $order->ordernumber ) {
 130             my $parent_order = Koha::Acquisition::Orders->find( $order->parent_ordernumber );
 131             $order_internalnote = $parent_order->order_internalnote;
 132             $order_vendornote   = $parent_order->order_vendornote;
 133         }
 134         $template->param( orders => $orders, );
 135     }
 136
 137     my $suggestion = GetSuggestionInfoFromBiblionumber( $order->biblionumber );
 138
 139     if ($suggestion) {
 140         $template->param( suggestion => $suggestion );
 141     }
 142
 143     $template->param(
 144         order              => $order,
 145         creator            => $creator,
 146         bookfund           => $budget->{budget_name},
 147         datereceived       => $datereceived,
 148         order_internalnote => $order_internalnote,
 149         order_vendornote   => $order_vendornote,
 150     );
 151 }
 152
 153 if ($multiple_orders) {
 154     $template->param( multiple_orders => $multiple_orders );
 155 }
 156
 157 my $currencies = Koha::Acquisition::Currencies->search;
 158 my $active_currency = $currencies->get_active;
 159
 160 # Check if ACQ framework exists
 161 my $acq_fw = GetMarcStructure( 1, 'ACQ', { unsafe => 1 } );
 162 unless($acq_fw) {
 163     $template->param('NoACQframework' => 1);
 164 }
 165
 166 # get option values for TaxRates syspref
 167 my @gst_values = map {
 168     option => $_ + 0.0
 169 }, split( '\|', C4::Context->preference("TaxRates") );
 170
 171 $template->param(
 172     freight               => $freight,
 173     name                  => $bookseller->name,
 174     active_currency       => $active_currency,
 175     currencies            => $currencies->search({ rate => { '!=' => 1 } }),
 176     invoiceincgst         => $bookseller->invoiceincgst,
 177     invoiceid             => $invoice->{invoiceid},
 178     invoice               => $invoice->{invoicenumber},
 179     gst_values            => \@gst_values,
 180     vendor                => $bookseller,
 181 );
 182
 183 my $patron = Koha::Patrons->find( $loggedinuser )->unblessed;
 184 my %budget_loops;
 185 my $budgets = GetBudgetHierarchy( undef, undef, undef, 1 );
 186 foreach my $budget (@{$budgets}) {
 187     next unless (CanUserUseBudget($patron, $budget, $userflags));
 188     unless ( defined $budget_loops{$budget->{budget_period_id}} ){
 189         $budget_loops{$budget->{budget_period_id}}->{description} = $budget->{budget_period_description};
 190         $budget_loops{$budget->{budget_period_id}}->{active} = $budget->{budget_period_active};
 191         $budget_loops{$budget->{budget_period_id}}->{funds} = [];
 192     }
 193     push @{$budget_loops{$budget->{budget_period_id}}->{funds}}, {
 194         b_id  => $budget->{budget_id},
 195         b_txt => $budget->{budget_name},
 196         b_sort1_authcat => $budget->{'sort1_authcat'},
 197         b_sort2_authcat => $budget->{'sort2_authcat'},
 198         b_active => $budget->{budget_period_active},
 199         b_level => $budget->{budget_level},
 200     };
 201 }
 202 $template->{'VARS'}->{'budget_loops'} = \%budget_loops;
 203
 204 my $op = $input->param('op');
 205 if ($op and $op eq 'edit'){
 206     $template->param(edit   =>   1);
 207 }
 208 output_html_with_http_headers $input, $cookie, $template->output;