cataloguing/additem.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2004-2010 BibLibre
   5 # Parts Copyright Catalyst IT 2011
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use Modern::Perl;
  23
  24 use CGI qw ( -utf8 );
  25 use C4::Auth qw( get_template_and_user haspermission );
  26 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  27 use C4::Biblio qw(
  28     GetAuthorisedValueDesc
  29     GetFrameworkCode
  30     GetMarcBiblio
  31     GetMarcFromKohaField
  32     GetMarcStructure
  33     IsMarcStructureInternal
  34     ModBiblio
  35     TransformHtmlToXml
  36     TransformMarcToKoha
  37 );
  38 use C4::Items qw( AddItemFromMarc ModItemFromMarc );
  39 use C4::Context;
  40 use C4::Circulation qw( LostItem );
  41 use C4::Koha qw( GetAuthorisedValues );
  42 use C4::ClassSource qw( GetClassSources GetClassSource );
  43 use C4::Barcodes;
  44 use C4::Barcodes::ValueBuilder;
  45 use Koha::DateUtils qw( dt_from_string );
  46 use Koha::Items;
  47 use Koha::ItemTypes;
  48 use Koha::Libraries;
  49 use Koha::Patrons;
  50 use Koha::SearchEngine::Indexer;
  51 use C4::Search qw( enabled_staff_search_views );
  52 use Storable qw( freeze thaw );
  53 use URI::Escape qw( uri_escape_utf8 );
  54 use C4::Members;
  55
  56 use MARC::File::XML;
  57 use URI::Escape qw( uri_escape_utf8 );
  58 use MIME::Base64 qw( decode_base64url encode_base64url );
  59 use List::Util qw( first );
  60 use List::MoreUtils qw( any uniq );
  61
  62 our $dbh = C4::Context->dbh;
  63
  64 sub generate_subfield_form {
  65         my ($tag, $subfieldtag, $value, $tagslib,$subfieldlib, $branches, $biblionumber, $temp, $subfields, $i, $restrictededition, $item) = @_;
  66
  67         my $frameworkcode = &GetFrameworkCode($biblionumber);
  68
  69         $item //= {};
  70
  71         my %subfield_data;
  72         my $dbh = C4::Context->dbh;
  73
  74         my $index_subfield = int(rand(1000000));
  75         if ($subfieldtag eq '@'){
  76             $subfield_data{id} = "tag_".$tag."_subfield_00_".$index_subfield;
  77         } else {
  78             $subfield_data{id} = "tag_".$tag."_subfield_".$subfieldtag."_".$index_subfield;
  79         }
  80
  81         $subfield_data{tag}        = $tag;
  82         $subfield_data{subfield}   = $subfieldtag;
  83         $subfield_data{marc_lib}   ="<span id=\"error$i\" title=\"".$subfieldlib->{lib}."\">".$subfieldlib->{lib}."</span>";
  84         $subfield_data{mandatory}  = $subfieldlib->{mandatory};
  85         $subfield_data{important}  = $subfieldlib->{important};
  86         $subfield_data{repeatable} = $subfieldlib->{repeatable};
  87         $subfield_data{maxlength}  = $subfieldlib->{maxlength};
  88         $subfield_data{display_order} = $subfieldlib->{display_order};
  89         $subfield_data{kohafield}  = $subfieldlib->{kohafield} || 'items.more_subfields_xml';
  90
  91         if ( ! defined( $value ) || $value eq '')  {
  92             $value = $subfieldlib->{defaultvalue};
  93             if ( $value ) {
  94                 # get today date & replace <<YYYY>>, <<YY>>, <<MM>>, <<DD>> if provided in the default value
  95                 my $today_dt = dt_from_string;
  96                 my $year = $today_dt->strftime('%Y');
  97                 my $shortyear = $today_dt->strftime('%y');
  98                 my $month = $today_dt->strftime('%m');
  99                 my $day = $today_dt->strftime('%d');
 100                 $value =~ s/<<YYYY>>/$year/g;
 101                 $value =~ s/<<YY>>/$shortyear/g;
 102                 $value =~ s/<<MM>>/$month/g;
 103                 $value =~ s/<<DD>>/$day/g;
 104                 # And <<USER>> with surname (?)
 105                 my $username=(C4::Context->userenv?C4::Context->userenv->{'surname'}:"superlibrarian");
 106                 $value=~s/<<USER>>/$username/g;
 107             }
 108         }
 109
 110         $subfield_data{visibility} = "display:none;" if (($subfieldlib->{hidden} > 4) || ($subfieldlib->{hidden} <= -4));
 111
 112         my $pref_itemcallnumber = C4::Context->preference('itemcallnumber');
 113         if (!$value && $subfieldlib->{kohafield} eq 'items.itemcallnumber' && $pref_itemcallnumber) {
 114             foreach my $pref_itemcallnumber_part (split(/,/, $pref_itemcallnumber)){
 115                 my $CNtag       = substr( $pref_itemcallnumber_part, 0, 3 ); # 3-digit tag number
 116                 my $CNsubfields = substr( $pref_itemcallnumber_part, 3 ); # Any and all subfields
 117                 $CNsubfields = undef if $CNsubfields eq '';
 118                 my $temp2 = $temp->field($CNtag);
 119
 120                 next unless $temp2;
 121                 $value = $temp2->as_string( $CNsubfields, ' ' );
 122                 last if $value;
 123             }
 124         }
 125
 126         my $default_location = C4::Context->preference('NewItemsDefaultLocation');
 127         if ( !$value && $subfieldlib->{kohafield} eq 'items.location' && $default_location ) {
 128             $value = $default_location;
 129         }
 130
 131         if ($frameworkcode eq 'FA' && $subfieldlib->{kohafield} eq 'items.barcode' && !$value){
 132             my $input = CGI->new;
 133             $value = $input->param('barcode');
 134         }
 135
 136         if ( $subfieldlib->{authorised_value} ) {
 137             my @authorised_values;
 138             my %authorised_lib;
 139             # builds list, depending on authorised value...
 140             if ( $subfieldlib->{authorised_value} eq "LOST" ) {
 141                 my $ClaimReturnedLostValue = C4::Context->preference('ClaimReturnedLostValue');
 142                 my $item_is_return_claim = $ClaimReturnedLostValue && exists $item->{itemlost} && $ClaimReturnedLostValue eq $item->{itemlost};
 143                 $subfield_data{IS_RETURN_CLAIM} = $item_is_return_claim;
 144
 145                 $subfield_data{IS_LOST_AV} = 1;
 146
 147                 push @authorised_values, qq{};
 148                 my $av = GetAuthorisedValues( $subfieldlib->{authorised_value} );
 149                 for my $r ( @$av ) {
 150                     push @authorised_values, $r->{authorised_value};
 151                     $authorised_lib{$r->{authorised_value}} = $r->{lib};
 152                 }
 153             }
 154             elsif ( $subfieldlib->{authorised_value} eq "branches" ) {
 155                 foreach my $thisbranch (@$branches) {
 156                     push @authorised_values, $thisbranch->{branchcode};
 157                     $authorised_lib{$thisbranch->{branchcode}} = $thisbranch->{branchname};
 158                     $value = $thisbranch->{branchcode} if $thisbranch->{selected} && !$value;
 159                 }
 160             }
 161             elsif ( $subfieldlib->{authorised_value} eq "itemtypes" ) {
 162                   push @authorised_values, "";
 163                   my $branch_limit = C4::Context->userenv && C4::Context->userenv->{"branch"};
 164                   my $itemtypes;
 165                   if($branch_limit) {
 166                       $itemtypes = Koha::ItemTypes->search_with_localization({branchcode => $branch_limit});
 167                   } else {
 168                       $itemtypes = Koha::ItemTypes->search_with_localization;
 169                   }
 170                   while ( my $itemtype = $itemtypes->next ) {
 171                       push @authorised_values, $itemtype->itemtype;
 172                       $authorised_lib{$itemtype->itemtype} = $itemtype->translated_description;
 173                   }
 174
 175                   unless ( $value ) {
 176                       my $itype_sth = $dbh->prepare("SELECT itemtype FROM biblioitems WHERE biblionumber = ?");
 177                       $itype_sth->execute( $biblionumber );
 178                       ( $value ) = $itype_sth->fetchrow_array;
 179                   }
 180
 181                   #---- class_sources
 182             }
 183             elsif ( $subfieldlib->{authorised_value} eq "cn_source" ) {
 184                   push @authorised_values, "";
 185
 186                   my $class_sources = GetClassSources();
 187                   my $default_source = C4::Context->preference("DefaultClassificationSource");
 188
 189                   foreach my $class_source (sort keys %$class_sources) {
 190                       next unless $class_sources->{$class_source}->{'used'} or
 191                                   ($value and $class_source eq $value)      or
 192                                   ($class_source eq $default_source);
 193                       push @authorised_values, $class_source;
 194                       $authorised_lib{$class_source} = $class_sources->{$class_source}->{'description'};
 195                   }
 196                           $value = $default_source unless ($value);
 197
 198                   #---- "true" authorised value
 199             }
 200             else {
 201                   push @authorised_values, qq{};
 202                   my $av = GetAuthorisedValues( $subfieldlib->{authorised_value} );
 203                   for my $r ( @$av ) {
 204                       push @authorised_values, $r->{authorised_value};
 205                       $authorised_lib{$r->{authorised_value}} = $r->{lib};
 206                   }
 207             }
 208
 209             if ( $subfieldlib->{hidden} > 4 or $subfieldlib->{hidden} <= -4 ) {
 210                 $subfield_data{marc_value} = {
 211                     type        => 'hidden',
 212                     id          => $subfield_data{id},
 213                     maxlength   => $subfield_data{maxlength},
 214                     value       => $value,
 215                     ( ( grep { $_ eq $subfieldlib->{authorised_value}} ( qw(branches itemtypes cn_source) ) ) ? () : ( category => $subfieldlib->{authorised_value}) ),
 216                 };
 217             }
 218             else {
 219                 $subfield_data{marc_value} = {
 220                     type     => 'select',
 221                     id       => "tag_".$tag."_subfield_".$subfieldtag."_".$index_subfield,
 222                     values   => \@authorised_values,
 223                     labels   => \%authorised_lib,
 224                     default  => $value,
 225                     ( ( grep { $_ eq $subfieldlib->{authorised_value}} ( qw(branches itemtypes cn_source) ) ) ? () : ( category => $subfieldlib->{authorised_value}) ),
 226                 };
 227             }
 228         }
 229             # it's a thesaurus / authority field
 230         elsif ( $subfieldlib->{authtypecode} ) {
 231                 $subfield_data{marc_value} = {
 232                     type         => 'text_auth',
 233                     id           => $subfield_data{id},
 234                     maxlength    => $subfield_data{maxlength},
 235                     value        => $value,
 236                     authtypecode => $subfieldlib->{authtypecode},
 237                 };
 238         }
 239             # it's a plugin field
 240         elsif ( $subfieldlib->{value_builder} ) { # plugin
 241             require Koha::FrameworkPlugin;
 242             my $plugin = Koha::FrameworkPlugin->new({
 243                 name => $subfieldlib->{'value_builder'},
 244                 item_style => 1,
 245             });
 246             my $pars=  { dbh => $dbh, record => $temp, tagslib =>$tagslib,
 247                 id => $subfield_data{id}, tabloop => $subfields };
 248             $plugin->build( $pars );
 249             if( !$plugin->errstr ) {
 250                 my $class= 'buttonDot'. ( $plugin->noclick? ' disabled': '' );
 251                 $subfield_data{marc_value} = {
 252                     type        => 'text_plugin',
 253                     id          => $subfield_data{id},
 254                     maxlength   => $subfield_data{maxlength},
 255                     value       => $value,
 256                     class       => $class,
 257                     nopopup     => $plugin->noclick,
 258                     javascript  => $plugin->javascript,
 259                 };
 260             } else {
 261                 warn $plugin->errstr;
 262                 $subfield_data{marc_value} = {
 263                     type        => 'text',
 264                     id          => $subfield_data{id},
 265                     maxlength   => $subfield_data{maxlength},
 266                     value       => $value,
 267                 }; # supply default input form
 268             }
 269         }
 270         elsif ( $tag eq '' ) {       # it's an hidden field
 271             $subfield_data{marc_value} = {
 272                 type        => 'hidden',
 273                 id          => $subfield_data{id},
 274                 maxlength   => $subfield_data{maxlength},
 275                 value       => $value,
 276             };
 277         }
 278         elsif ( $subfieldlib->{'hidden'} ) {   # FIXME: shouldn't input type be "hidden" ?
 279             $subfield_data{marc_value} = {
 280                 type        => 'text',
 281                 id          => $subfield_data{id},
 282                 maxlength   => $subfield_data{maxlength},
 283                 value       => $value,
 284             };
 285         }
 286         elsif (
 287                 (
 288                     $value and length($value) > 100
 289                 )
 290                 or (
 291                     C4::Context->preference("marcflavour") eq "UNIMARC"
 292                     and 300 <= $tag && $tag < 400 && $subfieldtag eq 'a'
 293                 )
 294                 or (
 295                     C4::Context->preference("marcflavour") eq "MARC21"
 296                     and 500 <= $tag && $tag < 600
 297                 )
 298               ) {
 299             # oversize field (textarea)
 300             $subfield_data{marc_value} = {
 301                 type        => 'textarea',
 302                 id          => $subfield_data{id},
 303                 value       => $value,
 304             };
 305         } else {
 306             # it's a standard field
 307             $subfield_data{marc_value} = {
 308                 type        => 'text',
 309                 id          => $subfield_data{id},
 310                 maxlength   => $subfield_data{maxlength},
 311                 value       => $value,
 312             };
 313         }
 314
 315         # Getting list of subfields to keep when restricted editing is enabled
 316         my $subfieldsToAllowForRestrictedEditing = C4::Context->preference('SubfieldsToAllowForRestrictedEditing');
 317         my $allowAllSubfields = (
 318             not defined $subfieldsToAllowForRestrictedEditing
 319               or $subfieldsToAllowForRestrictedEditing eq q||
 320         ) ? 1 : 0;
 321         my @subfieldsToAllow = split(/ /, $subfieldsToAllowForRestrictedEditing);
 322
 323         # If we're on restricted editing, and our field is not in the list of subfields to allow,
 324         # then it is read-only
 325         $subfield_data{marc_value}->{readonly} = (
 326             not $allowAllSubfields
 327             and $restrictededition
 328             and !grep { $tag . '$' . $subfieldtag  eq $_ } @subfieldsToAllow
 329         ) ? 1: 0;
 330
 331         return \%subfield_data;
 332 }
 333
 334 sub get_item_from_cookie {
 335     my ( $input ) = @_;
 336
 337     my $item_from_cookie;
 338     my $lastitemcookie = $input->cookie('LastCreatedItem');
 339     if ($lastitemcookie) {
 340         $lastitemcookie = decode_base64url($lastitemcookie);
 341         eval {
 342             if ( thaw($lastitemcookie) ) {
 343                 $item_from_cookie = thaw($lastitemcookie);
 344             }
 345         };
 346         if ($@) {
 347             $lastitemcookie ||= 'undef';
 348             warn "Storable::thaw failed to thaw LastCreatedItem-cookie. Cookie value '".encode_base64url($lastitemcookie)."'. Caught error follows: '$@'";
 349         }
 350     }
 351     return $item_from_cookie;
 352 }
 353
 354 my $input        = CGI->new;
 355 my $error        = $input->param('error');
 356
 357 my $biblionumber;
 358 my $itemnumber;
 359 if( $input->param('itemnumber') && !$input->param('biblionumber') ){
 360     $itemnumber = $input->param('itemnumber');
 361     my $item = Koha::Items->find( $itemnumber );
 362     $biblionumber = $item->biblionumber;
 363 } else {
 364     $biblionumber = $input->param('biblionumber');
 365     $itemnumber = $input->param('itemnumber');
 366 }
 367
 368 my $biblio = Koha::Biblios->find($biblionumber);
 369
 370 my $op           = $input->param('op') || q{};
 371 my $hostitemnumber = $input->param('hostitemnumber');
 372 my $marcflavour  = C4::Context->preference("marcflavour");
 373 my $searchid     = $input->param('searchid');
 374 # fast cataloguing datas
 375 my $fa_circborrowernumber = $input->param('circborrowernumber');
 376 my $fa_barcode            = $input->param('barcode');
 377 my $fa_branch             = $input->param('branch');
 378 my $fa_stickyduedate      = $input->param('stickyduedate');
 379 my $fa_duedatespec        = $input->param('duedatespec');
 380
 381 our $frameworkcode = &GetFrameworkCode($biblionumber);
 382
 383 # Defining which userflag is needing according to the framework currently used
 384 my $userflags;
 385 if (defined $input->param('frameworkcode')) {
 386     $userflags = ($input->param('frameworkcode') eq 'FA') ? "fast_cataloging" : "edit_items";
 387 }
 388
 389 if (not defined $userflags) {
 390     $userflags = ($frameworkcode eq 'FA') ? "fast_cataloging" : "edit_items";
 391 }
 392
 393 my ($template, $loggedinuser, $cookie)
 394     = get_template_and_user({template_name => "cataloguing/additem.tt",
 395                  query => $input,
 396                  type => "intranet",
 397                  flagsrequired => {editcatalogue => $userflags},
 398                  });
 399
 400
 401 # Does the user have a restricted item editing permission?
 402 my $uid = Koha::Patrons->find( $loggedinuser )->userid;
 403 my $restrictededition = $uid ? haspermission($uid,  {'editcatalogue' => 'edit_items_restricted'}) : undef;
 404 # In case user is a superlibrarian, editing is not restricted
 405 $restrictededition = 0 if ($restrictededition != 0 &&  C4::Context->IsSuperLibrarian());
 406 # In case user has fast cataloging permission (and we're in fast cataloging), editing is not restricted
 407 $restrictededition = 0 if ($restrictededition != 0 && $frameworkcode eq 'FA' && haspermission($uid, {'editcatalogue' => 'fast_cataloging'}));
 408
 409 our $tagslib = &GetMarcStructure(1,$frameworkcode);
 410 my $record = GetMarcBiblio({ biblionumber => $biblionumber });
 411
 412 output_and_exit_if_error( $input, $cookie, $template,
 413     { module => 'cataloguing', record => $record } );
 414
 415 my $oldrecord = TransformMarcToKoha($record);
 416 my $current_item;
 417 my $nextop="additem";
 418 my @errors; # store errors found while checking data BEFORE saving item.
 419
 420 # Getting last created item cookie
 421 my $prefillitem = C4::Context->preference('PrefillItem');
 422
 423 #-------------------------------------------------------------------------------
 424 if ($op eq "additem") {
 425
 426     my $add_submit                 = $input->param('add_submit');
 427     my $add_duplicate_submit       = $input->param('add_duplicate_submit');
 428     my $add_multiple_copies_submit = $input->param('add_multiple_copies_submit');
 429     my $number_of_copies           = $input->param('number_of_copies');
 430
 431     my @columns = Koha::Items->columns;
 432     my $item = Koha::Item->new;
 433     $item->biblionumber($biblio->biblionumber);
 434     for my $c ( @columns ) {
 435         if ( $c eq 'more_subfields_xml' ) {
 436             my @more_subfields_xml = $input->multi_param("items.more_subfields_xml");
 437             my @unlinked_item_subfields;
 438             for my $subfield ( @more_subfields_xml ) {
 439                 my $v = $input->param('items.more_subfields_xml_' . $subfield);
 440                 push @unlinked_item_subfields, $subfield, $v;
 441             }
 442             if ( @unlinked_item_subfields ) {
 443                 my $marc = MARC::Record->new();
 444                 # use of tag 999 is arbitrary, and doesn't need to match the item tag
 445                 # used in the framework
 446                 $marc->append_fields(MARC::Field->new('999', ' ', ' ', @unlinked_item_subfields));
 447                 $marc->encoding("UTF-8");
 448                 $item->more_subfields_xml($marc->as_xml("USMARC"));
 449                 next;
 450             }
 451             $item->more_subfields_xml(undef);
 452         } else {
 453             my @v = $input->multi_param("items.".$c);
 454             next unless @v;
 455             $item->$c(join ' | ', uniq @v);
 456         }
 457     }
 458
 459     # if autoBarcode is set to 'incremental', calculate barcode...
 460     if ( ! defined $item->barcode && C4::Context->preference('autoBarcode') eq 'incremental' ) {
 461         my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 462         $item->barcode($barcode);
 463     }
 464
 465     # If we have to add or add & duplicate, we add the item
 466     if ( $add_submit || $prefillitem) {
 467
 468         # check for item barcode # being unique
 469         if ( defined $item->barcode
 470             && Koha::Items->search( { barcode => $item->barcode } )->count )
 471         {
 472             # if barcode exists, don't create, but report The problem.
 473             push @errors, "barcode_not_unique";
 474
 475             $current_item = $item->unblessed; # Restore edit form for the same item
 476         }
 477         else {
 478             $item->store->discard_changes;
 479
 480             # This is a bit tricky : if there is a cookie for the last created item and
 481             # we just added an item, the cookie value is not correct yet (it will be updated
 482             # next page). To prevent the form from being filled with outdated values, we
 483             # force the use of "add and duplicate" feature, so the form will be filled with
 484             # correct values.
 485
 486             # Pushing the last created item cookie back
 487             if ( $prefillitem ) {
 488                 my $last_created_item_cookie = $input->cookie(
 489                     -name => 'LastCreatedItem',
 490                     # We encode_base64url the whole freezed structure so we're sure we won't have any encoding problems
 491                     -value   => encode_base64url( freeze( { %{$item->unblessed}, itemnumber => undef } ) ),
 492                     -HttpOnly => 1,
 493                     -expires => ''
 494                 );
 495
 496                 $cookie = [ $cookie, $last_created_item_cookie ];
 497             }
 498
 499         }
 500         $nextop = "additem";
 501
 502     }
 503
 504     # If we have to add & duplicate
 505     if ($prefillitem || $add_duplicate_submit) {
 506
 507         $current_item = $item->unblessed;
 508
 509         if (C4::Context->preference('autoBarcode') eq 'incremental') {
 510             my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 511             $current_item->{barcode} = $barcode;
 512         }
 513         else {
 514             # we have to clear the barcode field in the duplicate item record to make way for the new one generated by the javascript plugin
 515             $current_item->{barcode} = undef; # FIXME or delete?
 516         }
 517
 518         # Don't use the "prefill" feature if we want to generate the form with all the info from this item
 519         # It will remove subfields that are not in SubfieldsToUseWhenPrefill.
 520         $prefillitem = 0 if $add_duplicate_submit;
 521     }
 522
 523     # If we have to add multiple copies
 524     if ($add_multiple_copies_submit) {
 525
 526         $current_item = $item->unblessed;
 527
 528         my $copynumber = $current_item->{copynumber};
 529         my $oldbarcode = $current_item->{barcode};
 530
 531         # If there is a barcode and we can't find their new values, we can't add multiple copies
 532         my $testbarcode;
 533         my $barcodeobj = C4::Barcodes->new;
 534         $testbarcode = $barcodeobj->next_value($oldbarcode) if $barcodeobj;
 535         if ( $oldbarcode && !$testbarcode ) {
 536
 537             push @errors, "no_next_barcode";
 538
 539         }
 540         else {
 541             # We add each item
 542
 543             # For the first iteration
 544             my $barcodevalue = $oldbarcode;
 545             my $exist_itemnumber;
 546
 547             for ( my $i = 0 ; $i < $number_of_copies ; ) {
 548
 549                 # If there is a barcode
 550                 if ($barcodevalue) {
 551
 552 # Getting a new barcode (if it is not the first iteration or the barcode we tried already exists)
 553                     $barcodevalue = $barcodeobj->next_value($oldbarcode)
 554                       if ( $i > 0 || $exist_itemnumber );
 555
 556                     # Putting it into the record
 557                     if ($barcodevalue) {
 558                         if ( C4::Context->preference("autoBarcode") eq
 559                             'hbyymmincr' && $i > 0 )
 560                         { # The first copy already contains the homebranch prefix
 561                              # This is terribly hacky but the easiest way to fix the way hbyymmincr is working
 562                              # Contrary to what one might think, the barcode plugin does not prefix the returned string with the homebranch
 563                              # For a single item, it is handled with some JS code (see cataloguing/value_builder/barcode.pl)
 564                              # But when adding multiple copies we need to prefix it here,
 565                              # so we retrieve the homebranch from the item and prefix the barcode with it.
 566                             my $homebranch = $current_item->{homebranch};
 567                             $barcodevalue = $homebranch . $barcodevalue;
 568                         }
 569                         $current_item->{barcode} = $barcodevalue;
 570                     }
 571
 572                     # Checking if the barcode already exists
 573                     $exist_itemnumber = Koha::Items->search({ barcode => $barcodevalue })->count;
 574                 }
 575
 576                 # Updating record with the new copynumber
 577                 if ($copynumber) {
 578                     $current_item->{copynumber} = $copynumber;
 579                 }
 580
 581                 # Adding the item
 582                 if ( !$exist_itemnumber ) {
 583                     delete $current_item->{itemnumber};
 584                     $current_item = Koha::Item->new($current_item)->store(
 585                         { skip_record_index => 1 } );
 586                     $current_item->discard_changes; # Cannot chain discard_changes
 587                     $current_item = $current_item->unblessed;
 588
 589 # We count the item only if it was really added
 590 # That way, all items are added, even if there was some already existing barcodes
 591 # FIXME : Please note that there is a risk of infinite loop here if we never find a suitable barcode
 592                     $i++;
 593
 594                     # Only increment copynumber if item was really added
 595                     $copynumber++ if ( $copynumber && $copynumber =~ m/^\d+$/ );
 596                 }
 597
 598                 # Preparing the next iteration
 599                 $oldbarcode = $barcodevalue;
 600             }
 601
 602             my $indexer = Koha::SearchEngine::Indexer->new(
 603                 { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 604             $indexer->index_records( $biblionumber, "specialUpdate",
 605                 "biblioserver" );
 606
 607             undef($current_item);
 608         }
 609     }
 610     if ($frameworkcode eq 'FA' && $fa_circborrowernumber){
 611         print $input->redirect(
 612            '/cgi-bin/koha/circ/circulation.pl?'
 613            .'borrowernumber='.$fa_circborrowernumber
 614            .'&barcode='.uri_escape_utf8($fa_barcode)
 615            .'&duedatespec='.$fa_duedatespec
 616            .'&stickyduedate='.$fa_stickyduedate
 617         );
 618         exit;
 619     }
 620
 621
 622 #-------------------------------------------------------------------------------
 623 } elsif ($op eq "edititem") {
 624 #-------------------------------------------------------------------------------
 625 # retrieve item if exist => then, it's a modif
 626     $current_item = Koha::Items->find($itemnumber)->unblessed;
 627     # FIXME Handle non existent item
 628     $nextop = "saveitem";
 629 #-------------------------------------------------------------------------------
 630 } elsif ($op eq "dupeitem") {
 631 #-------------------------------------------------------------------------------
 632 # retrieve item if exist => then, it's a modif
 633     my $item = Koha::Items->find($itemnumber);
 634     # FIXME Handle non existent item
 635     if (C4::Context->preference('autoBarcode') eq 'incremental') {
 636         my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 637         $item->barcode($barcode);
 638     }
 639     else {
 640         $item->barcode(undef); # Don't save it!
 641     }
 642
 643     $nextop = "additem";
 644 #-------------------------------------------------------------------------------
 645 } elsif ($op eq "delitem") {
 646 #-------------------------------------------------------------------------------
 647     # check that there is no issue on this item before deletion.
 648     my $item = Koha::Items->find($itemnumber);
 649     $error = $item->safe_delete;
 650     if(ref($error) eq 'Koha::Item'){
 651         print $input->redirect("additem.pl?biblionumber=$biblionumber&frameworkcode=$frameworkcode&searchid=$searchid");
 652     }else{
 653         push @errors,$error;
 654         $nextop="additem";
 655     }
 656 #-------------------------------------------------------------------------------
 657 } elsif ($op eq "delallitems") {
 658 #-------------------------------------------------------------------------------
 659     my $items = Koha::Items->search({ biblionumber => $biblionumber });
 660     while ( my $item = $items->next ) {
 661         $error = $item->safe_delete({ skip_record_index => 1 });
 662         next if ref $error eq 'Koha::Item'; # Deleted item is returned if deletion successful
 663         push @errors,$error;
 664     }
 665     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 666     $indexer->index_records( $biblionumber, "specialUpdate", "biblioserver" );
 667     if ( @errors ) {
 668         $nextop="additem";
 669     } else {
 670         my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 671         my $views = { C4::Search::enabled_staff_search_views };
 672         if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 673             print $input->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 674         } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 675             print $input->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 676         } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 677             print $input->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 678         } else {
 679             print $input->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&searchid=$searchid");
 680         }
 681         exit;
 682     }
 683 #-------------------------------------------------------------------------------
 684 } elsif ($op eq "saveitem") {
 685 #-------------------------------------------------------------------------------
 686
 687     my $itemnumber = $input->param('itemnumber');
 688     my $item = Koha::Items->find($itemnumber);
 689     # FIXME Handle non existent item
 690     my $olditemlost = $item->itemlost;
 691     my @columns = Koha::Items->columns;
 692     for my $c ( @columns ) {
 693         if ( $c eq 'more_subfields_xml' ) {
 694             my @more_subfields_xml = $input->multi_param("items.more_subfields_xml");
 695             my @unlinked_item_subfields;
 696             for my $subfield ( uniq @more_subfields_xml ) {
 697                 my @v = $input->multi_param('items.more_subfields_xml_' . $subfield);
 698                 push @unlinked_item_subfields, $subfield, $_ for @v;
 699             }
 700             if ( @unlinked_item_subfields ) {
 701                 my $marc = MARC::Record->new();
 702                 # use of tag 999 is arbitrary, and doesn't need to match the item tag
 703                 # used in the framework
 704                 $marc->append_fields(MARC::Field->new('999', ' ', ' ', @unlinked_item_subfields));
 705                 $marc->encoding("UTF-8");
 706                 $item->more_subfields_xml($marc->as_xml("USMARC"));
 707                 next;
 708             }
 709             $item->more_subfields_xml(undef);
 710         } else {
 711             my @v = $input->multi_param("items.".$c);
 712             next unless @v;
 713             $item->$c(join ' | ', uniq @v);
 714         }
 715     }
 716
 717     # check that the barcode don't exist already
 718     if (
 719         defined $item->barcode
 720         && Koha::Items->search(
 721             {
 722                 barcode    => $item->barcode,
 723                 itemnumber => { '!=' => $item->itemnumber }
 724             }
 725         )->count
 726       )
 727     {
 728         # FIXME We shouldn't need that, ->store would explode as there is a unique constraint on items.barcode
 729         push @errors,"barcode_not_unique";
 730         $current_item = $item->unblessed; # Restore edit form for the same item
 731     } else {
 732         my $newitemlost = $item->itemlost;
 733         if ( $newitemlost && $newitemlost ge '1' && !$olditemlost ) {
 734             LostItem( $item->itemnumber, 'additem' );
 735         }
 736         $item->store;
 737     }
 738
 739     $nextop="additem";
 740 } elsif ($op eq "delinkitem"){
 741
 742     my $analyticfield = '773';
 743         if ($marcflavour  eq 'MARC21' || $marcflavour eq 'NORMARC'){
 744         $analyticfield = '773';
 745     } elsif ($marcflavour eq 'UNIMARC') {
 746         $analyticfield = '461';
 747     }
 748     foreach my $field ($record->field($analyticfield)){
 749         if ($field->subfield('9') eq $hostitemnumber){
 750             $record->delete_field($field);
 751             last;
 752         }
 753     }
 754         my $modbibresult = ModBiblio($record, $biblionumber,'');
 755 }
 756
 757 # update OAI-PMH sets
 758 if ($op) {
 759     if (C4::Context->preference("OAI-PMH:AutoUpdateSets")) {
 760         C4::OAI::Sets::UpdateOAISetsBiblio($biblionumber, $record);
 761     }
 762 }
 763
 764 #
 765 #-------------------------------------------------------------------------------
 766 # build screen with existing items. and "new" one
 767 #-------------------------------------------------------------------------------
 768
 769 # now, build existiing item list
 770
 771 my @items;
 772 for my $item ( $biblio->items->as_list, $biblio->host_items->as_list ) {
 773     push @items, $item->columns_to_str;
 774 }
 775
 776 my @witness_attributes = uniq map {
 777     my $item = $_;
 778     map { defined $item->{$_} && $item->{$_} ne "" ? $_ : () } keys %$item
 779 } @items;
 780
 781 our ( $itemtagfield, $itemtagsubfield ) = &GetMarcFromKohaField("items.itemnumber");
 782
 783 my $subfieldcode_attribute_mappings;
 784 for my $subfield_code ( keys %{ $tagslib->{$itemtagfield} } ) {
 785
 786     my $subfield = $tagslib->{$itemtagfield}->{$subfield_code};
 787
 788     next if IsMarcStructureInternal( $subfield );
 789     next unless $subfield->{tab} eq 10; # Is this really needed?
 790
 791     my $attribute;
 792     if ( $subfield->{kohafield} ) {
 793         ( $attribute = $subfield->{kohafield} ) =~ s|^items\.||;
 794     } else {
 795         $attribute = $subfield_code; # It's in more_subfields_xml
 796     }
 797     next unless grep { $attribute eq $_ } @witness_attributes;
 798     $subfieldcode_attribute_mappings->{$subfield_code} = $attribute;
 799 }
 800
 801 my @header_value_loop = map {
 802     {
 803         header_value  => $tagslib->{$itemtagfield}->{$_}->{lib},
 804         attribute     => $subfieldcode_attribute_mappings->{$_},
 805         subfield_code => $_,
 806     }
 807 } sort keys %$subfieldcode_attribute_mappings;
 808
 809 # now, build the item form for entering a new item
 810 my $branch = $input->param('branch') || C4::Context->userenv->{branch};
 811 my $libraries = Koha::Libraries->search({}, { order_by => ['branchname'] })->unblessed;# build once ahead of time, instead of multiple times later.
 812 for my $library ( @$libraries ) {
 813     $library->{selected} = 1 if $library->{branchcode} eq $branch
 814 }
 815
 816
 817 # Using last created item if it exists
 818 if (   $prefillitem
 819     && $op ne "additem"
 820     && $op ne "edititem" )
 821 {
 822     my $item_from_cookie = get_item_from_cookie($input);
 823     $current_item = $item_from_cookie if $item_from_cookie;
 824 }
 825
 826 my @subfields_to_prefill = split ' ', C4::Context->preference('SubfieldsToUseWhenPrefill');
 827
 828 if ( $current_item->{more_subfields_xml} ) {
 829     $current_item->{marc_more_subfields_xml} = MARC::Record->new_from_xml($current_item->{more_subfields_xml}, 'UTF-8');
 830 }
 831
 832 # We generate form, and fill with values if defined
 833 my $temp = GetMarcBiblio({ biblionumber => $biblionumber });
 834 my $i = 0;
 835 my @subfields;
 836 foreach my $tag ( keys %{$tagslib} ) {
 837     foreach my $subtag ( keys %{ $tagslib->{$tag} } ) {
 838
 839         my $subfield = $tagslib->{$tag}{$subtag};
 840
 841         next if IsMarcStructureInternal( $subfield );
 842         next if ( $subfield->{tab} ne "10" );
 843
 844         my @values = ();
 845
 846         my $subfield_data;
 847
 848         # If we are not adding a new item
 849         # OR
 850         # If the subfield must be prefilled with last catalogued item
 851         if (
 852             $nextop ne 'additem'
 853             || (
 854                 !$prefillitem
 855                 || ( $prefillitem && grep { $_ eq $subtag }
 856                     @subfields_to_prefill )
 857             )
 858           )
 859         {
 860             my $kohafield = $subfield->{kohafield};
 861             if ($kohafield) {
 862
 863                 # This is a mapped field
 864                 ( my $attribute = $kohafield ) =~ s|^items\.||;
 865                 push @values, $subfield->{repeatable}
 866                     ? split '\s\|\s', $current_item->{$attribute}
 867                     : $current_item->{$attribute}
 868                   if defined $current_item->{$attribute};
 869             } else {
 870                 # Not mapped, picked the values from more_subfields_xml's MARC
 871                 my $marc_more = $current_item->{marc_more_subfields_xml};
 872                 if ( $marc_more ) {
 873                     for my $f ( $marc_more->fields($tag) ) {
 874                         push @values, $f->subfield($subtag);
 875                     }
 876                 }
 877             }
 878         }
 879
 880         @values = ('') unless @values;
 881
 882         for my $value (@values) {
 883             my $subfield_data = generate_subfield_form(
 884                 $tag,                        $subtag,
 885                 $value,                      $tagslib,
 886                 $subfield,                   $libraries,
 887                 $biblionumber,               $temp,
 888                 \@subfields,                 $i,
 889                 $restrictededition,          $current_item,
 890             );
 891             push @subfields, $subfield_data;
 892             $i++;
 893         }
 894     }
 895 }
 896 @subfields = sort { $a->{display_order} <=> $b->{display_order} || $a->{subfield} cmp $b->{subfield} } @subfields;
 897
 898 # what's the next op ? it's what we are not in : an add if we're editing, otherwise, and edit.
 899 $template->param(
 900     biblionumber => $biblionumber,
 901     title        => $oldrecord->{title},
 902     author       => $oldrecord->{author},
 903     items        => \@items,
 904     item_header_loop => \@header_value_loop,
 905     subfields    => \@subfields,
 906     itemnumber       => $itemnumber,
 907     barcode          => $current_item->{barcode},
 908     itemtagfield     => $itemtagfield,
 909     itemtagsubfield  => $itemtagsubfield,
 910     op      => $nextop,
 911     popup => scalar $input->param('popup') ? 1: 0,
 912     C4::Search::enabled_staff_search_views,
 913 );
 914 $template->{'VARS'}->{'searchid'} = $searchid;
 915
 916 if ($frameworkcode eq 'FA'){
 917     # fast cataloguing datas
 918     $template->param(
 919         'circborrowernumber' => $fa_circborrowernumber,
 920         'barcode'            => $fa_barcode,
 921         'branch'             => $fa_branch,
 922         'stickyduedate'      => $fa_stickyduedate,
 923         'duedatespec'        => $fa_duedatespec,
 924     );
 925 }
 926
 927 foreach my $error (@errors) {
 928     $template->param($error => 1);
 929 }
 930 output_html_with_http_headers $input, $cookie, $template->output;