t/db_dependent/XISBN.t

   1 #!/usr/bin/perl
   2 #
   3 # This Koha test module is a stub!
   4 # Add more tests here!!!
   5
   6 use Modern::Perl;
   7
   8 use Test::More tests => 4;
   9 use MARC::Record;
  10 use C4::Biblio;
  11 use C4::XISBN;
  12 use C4::Context;
  13 use C4::Search;
  14 use t::lib::Mocks;
  15 use Test::MockModule;
  16
  17 BEGIN {
  18     use_ok('C4::XISBN');
  19 }
  20
  21 my $dbh = C4::Context->dbh;
  22 $dbh->{RaiseError} = 1;
  23 $dbh->{AutoCommit} = 0;
  24
  25 my $search_module = new Test::MockModule('C4::Search');
  26
  27 $search_module->mock('SimpleSearch', \&Mock_SimpleSearch );
  28 my $errors;
  29 my $context = C4::Context->new;
  30
  31 my ( $biblionumber_tag, $biblionumber_subfield ) =
  32   GetMarcFromKohaField( 'biblio.biblionumber', '' );
  33 my ( $isbn_tag, $isbn_subfield ) =
  34   GetMarcFromKohaField( 'biblioitems.isbn', '' );
  35
  36 # Harry Potter and the Sorcerer's Stone, 1st American ed. 1997
  37 my $isbn1 = '0590353403';
  38 # ThingISBN match : Silent Wing, First Edition 1998
  39 my $isbn2 = '0684843897';
  40 # XISBN match : Harry Potter and the Sorcerer's Stone,
  41 # 1. Scholastic mass market paperback printing1.
  42 my $isbn3 = '043936213X';
  43
  44 my $biblionumber1 = _add_biblio_with_isbn($isbn1);
  45 my $biblionumber2 = _add_biblio_with_isbn($isbn2);
  46 my $biblionumber3 = _add_biblio_with_isbn($isbn3);
  47
  48 my $trial = C4::XISBN::get_biblionumber_from_isbn($isbn1);
  49 is( $trial->[0]->{biblionumber},
  50     $biblionumber1,
  51     "It gets the correct biblionumber from the only isbn we have added." );
  52
  53 $trial = C4::XISBN::_get_biblio_from_xisbn($isbn1);
  54 is( $trial->{biblionumber},
  55     $biblionumber1, "Gets biblionumber like the previous test." );
  56
  57 ## Test ThingISBN
  58 t::lib::Mocks::mock_preference( 'ThingISBN', 1 );
  59
  60 my $results_thingisbn;
  61 eval { $results_thingisbn = C4::XISBN::get_xisbns($isbn1); };
  62 SKIP: {
  63     skip "Problem retrieving ThingISBN", 1
  64         unless $@ eq '';
  65     is( $results_thingisbn->[0]->{biblionumber},
  66         $biblionumber3,
  67         "Gets correct biblionumber from a book with a similar isbn using ThingISBN." );
  68 }
  69
  70 $dbh->rollback;
  71
  72 # Util subs
  73
  74 # Add new biblio with isbn and return biblionumber
  75 sub _add_biblio_with_isbn {
  76     my $isbn = shift;
  77
  78     my $marc_record = MARC::Record->new;
  79     my $field = MARC::Field->new( $isbn_tag, '', '', $isbn_subfield => $isbn );
  80     $marc_record->append_fields($field);
  81     my ( $biblionumber, $biblioitemnumber ) = AddBiblio( $marc_record, '' );
  82     return $biblionumber;
  83 }
  84
  85 # Mocked subs
  86
  87 # C4::Search::SimpleSearch
  88 sub Mock_SimpleSearch {
  89     my $query = shift;
  90     my @results;
  91
  92     $query =~ s/-//g;
  93     my $ret_biblionumber;
  94     if ( $query =~ /$isbn1/ ) {
  95         $ret_biblionumber = $biblionumber1;
  96     }
  97     elsif ( $query =~ /$isbn2/ ) {
  98         $ret_biblionumber = $biblionumber2;
  99     }
 100     elsif ( $query =~ /$isbn3/ ) {
 101         $ret_biblionumber = $biblionumber3;
 102     }
 103
 104     my $record = MARC::Record->new;
 105     $record->leader('     ngm a22     7a 4500');
 106     my $biblionumber_field;
 107     if ( $biblionumber_tag < 10 ) {
 108         $biblionumber_field =
 109           MARC::Field->new( $biblionumber_tag, $ret_biblionumber );
 110     }
 111     else {
 112         $biblionumber_field = MARC::Field->new( $biblionumber_tag, '', '',
 113             $biblionumber_subfield => $ret_biblionumber );
 114     }
 115     $record->append_fields($biblionumber_field);
 116
 117     my $indexing_mode = C4::Context->config('zebra_bib_index_mode') // 'dom';
 118     push @results, ( $indexing_mode eq 'dom' )
 119                     ? $record->as_xml()
 120                     : $record->as_usmarc() ;
 121
 122     return ( undef, \@results, 1 );
 123 }