members/member-password.pl

   1 #!/usr/bin/perl
   2 #script to set the password, and optionally a userid, for a borrower
   3 #written 2/5/00
   4 #by chris@katipo.co.nz
   5 #converted to using templates 3/16/03 by mwhansen@hmc.edu
   6
   7 use Modern::Perl;
   8
   9 use C4::Auth qw( get_template_and_user );
  10 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  11 use C4::Context;
  12 use CGI qw ( -utf8 );
  13
  14 use Koha::Patrons;
  15 use Koha::Patron::Categories;
  16
  17 use Try::Tiny qw( catch try );
  18
  19 my $input = CGI->new;
  20
  21 my $theme = $input->param('theme') || "default";
  22
  23 # only used if allowthemeoverride is set
  24
  25 my ( $template, $loggedinuser, $cookie, $staffflags ) = get_template_and_user(
  26     {
  27         template_name   => "members/member-password.tt",
  28         query           => $input,
  29         type            => "intranet",
  30         flagsrequired   => { borrowers => 'edit_borrowers' },
  31     }
  32 );
  33
  34 my $op           = $input->param('op') // q{};
  35 my $patron_id    = $input->param('member');
  36 my $destination  = $input->param('destination');
  37 my $newpassword  = $input->param('newpassword');
  38 my $newpassword2 = $input->param('newpassword2');
  39 my $new_user_id  = $input->param('newuserid');
  40
  41 my @errors;
  42
  43 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
  44 my $patron = Koha::Patrons->find( $patron_id );
  45 output_and_exit_if_error( $input, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
  46
  47 my $category_type = $patron->category->category_type;
  48
  49 if ( ( $patron_id ne $loggedinuser ) && ( $category_type eq 'S' ) ) {
  50     push( @errors, 'NOPERMISSION' )
  51       unless ( $staffflags->{'superlibrarian'} || $staffflags->{'staffaccess'} );
  52
  53     # need superlibrarian for koha-conf.xml fakeuser.
  54 }
  55
  56 push( @errors, 'NOMATCH' ) if ( ( $newpassword && $newpassword2 ) && ( $newpassword ne $newpassword2 ) );
  57
  58 if ( $op eq 'cud-update' && $newpassword and not @errors ) {
  59
  60     try {
  61         $patron->set_password({ password => $newpassword });
  62         $patron->userid($new_user_id)->store
  63             if $new_user_id and $new_user_id ne $patron->userid;
  64         $template->param( newpassword => $newpassword );
  65         if ( $destination eq 'circ' ) {
  66             print $input->redirect("/cgi-bin/koha/circ/circulation.pl?findborrower=" . $patron->cardnumber);
  67         }
  68         else {
  69             print $input->redirect("/cgi-bin/koha/members/moremember.pl?borrowernumber=$patron_id");
  70         }
  71     }
  72     catch {
  73         if ( $_->isa('Koha::Exceptions::Password::TooShort') ) {
  74             push @errors, 'ERROR_password_too_short';
  75         }
  76         elsif ( $_->isa('Koha::Exceptions::Password::WhitespaceCharacters') ) {
  77             push @errors, 'ERROR_password_has_whitespaces';
  78         }
  79         elsif ( $_->isa('Koha::Exceptions::Password::TooWeak') ) {
  80             push @errors, 'ERROR_password_too_weak';
  81         }
  82         elsif ( $_->isa('Koha::Exceptions::Password::Plugin') ) {
  83             push @errors, 'ERROR_from_plugin';
  84         }
  85         else {
  86             push( @errors, 'BADUSERID' );
  87         }
  88     };
  89 }
  90
  91 $template->param(
  92     patron      => $patron,
  93     destination => $destination,
  94 );
  95
  96 if ( scalar(@errors) ) {
  97     $template->param( errormsg => 1 );
  98     foreach my $error (@errors) {
  99         $template->param($error) || $template->param( $error => 1 );
 100     }
 101 }
 102
 103 output_html_with_http_headers $input, $cookie, $template->output;