t/db_dependent/Acquisition/TransferOrder.t

   1 #!/usr/bin/perl
   2
   3 use Modern::Perl;
   4
   5 use Test::More tests => 14;
   6 use C4::Context;
   7 use C4::Acquisition qw( NewBasket GetOrders GetOrder TransferOrder SearchOrders ModReceiveOrder CancelReceipt );
   8 use C4::Biblio;
   9 use C4::Items;
  10 use C4::Budgets qw( AddBudget GetBudget );
  11 use Koha::Database;
  12 use Koha::DateUtils;
  13 use Koha::Acquisition::Booksellers;
  14 use Koha::Acquisition::Orders;
  15 use t::lib::TestBuilder;
  16 use MARC::Record;
  17 use String::Random qw(random_string);
  18
  19 my $schema = Koha::Database->new()->schema();
  20 $schema->storage->txn_begin();
  21
  22 my $builder = t::lib::TestBuilder->new;
  23
  24 my $bookseller1 = Koha::Acquisition::Bookseller->new(
  25     {
  26         name => "my vendor 1",
  27         address1 => "bookseller's address",
  28         phone => "0123456",
  29         active => 1
  30     }
  31 )->store;
  32
  33 my $basketno1 = C4::Acquisition::NewBasket(
  34     $bookseller1->id
  35 );
  36
  37 my $bookseller2 = Koha::Acquisition::Bookseller->new(
  38     {
  39         name => "my vendor 2",
  40         address1 => "bookseller's address",
  41         phone => "0123456",
  42         active => 1
  43     }
  44 )->store;
  45
  46 my $basketno2 = C4::Acquisition::NewBasket(
  47     $bookseller2->id
  48 );
  49
  50 my $budgetid = C4::Budgets::AddBudget(
  51     {
  52         budget_code => "budget_code_test_transferorder",
  53         budget_name => "budget_name_test_transferorder",
  54     }
  55 );
  56
  57 my $budget = C4::Budgets::GetBudget( $budgetid );
  58
  59 my $biblio = $builder->build_sample_biblio();
  60 my $item_1 = $builder->build_sample_item({ biblionumber => $biblio->biblionumber });
  61 my $biblionumber = $biblio->biblionumber;
  62
  63 my $order = Koha::Acquisition::Order->new(
  64     {
  65         basketno => $basketno1,
  66         quantity => 2,
  67         biblionumber => $biblionumber,
  68         budget_id => $budget->{budget_id},
  69     }
  70 )->store;
  71 my $ordernumber = $order->ordernumber;
  72 $order->add_item( $item_1->itemnumber );
  73
  74 # Begin tests
  75 is(scalar GetOrders($basketno1), 1, "1 order in basket1");
  76 ($order) = GetOrders($basketno1);
  77 $order = Koha::Acquisition::Orders->find($order->{ordernumber});
  78 is($order->items->count, 1, "1 item in basket1's order");
  79 is(scalar GetOrders($basketno2), 0, "0 order in basket2");
  80
  81 # Transfering order to basket2
  82 my $newordernumber = TransferOrder($ordernumber, $basketno2);
  83 is(scalar GetOrders($basketno1), 0, "0 order in basket1");
  84 is(scalar GetOrders($basketno2), 1, "1 order in basket2");
  85
  86 # Determine if the transfer marked things cancelled properly.
  87 is($order->orderstatus,'new','Before the transfer, the order status should be new');
  88 $order = Koha::Acquisition::Orders->find($order->ordernumber);
  89 is($order->orderstatus,'cancelled','After the transfer, the order status should be set to cancelled');
  90
  91 ($order) = GetOrders($basketno2);
  92 $order = Koha::Acquisition::Orders->find($order->{ordernumber});
  93 is($order->items->count, 1, "1 item in basket2's order");
  94
  95 # Bug 11552
  96 my $orders = SearchOrders({ ordernumber => $newordernumber });
  97 is ( scalar( @$orders ), 1, 'SearchOrders returns 1 order with newordernumber' );
  98 $orders = SearchOrders({ ordernumber => $ordernumber });
  99 is ( scalar( @$orders ), 1, 'SearchOrders returns 1 order with [old]ordernumber' );
 100 is ( $orders->[0]->{ordernumber}, $newordernumber, 'SearchOrders returns newordernumber if [old]ordernumber is given' );
 101
 102 my $neworder = Koha::Acquisition::Orders->find( $newordernumber )->unblessed;
 103
 104 ModReceiveOrder({
 105     biblionumber => $biblionumber,
 106     order       => $neworder,
 107     quantityreceived => 2,
 108 });
 109 CancelReceipt( $newordernumber );
 110 $order = GetOrder( $newordernumber );
 111 is ( $order->{ordernumber}, $newordernumber, 'Regression test Bug 11549: After a transfer, receive and cancel the receive should be possible.' );
 112 is ( $order->{basketno}, $basketno2, 'Regression test Bug 11549: The order still exist in the basket where the transfer has been done.');
 113
 114 subtest 'TransferOrder should copy additional fields' => sub {
 115     plan tests => 2;
 116
 117     my $field = Koha::AdditionalField->new(
 118         {
 119             tablename => 'aqorders',
 120             name => random_string('c' x 100),
 121         }
 122     );
 123     $field->store()->discard_changes();
 124     my $order = Koha::Acquisition::Order->new(
 125         {
 126             basketno => $basketno1,
 127             quantity => 2,
 128             biblionumber => $biblionumber,
 129             budget_id => $budget->{budget_id},
 130         }
 131     )->store;
 132     $order->set_additional_fields(
 133         [
 134             {
 135                 id => $field->id,
 136                 value => 'additional field value',
 137             },
 138         ]
 139     );
 140
 141     my $newordernumber = TransferOrder($order->ordernumber, $basketno2);
 142     my $neworder = Koha::Acquisition::Orders->find($newordernumber);
 143     my $field_values = $neworder->additional_field_values()->as_list;
 144
 145     is(scalar @$field_values, 1, 'transfered order has one additional field value');
 146     is($field_values->[0]->value, 'additional field value', 'transfered order additional field has the correct value');
 147 };
 148
 149 $schema->storage->txn_rollback();