misc/workers/background_jobs_worker.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 =head1 NAME
  19
  20 background_jobs_worker.pl - Worker script that will process background jobs
  21
  22 =head1 SYNOPSIS
  23
  24 ./background_jobs_worker.pl [--queue QUEUE] [-m|--max-processes MAX_PROCESSES]
  25
  26 =head1 DESCRIPTION
  27
  28 This script will connect to the Stomp server (RabbitMQ) and subscribe to the queues passed in parameter (or the 'default' queue),
  29 or if a Stomp server is not active it will poll the database every 10s for new jobs in the passed queue.
  30
  31 You can specify some queues only (using --queue, which is repeatable) if you want to run several workers that will handle their own jobs.
  32
  33 --m --max-processes specifies how many jobs to process simultaneously
  34
  35 Max processes will be set from the command line option, the environment variable MAX_PROCESSES, or the koha-conf file, in that order of precedence.
  36 By default the script will only run one job at a time.
  37
  38 =head1 OPTIONS
  39
  40 =over
  41
  42 =item B<--queue>
  43
  44 Repeatable. Give the job queues this worker will process.
  45
  46 The different values available are:
  47
  48     default
  49     long_tasks
  50     elastic_index
  51
  52 =back
  53
  54 =cut
  55
  56 use Modern::Perl;
  57 use JSON qw( decode_json );
  58 use Try::Tiny;
  59 use Pod::Usage;
  60 use Getopt::Long;
  61 use Parallel::ForkManager;
  62
  63 use C4::Context;
  64 use Koha::Logger;
  65 use Koha::BackgroundJobs;
  66 use C4::Context;
  67
  68 $SIG{'PIPE'} = 'IGNORE';    # See BZ 35111; added to ignore PIPE error when connection lost on Ubuntu.
  69
  70 my ( $help, @queues );
  71
  72 my $max_processes = $ENV{MAX_PROCESSES};
  73 $max_processes ||= C4::Context->config('background_jobs_worker')->{max_processes} if C4::Context->config('background_jobs_worker');
  74 $max_processes ||= 1;
  75
  76 GetOptions(
  77     'm|max-processes=i' => \$max_processes,
  78     'h|help' => \$help,
  79     'queue=s' => \@queues,
  80 ) || pod2usage(1);
  81
  82
  83 pod2usage(0) if $help;
  84
  85 unless (@queues) {
  86     push @queues, 'default';
  87 }
  88
  89 my $conn;
  90 try {
  91     $conn = Koha::BackgroundJob->connect;
  92 } catch {
  93     warn sprintf "Cannot connect to the message broker, the jobs will be processed anyway (%s)", $_;
  94 };
  95
  96 my $pm = Parallel::ForkManager->new($max_processes);
  97
  98 if ( $conn ) {
  99     # FIXME cf note in Koha::BackgroundJob about $namespace
 100     my $namespace = C4::Context->config('memcached_namespace');
 101     for my $queue (@queues) {
 102         $conn->subscribe(
 103             {
 104                 destination      => sprintf( "/queue/%s-%s", $namespace, $queue ),
 105                 ack              => 'client',
 106                 'prefetch-count' => 1,
 107             }
 108         );
 109     }
 110 }
 111 while (1) {
 112     if ( $conn ) {
 113         my $frame = $conn->receive_frame;
 114         if ( !defined $frame ) {
 115             # maybe log connection problems
 116             next;    # will reconnect automatically
 117         }
 118
 119         my $args = try {
 120             my $body = $frame->body;
 121             decode_json($body); # TODO Should this be from_json? Check utf8 flag.
 122         } catch {
 123             Koha::Logger->get({ interface => 'worker' })->warn(sprintf "Frame not processed - %s", $_);
 124             return;
 125         } finally {
 126             $conn->ack( { frame => $frame } );
 127         };
 128
 129         next unless $args;
 130
 131         # FIXME This means we need to have create the DB entry before
 132         # It could work in a first step, but then we will want to handle job that will be created from the message received
 133         my $job = Koha::BackgroundJobs->search( { id => $args->{job_id}, status => 'new' } )->next;
 134
 135         unless( $job ) {
 136             Koha::Logger->get( { interface => 'worker' } )
 137                 ->warn( sprintf "Job %s not found, or has wrong status", $args->{job_id} );
 138             next;
 139         }
 140
 141         $pm->start and next;
 142         srand();    # ensure each child process begins with a new seed
 143         process_job( $job, $args );
 144         $pm->finish;
 145
 146     } else {
 147         my $jobs = Koha::BackgroundJobs->search({ status => 'new', queue => \@queues });
 148         while ( my $job = $jobs->next ) {
 149             my $args = try {
 150                 $job->json->decode($job->data);
 151             } catch {
 152                 Koha::Logger->get({ interface => 'worker' })->warn(sprintf "Cannot decode data for job id=%s", $job->id);
 153                 $job->status('failed')->store;
 154                 return;
 155             };
 156
 157             next unless $args;
 158
 159             $pm->start and next;
 160             srand();    # ensure each child process begins with a new seed
 161             process_job( $job, { job_id => $job->id, %$args } );
 162             $pm->finish;
 163
 164         }
 165         sleep 10;
 166     }
 167 }
 168 $conn->disconnect;
 169 $pm->wait_all_children;
 170
 171 sub process_job {
 172     my ( $job, $args ) = @_;
 173     try {
 174         $job->process( $args );
 175     } catch {
 176         $job->status('failed')->store;
 177     };
 178 }