reserve/request.pl

   1 #!/usr/bin/perl
   2
   3
   4 #written 2/1/00 by chris@katipo.oc.nz
   5 # Copyright 2000-2002 Katipo Communications
   6 # Parts Copyright 2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 request.pl
  24
  25 script to place reserves/requests
  26
  27 =cut
  28
  29 use Modern::Perl;
  30
  31 use CGI qw ( -utf8 );
  32 use List::MoreUtils qw/uniq/;
  33 use Date::Calc qw/Date_to_Days/;
  34 use C4::Output;
  35 use C4::Auth;
  36 use C4::Reserves;
  37 use C4::Biblio;
  38 use C4::Items;
  39 use C4::Koha;
  40 use C4::Circulation;
  41 use Koha::DateUtils;
  42 use C4::Utils::DataTables::Members;
  43 use C4::Members;
  44 use C4::Search;         # enabled_staff_search_views
  45 use Koha::DateUtils;
  46 use Koha::Holds;
  47 use Koha::Libraries;
  48
  49 my $dbh = C4::Context->dbh;
  50 my $input = new CGI;
  51 my ( $template, $borrowernumber, $cookie, $flags ) = get_template_and_user(
  52     {
  53         template_name   => "reserve/request.tt",
  54         query           => $input,
  55         type            => "intranet",
  56         authnotrequired => 0,
  57         flagsrequired   => { reserveforothers => 'place_holds' },
  58     }
  59 );
  60
  61 my $multihold = $input->param('multi_hold');
  62 $template->param(multi_hold => $multihold);
  63 my $showallitems = $input->param('showallitems');
  64
  65 my $itemtypes = GetItemTypes();
  66
  67 # Select borrowers infos
  68 my $findborrower = $input->param('findborrower');
  69 $findborrower = '' unless defined $findborrower;
  70 $findborrower =~ s|,| |g;
  71 my $borrowernumber_hold = $input->param('borrowernumber') || '';
  72 my $messageborrower;
  73 my $warnings;
  74 my $messages;
  75 my $exceeded_maxreserves;
  76 my $exceeded_holds_per_record;
  77
  78 my $date = output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 });
  79 my $action = $input->param('action');
  80 $action ||= q{};
  81
  82 if ( $action eq 'move' ) {
  83   my $where = $input->param('where');
  84   my $reserve_id = $input->param('reserve_id');
  85   AlterPriority( $where, $reserve_id );
  86 } elsif ( $action eq 'cancel' ) {
  87   my $reserve_id = $input->param('reserve_id');
  88   CancelReserve({ reserve_id => $reserve_id });
  89 } elsif ( $action eq 'setLowestPriority' ) {
  90   my $reserve_id = $input->param('reserve_id');
  91   ToggleLowestPriority( $reserve_id );
  92 } elsif ( $action eq 'toggleSuspend' ) {
  93   my $reserve_id = $input->param('reserve_id');
  94   my $suspend_until  = $input->param('suspend_until');
  95   ToggleSuspend( $reserve_id, $suspend_until );
  96 }
  97
  98 if ($findborrower) {
  99     my $borrower = C4::Members::GetMember( cardnumber => $findborrower );
 100     if ( $borrower ) {
 101         $borrowernumber_hold = $borrower->{borrowernumber};
 102     } else {
 103         my $dt_params = { iDisplayLength => -1 };
 104         my $results = C4::Utils::DataTables::Members::search(
 105             {
 106                 searchmember => $findborrower,
 107                 dt_params => $dt_params,
 108             }
 109         );
 110         my $borrowers = $results->{patrons};
 111         if ( scalar @$borrowers == 1 ) {
 112             $borrowernumber_hold = $borrowers->[0]->{borrowernumber};
 113         } elsif ( @$borrowers ) {
 114             $template->param( borrowers => $borrowers );
 115         } else {
 116             $messageborrower = "'$findborrower'";
 117         }
 118     }
 119 }
 120
 121 my @biblionumbers = ();
 122 my $biblionumbers = $input->param('biblionumbers');
 123 if ($multihold) {
 124     @biblionumbers = split '/', $biblionumbers;
 125 } else {
 126     push @biblionumbers, $input->multi_param('biblionumber');
 127 }
 128
 129
 130 # If we have the borrowernumber because we've performed an action, then we
 131 # don't want to try to place another reserve.
 132 if ($borrowernumber_hold && !$action) {
 133     my $borrowerinfo = GetMember( borrowernumber => $borrowernumber_hold );
 134     my $diffbranch;
 135
 136     # we check the reserves of the borrower, and if he can reserv a document
 137     # FIXME At this time we have a simple count of reservs, but, later, we could improve the infos "title" ...
 138
 139     my $reserves_count =
 140       GetReserveCount( $borrowerinfo->{'borrowernumber'} );
 141
 142     my $new_reserves_count = scalar( @biblionumbers );
 143
 144     my $maxreserves = C4::Context->preference('maxreserves');
 145     if ( $maxreserves
 146         && ( $reserves_count + $new_reserves_count > $maxreserves ) )
 147     {
 148         my $new_reserves_allowed =
 149             $maxreserves - $reserves_count > 0
 150           ? $maxreserves - $reserves_count
 151           : 0;
 152         $warnings             = 1;
 153         $exceeded_maxreserves = 1;
 154         $template->param(
 155             new_reserves_allowed => $new_reserves_allowed,
 156             new_reserves_count   => $new_reserves_count,
 157             reserves_count       => $reserves_count,
 158             maxreserves          => $maxreserves,
 159         );
 160     }
 161
 162     # we check the date expiry of the borrower (only if there is an expiry date, otherwise, set to 1 (warn)
 163     my $expiry_date = $borrowerinfo->{dateexpiry};
 164     my $expiry = 0; # flag set if patron account has expired
 165     if ($expiry_date and $expiry_date ne '0000-00-00' and
 166         Date_to_Days(split /-/,$date) > Date_to_Days(split /-/,$expiry_date)) {
 167         $expiry = 1;
 168     }
 169
 170     # check if the borrower make the reserv in a different branch
 171     if ( $borrowerinfo->{'branchcode'} ne C4::Context->userenv->{'branch'} ) {
 172         $diffbranch = 1;
 173     }
 174
 175     my $is_debarred = Koha::Patrons->find( $borrowerinfo->{borrowernumber} )->is_debarred;
 176     $template->param(
 177                 borrowernumber      => $borrowerinfo->{'borrowernumber'},
 178                 borrowersurname     => $borrowerinfo->{'surname'},
 179                 borrowerfirstname   => $borrowerinfo->{'firstname'},
 180                 borrowerstreetaddress   => $borrowerinfo->{'address'},
 181                 borrowercity        => $borrowerinfo->{'city'},
 182                 borrowerphone       => $borrowerinfo->{'phone'},
 183                 borrowermobile      => $borrowerinfo->{'mobile'},
 184                 borrowerfax         => $borrowerinfo->{'fax'},
 185                 borrowerphonepro    => $borrowerinfo->{'phonepro'},
 186                 borroweremail       => $borrowerinfo->{'email'},
 187                 borroweremailpro    => $borrowerinfo->{'emailpro'},
 188                 borrowercategory    => $borrowerinfo->{'category'},
 189                 cardnumber          => $borrowerinfo->{'cardnumber'},
 190                 expiry              => $expiry,
 191                 diffbranch          => $diffbranch,
 192                 messages            => $messages,
 193                 warnings            => $warnings,
 194                 restricted          => $is_debarred,
 195                 amount_outstanding  => GetMemberAccountRecords($borrowerinfo->{borrowernumber}),
 196     );
 197 }
 198
 199 $template->param( messageborrower => $messageborrower );
 200
 201 # FIXME launch another time GetMember perhaps until
 202 my $borrowerinfo = GetMember( borrowernumber => $borrowernumber_hold );
 203
 204 my $itemdata_enumchron = 0;
 205 my @biblioloop = ();
 206 foreach my $biblionumber (@biblionumbers) {
 207     next unless $biblionumber =~ m|^\d+$|;
 208
 209     my %biblioloopiter = ();
 210
 211     my $dat = GetBiblioData($biblionumber);
 212
 213     my $canReserve = CanBookBeReserved( $borrowerinfo->{borrowernumber}, $biblionumber );
 214     $canReserve //= '';
 215     if ( $canReserve eq 'OK' ) {
 216
 217         #All is OK and we can continue
 218     }
 219     elsif ( $canReserve eq 'tooManyReserves' ) {
 220         $exceeded_maxreserves = 1;
 221     }
 222     elsif ( $canReserve eq 'tooManyHoldsForThisRecord' ) {
 223         $exceeded_holds_per_record = 1;
 224         $biblioloopiter{$canReserve} = 1;
 225     }
 226     elsif ( $canReserve eq 'ageRestricted' ) {
 227         $template->param( $canReserve => 1 );
 228         $biblioloopiter{$canReserve} = 1;
 229     }
 230     else {
 231         $biblioloopiter{$canReserve} = 1;
 232     }
 233
 234     my $force_hold_level;
 235     if ( $borrowerinfo->{borrowernumber} ) {
 236         # For multiple holds per record, if a patron has previously placed a hold,
 237         # the patron can only place more holds of the same type. That is, if the
 238         # patron placed a record level hold, all the holds the patron places must
 239         # be record level. If the patron placed an item level hold, all holds
 240         # the patron places must be item level
 241         my $holds = Koha::Holds->search(
 242             {
 243                 borrowernumber => $borrowerinfo->{borrowernumber},
 244                 biblionumber   => $biblionumber,
 245                 found          => undef,
 246             }
 247         );
 248         $force_hold_level = $holds->forced_hold_level();
 249         $biblioloopiter{force_hold_level} = $force_hold_level;
 250         $template->param( force_hold_level => $force_hold_level );
 251
 252         # For a librarian to be able to place multiple record holds for a patron for a record,
 253         # we must find out what the maximum number of holds they can place for the patron is
 254         my $max_holds_for_record = GetMaxPatronHoldsForRecord( $borrowerinfo->{borrowernumber}, $biblionumber );
 255         my $remaining_holds_for_record = $max_holds_for_record - $holds->count();
 256         $biblioloopiter{remaining_holds_for_record} = $max_holds_for_record;
 257         $template->param( max_holds_for_record => $max_holds_for_record );
 258         $template->param( remaining_holds_for_record => $remaining_holds_for_record );
 259     }
 260
 261     # Check to see if patron is allowed to place holds on records where the
 262     # patron already has an item from that record checked out
 263     if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 264         && CheckIfIssuedToPatron( $borrowerinfo->{borrowernumber}, $biblionumber ) )
 265     {
 266         $template->param( alreadypossession => 1, );
 267     }
 268
 269
 270     my $count = Koha::Holds->search( { biblionumber => $biblionumber } )->count();
 271     my $totalcount = $count;
 272
 273     # FIXME think @optionloop, is maybe obsolete, or  must be switchable by a systeme preference fixed rank or not
 274     # make priorities options
 275
 276     my @optionloop;
 277     for ( 1 .. $count + 1 ) {
 278         push(
 279              @optionloop,
 280              {
 281               num      => $_,
 282               selected => ( $_ == $count + 1 ),
 283              }
 284             );
 285     }
 286     # adding a fixed value for priority options
 287     my $fixedRank = $count+1;
 288
 289     my %itemnumbers_of_biblioitem;
 290     my @itemnumbers;
 291
 292     ## $items is array of 'item' table numbers
 293     if (my $items = get_itemnumbers_of($biblionumber)->{$biblionumber}){
 294         @itemnumbers  = @$items;
 295     }
 296     my @hostitems = get_hostitemnumbers_of($biblionumber);
 297     if (@hostitems){
 298         $template->param('hostitemsflag' => 1);
 299         push(@itemnumbers, @hostitems);
 300     }
 301
 302     if (!@itemnumbers) {
 303         $template->param('noitems' => 1);
 304         $biblioloopiter{noitems} = 1;
 305     }
 306
 307     ## Hash of item number to 'item' table fields
 308     my $iteminfos_of = GetItemInfosOf(@itemnumbers);
 309
 310     ## Here we go backwards again to create hash of biblioitemnumber to itemnumbers,
 311     ## when by definition all of the itemnumber have the same biblioitemnumber
 312     foreach my $itemnumber (@itemnumbers) {
 313         my $biblioitemnumber = $iteminfos_of->{$itemnumber}->{biblioitemnumber};
 314         push( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} }, $itemnumber );
 315     }
 316
 317     ## Should be same as biblionumber
 318     my @biblioitemnumbers = keys %itemnumbers_of_biblioitem;
 319
 320     my $notforloan_label_of = get_notforloan_label_of();
 321
 322     ## Hash of biblioitemnumber to 'biblioitem' table records
 323     my $biblioiteminfos_of  = GetBiblioItemInfosOf(@biblioitemnumbers);
 324
 325     my @bibitemloop;
 326
 327     my @available_itemtypes;
 328     foreach my $biblioitemnumber (@biblioitemnumbers) {
 329         my $biblioitem = $biblioiteminfos_of->{$biblioitemnumber};
 330         my $num_available = 0;
 331         my $num_override  = 0;
 332         my $hiddencount   = 0;
 333
 334         $biblioitem->{force_hold_level} = $force_hold_level;
 335
 336         if ( $biblioitem->{biblioitemnumber} ne $biblionumber ) {
 337             $biblioitem->{hostitemsflag} = 1;
 338         }
 339
 340         $biblioloopiter{description} = $biblioitem->{description};
 341         $biblioloopiter{itypename}   = $biblioitem->{description};
 342         if ( $biblioitem->{itemtype} ) {
 343
 344             $biblioitem->{description} =
 345               $itemtypes->{ $biblioitem->{itemtype} }{description};
 346
 347             $biblioloopiter{imageurl} =
 348               getitemtypeimagelocation( 'intranet',
 349                 $itemtypes->{ $biblioitem->{itemtype} }{imageurl} );
 350         }
 351
 352         foreach my $itemnumber ( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} } )    {
 353             my $item = $iteminfos_of->{$itemnumber};
 354
 355             $item->{force_hold_level} = $force_hold_level;
 356
 357             unless (C4::Context->preference('item-level_itypes')) {
 358                 $item->{itype} = $biblioitem->{itemtype};
 359             }
 360
 361             $item->{itypename} = $itemtypes->{ $item->{itype} }{description};
 362             $item->{imageurl} = getitemtypeimagelocation( 'intranet', $itemtypes->{ $item->{itype} }{imageurl} );
 363             $item->{homebranch} = $item->{homebranch};
 364
 365             # if the holdingbranch is different than the homebranch, we show the
 366             # holdingbranch of the document too
 367             if ( $item->{homebranch} ne $item->{holdingbranch} ) {
 368                 $item->{holdingbranch} = $item->{holdingbranch};
 369             }
 370
 371                 if($item->{biblionumber} ne $biblionumber){
 372                         $item->{hostitemsflag}=1;
 373                         $item->{hosttitle} = GetBiblioData($item->{biblionumber})->{title};
 374                 }
 375
 376             # if the item is currently on loan, we display its return date and
 377             # change the background color
 378             my $issues= GetItemIssue($itemnumber);
 379             if ( $issues->{'date_due'} ) {
 380                 $item->{date_due} = $issues->{date_due_sql};
 381                 $item->{backgroundcolor} = 'onloan';
 382             }
 383
 384             # checking reserve
 385             my ($reservedate,$reservedfor,$expectedAt,$reserve_id,$wait) = GetReservesFromItemnumber($itemnumber);
 386             if ( defined $reservedate ) {
 387                 my $ItemBorrowerReserveInfo = GetMember( borrowernumber => $reservedfor );
 388
 389                 $item->{backgroundcolor} = 'reserved';
 390                 $item->{reservedate}     = output_pref({ dt => dt_from_string( $reservedate ), dateonly => 1 });
 391                 $item->{ReservedForBorrowernumber}     = $reservedfor;
 392                 $item->{ReservedForSurname}     = $ItemBorrowerReserveInfo->{'surname'};
 393                 $item->{ReservedForFirstname}     = $ItemBorrowerReserveInfo->{'firstname'};
 394                 $item->{ExpectedAtLibrary}     = $expectedAt;
 395                 $item->{waitingdate} = $wait;
 396             }
 397
 398             # Management of the notforloan document
 399             if ( $item->{notforloan} ) {
 400                 $item->{backgroundcolor} = 'other';
 401                 $item->{notforloanvalue} =
 402                   $notforloan_label_of->{ $item->{notforloan} };
 403             }
 404
 405             # Management of lost or long overdue items
 406             if ( $item->{itemlost} ) {
 407
 408                 # FIXME localized strings should never be in Perl code
 409                 $item->{message} =
 410                   $item->{itemlost} == 1 ? "(lost)"
 411                     : $item->{itemlost} == 2 ? "(long overdue)"
 412                       : "";
 413                 $item->{backgroundcolor} = 'other';
 414                 if (GetHideLostItemsPreference($borrowernumber) && !$showallitems) {
 415                     $item->{hide} = 1;
 416                     $hiddencount++;
 417                 }
 418             }
 419
 420             # Check the transit status
 421             my ( $transfertwhen, $transfertfrom, $transfertto ) =
 422               GetTransfers($itemnumber);
 423
 424             if ( defined $transfertwhen && $transfertwhen ne '' ) {
 425                 $item->{transfertwhen} = output_pref({ dt => dt_from_string( $transfertwhen ), dateonly => 1 });
 426                 $item->{transfertfrom} = $transfertfrom;
 427                 $item->{transfertto} = $transfertto;
 428                 $item->{nocancel} = 1;
 429             }
 430
 431             # If there is no loan, return and transfer, we show a checkbox.
 432             $item->{notforloan} ||= 0;
 433
 434             # if independent branches is on we need to check if the person can reserve
 435             # for branches they arent logged in to
 436             if ( C4::Context->preference("IndependentBranches") ) {
 437                 if (! C4::Context->preference("canreservefromotherbranches")){
 438                     # cant reserve items so need to check if item homebranch and userenv branch match if not we cant reserve
 439                     my $userenv = C4::Context->userenv;
 440                     unless ( C4::Context->IsSuperLibrarian ) {
 441                         $item->{cantreserve} = 1 if ( $item->{homebranch} ne $userenv->{branch} );
 442                     }
 443                 }
 444             }
 445
 446             my $branch = C4::Circulation::_GetCircControlBranch($item, $borrowerinfo);
 447
 448             my $branchitemrule = GetBranchItemRule( $branch, $item->{'itype'} );
 449
 450             $item->{'holdallowed'} = $branchitemrule->{'holdallowed'};
 451
 452             my $can_item_be_reserved = CanItemBeReserved( $borrowerinfo->{borrowernumber}, $itemnumber );
 453             $item->{not_holdable} = $can_item_be_reserved unless ( $can_item_be_reserved eq 'OK' );
 454
 455             $item->{item_level_holds} = OPACItemHoldsAllowed( $item, $borrowerinfo );
 456
 457             if (
 458                    !$item->{cantreserve}
 459                 && !$exceeded_maxreserves
 460                 && IsAvailableForItemLevelRequest($item, $borrowerinfo)
 461                 && $can_item_be_reserved eq 'OK'
 462               )
 463             {
 464                 $item->{available} = 1;
 465                 $num_available++;
 466
 467                 push( @available_itemtypes, $item->{itype} );
 468             }
 469             elsif ( C4::Context->preference('AllowHoldPolicyOverride') ) {
 470                 # If AllowHoldPolicyOverride is set, it should override EVERY restriction, not just branch item rules
 471                 $item->{override} = 1;
 472                 $num_override++;
 473             }
 474
 475             # If none of the conditions hold true, then neither override nor available is set and the item cannot be checked
 476
 477             # Show serial enumeration when needed
 478             if ($item->{enumchron}) {
 479                 $itemdata_enumchron = 1;
 480             }
 481
 482             push @{ $biblioitem->{itemloop} }, $item;
 483         }
 484
 485         if ( $num_override == scalar( @{ $biblioitem->{itemloop} } ) ) { # That is, if all items require an override
 486             $template->param( override_required => 1 );
 487         } elsif ( $num_available == 0 ) {
 488             $template->param( none_available => 1 );
 489             $biblioloopiter{warn} = 1;
 490             $biblioloopiter{none_avail} = 1;
 491         }
 492         $template->param( hiddencount => $hiddencount);
 493
 494         push @bibitemloop, $biblioitem;
 495     }
 496
 497     @available_itemtypes = uniq( @available_itemtypes );
 498     $template->param( available_itemtypes => \@available_itemtypes );
 499
 500     # existingreserves building
 501     my @reserveloop;
 502     my @reserves = Koha::Holds->search( { biblionumber => $biblionumber }, { order_by => 'priority' } );
 503     foreach my $res (
 504         sort {
 505             my $a_found = $a->found() || '';
 506             my $b_found = $a->found() || '';
 507             $a_found cmp $b_found;
 508         } @reserves
 509       )
 510     {
 511         my %reserve;
 512         my @optionloop;
 513         for ( my $i = 1 ; $i <= $totalcount ; $i++ ) {
 514             push(
 515                 @optionloop,
 516                 {
 517                     num      => $i,
 518                     selected => ( $i == $res->priority() ),
 519                 }
 520             );
 521         }
 522
 523         if ( $res->is_found() ) {
 524             $reserve{'holdingbranch'} = $res->item()->holdingbranch();
 525             $reserve{'biblionumber'}  = $res->item()->biblionumber();
 526             $reserve{'barcodenumber'} = $res->item()->barcode();
 527             $reserve{'wbrcode'}       = $res->branchcode();
 528             $reserve{'itemnumber'}    = $res->itemnumber();
 529             $reserve{'wbrname'}       = $res->branch()->branchname();
 530
 531             if ( $reserve{'holdingbranch'} eq $reserve{'wbrcode'} ) {
 532
 533                 # Just because the holdingbranch matches the reserve branch doesn't mean the item
 534                 # has arrived at the destination, check for an open transfer for the item as well
 535                 my ( $transfertwhen, $transfertfrom, $transferto ) =
 536                   C4::Circulation::GetTransfers( $res->itemnumber() );
 537                 if ( not $transferto or $transferto ne $res->branchcode() ) {
 538                     $reserve{'atdestination'} = 1;
 539                 }
 540             }
 541
 542             # set found to 1 if reserve is waiting for patron pickup
 543             $reserve{'found'}     = $res->is_found();
 544             $reserve{'intransit'} = $res->is_in_transit();
 545         }
 546         elsif ( $res->priority() > 0 ) {
 547             if ( my $item = $res->item() )  {
 548                 $reserve{'itemnumber'}      = $item->id();
 549                 $reserve{'barcodenumber'}   = $item->barcode();
 550                 $reserve{'item_level_hold'} = 1;
 551             }
 552         }
 553
 554         #     get borrowers reserve info
 555         if ( C4::Context->preference('HidePatronName') ) {
 556             $reserve{'hidename'}   = 1;
 557             $reserve{'cardnumber'} = $res->borrower()->cardnumber();
 558         }
 559         $reserve{'expirationdate'} = output_pref( { dt => dt_from_string( $res->expirationdate ), dateonly => 1 } )
 560           unless ( !defined( $res->expirationdate ) || $res->expirationdate eq '0000-00-00' );
 561         $reserve{'date'}           = output_pref( { dt => dt_from_string( $res->reservedate ), dateonly => 1 } );
 562         $reserve{'borrowernumber'} = $res->borrowernumber();
 563         $reserve{'biblionumber'}   = $res->biblionumber();
 564         $reserve{'borrowernumber'} = $res->borrowernumber();
 565         $reserve{'firstname'}      = $res->borrower()->firstname();
 566         $reserve{'surname'}        = $res->borrower()->surname();
 567         $reserve{'notes'}          = $res->reservenotes();
 568         $reserve{'waiting_date'}   = $res->waitingdate();
 569         $reserve{'waiting_until'}  = $res->is_waiting() ? $res->waiting_expires_on() : undef;
 570         $reserve{'ccode'}          = $res->item() ? $res->item()->ccode() : undef;
 571         $reserve{'barcode'}        = $res->item() ? $res->item()->barcode() : undef;
 572         $reserve{'priority'}       = $res->priority();
 573         $reserve{'lowestPriority'} = $res->lowestPriority();
 574         $reserve{'optionloop'}     = \@optionloop;
 575         $reserve{'suspend'}        = $res->suspend();
 576         $reserve{'suspend_until'}  = $res->suspend_until();
 577         $reserve{'reserve_id'}     = $res->reserve_id();
 578         $reserve{itemtype}         = $res->itemtype();
 579         $reserve{branchcode}       = $res->branchcode();
 580
 581         push( @reserveloop, \%reserve );
 582     }
 583
 584     # get the time for the form name...
 585     my $time = time();
 586
 587     $template->param(
 588                      time        => $time,
 589                      fixedRank   => $fixedRank,
 590                     );
 591
 592     # display infos
 593     $template->param(
 594                      optionloop        => \@optionloop,
 595                      bibitemloop       => \@bibitemloop,
 596                      itemdata_enumchron => $itemdata_enumchron,
 597                      date              => $date,
 598                      biblionumber      => $biblionumber,
 599                      findborrower      => $findborrower,
 600                      title             => $dat->{title},
 601                      author            => $dat->{author},
 602                      holdsview => 1,
 603                      C4::Search::enabled_staff_search_views,
 604                     );
 605     if (defined $borrowerinfo && exists $borrowerinfo->{'branchcode'}) {
 606         $template->param( borrower_branchcode => $borrowerinfo->{'branchcode'},);
 607     }
 608
 609     $biblioloopiter{biblionumber} = $biblionumber;
 610     $biblioloopiter{title} = $dat->{title};
 611     $biblioloopiter{rank} = $fixedRank;
 612     $biblioloopiter{reserveloop} = \@reserveloop;
 613
 614     if (@reserveloop) {
 615         $template->param( reserveloop => \@reserveloop );
 616     }
 617
 618     push @biblioloop, \%biblioloopiter;
 619 }
 620
 621 $template->param( biblioloop => \@biblioloop );
 622 $template->param( biblionumbers => $biblionumbers );
 623 $template->param( exceeded_maxreserves => $exceeded_maxreserves );
 624 $template->param( exceeded_holds_per_record => $exceeded_holds_per_record );
 625
 626 if ($multihold) {
 627     $template->param( multi_hold => 1 );
 628 }
 629
 630 if ( C4::Context->preference( 'AllowHoldDateInFuture' ) ) {
 631     $template->param( reserve_in_future => 1 );
 632 }
 633
 634 $template->param(
 635     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 636     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 637 );
 638
 639 # printout the page
 640 output_html_with_http_headers $input, $cookie, $template->output;
 641
 642 sub sort_borrowerlist {
 643     my $borrowerslist = shift;
 644     my $ref           = [];
 645     push @{$ref}, sort {
 646         uc( $a->{surname} . $a->{firstname} ) cmp
 647           uc( $b->{surname} . $b->{firstname} )
 648     } @{$borrowerslist};
 649     return $ref;
 650 }