circ/renew.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2013 ByWater Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use C4::Context;
  24 use C4::Auth qw( get_template_and_user );
  25 use C4::Output qw( output_html_with_http_headers );
  26 use C4::Circulation qw( barcodedecode CanBookBeRenewed GetLatestAutoRenewDate AddRenewal );
  27 use Koha::DateUtils qw( dt_from_string );
  28 use Koha::Database;
  29 use Koha::BiblioFrameworks;
  30
  31 my $cgi = CGI->new;
  32
  33 my ( $template, $librarian, $cookie, $flags ) = get_template_and_user(
  34     {
  35         template_name   => "circ/renew.tt",
  36         query           => $cgi,
  37         type            => "intranet",
  38         flagsrequired   => { circulate => "circulate_remaining_permissions" },
  39     }
  40 );
  41
  42 my $schema = Koha::Database->new()->schema();
  43
  44 my $barcode        = $cgi->param('barcode') // '';
  45 my $unseen         = $cgi->param('unseen') || 0;
  46 $barcode = barcodedecode($barcode) if $barcode;
  47 my $override_limit = $cgi->param('override_limit');
  48 my $override_holds = $cgi->param('override_holds');
  49 my $hard_due_date  = $cgi->param('hard_due_date');
  50
  51 my ( $item, $checkout, $patron );
  52 my $error = q{};
  53 my ( $soonest_renew_date, $latest_auto_renew_date );
  54
  55 if ($barcode) {
  56     $barcode = barcodedecode($barcode) if $barcode;
  57     $item = Koha::Items->find({ barcode => $barcode });
  58
  59     if ($item) {
  60
  61         $checkout = $item->checkout;
  62
  63         if ($checkout) {
  64
  65             $patron = $checkout->patron;
  66
  67             if ( ( $patron->is_debarred || q{} ) lt dt_from_string()->ymd() ) {
  68                 my $can_renew;
  69                 my $info;
  70                 ( $can_renew, $error, $info ) =
  71                   CanBookBeRenewed( $patron, $checkout, $override_limit );
  72
  73                 if ( $error && ($error eq 'on_reserve') ) {
  74                     if ($override_holds) {
  75                         $can_renew = 1;
  76                         $error     = undef;
  77                     }
  78                     else {
  79                         $can_renew = 0;
  80                     }
  81                 }
  82
  83                 if ( $error && ($error eq 'too_soon' or $error eq 'auto_too_soon') ) {
  84                     $soonest_renew_date = $info->{soonest_renew_date};
  85                 }
  86                 if ( $error && ( $error eq 'auto_too_late' ) ) {
  87                     $latest_auto_renew_date = GetLatestAutoRenewDate(
  88                         $patron,
  89                         $checkout,
  90                     );
  91                 }
  92                 if ($can_renew) {
  93                     my $branchcode = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
  94                     my $date_due =
  95                       ( C4::Context->preference('SpecifyDueDate')
  96                           && $hard_due_date )
  97                       ? $hard_due_date
  98                       : $cgi->param('renewonholdduedate');
  99
 100                     $date_due = AddRenewal(
 101                         {
 102                             itemnumber => $item->itemnumber(),
 103                             branch     => $branchcode,
 104                             datedue    => $date_due,
 105                             seen       => !$unseen
 106                         }
 107                     );
 108                     $template->param( date_due => $date_due );
 109                 }
 110             }
 111             else {
 112                 $error = "patron_restricted";
 113             }
 114         }
 115         else {
 116             $error = "no_checkout";
 117         }
 118     }
 119     else {
 120         $error = "no_item";
 121     }
 122
 123     $template->param(
 124         item     => $item,
 125         issue    => $checkout,
 126         borrower => $patron,
 127         error    => $error,
 128         soonestrenewdate => $soonest_renew_date,
 129         latestautorenewdate => $latest_auto_renew_date,
 130     );
 131 }
 132
 133 $template->param( hard_due_date => $hard_due_date );
 134 # Checking if there is a Fast Cataloging Framework
 135 $template->param( fast_cataloging => 1 ) if Koha::BiblioFrameworks->find( 'FA' );
 136
 137 output_html_with_http_headers( $cgi, $cookie, $template->output );