t/db_dependent/api/v1/biblios.t

   1 #!/usr/bin/env perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use utf8;
  21 use Encode;
  22
  23 use Test::More tests => 7;
  24 use Test::MockModule;
  25 use Test::Mojo;
  26 use Test::Warn;
  27
  28 use t::lib::Mocks;
  29 use t::lib::TestBuilder;
  30
  31 use C4::Auth;
  32 use C4::Circulation qw( AddIssue AddReturn );
  33
  34 use Koha::Biblios;
  35 use Koha::Database;
  36 use Koha::Checkouts;
  37 use Koha::Old::Checkouts;
  38
  39 my $schema  = Koha::Database->new->schema;
  40 my $builder = t::lib::TestBuilder->new;
  41
  42 t::lib::Mocks::mock_preference( 'RESTBasicAuth', 1 );
  43
  44 my $t = Test::Mojo->new('Koha::REST::V1');
  45
  46 subtest 'get() tests' => sub {
  47
  48     plan tests => 22;
  49
  50     $schema->storage->txn_begin;
  51
  52     my $patron = $builder->build_object(
  53         {
  54             class => 'Koha::Patrons',
  55             value => { flags => 0 }
  56         }
  57     );
  58     my $password = 'thePassword123';
  59     $patron->set_password( { password => $password, skip_validation => 1 } );
  60     $patron->discard_changes;
  61     my $userid = $patron->userid;
  62
  63     my $biblio = $builder->build_sample_biblio({
  64         title  => 'The unbearable lightness of being',
  65         author => 'Milan Kundera'
  66     });
  67     $t->get_ok("//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber)
  68       ->status_is(403);
  69
  70     $patron->flags(4)->store;
  71
  72     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
  73                 => { Accept => 'application/weird+format' } )
  74       ->status_is(406)
  75       ->json_is( [ "application/json",
  76                    "application/marcxml+xml",
  77                    "application/marc-in-json",
  78                    "application/marc",
  79                    "text/plain" ] );
  80
  81     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
  82                  => { Accept => 'application/json' } )
  83       ->status_is(200)
  84       ->json_is( '/title', 'The unbearable lightness of being' )
  85       ->json_is( '/author', 'Milan Kundera' );
  86
  87     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
  88                  => { Accept => 'application/marcxml+xml' } )
  89       ->status_is(200);
  90
  91     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
  92                  => { Accept => 'application/marc-in-json' } )
  93       ->status_is(200);
  94
  95     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
  96                  => { Accept => 'application/marc' } )
  97       ->status_is(200);
  98
  99     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
 100                  => { Accept => 'text/plain' } )
 101       ->status_is(200)
 102       ->content_is($biblio->metadata->record->as_formatted);
 103
 104     $biblio->delete;
 105     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
 106                  => { Accept => 'application/marc' } )
 107       ->status_is(404)
 108       ->json_is( '/error', 'Object not found.' );
 109
 110     subtest 'marc-in-json encoding tests' => sub {
 111
 112         plan tests => 3;
 113
 114         my $title_with_diacritics = "L'insoutenable légèreté de l'être";
 115
 116         my $biblio = $builder->build_sample_biblio(
 117             {
 118                 title  => $title_with_diacritics,
 119                 author => "Milan Kundera"
 120             }
 121         );
 122
 123         my $result = $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber
 124                     => { Accept => 'application/marc-in-json' } )
 125           ->status_is(200)->tx->res->body;
 126
 127         my $encoded_title  = Encode::encode( "UTF-8", $title_with_diacritics );
 128
 129         like( $result, qr/\Q$encoded_title/, "The title is not double encoded" );
 130     };
 131
 132     $schema->storage->txn_rollback;
 133 };
 134
 135 subtest 'get_items() tests' => sub {
 136
 137     plan tests => 8;
 138
 139     $schema->storage->txn_begin;
 140
 141     my $patron = $builder->build_object(
 142         {
 143             class => 'Koha::Patrons',
 144             value => { flags => 0 }
 145         }
 146     );
 147     my $password = 'thePassword123';
 148     $patron->set_password( { password => $password, skip_validation => 1 } );
 149     $patron->discard_changes;
 150     my $userid = $patron->userid;
 151
 152     my $biblio = $builder->build_sample_biblio();
 153     $t->get_ok("//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/items")
 154       ->status_is(403);
 155
 156     $patron->flags(4)->store;
 157
 158     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/items")
 159       ->status_is(200)
 160       ->json_is( '' => [], 'No items on the biblio' );
 161
 162     my $item_1 = $builder->build_sample_item({ biblionumber => $biblio->biblionumber });
 163     my $item_2 = $builder->build_sample_item({ biblionumber => $biblio->biblionumber });
 164
 165     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/items")
 166       ->status_is(200)
 167       ->json_is( '' => [ $item_1->to_api, $item_2->to_api ], 'The items are returned' );
 168
 169     $schema->storage->txn_rollback;
 170 };
 171
 172 subtest 'delete() tests' => sub {
 173
 174     plan tests => 9;
 175
 176     $schema->storage->txn_begin;
 177
 178     my $patron = $builder->build_object(
 179         {
 180             class => 'Koha::Patrons',
 181             value => { flags => 0 } # no permissions
 182         }
 183     );
 184     my $password = 'thePassword123';
 185     $patron->set_password( { password => $password, skip_validation => 1 } );
 186     my $userid = $patron->userid;
 187
 188     my $item      = $builder->build_sample_item();
 189     my $biblio_id = $item->biblionumber;
 190
 191     $t->delete_ok("//$userid:$password@/api/v1/biblios/$biblio_id")
 192       ->status_is(403, 'Not enough permissions makes it return the right code');
 193
 194     # Add permissions
 195     $builder->build(
 196         {
 197             source => 'UserPermission',
 198             value  => {
 199                 borrowernumber => $patron->borrowernumber,
 200                 module_bit     => 9,
 201                 code           => 'edit_catalogue'
 202             }
 203         }
 204     );
 205
 206
 207     # Bibs with items cannot be deleted
 208     $t->delete_ok("//$userid:$password@/api/v1/biblios/$biblio_id")
 209       ->status_is(409);
 210
 211     $item->delete();
 212
 213     # Bibs with no items can be deleted
 214     $t->delete_ok("//$userid:$password@/api/v1/biblios/$biblio_id")
 215       ->status_is(204, 'SWAGGER3.2.4')
 216       ->content_is('', 'SWAGGER3.3.4');
 217
 218     $t->delete_ok("//$userid:$password@/api/v1/biblios/$biblio_id")
 219       ->status_is(404);
 220
 221     $schema->storage->txn_rollback;
 222 };
 223
 224 subtest 'get_public() tests' => sub {
 225
 226     plan tests => 26;
 227
 228     $schema->storage->txn_begin;
 229
 230     my $category = $builder->build_object({ class => 'Koha::Patron::Categories' });
 231     my $patron = $builder->build_object(
 232         {
 233             class => 'Koha::Patrons',
 234             value => {
 235                 flags        => undef, # opac user
 236                 categorycode => $category->categorycode
 237             }
 238         }
 239     );
 240     my $password = 'thePassword123';
 241     $patron->set_password( { password => $password, skip_validation => 1 } );
 242     $patron->discard_changes;
 243     my $userid = $patron->userid;
 244
 245     my $biblio = $builder->build_sample_biblio({
 246         title  => 'The unbearable lightness of being',
 247         author => 'Milan Kundera'
 248     });
 249
 250     # Make sure author in shown in the OPAC
 251     my $subfields = Koha::MarcSubfieldStructures->search({ tagfield => '100' });
 252     while ( my $subfield = $subfields->next ) {
 253         $subfield->set({ hidden => -1 })->store;
 254     }
 255     Koha::Caches->get_instance()->flush_all;
 256
 257     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 258                 => { Accept => 'application/weird+format' } )
 259       ->status_is(406)
 260       ->json_is( [ "application/marcxml+xml",
 261                    "application/marc-in-json",
 262                    "application/marc",
 263                    "text/plain" ] );
 264
 265     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 266                  => { Accept => 'text/plain' } )
 267       ->status_is(200)
 268       ->content_like( qr{100\s+_aMilan Kundera} )
 269       ->content_like( qr{245\s+_aThe unbearable lightness of being} );
 270
 271     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 272                  => { Accept => 'application/marcxml+xml' } )
 273       ->status_is(200);
 274
 275     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 276                  => { Accept => 'application/marc-in-json' } )
 277       ->status_is(200);
 278
 279     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 280                  => { Accept => 'application/marc' } )
 281       ->status_is(200);
 282
 283     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 284                  => { Accept => 'text/plain' } )
 285       ->status_is(200)
 286       ->content_is($biblio->metadata->record->as_formatted);
 287
 288     subtest 'anonymous access' => sub {
 289         plan tests => 9;
 290
 291         $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 292                  => { Accept => 'application/marcxml+xml' } )
 293           ->status_is(200);
 294
 295         $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 296                     => { Accept => 'application/marc-in-json' } )
 297         ->status_is(200);
 298
 299         $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 300                     => { Accept => 'application/marc' } )
 301         ->status_is(200);
 302
 303         $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 304                     => { Accept => 'text/plain' } )
 305         ->status_is(200)
 306         ->content_is($biblio->metadata->record->as_formatted);
 307     };
 308
 309     subtest 'marc-in-json encoding tests' => sub {
 310
 311         plan tests => 3;
 312
 313         my $title_with_diacritics = "L'insoutenable légèreté de l'être";
 314
 315         my $biblio = $builder->build_sample_biblio(
 316             {
 317                 title  => $title_with_diacritics,
 318                 author => "Milan Kundera"
 319             }
 320         );
 321
 322         my $result = $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 323                     => { Accept => 'application/marc-in-json' } )
 324           ->status_is(200)->tx->res->body;
 325
 326         my $encoded_title  = Encode::encode( "UTF-8", $title_with_diacritics );
 327
 328         like( $result, qr/\Q$encoded_title/, "The title is not double encoded" );
 329     };
 330
 331     # Hide author in OPAC
 332     $subfields = Koha::MarcSubfieldStructures->search({ tagfield => '100' });
 333     while ( my $subfield = $subfields->next ) {
 334         $subfield->set({ hidden => 1 })->store;
 335     }
 336
 337     Koha::Caches->get_instance()->flush_all;
 338
 339     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 340                  => { Accept => 'text/plain' } )
 341       ->status_is(200)
 342       ->content_unlike( qr{100\s+_aMilan Kundera} )
 343       ->content_like( qr{245\s+_aThe unbearable lightness of being} );
 344
 345     subtest 'hidden_in_opac tests' => sub {
 346
 347         plan tests => 6;
 348
 349         my $biblio_hidden_in_opac = 1;
 350
 351         my $biblio_class = Test::MockModule->new('Koha::Biblio');
 352         # force biblio hidden in OPAC
 353         $biblio_class->mock( 'hidden_in_opac', sub { return $biblio_hidden_in_opac; } );
 354
 355         $t->get_ok( "/api/v1/public/biblios/" . $biblio->biblionumber
 356                  => { Accept => 'text/plain' } )
 357           ->status_is(404, 'hidden_in_opac + anonymous => hidden');
 358
 359         my $category_override_hidden_items = 0;
 360         my $category_class = Test::MockModule->new('Koha::Patron::Category');
 361         $category_class->mock( 'override_hidden_items', sub { return $category_override_hidden_items; } );
 362         $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 363                  => { Accept => 'text/plain' } )
 364           ->status_is(404, "hidden_in_opac + patron whose category doesn't override => hidden");
 365
 366         # Make the category override
 367         $category_override_hidden_items = 1;
 368         $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 369                  => { Accept => 'text/plain' } )
 370           ->status_is(200, "hidden_in_opac + patron whose category that overrides => displayed");
 371
 372         t::lib::Mocks::mock_preference('OpacHiddenItems');
 373     };
 374
 375     $biblio->delete;
 376     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/" . $biblio->biblionumber
 377                  => { Accept => 'application/marc' } )
 378       ->status_is(404)
 379       ->json_is( '/error', 'Object not found.' );
 380
 381     $schema->storage->txn_rollback;
 382 };
 383
 384 subtest 'pickup_locations() tests' => sub {
 385
 386     plan tests => 15;
 387
 388     $schema->storage->txn_begin;
 389
 390     t::lib::Mocks::mock_preference( 'AllowHoldPolicyOverride', 0 );
 391
 392     # Small trick to ease testing
 393     Koha::Libraries->search->update({ pickup_location => 0 });
 394
 395     my $library_1 = $builder->build_object({ class => 'Koha::Libraries', value => { marcorgcode => 'A', pickup_location => 1 } });
 396     my $library_2 = $builder->build_object({ class => 'Koha::Libraries', value => { marcorgcode => 'B', pickup_location => 1 } });
 397     my $library_3 = $builder->build_object({ class => 'Koha::Libraries', value => { marcorgcode => 'C', pickup_location => 1 } });
 398
 399     my $library_1_api = $library_1->to_api();
 400     my $library_2_api = $library_2->to_api();
 401     my $library_3_api = $library_3->to_api();
 402
 403     $library_1_api->{needs_override} = Mojo::JSON->false;
 404     $library_2_api->{needs_override} = Mojo::JSON->false;
 405     $library_3_api->{needs_override} = Mojo::JSON->true;
 406
 407     my $patron = $builder->build_object(
 408         {
 409             class => 'Koha::Patrons',
 410             value => { userid => 'tomasito', flags => 0 }
 411         }
 412     );
 413     my $password = 'thePassword123';
 414     $patron->set_password( { password => $password, skip_validation => 1 } );
 415     my $userid = $patron->userid;
 416     $builder->build(
 417         {
 418             source => 'UserPermission',
 419             value  => {
 420                 borrowernumber => $patron->borrowernumber,
 421                 module_bit     => 6,
 422                 code           => 'place_holds',
 423             },
 424         }
 425     );
 426
 427     my $biblio_class = Test::MockModule->new('Koha::Biblio');
 428     $biblio_class->mock(
 429         'pickup_locations',
 430         sub {
 431             my ( $self, $params ) = @_;
 432             my $mock_patron = $params->{patron};
 433             is( $mock_patron->borrowernumber,
 434                 $patron->borrowernumber, 'Patron passed correctly' );
 435             return Koha::Libraries->search(
 436                 {
 437                     branchcode => {
 438                         '-in' => [
 439                             $library_1->branchcode,
 440                             $library_2->branchcode
 441                         ]
 442                     }
 443                 },
 444                 {   # we make sure no surprises in the order of the result
 445                     order_by => { '-asc' => 'marcorgcode' }
 446                 }
 447             );
 448         }
 449     );
 450
 451     my $biblio = $builder->build_sample_biblio;
 452
 453     $t->get_ok( "//$userid:$password@/api/v1/biblios/"
 454           . $biblio->id
 455           . "/pickup_locations?patron_id=" . $patron->id )
 456       ->json_is( [ $library_1_api, $library_2_api ] );
 457
 458     # filtering works!
 459     $t->get_ok( "//$userid:$password@/api/v1/biblios/"
 460           . $biblio->id
 461           . '/pickup_locations?'
 462           . 'patron_id=' . $patron->id . '&q={"marc_org_code": { "-like": "A%" }}' )
 463       ->json_is( [ $library_1_api ] );
 464
 465     t::lib::Mocks::mock_preference( 'AllowHoldPolicyOverride', 1 );
 466
 467     my $library_4 = $builder->build_object({ class => 'Koha::Libraries', value => { pickup_location => 0, marcorgcode => 'X' } });
 468     my $library_5 = $builder->build_object({ class => 'Koha::Libraries', value => { pickup_location => 1, marcorgcode => 'Y' } });
 469
 470     my $library_5_api = $library_5->to_api();
 471     $library_5_api->{needs_override} = Mojo::JSON->true;
 472
 473     $t->get_ok( "//$userid:$password@/api/v1/biblios/"
 474           . $biblio->id
 475           . "/pickup_locations?"
 476           . "patron_id=" . $patron->id . "&_order_by=marc_org_code" )
 477       ->json_is( [ $library_1_api, $library_2_api, $library_3_api, $library_5_api ] );
 478
 479     my $deleted_patron = $builder->build_object({ class => 'Koha::Patrons' });
 480     my $deleted_patron_id = $deleted_patron->id;
 481     $deleted_patron->delete;
 482
 483     $t->get_ok( "//$userid:$password@/api/v1/biblios/"
 484           . $biblio->id
 485           . "/pickup_locations?"
 486           . "patron_id=" . $deleted_patron_id )
 487       ->status_is( 400 )
 488       ->json_is( '/error' => 'Patron not found' );
 489
 490     $biblio->delete;
 491
 492     $t->get_ok( "//$userid:$password@/api/v1/biblios/"
 493           . $biblio->id
 494           . "/pickup_locations?"
 495           . "patron_id=" . $patron->id )
 496       ->status_is( 404 )
 497       ->json_is( '/error' => 'Biblio not found' );
 498
 499     $schema->storage->txn_rollback;
 500 };
 501
 502 subtest 'get_items_public() tests' => sub {
 503
 504     plan tests => 15;
 505
 506     $schema->storage->txn_begin;
 507
 508     my $override_hidden_items = 0;
 509
 510     my $mocked_category = Test::MockModule->new('Koha::Patron::Category');
 511     $mocked_category->mock(
 512         'override_hidden_items',
 513         sub {
 514             return $override_hidden_items;
 515         }
 516     );
 517
 518     my $rules = undef;
 519
 520     my $mocked_context = Test::MockModule->new('C4::Context');
 521     $mocked_context->mock(
 522         'yaml_preference',
 523         sub {
 524             return $rules;
 525         }
 526     );
 527
 528     my $patron   = $builder->build_object( { class => 'Koha::Patrons' } );
 529     my $password = 'thePassword123';
 530     $patron->set_password( { password => $password, skip_validation => 1 } );
 531     $patron->discard_changes;
 532     my $userid = $patron->userid;
 533
 534     my $biblio = $builder->build_sample_biblio();
 535
 536     $t->get_ok(
 537         "//$userid:$password@/api/v1/public/biblios/" . $biblio->id . "/items" )
 538       ->status_is(200)->json_is( '' => [], 'No items on the biblio' );
 539
 540     my $item_1 = $builder->build_sample_item( { biblionumber => $biblio->id } );
 541     my $item_2 = $builder->build_sample_item(
 542         { biblionumber => $biblio->id, withdrawn => 1 } );
 543
 544     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/"
 545           . $biblio->biblionumber
 546           . "/items" )->status_is(200)->json_is(
 547         '' => [
 548             $item_1->to_api( { public => 1 } ),
 549             $item_2->to_api( { public => 1 } )
 550         ],
 551         'The items are returned'
 552           );
 553
 554     $rules = { withdrawn => ['1'] };
 555
 556     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/"
 557           . $biblio->biblionumber
 558           . "/items" )->status_is(200)->json_is(
 559         '' => [ $item_1->to_api( { public => 1 } ) ],
 560         'The items are returned, hidden one is not returned'
 561           );
 562
 563     $t->get_ok( "/api/v1/public/biblios/"
 564           . $biblio->biblionumber
 565           . "/items" )->status_is(200)->json_is(
 566         '' => [ $item_1->to_api( { public => 1 } ) ],
 567         'Anonymous user, items are returned, hidden one is not returned'
 568           );
 569
 570
 571     $override_hidden_items = 1;
 572
 573     $t->get_ok( "//$userid:$password@/api/v1/public/biblios/"
 574           . $biblio->biblionumber
 575           . "/items" )->status_is(200)->json_is(
 576         '' => [
 577             $item_1->to_api( { public => 1 } ),
 578             $item_2->to_api( { public => 1 } )
 579         ],
 580         'The items are returned, the patron category has an override'
 581           );
 582
 583     $schema->storage->txn_rollback;
 584 };
 585
 586 subtest 'get_checkouts() tests' => sub {
 587
 588     plan tests => 14;
 589
 590     $schema->storage->txn_begin;
 591
 592     my $patron = $builder->build_object(
 593         {
 594             class => 'Koha::Patrons',
 595             value => { flags => 0 }
 596         }
 597     );
 598     my $password = 'thePassword123';
 599     $patron->set_password( { password => $password, skip_validation => 1 } );
 600     $patron->discard_changes;
 601     my $userid = $patron->userid;
 602
 603     my $biblio = $builder->build_sample_biblio();
 604     $t->get_ok("//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/checkouts")
 605       ->status_is(403);
 606
 607     $patron->flags(1)->store; # circulate permissions
 608
 609     $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/checkouts")
 610       ->status_is(200)
 611       ->json_is( '' => [], 'No checkouts on the biblio' );
 612
 613     my $item_1 = $builder->build_sample_item({ biblionumber => $biblio->biblionumber });
 614     my $item_2 = $builder->build_sample_item({ biblionumber => $biblio->biblionumber });
 615
 616     AddIssue( $patron->unblessed, $item_1->barcode );
 617     AddIssue( $patron->unblessed, $item_2->barcode );
 618
 619     my $ret = $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/checkouts")
 620       ->status_is(200)
 621       ->tx->res->json;
 622
 623     my $checkout_1 = Koha::Checkouts->find({ itemnumber => $item_1->id });
 624     my $checkout_2 = Koha::Checkouts->find({ itemnumber => $item_2->id });
 625
 626     is_deeply( $ret, [ $checkout_1->to_api, $checkout_2->to_api ] );
 627
 628     AddReturn( $item_1->barcode );
 629
 630     $ret = $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/checkouts")
 631       ->status_is(200)
 632       ->tx->res->json;
 633
 634     is_deeply( $ret, [ $checkout_2->to_api ] );
 635
 636     $ret = $t->get_ok( "//$userid:$password@/api/v1/biblios/" . $biblio->biblionumber . "/checkouts?checked_in=1")
 637       ->status_is(200)
 638       ->tx->res->json;
 639
 640     my $old_checkout_1 = Koha::Old::Checkouts->find( $checkout_1->id );
 641
 642     is_deeply( $ret, [ $old_checkout_1->to_api ] );
 643
 644     $schema->storage->txn_rollback;
 645 };