misc/export_records.pl

   1 #!/usr/bin/perl
   2
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use MARC::File::XML;
  21 use List::MoreUtils qw( uniq );
  22 use Getopt::Long qw( GetOptions );
  23 use Pod::Usage qw( pod2usage );
  24
  25 use Koha::Script;
  26 use C4::Auth;
  27 use C4::Context;
  28 use C4::Record;
  29
  30 use Koha::Biblioitems;
  31 use Koha::Database;
  32 use Koha::CsvProfiles;
  33 use Koha::Exporter::Record;
  34 use Koha::DateUtils qw( dt_from_string output_pref );
  35
  36 my (
  37     $output_format,
  38     $timestamp,
  39     $dont_export_items,
  40     $csv_profile_id,
  41     $deleted_barcodes,
  42     $clean,
  43     $filename,
  44     $record_type,
  45     $id_list_file,
  46     $starting_authid,
  47     $ending_authid,
  48     $authtype,
  49     $starting_biblionumber,
  50     $ending_biblionumber,
  51     $itemtype,
  52     $starting_callnumber,
  53     $ending_callnumber,
  54     $start_accession,
  55     $end_accession,
  56     $marc_conditions,
  57     $help
  58 );
  59
  60 GetOptions(
  61     'format=s'                => \$output_format,
  62     'date=s'                  => \$timestamp,
  63     'dont_export_items'       => \$dont_export_items,
  64     'csv_profile_id=s'        => \$csv_profile_id,
  65     'deleted_barcodes'        => \$deleted_barcodes,
  66     'clean'                   => \$clean,
  67     'filename=s'              => \$filename,
  68     'record-type=s'           => \$record_type,
  69     'id_list_file=s'          => \$id_list_file,
  70     'starting_authid=s'       => \$starting_authid,
  71     'ending_authid=s'         => \$ending_authid,
  72     'authtype=s'              => \$authtype,
  73     'starting_biblionumber=s' => \$starting_biblionumber,
  74     'ending_biblionumber=s'   => \$ending_biblionumber,
  75     'itemtype=s'              => \$itemtype,
  76     'starting_callnumber=s'   => \$starting_callnumber,
  77     'ending_callnumber=s'     => \$ending_callnumber,
  78     'start_accession=s'       => \$start_accession,
  79     'end_accession=s'         => \$end_accession,
  80     'marc_conditions=s'       => \$marc_conditions,
  81     'h|help|?'                => \$help
  82 ) || pod2usage(1);
  83
  84 if ($help) {
  85     pod2usage(1);
  86 }
  87
  88 $filename ||= 'koha.mrc';
  89 $output_format ||= 'iso2709';
  90 $record_type ||= 'bibs';
  91
  92 # Retrocompatibility for the format parameter
  93 $output_format = 'iso2709' if $output_format eq 'marc';
  94
  95 if ( $output_format eq 'csv' and $record_type eq 'auths' ) {
  96     pod2usage(q|CSV output is only available for biblio records|);
  97 }
  98
  99 if ( $output_format eq 'csv' and not $csv_profile_id ) {
 100     pod2usage(q|Define a csv profile to export in CSV|);
 101 }
 102
 103
 104 if ( $record_type ne 'bibs' and $record_type ne 'auths' ) {
 105     pod2usage(q|--record_type is not valid|);
 106 }
 107
 108 if ( $deleted_barcodes and $record_type ne 'bibs' ) {
 109     pod2usage(q|--deleted_barcodes can only be used with biblios|);
 110 }
 111
 112 $start_accession = dt_from_string( $start_accession ) if $start_accession;
 113 $end_accession   = dt_from_string( $end_accession )   if $end_accession;
 114
 115 # Parse marc conditions
 116 my @marc_conditions;
 117 if ($marc_conditions) {
 118     foreach my $condition (split(/,\s*/, $marc_conditions)) {
 119         if ($condition =~ /^(\d{3})([\w\d]?)(=|(?:!=)|>|<)([^,]+)$/) {
 120             push @marc_conditions, [$1, $2, $3, $4];
 121         }
 122         elsif ($condition =~ /^(exists|not_exists)\((\d{3})([\w\d]?)\)$/) {
 123             push @marc_conditions, [$2, $3, $1 eq 'exists' ? '?' : '!?'];
 124         }
 125         else {
 126             die("Invalid condititon: $condition");
 127         }
 128     }
 129 }
 130
 131 my $dbh = C4::Context->dbh;
 132
 133 # Redirect stdout
 134 open STDOUT, '>', $filename if $filename;
 135
 136
 137 my @record_ids;
 138
 139 $timestamp = ($timestamp) ? output_pref({ dt => dt_from_string($timestamp), dateformat => 'iso', dateonly => 0, }): '';
 140
 141 if ( $record_type eq 'bibs' ) {
 142     if ( $timestamp ) {
 143         if (!$dont_export_items) {
 144             push @record_ids, $_->{biblionumber} for @{
 145                 $dbh->selectall_arrayref(q| (
 146                     SELECT biblio_metadata.biblionumber
 147                     FROM biblio_metadata
 148                       LEFT JOIN items USING(biblionumber)
 149                     WHERE biblio_metadata.timestamp >= ?
 150                       OR items.timestamp >= ?
 151                 ) UNION (
 152                     SELECT biblio_metadata.biblionumber
 153                     FROM biblio_metadata
 154                       LEFT JOIN deleteditems USING(biblionumber)
 155                     WHERE biblio_metadata.timestamp >= ?
 156                       OR deleteditems.timestamp >= ?
 157                 ) |, { Slice => {} }, ( $timestamp ) x 4 );
 158             };
 159         } else {
 160             push @record_ids, $_->{biblionumber} for @{
 161                 $dbh->selectall_arrayref(q| (
 162                     SELECT biblio_metadata.biblionumber
 163                     FROM biblio_metadata
 164                     WHERE biblio_metadata.timestamp >= ?
 165                 ) |, { Slice => {} }, $timestamp );
 166             };
 167         }
 168     } else {
 169         my $conditions = {
 170             ( $starting_biblionumber or $ending_biblionumber )
 171                 ? (
 172                     "me.biblionumber" => {
 173                         ( $starting_biblionumber ? ( '>=' => $starting_biblionumber ) : () ),
 174                         ( $ending_biblionumber   ? ( '<=' => $ending_biblionumber   ) : () ),
 175                     }
 176                 )
 177                 : (),
 178             ( $starting_callnumber or $ending_callnumber )
 179                 ? (
 180                     callnumber => {
 181                         ( $starting_callnumber ? ( '>=' => $starting_callnumber ) : () ),
 182                         ( $ending_callnumber   ? ( '<=' => $ending_callnumber   ) : () ),
 183                     }
 184                 )
 185                 : (),
 186             ( $start_accession or $end_accession )
 187                 ? (
 188                     dateaccessioned => {
 189                         ( $start_accession ? ( '>=' => $start_accession ) : () ),
 190                         ( $end_accession   ? ( '<=' => $end_accession   ) : () ),
 191                     }
 192                 )
 193                 : (),
 194             ( $itemtype
 195                 ?
 196                   C4::Context->preference('item-level_itypes')
 197                     ? ( 'items.itype' => $itemtype )
 198                     : ( 'me.itemtype' => $itemtype )
 199                 : ()
 200             ),
 201
 202         };
 203         my $biblioitems = Koha::Biblioitems->search( $conditions, { join => 'items' } );
 204         while ( my $biblioitem = $biblioitems->next ) {
 205             push @record_ids, $biblioitem->biblionumber;
 206         }
 207     }
 208 }
 209 elsif ( $record_type eq 'auths' ) {
 210     if ($timestamp) {
 211         push @record_ids, $_->{authid} for @{
 212             $dbh->selectall_arrayref(
 213                 q| (
 214                 SELECT authid
 215                 FROM auth_header
 216                 WHERE modification_time >= ?
 217             ) |, { Slice => {} }, $timestamp
 218             );
 219         };
 220     } else {
 221         my $conditions = {
 222             ( $starting_authid or $ending_authid )
 223             ? (
 224                 authid => {
 225                     ( $starting_authid ? ( '>=' => $starting_authid ) : () ),
 226                     ( $ending_authid   ? ( '<=' => $ending_authid )   : () ),
 227                 }
 228                 )
 229             : (),
 230             ( $authtype ? ( authtypecode => $authtype ) : () ),
 231         };
 232
 233         # Koha::MetadataRecord::Authority is not a Koha::Object...
 234         my $authorities = Koha::Database->new->schema->resultset('AuthHeader')->search($conditions);
 235         @record_ids = map { $_->authid } $authorities->all;
 236     }
 237 }
 238
 239 @record_ids = uniq @record_ids;
 240 if ( @record_ids and $id_list_file ) {
 241     open my $fh, '<', $id_list_file or die "Cannot open file $id_list_file ($!)";
 242     my @filter_record_ids = <$fh>;
 243     @filter_record_ids = map { my $id = $_; $id =~ s/[\r\n]*$//; $id } @filter_record_ids;
 244     # intersection
 245     my %record_ids = map { $_ => 1 } @record_ids;
 246     @record_ids = grep $record_ids{$_}, @filter_record_ids;
 247 }
 248
 249 if ($deleted_barcodes) {
 250     for my $record_id ( @record_ids ) {
 251         my $barcode = $dbh->selectall_arrayref(q|
 252             SELECT DISTINCT barcode
 253             FROM deleteditems
 254             WHERE deleteditems.biblionumber = ?
 255             AND barcode IS NOT NULL AND barcode != ''
 256         |, { Slice => {} }, $record_id );
 257         say $_->{barcode} for @$barcode;
 258     }
 259 }
 260 else {
 261     Koha::Exporter::Record::export(
 262         {   record_type        => $record_type,
 263             record_ids         => \@record_ids,
 264             record_conditions  => @marc_conditions ? \@marc_conditions : undef,
 265             format             => $output_format,
 266             csv_profile_id     => $csv_profile_id,
 267             export_items       => (not $dont_export_items),
 268             clean              => $clean || 0,
 269         }
 270     );
 271 }
 272 exit;
 273
 274
 275 =head1 NAME
 276
 277 export records - This script exports record (biblios or authorities)
 278
 279 =head1 SYNOPSIS
 280
 281 export_records.pl [-h|--help] [--format=format] [--date=datetime] [--record-type=TYPE] [--dont_export_items] [--deleted_barcodes] [--clean] [--id_list_file=PATH] --filename=outputfile
 282
 283 =head1 OPTIONS
 284
 285 =over
 286
 287 =item B<-h|--help>
 288
 289 Print a brief help message.
 290
 291 =item B<--format>
 292
 293  --format=FORMAT        FORMAT is either 'xml', 'csv' (biblio records only) or 'marc' (default).
 294
 295 =item B<--date>
 296
 297  --date=DATETIME        DATETIME should be entered as the 'dateformat' syspref is
 298                         set (dd/mm/yyyy[ hh:mm:ss] for metric, yyyy-mm-dd[ hh:mm:ss] for iso,
 299                         mm/dd/yyyy[ hh:mm:ss] for us) records exported are the ones that
 300                         have been modified since DATETIME.
 301
 302 =item B<--record-type>
 303
 304  --record-type=TYPE     TYPE is 'bibs' or 'auths'.
 305
 306 =item B<--dont_export_items>
 307
 308  --dont_export_items    If enabled, the item infos won't be exported.
 309
 310 =item B<--csv_profile_id>
 311
 312  --csv_profile_id=ID    Generate a CSV file with the given CSV profile id (see tools/csv-profiles.pl)
 313                         This can only be used to export biblio records.
 314
 315 =item B<--deleted_barcodes>
 316
 317  --deleted_barcodes     If used, a list of barcodes of items deleted since DATE
 318                         is produced (or from all deleted items if no date is
 319                         specified). Used only if TYPE is 'bibs'.
 320
 321 =item B<--clean>
 322
 323  --clean                removes NSE/NSB.
 324
 325 =item B<--id_list_file>
 326
 327  --id_list_file=PATH    PATH is a path to a file containing a list of
 328                         IDs (biblionumber or authid) with one ID per line.
 329                         This list works as a filter; it is compatible with
 330                         other parameters for selecting records.
 331
 332 =item B<--filename>
 333
 334  --filename=FILENAME   FILENAME used to export the data.
 335
 336 =item B<--starting_authid>
 337
 338  --starting_authid=ID  Export authorities with authid >= ID
 339
 340 =item B<--ending_authid>
 341
 342  --ending_authid=ID    Export authorities with authid <= ID
 343
 344 =item B<--authtype>
 345
 346  --authtype=AUTHTYPE   Export authorities from the given AUTHTYPE
 347
 348 =item B<--starting_biblionumber>
 349
 350  --starting_biblionumber=ID  Export biblio with biblionumber >= ID
 351
 352 =item B<--ending_biblionumber>
 353
 354  --ending_biblionumber=ID    Export biblio with biblionumber <= ID
 355
 356 =item B<--itemtype>
 357
 358  --itemtype=ITEMTYPE         Export biblio from the given ITEMTYPE
 359
 360 =item B<--starting_callnumber>
 361
 362  --starting_callnumber=CALLNUMBER Export biblio with callnumber >=CALLNUMBER
 363
 364 =item B<--ending_callnumber>
 365
 366  --ending_callnumber=CALLNUMBER Export biblio with callnumber <=CALLNUMBER
 367
 368 =item B<--start_accession>
 369
 370  --starting_accession=DATE      Export biblio with an item accessionned after DATE
 371
 372 =item B<--end_accession>
 373
 374  --end_accession=DATE           Export biblio with an item accessionned after DATE
 375
 376 =item B<--marc_conditions>
 377
 378  --marc_conditions=CONDITIONS   Only include biblios with MARC data matching CONDITIONS.
 379                                 CONDITIONS is on the format: <marc_target><binary_operator><value>,
 380                                 or <unary_operation>(<marc_target>).
 381                                 with multiple conditions separated by commas (,).
 382                                 For example: --marc_conditions="035a!=(EXAMPLE)123,041a=swe".
 383                                 Multiple conditions are all required to match.
 384                                 If <marc_target> has multiple values all values
 385                                 are also required to match.
 386                                 Valid operators are: = (equal to), != (not equal to),
 387                                 > (great than) and < (less than).
 388
 389                                 Two unary operations are also supported:
 390                                 exists(<marc_target>) and not_exists(<marc_target>).
 391                                 For example: --marc_conditions="exists(035a)".
 392
 393                                 "exists(<marc_target)" will include marc records where
 394                                 <marc_target> exists regardless of target value, and
 395                                 "exists(<marc_target>)" will include marc records where
 396                                 no <marc_target> exists.
 397
 398 =back
 399
 400 =head1 AUTHOR
 401
 402 Koha Development Team
 403
 404 =head1 COPYRIGHT
 405
 406 Copyright Koha Team
 407
 408 =head1 LICENSE
 409
 410 This file is part of Koha.
 411
 412 # Koha is free software; you can redistribute it and/or modify it
 413 # under the terms of the GNU General Public License as published by
 414 # the Free Software Foundation; either version 3 of the License, or
 415 # (at your option) any later version.
 416 #
 417 # Koha is distributed in the hope that it will be useful, but
 418 # WITHOUT ANY WARRANTY; without even the implied warranty of
 419 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
 420 # GNU General Public License for more details.
 421 #
 422 # You should have received a copy of the GNU General Public License
 423 # along with Koha; if not, see <http://www.gnu.org/licenses>.
 424
 425 =cut