misc/cronjobs/automatic_renewals.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright (C) 2014 Hochschule für Gesundheit (hsg), Germany
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 automatic_renewals.pl - cron script to renew loans
  23
  24 =head1 SYNOPSIS
  25
  26 ./automatic_renewals.pl [-c|--confirm] [-s|--send-notices] [-d|--digest] [-b|--digest-per-branch] [-v|--verbose]
  27
  28 or, in crontab:
  29 # Once every day for digest messages
  30 0 3 * * * automatic_renewals.pl -c -d
  31 # Three times a day for non digest messages
  32 0 0,8,16 * * * automatic_renewals.pl -c
  33
  34 =head1 DESCRIPTION
  35
  36 This script searches for issues scheduled for automatic renewal
  37 (issues.auto_renew). If there are still renews left (Renewals allowed)
  38 and the renewal isn't premature (No Renewal before) the issue is renewed.
  39
  40 =head1 OPTIONS
  41
  42 =over
  43
  44 =item B<-s|--send-notices>
  45
  46 DEPRECATED: The system preference AutoRenewalNotices should be used to determine
  47 whether notices are sent or not
  48 Send AUTO_RENEWALS notices to patrons if the auto renewal has been done.
  49
  50 =item B<-v|--verbose>
  51
  52 Print report to standard out.
  53
  54 =item B<-c|--confirm>
  55
  56 Without this parameter no changes will be made
  57
  58 =item B<-b|--digest-per-branch>
  59
  60 Flag to indicate that generation of message digests should be
  61 performed separately for each branch.
  62
  63 A patron could potentially have loans at several different branches
  64 There is no natural branch to set as the sender on the aggregated
  65 message in this situation so the default behavior is to use the
  66 borrowers home branch.  This could surprise to the borrower when
  67 message sender is a library where they have not borrowed anything.
  68
  69 Enabling this flag ensures that the issuing library is the sender of
  70 the digested message.  It has no effect unless the borrower has
  71 chosen 'Digests only' on the advance messages.
  72
  73 =back
  74
  75 =cut
  76
  77 use Modern::Perl;
  78 use Pod::Usage qw( pod2usage );
  79 use Getopt::Long qw( GetOptions );
  80
  81 use Koha::Script -cron;
  82 use C4::Circulation qw( CanBookBeRenewed AddRenewal );
  83 use C4::Context;
  84 use C4::Log qw( cronlogaction );
  85 use C4::Letters;
  86 use Koha::Checkouts;
  87 use Koha::Libraries;
  88 use Koha::Patrons;
  89
  90 my $command_line_options = join(" ",@ARGV);
  91
  92 my ( $help, $send_notices, $verbose, $confirm, $digest_per_branch );
  93 GetOptions(
  94     'h|help' => \$help,
  95     's|send-notices' => \$send_notices,
  96     'v|verbose'    => \$verbose,
  97     'c|confirm'     => \$confirm,
  98     'b|digest-per-branch' => \$digest_per_branch,
  99 ) || pod2usage(1);
 100
 101 pod2usage(0) if $help;
 102
 103 my $send_notices_pref = C4::Context->preference('AutoRenewalNotices');
 104 if ( $send_notices_pref eq 'cron' ) {
 105     warn <<'END_WARN';
 106
 107 The "AutoRenewalNotices" syspref is set to 'Follow the cron switch'.
 108 The send_notices switch for this script is deprecated, you should either set the preference
 109 to 'Never send emails' or 'Follow patron messaging preferences'
 110
 111 END_WARN
 112 } else {
 113     # If not following cron then:
 114     # - we should not send if set to never
 115     # - we will send any notice generated according to preferences if following those
 116     $send_notices = $send_notices_pref eq 'never' ? 0 : 1;
 117 }
 118
 119 # Since advance notice options are not visible in the web-interface
 120 # unless EnhancedMessagingPreferences is on, let the user know that
 121 # this script probably isn't going to do much
 122 if ( ! C4::Context->preference('EnhancedMessagingPreferences') ) {
 123     warn <<'END_WARN';
 124
 125 The "EnhancedMessagingPreferences" syspref is off.
 126 Therefore, it is unlikely that this script will actually produce any messages to be sent.
 127 To change this, edit the "EnhancedMessagingPreferences" syspref.
 128
 129 END_WARN
 130 }
 131
 132 cronlogaction({ info => $command_line_options });
 133
 134 $verbose = 1 unless $verbose or $confirm;
 135 print "Test run only\n" unless $confirm;
 136
 137 print "getting auto renewals\n" if $verbose;
 138 my $auto_renews = Koha::Checkouts->search(
 139     {
 140         auto_renew                   => 1,
 141         'patron.autorenew_checkouts' => 1,
 142     },
 143     {
 144         join => ['patron','item']
 145     }
 146 );
 147 print "found " . $auto_renews->count . " auto renewals\n" if $verbose;
 148
 149 my $renew_digest = {};
 150 my %report;
 151 my @item_renewal_ids;
 152 while ( my $auto_renew = $auto_renews->next ) {
 153     print "examining item '" . $auto_renew->itemnumber . "' to auto renew\n" if $verbose;
 154
 155     my ( $borrower_preferences, $wants_messages, $wants_digest ) = ( undef, 0, 0 );
 156     if ( $send_notices_pref eq 'preferences' ){
 157         $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences(
 158             {
 159                 borrowernumber => $auto_renew->borrowernumber,
 160                 message_name   => 'auto_renewals'
 161             }
 162         );
 163         $wants_messages = 1
 164             if $borrower_preferences
 165             && $borrower_preferences->{transports};
 166         $wants_digest = 1
 167             if $wants_messages
 168             && $borrower_preferences->{wants_digest};
 169     } else { # Preference is never or cron
 170         $wants_messages = $send_notices;
 171         $wants_digest = 0;
 172     }
 173
 174     # CanBookBeRenewed returns 'auto_renew' when the renewal should be done by this script
 175     my ( $ok, $error ) = CanBookBeRenewed( $auto_renew->patron, $auto_renew, undef, 1 );
 176     my $updated;
 177     if ( $error eq 'auto_renew' ) {
 178         $updated = 1;
 179         if ($verbose) {
 180             say sprintf "Issue id: %s for borrower: %s and item: %s %s be renewed.",
 181               $auto_renew->issue_id, $auto_renew->borrowernumber, $auto_renew->itemnumber, $confirm ? 'will' : 'would';
 182         }
 183         if ($confirm){
 184             my $date_due = AddRenewal( $auto_renew->borrowernumber, $auto_renew->itemnumber, $auto_renew->branchcode, undef, undef, undef, 0, 1 );
 185             push @item_renewal_ids, $auto_renew->itemnumber;
 186             $auto_renew->auto_renew_error(undef)->store;
 187         }
 188         push @{ $report{ $auto_renew->borrowernumber } }, $auto_renew
 189             if ( $wants_messages ) && !$wants_digest;
 190     } elsif (
 191         $error eq 'too_many' ||
 192         $error eq 'on_reserve' ||
 193         $error eq 'restriction' ||
 194         $error eq 'overdue' ||
 195         $error eq 'too_unseen' ||
 196         $error eq 'auto_account_expired' ||
 197         $error eq 'auto_too_late' ||
 198         $error eq 'auto_too_much_oweing' ||
 199         $error eq 'auto_too_soon' ||
 200         $error eq 'item_denied_renewal' ||
 201         $error eq 'item_issued_to_other_patron'
 202     ) {
 203         if ( $verbose ) {
 204             say sprintf "Issue id: %s for borrower: %s and item: %s %s not be renewed. (%s)",
 205               $auto_renew->issue_id, $auto_renew->borrowernumber, $auto_renew->itemnumber, $confirm ? 'will' : 'would', $error;
 206         }
 207         $updated = 1 if (!$auto_renew->auto_renew_error || $error ne $auto_renew->auto_renew_error);
 208         if ( $updated ) {
 209             $auto_renew->auto_renew_error($error)->store if $confirm;
 210             push @{ $report{ $auto_renew->borrowernumber } }, $auto_renew
 211               if $error ne 'auto_too_soon' && ( $wants_messages  && !$wants_digest );    # Do not notify if it's too soon
 212         }
 213     }
 214
 215     if ( $wants_digest ) {
 216         # cache this one to process after we've run through all of the items.
 217         if ($digest_per_branch) {
 218             $renew_digest->{ $auto_renew->branchcode }->{ $auto_renew->borrowernumber }->{success}++ if $error eq 'auto_renew';
 219             $renew_digest->{ $auto_renew->branchcode }->{ $auto_renew->borrowernumber }->{error}++ unless $error eq 'auto_renew' || $error eq 'auto_too_soon';
 220             $renew_digest->{ $auto_renew->branchcode }->{ $auto_renew->borrowernumber }->{results}->{$error}++ ;
 221             push @{$renew_digest->{ $auto_renew->branchcode }->{ $auto_renew->borrowernumber }->{issues}}, $auto_renew->itemnumber;
 222             $renew_digest->{ $auto_renew->branchcode }->{ $auto_renew->borrowernumber }->{updated} = 1 if $updated && $error ne 'auto_too_soon';
 223         } else {
 224             $renew_digest->{ $auto_renew->borrowernumber }->{success} ++ if $error eq 'auto_renew';
 225             $renew_digest->{ $auto_renew->borrowernumber }->{error}++ unless $error eq 'auto_renew' || $error eq 'auto_too_soon';
 226             $renew_digest->{ $auto_renew->borrowernumber }->{results}->{$error}++ ;
 227             $renew_digest->{ $auto_renew->borrowernumber }->{updated} = 1 if $updated && $error ne 'auto_too_soon';
 228             push @{$renew_digest->{ $auto_renew->borrowernumber }->{issues}}, $auto_renew->itemnumber;
 229         }
 230     }
 231
 232 }
 233
 234 if( @item_renewal_ids ){
 235     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 236     $indexer->index_records( \@item_renewal_ids, "specialUpdate", "biblioserver" );
 237 }
 238
 239 if ( $send_notices && $confirm ) {
 240     for my $borrowernumber ( keys %report ) {
 241         my $patron = Koha::Patrons->find($borrowernumber);
 242         my $borrower_preferences =
 243             C4::Members::Messaging::GetMessagingPreferences(
 244                 {
 245                     borrowernumber => $borrowernumber,
 246                     message_name   => 'auto_renewals'
 247                 }
 248             );
 249         for my $issue ( @{ $report{$borrowernumber} } ) {
 250             my $item = $issue->item;
 251             # Force sending of email and only email if pref is set to "cron"
 252             my @transports = $send_notices_pref eq 'preferences' ? keys %{ $borrower_preferences->{'transports'} } : 'email';
 253             foreach my $transport ( @transports ) {
 254                 my $letter = C4::Letters::GetPreparedLetter (
 255                     module      => 'circulation',
 256                     letter_code => 'AUTO_RENEWALS',
 257                     tables      => {
 258                         borrowers => $patron->borrowernumber,
 259                         issues    => $issue->itemnumber,
 260                         items     => $issue->itemnumber,
 261                         biblio    => $item->biblionumber,
 262                     },
 263                     lang => $patron->lang,
 264                     message_transport_type => $transport,
 265                 );
 266
 267                 if ($letter) {
 268                     my $library = $patron->library;
 269                     my $admin_email_address = $library->from_email_address;
 270
 271                     C4::Letters::EnqueueLetter(
 272                         {
 273                             letter                 => $letter,
 274                             borrowernumber         => $borrowernumber,
 275                             from_address           => $admin_email_address,
 276                             message_transport_type => $transport
 277                         }
 278                     );
 279                 }
 280             }
 281         }
 282     }
 283
 284     if ($digest_per_branch) {
 285         while (my ($branchcode, $digests) = each %$renew_digest) {
 286             send_digests({
 287                 digests => $digests,
 288                 branchcode => $branchcode,
 289                 letter_code => 'AUTO_RENEWALS_DGST',
 290             });
 291         }
 292     } else {
 293         send_digests({
 294             digests => $renew_digest,
 295             letter_code => 'AUTO_RENEWALS_DGST',
 296         });
 297     }
 298 }
 299
 300 cronlogaction({ action => 'End', info => "COMPLETED" });
 301
 302 =head1 METHODS
 303
 304 =head2 send_digests
 305
 306     send_digests({
 307         digests => ...,
 308         letter_code => ...,
 309     })
 310
 311 Enqueue digested letters.
 312
 313 Parameters:
 314
 315 =over 4
 316
 317 =item C<$digests>
 318
 319 Reference to the array of digested messages.
 320
 321 =item C<$letter_code>
 322
 323 String that denote the letter code.
 324
 325 =back
 326
 327 =cut
 328
 329 sub send_digests {
 330     my $params = shift;
 331
 332     PATRON: while ( my ( $borrowernumber, $digest ) = each %{$params->{digests}} ) {
 333         next unless defined $digest->{updated} && $digest->{updated} == 1;
 334         my $borrower_preferences =
 335             C4::Members::Messaging::GetMessagingPreferences(
 336                 {
 337                     borrowernumber => $borrowernumber,
 338                     message_name   => 'auto_renewals'
 339                 }
 340             );
 341
 342         next PATRON unless $borrower_preferences; # how could this happen?
 343
 344         my $patron = Koha::Patrons->find( $borrowernumber );
 345         my $branchcode;
 346         if ( defined $params->{branchcode} ) {
 347             $branchcode = $params->{branchcode};
 348         } else {
 349             $branchcode = $patron->branchcode;
 350         }
 351         my $library = Koha::Libraries->find( $branchcode );
 352         my $from_address = $library->from_email_address;
 353
 354         foreach my $transport ( keys %{ $borrower_preferences->{'transports'} } ) {
 355             my $letter = C4::Letters::GetPreparedLetter (
 356                 module => 'circulation',
 357                 letter_code => $params->{letter_code},
 358                 branchcode => $branchcode,
 359                 lang => $patron->lang,
 360                 substitute => {
 361                     error => $digest->{error}||0,
 362                     success => $digest->{success}||0,
 363                     results => $digest->{results},
 364                 },
 365                 loops => { issues => \@{$digest->{issues}} },
 366                 tables      => {
 367                     borrowers => $patron->borrowernumber,
 368                 },
 369                 message_transport_type => $transport,
 370             );
 371
 372             if ($letter) {
 373                 C4::Letters::EnqueueLetter(
 374                     {
 375                         letter                 => $letter,
 376                         borrowernumber         => $borrowernumber,
 377                         from_address           => $from_address,
 378                         message_transport_type => $transport
 379                     }
 380                 );
 381             }
 382             else {
 383                 warn
 384 "no letter of type '$params->{letter_code}' found for borrowernumber $borrowernumber. Please see sample_notices.sql";
 385             }
 386
 387         }
 388     }
 389 }