t/db_dependent/Circulation/dateexpiry.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use DateTime;
  21 use Time::HiRes qw/gettimeofday time/;
  22 use Test::More tests => 2;
  23 use C4::Members;
  24 use Koha::DateUtils qw( dt_from_string output_pref );
  25 use Koha::Database;
  26
  27 use t::lib::TestBuilder;
  28 use t::lib::Mocks qw( mock_preference );
  29
  30 my $schema  = Koha::Database->new->schema;
  31 $schema->storage->txn_begin;
  32
  33 my $builder = t::lib::TestBuilder->new();
  34
  35 my $patron_category = $builder->build({ source => 'Category', value => { category_type => 'P', enrolmentfee => 0 } });
  36
  37 subtest 'Tests for CanBookBeIssued related to dateexpiry' => sub {
  38     plan tests => 4;
  39     can_book_be_issued();
  40 };
  41 subtest 'Tests for CalcDateDue related to dateexpiry' => sub {
  42     plan tests => 4;
  43     calc_date_due();
  44 };
  45
  46 sub can_book_be_issued {
  47     my $item    = $builder->build_sample_item;
  48     my $patron  = $builder->build_object(
  49         {   class  => 'Koha::Patrons',
  50             value  => {
  51                 dateexpiry => '9999-12-31',
  52                 categorycode => $patron_category->{categorycode},
  53             }
  54         }
  55     );
  56     my $duration = gettimeofday();
  57     my ( $issuingimpossible, $needsconfirmation ) = C4::Circulation::CanBookBeIssued( $patron, $item->barcode );
  58     $duration = gettimeofday() - $duration;
  59     cmp_ok $duration, '<', 1, "CanBookBeIssued should not be take more than 1s if the patron is expired";
  60     is( not( exists $issuingimpossible->{EXPIRED} ), 1, 'The patron should not be considered as expired if dateexpiry is 9999-*' );
  61
  62     $item   = $builder->build_sample_item;
  63     $patron = $builder->build_object(
  64         {   class  => 'Koha::Patrons',
  65             value  => {
  66                 dateexpiry => undef,
  67                 categorycode => $patron_category->{categorycode},
  68             }
  69         }
  70     );
  71     ( $issuingimpossible, $needsconfirmation ) = C4::Circulation::CanBookBeIssued( $patron, $item->barcode );
  72     is( not( exists $issuingimpossible->{EXPIRED} ), 1, 'The patron should not be considered as expired if dateexpiry is not set' );
  73
  74     my $tomorrow = dt_from_string->add_duration( DateTime::Duration->new( days => 1 ) );
  75     $item   = $builder->build_sample_item;
  76     $patron = $builder->build_object(
  77         {   class  => 'Koha::Patrons',
  78             value  => {
  79                 dateexpiry => output_pref( { dt => $tomorrow, dateonly => 1, dateformat => 'sql' } ),
  80                 categorycode => $patron_category->{categorycode},
  81             },
  82         }
  83     );
  84     ( $issuingimpossible, $needsconfirmation ) = C4::Circulation::CanBookBeIssued( $patron, $item->barcode );
  85     is( not( exists $issuingimpossible->{EXPIRED} ), 1, 'The patron should not be considered as expired if dateexpiry is tomorrow' );
  86
  87 }
  88
  89 sub calc_date_due {
  90     t::lib::Mocks::mock_preference( 'ReturnBeforeExpiry', 1 );
  91
  92     # this triggers the compare between expiry and due date
  93
  94     my $patron = $builder->build_object(
  95         {
  96             class  => 'Koha::Patrons',
  97             value  => {
  98                 categorycode => $patron_category->{categorycode},
  99             }
 100         }
 101     );
 102     my $item   = $builder->build_sample_item;
 103     my $branch = $builder->build( { source => 'Branch' } );
 104     my $today  = dt_from_string();
 105
 106     # first test with empty expiry date
 107     # note that this expiry date will never lead to an issue btw !!
 108     $patron->dateexpiry(undef)->store;
 109     my $d = C4::Circulation::CalcDateDue( $today, $item->effective_itemtype, $branch->{branchcode}, $patron );
 110     is( ref $d eq "DateTime" && $d->mdy() =~ /^\d+/, 1, "CalcDateDue with expiry undef" );
 111
 112     # second test expiry date==today
 113     my $d2 = output_pref( { dt => $today, dateonly => 1, dateformat => 'sql' } );
 114     $patron->dateexpiry($d2)->store;
 115     $d = C4::Circulation::CalcDateDue( $today, $item->effective_itemtype, $branch->{branchcode}, $patron );
 116     is( ref $d eq "DateTime" && DateTime->compare( $d->truncate( to => 'day' ), $today->truncate( to => 'day' ) ) == 0, 1, "CalcDateDue with expiry today" );
 117
 118     # third test expiry date tomorrow
 119     my $dur = DateTime::Duration->new( days => 1 );
 120     my $tomorrow = $today->clone->add_duration($dur);
 121     $d2 = output_pref( { dt => $tomorrow, dateonly => 1, dateformat => 'sql' } );
 122     $patron->dateexpiry($d2)->store;
 123     $d = C4::Circulation::CalcDateDue( $today, $item->effective_itemtype, $branch->{branchcode}, $patron );
 124     is( ref $d eq "DateTime" && $d->mdy() =~ /^\d+/, 1, "CalcDateDue with expiry tomorrow" );
 125
 126     # fourth test far future
 127     $patron->dateexpiry('9876-12-31')->store;
 128     my $t1 = time;
 129     $d = C4::Circulation::CalcDateDue( $today, $item->effective_itemtype, $branch->{branchcode}, $patron );
 130     my $t2 = time;
 131     is( ref $d eq "DateTime" && $t2 - $t1 < 1, 1, "CalcDateDue with expiry in year 9876 in " . sprintf( "%6.4f", $t2 - $t1 ) . " seconds." );
 132 }
 133
 134 $schema->storage->txn_rollback;
 135